cgit.sxemacs.org Git - packages/blob - xemacs-packages/edit-utils/autorevert.el

   1 ;;; autorevert.el --- revert buffers when files on disk change
   2
   3 ;; Copyright (C) 1997, 1998, 1999, 2001 Free Software Foundation, Inc.
   4
   5 ;; Author: Anders Lindgren <andersl@andersl.com>
   6 ;; Keywords: convenience
   7 ;; Created: 1997-06-01
   8 ;; Date: 1999-11-30
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Introduction:
  30 ;;
  31 ;; Whenever a file that Emacs is editing has been changed by another
  32 ;; program the user normally has to execute the command `revert-buffer'
  33 ;; to load the new content of the file into Emacs.
  34 ;;
  35 ;; This package contains two minor modes: Global Auto-Revert Mode and
  36 ;; Auto-Revert Mode.  Both modes automatically revert buffers
  37 ;; whenever the corresponding files have been changed on disk.
  38 ;;
  39 ;; Auto-Revert Mode can be activated for individual buffers.
  40 ;; Global Auto-Revert Mode applies to all file buffers.
  41 ;;
  42 ;; Both modes operate by checking the time stamp of all files at
  43 ;; intervals of `auto-revert-interval'.  The default is every five
  44 ;; seconds.  The check is aborted whenever the user actually uses
  45 ;; Emacs.  You should never even notice that this package is active
  46 ;; (except that your buffers will be reverted, of course).
  47
  48 ;; Usage:
  49 ;;
  50 ;; Go to the appropriate buffer and press:
  51 ;;   M-x auto-revert-mode RET
  52 ;;
  53 ;; To activate Global Auto-Revert Mode, press:
  54 ;;   M-x global-auto-revert-mode RET
  55 ;;
  56 ;; To activate Global Auto-Revert Mode every time Emacs is started
  57 ;; customise the option `global-auto-revert-mode' or the following
  58 ;; line could be added to your ~/.emacs:
  59 ;;   (global-auto-revert-mode 1)
  60 ;;
  61 ;; The function `turn-on-auto-revert-mode' could be added to any major
  62 ;; mode hook to activate Auto-Revert Mode for all buffers in that
  63 ;; mode.  For example, the following line will activate Auto-Revert
  64 ;; Mode in all C mode buffers:
  65 ;;
  66 ;; (add-hook 'c-mode-hook 'turn-on-auto-revert-mode)
  67
  68 ;;; Code:
  69
  70 ;; Dependencies:
  71
  72 (require 'timer)
  73 (eval-when-compile (require 'cl))
  74
  75
  76 ;; Custom Group:
  77 ;;
  78 ;; The two modes will be placed next to Auto Save Mode under the
  79 ;; Files group under Emacs.
  80
  81 (defgroup auto-revert nil
  82   "Revert individual buffers when files on disk change.
  83
  84 Auto-Revert Mode can be activated for individual buffer.
  85 Global Auto-Revert Mode applies to all buffers."
  86   :group 'files)
  87
  88
  89 ;; Variables:
  90
  91 ;; Autoload for the benefit of `make-mode-line-mouse-sensitive'.
  92 ;;;###autoload
  93 (defvar auto-revert-mode nil
  94   "*Non-nil when Auto-Revert Mode is active.
  95
  96 Never set this variable directly, use the command `auto-revert-mode'
  97 instead.")
  98
  99 ;;;###autoload
 100 (defcustom global-auto-revert-mode nil
 101   "When on, buffers are automatically reverted when files on disk change.
 102
 103 Set this variable using \\[customize] only.  Otherwise, use the
 104 command `global-auto-revert-mode'."
 105   :group 'auto-revert
 106   :initialize 'custom-initialize-default
 107   :set '(lambda (symbol value)
 108           (global-auto-revert-mode (or value 0)))
 109   :type 'boolean
 110   :require 'autorevert)
 111
 112 (defcustom auto-revert-interval 5
 113   "Time, in seconds, between Auto-Revert Mode file checks."
 114   :group 'auto-revert
 115   :type 'integer)
 116
 117 (defcustom auto-revert-stop-on-user-input t
 118   "When non-nil Auto-Revert Mode stops checking files on user input."
 119   :group 'auto-revert
 120   :type 'boolean)
 121
 122 (defcustom auto-revert-verbose t
 123   "When nil, Auto-Revert Mode will not generate any messages.
 124
 125 Currently, messages are generated when the mode is activated or
 126 deactivated, and whenever a file is reverted."
 127   :group 'auto-revert
 128   :type 'boolean)
 129
 130 (defcustom auto-revert-mode-text " ARev"
 131   "String to display in the mode line when Auto-Revert Mode is active.
 132
 133 \(When the string is not empty, make sure that it has a leading space.)"
 134   :tag "Auto Revert Mode Text"          ; To separate it from `global-...'
 135   :group 'auto-revert
 136   :type 'string)
 137
 138 (defcustom auto-revert-mode-hook nil
 139   "Functions to run when Auto-Revert Mode is activated."
 140   :tag "Auto Revert Mode Hook"          ; To separate it from `global-...'
 141   :group 'auto-revert
 142   :type 'hook)
 143
 144 (defcustom global-auto-revert-mode-text ""
 145   "String to display when Global Auto-Revert Mode is active.
 146
 147 The default is nothing since when this mode is active this text doesn't
 148 vary over time, or between buffers.  Hence mode line text
 149 would only waste precious space."
 150   :group 'auto-revert
 151   :type 'string)
 152
 153 (defcustom global-auto-revert-mode-hook nil
 154   "Hook called when Global Auto-Revert Mode is activated."
 155   :group 'auto-revert
 156   :type 'hook)
 157
 158 (defcustom global-auto-revert-non-file-buffers nil
 159   "*When nil only file buffers are reverted by Global Auto-Revert Mode.
 160
 161 When non-nil, both file buffers and buffers with a custom
 162 `revert-buffer-function' are reverted by Global Auto-Revert Mode."
 163   :group 'auto-revert
 164   :type 'boolean)
 165
 166 (defcustom global-auto-revert-ignore-modes '(Info-mode)
 167   "List of major modes Global Auto-Revert Mode should not check."
 168   :group 'auto-revert
 169   :type '(repeat sexp))
 170
 171 (defcustom auto-revert-load-hook nil
 172   "Functions to run when Auto-Revert Mode is first loaded."
 173   :tag "Load Hook"
 174   :group 'auto-revert
 175   :type 'hook)
 176
 177 (defvar global-auto-revert-ignore-buffer nil
 178   "*When non-nil, Global Auto-Revert Mode will not revert this buffer.
 179
 180 This variable becomes buffer local when set in any fashion.")
 181 (make-variable-buffer-local 'global-auto-revert-ignore-buffer)
 182
 183
 184 ;; Internal variables:
 185
 186 (defvar auto-revert-buffer-list '()
 187   "List of buffers in Auto-Revert Mode.
 188
 189 Note that only Auto-Revert Mode, never Global Auto-Revert Mode, adds
 190 buffers to this list.
 191
 192 The timer function `auto-revert-buffers' is responsible for purging
 193 the list of old buffers.")
 194
 195 (defvar auto-revert-timer nil
 196   "Timer used by Auto-Revert Mode.")
 197
 198 (defvar auto-revert-remaining-buffers '()
 199   "Buffers not checked when user input stopped execution.")
 200
 201
 202 ;; Functions:
 203
 204 ;;;###autoload
 205 (defun auto-revert-mode (&optional arg)
 206   "Toggle reverting buffer when file on disk changes.
 207
 208 With arg, turn Auto Revert mode on if and only if arg is positive.
 209 This is a minor mode that affects only the current buffer.
 210 Use `global-auto-revert-mode' to automatically revert all buffers."
 211   (interactive "P")
 212   (make-local-variable 'auto-revert-mode)
 213   (put 'auto-revert-mode 'permanent-local t)
 214   (setq auto-revert-mode
 215         (if (null arg)
 216             (not auto-revert-mode)
 217           (> (prefix-numeric-value arg) 0)))
 218   (if (and auto-revert-verbose
 219            (interactive-p))
 220       (message "Auto-Revert Mode is now %s."
 221                (if auto-revert-mode "on" "off")))
 222   (if auto-revert-mode
 223       (if (not (memq (current-buffer) auto-revert-buffer-list))
 224           (push (current-buffer) auto-revert-buffer-list))
 225     (setq auto-revert-buffer-list
 226           (delq (current-buffer) auto-revert-buffer-list)))
 227   (auto-revert-set-timer)
 228   (when auto-revert-mode
 229     (auto-revert-buffers)
 230     (run-hooks 'auto-revert-mode-hook))
 231   auto-revert-mode)
 232
 233
 234 ;;;###autoload
 235 (defun turn-on-auto-revert-mode ()
 236   "Turn on Auto-Revert Mode.
 237
 238 This function is designed to be added to hooks, for example:
 239   (add-hook 'c-mode-hook 'turn-on-auto-revert-mode)"
 240   (auto-revert-mode 1))
 241
 242
 243 ;;;###autoload
 244 (defun global-auto-revert-mode (&optional arg)
 245   "Revert any buffer when file on disk change.
 246
 247 With arg, turn Auto Revert mode on globally if and only if arg is positive.
 248 This is a minor mode that affects all buffers.
 249 Use `auto-revert-mode' to revert a particular buffer."
 250   (interactive "P")
 251   (setq global-auto-revert-mode
 252         (if (null arg)
 253             (not global-auto-revert-mode)
 254           (> (prefix-numeric-value arg) 0)))
 255   (if (and auto-revert-verbose
 256            (interactive-p))
 257       (message "Global Auto-Revert Mode is now %s."
 258                (if global-auto-revert-mode "on" "off")))
 259   (auto-revert-set-timer)
 260   (when global-auto-revert-mode
 261     (auto-revert-buffers)
 262     (run-hooks 'global-auto-revert-mode-hook)))
 263
 264
 265 (defun auto-revert-set-timer ()
 266   "Restart or cancel the timer."
 267   (if (timerp auto-revert-timer)
 268       (cancel-timer auto-revert-timer))
 269   (if (or global-auto-revert-mode auto-revert-buffer-list)
 270       (setq auto-revert-timer (run-with-timer auto-revert-interval
 271                                               auto-revert-interval
 272                                               'auto-revert-buffers))
 273     (setq auto-revert-timer nil)))
 274
 275
 276 (defun auto-revert-buffers ()
 277   "Revert buffers as specified by Auto-Revert and Global Auto-Revert Mode.
 278
 279 Should `global-auto-revert-mode' be active all file buffers are checked.
 280
 281 Should `auto-revert-mode' be active in some buffers, those buffers
 282 are checked.
 283
 284 Non-file buffers that have a custom `revert-buffer-function' are
 285 reverted either when Auto-Revert Mode is active in that buffer, or
 286 when the variable `global-auto-revert-non-file-buffers' is non-nil
 287 and Global Auto-Revert Mode is active.
 288
 289 This function stops whenever there is user input.  The buffers not
 290 checked are stored in the variable `auto-revert-remaining-buffers'.
 291
 292 To avoid starvation, the buffers in `auto-revert-remaining-buffers'
 293 are checked first the next time this function is called.
 294
 295 This function is also responsible for removing buffers no longer in
 296 Auto-Revert mode from `auto-revert-buffer-list', and for canceling
 297 the timer when no buffers need to be checked."
 298   (let ((bufs (if global-auto-revert-mode
 299                   (buffer-list)
 300                 auto-revert-buffer-list))
 301         (remaining '())
 302         (new '()))
 303     ;; Partition `bufs' into two halves depending on whether or not
 304     ;; the buffers are in `auto-revert-remaining-buffers'.  The two
 305     ;; halves are then re-joined with the "remaining" buffers at the
 306     ;; head of the list.
 307     (dolist (buf auto-revert-remaining-buffers)
 308       (if (memq buf bufs)
 309           (push buf remaining)))
 310     (dolist (buf bufs)
 311       (if (not (memq buf remaining))
 312           (push buf new)))
 313     (setq bufs (nreverse (nconc new remaining)))
 314     (while (and bufs
 315                 (not (and auto-revert-stop-on-user-input
 316                           (input-pending-p))))
 317       (let ((buf (car bufs)))
 318         (if (buffer-name buf)           ; Buffer still alive?
 319             (save-excursion
 320               (set-buffer buf)
 321               ;; Test if someone has turned off Auto-Revert Mode in a
 322               ;; non-standard way, for example by changing major mode.
 323               (if (and (not auto-revert-mode)
 324                        (memq buf auto-revert-buffer-list))
 325                   (setq auto-revert-buffer-list
 326                         (delq buf auto-revert-buffer-list)))
 327               (when (and
 328                      (or auto-revert-mode
 329                          (and
 330                           global-auto-revert-mode
 331                           (not global-auto-revert-ignore-buffer)
 332                           (not (memq major-mode
 333                                      global-auto-revert-ignore-modes))))
 334                      (not (buffer-modified-p))
 335                      (if (buffer-file-name)
 336                          (and (file-readable-p (buffer-file-name))
 337                               (not (verify-visited-file-modtime buf)))
 338                        (and revert-buffer-function
 339                             (or (and global-auto-revert-mode
 340                                      global-auto-revert-non-file-buffers)
 341                                 auto-revert-mode))))
 342                 (if auto-revert-verbose
 343                     (message "Reverting buffer `%s'." buf))
 344                 (revert-buffer t t t)))
 345           ;; Remove dead buffer from `auto-revert-buffer-list'.
 346           (setq auto-revert-buffer-list
 347                 (delq buf auto-revert-buffer-list))))
 348       (setq bufs (cdr bufs)))
 349     (setq auto-revert-remaining-buffers bufs)
 350     ;; Check if we should cancel the timer.
 351     (when (and (not global-auto-revert-mode)
 352                (null auto-revert-buffer-list))
 353       (cancel-timer auto-revert-timer)
 354       (setq auto-revert-timer nil))))
 355
 356
 357 ;; The end:
 358
 359 (unless (assq 'auto-revert-mode minor-mode-alist)
 360   (push '(auto-revert-mode auto-revert-mode-text)
 361         minor-mode-alist))
 362 (unless (assq 'global-auto-revert-mode minor-mode-alist)
 363   (push '(global-auto-revert-mode global-auto-revert-mode-text)
 364         minor-mode-alist))
 365
 366 (provide 'autorevert)
 367
 368 (run-hooks 'auto-revert-load-hook)
 369
 370 ;; This makes it possible to set Global Auto-Revert Mode from
 371 ;; Customize.
 372 (if global-auto-revert-mode
 373     (global-auto-revert-mode 1))
 374
 375 ;;; autorevert.el ends here