cgit.sxemacs.org Git - packages/blob - xemacs-packages/cc-mode/cc-compat.el

   1 ;;; cc-compat.el --- cc-mode compatibility with c-mode.el confusion
   2
   3 ;; Copyright (C) 1985, 1987, 1992, 1993, 1994, 1995, 1996, 1997, 1998,
   4 ;;   1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009,
   5 ;;   2010, 2011, 2012, 2013   Free Software Foundation, Inc.
   6
   7 ;; Authors:    1998- Martin Stjernholm
   8 ;;             1994-1999 Barry A. Warsaw
   9 ;; Maintainer: bug-cc-mode@gnu.org
  10 ;; Created:    August 1994, split from cc-mode.el
  11 ;; Version:    See cc-mode.el
  12 ;; Keywords:   c languages oop
  13
  14 ;; This file is part of GNU Emacs.
  15
  16 ;; GNU Emacs is free software; you can redistribute it and/or modify
  17 ;; it under the terms of the GNU General Public License as published by
  18 ;; the Free Software Foundation; either version 3, or (at your option)
  19 ;; any later version.
  20
  21 ;; GNU Emacs is distributed in the hope that it will be useful,
  22 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 ;; GNU General Public License for more details.
  25
  26 ;; You should have received a copy of the GNU General Public License
  27 ;; along with this program; see the file COPYING.  If not, see
  28 ;; <http://www.gnu.org/licenses/>.
  29
  30 ;;; Commentary:
  31 ;;
  32 ;; Boring old c-mode.el (BOCM) is confusion and brain melt. cc-mode.el
  33 ;; is clarity of thought and purity of chi. If you are still unwilling
  34 ;; to accept enlightenment, this might help, or it may prolong your
  35 ;; agony.
  36 ;;
  37 ;; To use, add the following to your c-mode-hook:
  38 ;;
  39 ;; (require 'cc-compat)
  40 ;; (c-set-style "BOCM")
  41 ;;
  42 ;; This file is completely unsupported!  Although it has been patched
  43 ;; superficially to keep pace with the rest of CC Mode, it hasn't been
  44 ;; tested for a long time.
  45
  46 ;;; Code:
  47
  48 (eval-when-compile
  49   (let ((load-path
  50          (if (and (boundp 'byte-compile-dest-file)
  51                   (stringp byte-compile-dest-file))
  52              (cons (file-name-directory byte-compile-dest-file) load-path)
  53            load-path)))
  54     (load "cc-bytecomp" nil t)))
  55
  56 (cc-require 'cc-defs)
  57 (cc-require 'cc-vars)
  58 (cc-require 'cc-styles)
  59 (cc-require 'cc-engine)
  60
  61 \f
  62 ;; In case c-mode.el isn't loaded
  63 (defvar c-indent-level 2
  64   "*Indentation of C statements with respect to containing block.")
  65 (defvar c-brace-imaginary-offset 0
  66   "*Imagined indentation of a C open brace that actually follows a statement.")
  67 (defvar c-brace-offset 0
  68   "*Extra indentation for braces, compared with other text in same context.")
  69 (defvar c-argdecl-indent 5
  70   "*Indentation level of declarations of C function arguments.")
  71 (defvar c-label-offset -2
  72   "*Offset of C label lines and case statements relative to usual indentation.")
  73 (defvar c-continued-statement-offset 2
  74   "*Extra indent for lines not starting new statements.")
  75 (defvar c-continued-brace-offset 0
  76   "*Extra indent for substatements that start with open-braces.
  77 This is in addition to c-continued-statement-offset.")
  78
  79
  80 \f
  81 ;; these offsets are taken by brute force testing c-mode.el, since
  82 ;; there's no logic to what it does.
  83 (let* ((offsets '(c-offsets-alist .
  84                     ((defun-block-intro     . cc-block-intro-offset)
  85                      (statement-block-intro . cc-block-intro-offset)
  86                      (defun-open            . 0)
  87                      (class-open            . 0)
  88                      (inline-open           . c-brace-offset)
  89                      (block-open            . c-brace-offset)
  90                      (block-close           . cc-block-close-offset)
  91                      (brace-list-open       . c-brace-offset)
  92                      (substatement-open     . cc-substatement-open-offset)
  93                      (substatement          . c-continued-statement-offset)
  94                      (knr-argdecl-intro     . c-argdecl-indent)
  95                      (case-label            . c-label-offset)
  96                      (access-label          . c-label-offset)
  97                      (label                 . c-label-offset)
  98                      ))))
  99   (c-add-style "BOCM" offsets))
 100
 101
 102 (defun cc-block-intro-offset (langelem)
 103   ;; taken directly from calculate-c-indent confusion
 104   (save-excursion
 105     (c-backward-syntactic-ws)
 106     (if (eq (char-before) ?{)
 107         (forward-char -1)
 108       (goto-char (cdr langelem)))
 109     (let* ((curcol (save-excursion
 110                      (goto-char (cdr langelem))
 111                      (current-column)))
 112           (bocm-lossage
 113            ;; If no previous statement, indent it relative to line
 114            ;; brace is on.  For open brace in column zero, don't let
 115            ;; statement start there too.  If c-indent-level is zero,
 116            ;; use c-brace-offset + c-continued-statement-offset
 117            ;; instead.  For open-braces not the first thing in a line,
 118            ;; add in c-brace-imaginary-offset.
 119            (+ (if (and (bolp) (zerop c-indent-level))
 120                   (+ c-brace-offset c-continued-statement-offset)
 121                 c-indent-level)
 122               ;; Move back over whitespace before the openbrace.  If
 123               ;; openbrace is not first nonwhite thing on the line,
 124               ;; add the c-brace-imaginary-offset.
 125               (progn (skip-chars-backward " \t")
 126                      (if (bolp) 0 c-brace-imaginary-offset))
 127               ;; If the openbrace is preceded by a parenthesized exp,
 128               ;; move to the beginning of that; possibly a different
 129               ;; line
 130               (progn
 131                 (if (eq (char-before) ?\))
 132                     (c-forward-sexp -1))
 133                 ;; Get initial indentation of the line we are on.
 134                 (current-indentation)))))
 135       (- bocm-lossage curcol))))
 136
 137
 138 (defun cc-block-close-offset (langelem)
 139   (save-excursion
 140     (let* ((here (point))
 141            bracep
 142            (curcol (progn
 143                      (goto-char (cdr langelem))
 144                      (current-column)))
 145            (bocm-lossage (progn
 146                            (goto-char (cdr langelem))
 147                            (if (eq (char-after) ?{)
 148                                (setq bracep t)
 149                              (goto-char here)
 150                              (beginning-of-line)
 151                              (backward-up-list 1)
 152                              (forward-char 1)
 153                              (c-forward-syntactic-ws))
 154                            (current-column))))
 155       (- bocm-lossage curcol
 156          (if bracep 0 c-indent-level)))))
 157
 158
 159 (defun cc-substatement-open-offset (langelem)
 160   (+ c-continued-statement-offset c-continued-brace-offset))
 161
 162 \f
 163 (cc-provide 'cc-compat)
 164
 165 ;;; arch-tag: 564dab2f-e6ad-499c-a4a3-fedec3ecc192
 166 ;;; cc-compat.el ends here