cgit.sxemacs.org Git - packages/blob - xemacs-packages/edit-utils/saveplace.el

   1 ;;; saveplace.el --- automatically save place in files
   2
   3 ;; Copyright (C) 1993, 1994, 2001 Free Software Foundation, Inc.
   4
   5 ;; Author: Karl Fogel <kfogel@red-bean.com>
   6 ;; Maintainer: FSF
   7 ;; Created: July, 1993
   8 ;; Keywords: bookmarks, placeholders
   9
  10 ;; This file is part of XEmacs.
  11
  12 ;; XEmacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; XEmacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with XEmacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Synched up with: Emacs 21.2
  28
  29 ;;; Commentary:
  30
  31 ;; Automatically save place in files, so that visiting them later
  32 ;; (even during a different Emacs session) automatically moves point
  33 ;; to the saved position, when the file is first found.  Uses the
  34 ;; value of buffer-local variable save-place to determine whether to
  35 ;; save position or not.
  36 ;;
  37 ;; Thanks to Stefan Schoef, who sent a patch with the
  38 ;; `save-place-version-control' stuff in it.
  39
  40 ;;; Code:
  41
  42 ;; this is what I was using during testing:
  43 ;; (define-key ctl-x-map "p" 'toggle-save-place)
  44
  45 (defgroup save-place nil
  46   "Automatically save place in files."
  47   :group 'data)
  48
  49
  50 (defvar save-place-alist nil
  51   "Alist of saved places to go back to when revisiting files.
  52 Each element looks like (FILENAME . POSITION);
  53 visiting file FILENAME goes automatically to position POSITION
  54 rather than the beginning of the buffer.
  55 This alist is saved between Emacs sessions.")
  56
  57 (defcustom save-place nil
  58   "*Non-nil means automatically save place in each file.
  59 This means when you visit a file, point goes to the last place
  60 where it was when you previously visited the same file.
  61 This variable is automatically buffer-local.
  62
  63 If you wish your place in any file to always be automatically saved,
  64 simply put this in your `~/.emacs' file:
  65
  66 \(setq-default save-place t\)"
  67   :type 'boolean
  68   :require 'saveplace
  69   :group 'save-place)
  70
  71 (make-variable-buffer-local 'save-place)
  72
  73 (defcustom save-place-file (convert-standard-filename "~/.emacs-places")
  74   "*Name of the file that records `save-place-alist' value."
  75   :type 'file
  76   :group 'save-place)
  77
  78 (defcustom save-place-version-control nil
  79   "*Controls whether to make numbered backups of master save-place file.
  80 It can have four values: t, nil, `never', and `nospecial'.  The first
  81 three have the same meaning that they do for the variable
  82 `version-control', and the final value `nospecial' means just use the
  83 value of `version-control'."
  84   :type '(radio (const :tag "Unconditionally" t)
  85                 (const :tag "For VC Files" nil)
  86                 (const never)
  87                 (const :tag "Use value of `version-control'" nospecial))
  88   :group 'save-place)
  89
  90 (defvar save-place-loaded nil
  91   "Non-nil means that the `save-place-file' has been loaded.")
  92
  93 (defcustom save-place-limit nil
  94   "Maximum number of entries to retain in the list; nil means no limit."
  95   :type '(choice (integer :tag "Entries" :value 1)
  96                  (const :tag "No Limit" nil))
  97   :group 'save-place)
  98
  99 (defun toggle-save-place (&optional parg)
 100   "Toggle whether to save your place in this file between sessions.
 101 If this mode is enabled, point is recorded when you kill the buffer
 102 or exit Emacs.  Visiting this file again will go to that position,
 103 even in a later Emacs session.
 104
 105 If called with a prefix arg, the mode is enabled if and only if
 106 the argument is positive.
 107
 108 To save places automatically in all files, put this in your `.emacs' file:
 109
 110 \(setq-default save-place t\)"
 111   (interactive "P")
 112   (if (not buffer-file-name)
 113       (message "Buffer `%s' not visiting a file" (buffer-name))
 114     (if (and save-place (or (not parg) (<= parg 0)))
 115         (progn
 116           (message "No place will be saved in this file")
 117           (setq save-place nil))
 118       (message "Place will be saved")
 119       (setq save-place t))))
 120
 121 (defun save-place-to-alist ()
 122   ;; put filename and point in a cons box and then cons that onto the
 123   ;; front of the save-place-alist, if save-place is non-nil.
 124   ;; Otherwise, just delete that file from the alist.
 125   ;; first check to make sure alist has been loaded in from the master
 126   ;; file.  If not, do so, then feel free to modify the alist.  It
 127   ;; will be saved again when Emacs is killed.
 128   (or save-place-loaded (load-save-place-alist-from-file))
 129   (if buffer-file-name
 130       (progn
 131         (let ((cell (assoc buffer-file-name save-place-alist))
 132               (position (if (not (eq major-mode 'hexl-mode))
 133                             (point)
 134                           (1+ (hexl-current-address)))))
 135           (if cell
 136               (setq save-place-alist (delq cell save-place-alist)))
 137           (if (and save-place
 138                    (not (= position 1)))  ;; Optimize out the degenerate case.
 139             (setq save-place-alist
 140                     (cons (cons buffer-file-name position)
 141                           save-place-alist)))))))
 142
 143 (defun save-place-alist-to-file ()
 144   (let ((file (expand-file-name save-place-file)))
 145     (save-excursion
 146       (message "Saving places to %s..." file)
 147       (set-buffer (get-buffer-create " *Saved Places*"))
 148       (delete-region (point-min) (point-max))
 149       (print save-place-alist (current-buffer))
 150       (let ((version-control
 151              (cond
 152               ((null save-place-version-control) nil)
 153               ((eq 'never save-place-version-control) 'never)
 154               ((eq 'nospecial save-place-version-control) version-control)
 155               (t
 156                t))))
 157         (write-file file)
 158         (kill-buffer (current-buffer))
 159         (message "Saving places to %s...done" file)))))
 160
 161 (defun load-save-place-alist-from-file ()
 162   (if (not save-place-loaded)
 163       (progn
 164         (setq save-place-loaded t)
 165         (let ((file (expand-file-name save-place-file)))
 166           ;; make sure that the alist does not get overwritten, and then
 167           ;; load it if it exists:
 168           (if (file-readable-p file)
 169               (save-excursion
 170                 (message "Loading places from %s..." save-place-file)
 171                 ;; don't want to use find-file because we have been
 172                 ;; adding hooks to it.
 173                 (set-buffer (get-buffer-create " *Saved Places*"))
 174                 (delete-region (point-min) (point-max))
 175                 (insert-file-contents file)
 176                 (goto-char (point-min))
 177                 (setq save-place-alist
 178                       (car (read-from-string
 179                             (buffer-substring (point-min) (point-max)))))
 180
 181                 ;; If there is a limit, and we're over it, then we'll
 182                 ;; have to truncate the end of the list:
 183                 (if save-place-limit
 184                     (if (<= save-place-limit 0)
 185                         ;; Zero gets special cased.  I'm not thrilled
 186                         ;; with this, but the loop for >= 1 is tight.
 187                         (setq save-place-alist nil)
 188                       ;; Else the limit is >= 1, so enforce it by
 189                       ;; counting and then `setcdr'ing.
 190                       (let ((s save-place-alist)
 191                             (count 1))
 192                         (while s
 193                           (if (>= count save-place-limit)
 194                               (setcdr s nil)
 195                             (setq count (1+ count)))
 196                           (setq s (cdr s))))))
 197
 198                 (kill-buffer (current-buffer))
 199                 (message "Loading places from %s...done" file)))
 200           nil))))
 201
 202 (defun save-places-to-alist ()
 203   ;; go through buffer-list, saving places to alist if save-place is
 204   ;; non-nil, deleting them from alist if it is nil.
 205   (let ((buf-list (buffer-list)))
 206     (while buf-list
 207       ;; put this into a save-excursion in case someone is counting on
 208       ;; another function in kill-emacs-hook to act on the last buffer
 209       ;; they were in:
 210       (save-excursion
 211         (set-buffer (car buf-list))
 212         ;; save-place checks buffer-file-name too, but we can avoid
 213         ;; overhead of function call by checking here too.
 214         (and buffer-file-name (save-place-to-alist))
 215         (setq buf-list (cdr buf-list))))))
 216
 217 (defun save-place-find-file-hook ()
 218   (or save-place-loaded (load-save-place-alist-from-file))
 219   (let ((cell (assoc buffer-file-name save-place-alist)))
 220     (if cell
 221         (progn
 222           (or after-find-file-from-revert-buffer
 223               (goto-char (cdr cell)))
 224           ;; and make sure it will be saved again for later
 225           (setq save-place t)))))
 226
 227 (defun save-place-kill-emacs-hook ()
 228   ;; First update the alist.  This loads the old save-place-file if nec.
 229   (save-places-to-alist)
 230   ;; Now save the alist in the file, if we have ever loaded the file
 231   ;; (including just now).
 232   (if save-place-loaded
 233       (save-place-alist-to-file)))
 234
 235 (add-hook 'find-file-hooks 'save-place-find-file-hook t)
 236
 237 (add-hook 'kill-emacs-hook 'save-place-kill-emacs-hook)
 238
 239 (add-hook 'kill-buffer-hook 'save-place-to-alist)
 240
 241 (provide 'saveplace) ; why not...
 242
 243 ;;; saveplace.el ends here