cgit.sxemacs.org Git - packages/blob - xemacs-packages/calendar/lunar.el

   1 ;;; lunar.el --- calendar functions for phases of the moon
   2
   3 ;; Copyright (C) 1992, 1993, 1995, 1997, 2001, 2002, 2003, 2004, 2005,
   4 ;;   2006, 2007  Free Software Foundation, Inc.
   5
   6 ;; Author: Edward M. Reingold <reingold@cs.uiuc.edu>
   7 ;; Maintainer: Glenn Morris <rgm@gnu.org>
   8 ;; Keywords: calendar
   9 ;; Human-Keywords: moon, lunar phases, calendar, diary
  10
  11 ;; This file is part of XEmacs.
  12
  13 ;; XEmacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; XEmacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with XEmacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  26 ;; Boston, MA 02110-1301, USA.
  27
  28 ;;; Synched up with: FSF Emacs 22 CVS 2007-03-30
  29
  30 ;;; Commentary:
  31
  32 ;; This collection of functions implements lunar phases for calendar.el and
  33 ;; diary.el.
  34
  35 ;; Based on ``Astronomical Formulae for Calculators,'' 3rd ed., by Jean Meeus,
  36 ;; Willmann-Bell, Inc., 1985 and ``Astronomical Algorithms'' by Jean Meeus,
  37 ;; Willmann-Bell, Inc., 1991.
  38 ;;
  39 ;; WARNING: The calculations will be accurate only to within a few minutes.
  40
  41 ;; The author would be delighted to have an astronomically more sophisticated
  42 ;; person rewrite the code for the lunar calculations in this file!
  43
  44 ;; Technical details of all the calendrical calculations can be found in
  45 ;; ``Calendrical Calculations: The Millennium Edition'' by Edward M. Reingold
  46 ;; and Nachum Dershowitz, Cambridge University Press (2001).
  47
  48 ;; Comments, corrections, and improvements should be sent to
  49 ;;  Edward M. Reingold               Department of Computer Science
  50 ;;  (217) 333-6733                   University of Illinois at Urbana-Champaign
  51 ;;  reingold@cs.uiuc.edu             1304 West Springfield Avenue
  52 ;;                                   Urbana, Illinois 61801
  53
  54 ;;; Code:
  55
  56 (defvar date)
  57 (defvar displayed-month)
  58 (defvar displayed-year)
  59
  60 (if (fboundp 'atan)
  61     (require 'lisp-float-type)
  62   (error "Lunar calculations impossible since floating point is unavailable"))
  63
  64 (require 'solar)
  65
  66 (defun lunar-phase-list (month year)
  67   "List of lunar phases for three months starting with Gregorian MONTH, YEAR."
  68   (let ((end-month month)
  69         (end-year year)
  70         (start-month month)
  71         (start-year year))
  72     (increment-calendar-month end-month end-year 3)
  73     (increment-calendar-month start-month start-year -1)
  74     (let* ((end-date (list (list end-month 1 end-year)))
  75            (start-date (list (list start-month
  76                                    (calendar-last-day-of-month
  77                                     start-month start-year)
  78                                    start-year)))
  79            (index (* 4
  80                      (truncate
  81                       (* 12.3685
  82                          (+ year
  83                             ( / (calendar-day-number (list month 1 year))
  84                                 366.0)
  85                             -1900)))))
  86            (new-moon (lunar-phase index))
  87            (list))
  88       (while (calendar-date-compare new-moon end-date)
  89         (if (calendar-date-compare start-date new-moon)
  90             (setq list (append list (list new-moon))))
  91         (setq index (1+ index))
  92         (setq new-moon (lunar-phase index)))
  93       list)))
  94
  95 (defun lunar-phase (index)
  96   "Local date and time of lunar phase INDEX.
  97 Integer below INDEX/4 gives the lunation number, counting from Jan 1, 1900;
  98 remainder mod 4 gives the phase: 0 new moon, 1 first quarter, 2 full moon,
  99 3 last quarter."
 100   (let* ((phase (mod index 4))
 101          (index (/ index 4.0))
 102          (time (/ index 1236.85))
 103          (date (+ (calendar-absolute-from-gregorian '(1 0.5 1900))
 104                   0.75933
 105                   (* 29.53058868 index)
 106                   (* 0.0001178 time time)
 107                   (* -0.000000155 time time time)
 108                   (* 0.00033
 109                      (solar-sin-degrees (+ 166.56
 110                                            (* 132.87 time)
 111                                            (* -0.009173 time time))))))
 112          (sun-anomaly (mod
 113                        (+ 359.2242
 114                           (* 29.105356 index)
 115                           (* -0.0000333 time time)
 116                           (* -0.00000347 time time time))
 117                        360.0))
 118          (moon-anomaly (mod
 119                         (+ 306.0253
 120                            (* 385.81691806 index)
 121                            (* 0.0107306 time time)
 122                            (* 0.00001236 time time time))
 123                         360.0))
 124          (moon-lat (mod
 125                     (+ 21.2964
 126                        (* 390.67050646 index)
 127                        (* -0.0016528 time time)
 128                        (* -0.00000239 time time time))
 129                     360.0))
 130          (adjustment
 131           (if (memq phase '(0 2))
 132               (+ (* (- 0.1734 (* 0.000393 time))
 133                     (solar-sin-degrees sun-anomaly))
 134                  (* 0.0021 (solar-sin-degrees (* 2 sun-anomaly)))
 135                  (* -0.4068 (solar-sin-degrees moon-anomaly))
 136                  (* 0.0161 (solar-sin-degrees (* 2 moon-anomaly)))
 137                  (* -0.0004 (solar-sin-degrees (* 3 moon-anomaly)))
 138                  (* 0.0104 (solar-sin-degrees (* 2 moon-lat)))
 139                  (* -0.0051 (solar-sin-degrees (+ sun-anomaly moon-anomaly)))
 140                  (* -0.0074 (solar-sin-degrees (- sun-anomaly moon-anomaly)))
 141                  (* 0.0004 (solar-sin-degrees (+ (* 2 moon-lat) sun-anomaly)))
 142                  (* -0.0004 (solar-sin-degrees (- (* 2 moon-lat) sun-anomaly)))
 143                  (* -0.0006 (solar-sin-degrees
 144                              (+ (* 2 moon-lat) moon-anomaly)))
 145                  (* 0.0010 (solar-sin-degrees (- (* 2 moon-lat) moon-anomaly)))
 146                  (* 0.0005 (solar-sin-degrees
 147                             (+ (* 2 moon-anomaly) sun-anomaly))))
 148             (+ (* (- 0.1721 (* 0.0004 time))
 149                   (solar-sin-degrees sun-anomaly))
 150                (* 0.0021 (solar-sin-degrees (* 2 sun-anomaly)))
 151                (* -0.6280 (solar-sin-degrees moon-anomaly))
 152                (* 0.0089 (solar-sin-degrees (* 2 moon-anomaly)))
 153                (* -0.0004 (solar-sin-degrees (* 3 moon-anomaly)))
 154                (* 0.0079 (solar-sin-degrees (* 2 moon-lat)))
 155                (* -0.0119 (solar-sin-degrees (+ sun-anomaly moon-anomaly)))
 156                (* -0.0047 (solar-sin-degrees (- sun-anomaly moon-anomaly)))
 157                (* 0.0003 (solar-sin-degrees (+ (* 2 moon-lat) sun-anomaly)))
 158                (* -0.0004 (solar-sin-degrees (- (* 2 moon-lat) sun-anomaly)))
 159                (* -0.0006 (solar-sin-degrees (+ (* 2 moon-lat) moon-anomaly)))
 160                (* 0.0021 (solar-sin-degrees (- (* 2 moon-lat) moon-anomaly)))
 161                (* 0.0003 (solar-sin-degrees
 162                           (+ (* 2 moon-anomaly) sun-anomaly)))
 163                (* 0.0004 (solar-sin-degrees
 164                           (- sun-anomaly (* 2 moon-anomaly))))
 165                (* -0.0003 (solar-sin-degrees
 166                           (+ (* 2 sun-anomaly) moon-anomaly))))))
 167          (adj (+ 0.0028
 168                  (* -0.0004 (solar-cosine-degrees
 169                              sun-anomaly))
 170                  (* 0.0003 (solar-cosine-degrees
 171                             moon-anomaly))))
 172          (adjustment (cond ((= phase 1) (+ adjustment adj))
 173                            ((= phase 2) (- adjustment adj))
 174                            (t adjustment)))
 175          (date (+ date adjustment))
 176          (date (+ date (/ (- calendar-time-zone
 177                              (solar-ephemeris-correction
 178                               (extract-calendar-year
 179                                (calendar-gregorian-from-absolute
 180                                 (truncate date)))))
 181                           60.0 24.0)))
 182          (time (* 24 (- date (truncate date))))
 183          (date (calendar-gregorian-from-absolute (truncate date)))
 184          (adj (dst-adjust-time date time)))
 185     (list (car adj) (apply 'solar-time-string (cdr adj)) phase)))
 186
 187 (defun lunar-phase-name (phase)
 188   "Name of lunar PHASE.
 189 0 = new moon, 1 = first quarter, 2 = full moon, 3 = last quarter."
 190   (cond ((= 0 phase) "New Moon")
 191         ((= 1 phase) "First Quarter Moon")
 192         ((= 2 phase) "Full Moon")
 193         ((= 3 phase) "Last Quarter Moon")))
 194
 195 (defun calendar-phases-of-moon ()
 196   "Create a buffer with the lunar phases for the current calendar window."
 197   (interactive)
 198   (message "Computing phases of the moon...")
 199   (let ((m1 displayed-month)
 200         (y1 displayed-year)
 201         (m2 displayed-month)
 202         (y2 displayed-year))
 203     (increment-calendar-month m1 y1 -1)
 204     (increment-calendar-month m2 y2 1)
 205     (set-buffer (get-buffer-create lunar-phases-buffer))
 206     (setq buffer-read-only nil)
 207     (calendar-set-mode-line
 208      (if (= y1 y2)
 209          (format "Phases of the Moon from %s to %s, %d%%-"
 210                  (calendar-month-name m1) (calendar-month-name m2) y2)
 211        (format "Phases of the Moon from %s, %d to %s, %d%%-"
 212                (calendar-month-name m1) y1 (calendar-month-name m2) y2)))
 213     (erase-buffer)
 214     (insert
 215      (mapconcat
 216       '(lambda (x)
 217          (let ((date (car x))
 218                (time (car (cdr x)))
 219                (phase (car (cdr (cdr x)))))
 220            (concat (calendar-date-string date)
 221                    ": "
 222                    (lunar-phase-name phase)
 223                    " "
 224                    time)))
 225       (lunar-phase-list m1 y1) "\n"))
 226     (goto-char (point-min))
 227     (set-buffer-modified-p nil)
 228     (setq buffer-read-only t)
 229     (display-buffer lunar-phases-buffer)
 230     (message "Computing phases of the moon...done")))
 231
 232 ;;;###autoload
 233 (defun phases-of-moon (&optional arg)
 234   "Display the quarters of the moon for last month, this month, and next month.
 235 If called with an optional prefix argument, prompts for month and year.
 236
 237 This function is suitable for execution in a .emacs file."
 238   (interactive "P")
 239   (save-excursion
 240     (let* ((date (if arg
 241                      (calendar-read-date t)
 242                    (calendar-current-date)))
 243            (displayed-month (extract-calendar-month date))
 244            (displayed-year (extract-calendar-year date)))
 245       (calendar-phases-of-moon))))
 246
 247 (defun diary-phases-of-moon (&optional mark)
 248 "Moon phases diary entry.
 249
 250 An optional parameter MARK specifies a face or single-character string to
 251 use when highlighting the day in the calendar."
 252   (let* ((index (* 4
 253                    (truncate
 254                     (* 12.3685
 255                        (+ (extract-calendar-year date)
 256                           ( / (calendar-day-number date)
 257                               366.0)
 258                           -1900)))))
 259          (phase (lunar-phase index)))
 260     (while (calendar-date-compare phase (list date))
 261       (setq index (1+ index))
 262       (setq phase (lunar-phase index)))
 263     (if (calendar-date-equal (car phase) date)
 264         (cons mark (concat (lunar-phase-name (car (cdr (cdr phase)))) " "
 265                 (car (cdr phase)))))))
 266
 267
 268 ;;  For the Chinese calendar the calculations for the new moon need to be more
 269 ;;  accurate than those above, so we use more terms in the approximation.
 270
 271 (defun lunar-new-moon-time (k)
 272   "Astronomical (Julian) day number of K th new moon."
 273   (let* ((T (/ k 1236.85))
 274          (T2 (* T T))
 275          (T3 (* T T T))
 276          (T4 (* T2 T2))
 277          (JDE (+ 2451550.09765
 278                  (* 29.530588853 k)
 279                  (* 0.0001337 T2)
 280                  (* -0.000000150 T3)
 281                  (* 0.00000000073 T4)))
 282          (E (- 1 (* 0.002516 T) (* 0.0000074 T2)))
 283          (sun-anomaly (+ 2.5534
 284                          (* 29.10535669 k)
 285                          (* -0.0000218 T2)
 286                          (* -0.00000011 T3)))
 287          (moon-anomaly (+ 201.5643
 288                           (* 385.81693528 k)
 289                           (* 0.0107438 T2)
 290                           (* 0.00001239 T3)
 291                           (* -0.000000058 T4)))
 292          (moon-argument (+ 160.7108
 293                            (* 390.67050274 k)
 294                            (* -0.0016341 T2)
 295                            (* -0.00000227 T3)
 296                            (* 0.000000011 T4)))
 297          (omega (+ 124.7746
 298                    (* -1.56375580 k)
 299                    (* 0.0020691 T2)
 300                    (* 0.00000215 T3)))
 301          (A1  (+ 299.77 (*  0.107408 k) (* -0.009173 T2)))
 302          (A2  (+ 251.88 (*  0.016321 k)))
 303          (A3  (+ 251.83 (* 26.641886 k)))
 304          (A4  (+ 349.42 (* 36.412478 k)))
 305          (A5  (+  84.66 (* 18.206239 k)))
 306          (A6  (+ 141.74 (* 53.303771 k)))
 307          (A7  (+ 207.14 (*  2.453732 k)))
 308          (A8  (+ 154.84 (*  7.306860 k)))
 309          (A9  (+  34.52 (* 27.261239 k)))
 310          (A10 (+ 207.19 (*  0.121824 k)))
 311          (A11 (+ 291.34 (*  1.844379 k)))
 312          (A12 (+ 161.72 (* 24.198154 k)))
 313          (A13 (+ 239.56 (* 25.513099 k)))
 314          (A14 (+ 331.55 (*  3.592518 k)))
 315          (correction
 316             (+ (* -0.40720   (solar-sin-degrees moon-anomaly))
 317                (*  0.17241 E (solar-sin-degrees sun-anomaly))
 318                (*  0.01608   (solar-sin-degrees (* 2 moon-anomaly)))
 319                (*  0.01039   (solar-sin-degrees (* 2 moon-argument)))
 320                (*  0.00739 E (solar-sin-degrees (- moon-anomaly sun-anomaly)))
 321                (* -0.00514 E (solar-sin-degrees (+ moon-anomaly sun-anomaly)))
 322                (*  0.00208 E E (solar-sin-degrees (* 2 sun-anomaly)))
 323                (* -0.00111   (solar-sin-degrees
 324                                (- moon-anomaly (* 2 moon-argument))))
 325                (* -0.00057   (solar-sin-degrees
 326                                (+ moon-anomaly (* 2 moon-argument))))
 327                (*  0.00056 E (solar-sin-degrees
 328                                (+ (* 2 moon-anomaly) sun-anomaly)))
 329                (* -0.00042   (solar-sin-degrees (* 3 moon-anomaly)))
 330                (*  0.00042 E (solar-sin-degrees
 331                                (+ sun-anomaly (* 2 moon-argument))))
 332                (*  0.00038 E (solar-sin-degrees
 333                                (- sun-anomaly (* 2 moon-argument))))
 334                (* -0.00024 E (solar-sin-degrees
 335                                (- (* 2 moon-anomaly) sun-anomaly)))
 336                (* -0.00017   (solar-sin-degrees omega))
 337                (* -0.00007   (solar-sin-degrees
 338                                (+ moon-anomaly (* 2 sun-anomaly))))
 339                (*  0.00004   (solar-sin-degrees
 340                                (- (* 2 moon-anomaly) (* 2 moon-argument))))
 341                (*  0.00004   (solar-sin-degrees (* 3 sun-anomaly)))
 342                (*  0.00003   (solar-sin-degrees (+ moon-anomaly sun-anomaly
 343                                                    (* -2 moon-argument))))
 344                (*  0.00003   (solar-sin-degrees
 345                                (+ (* 2 moon-anomaly) (* 2 moon-argument))))
 346                (* -0.00003   (solar-sin-degrees (+ moon-anomaly sun-anomaly
 347                                                    (* 2 moon-argument))))
 348                (*  0.00003   (solar-sin-degrees (- moon-anomaly sun-anomaly
 349                                                    (* -2 moon-argument))))
 350                (* -0.00002   (solar-sin-degrees (- moon-anomaly sun-anomaly
 351                                                    (* 2 moon-argument))))
 352                (* -0.00002   (solar-sin-degrees
 353                                (+ (* 3 moon-anomaly) sun-anomaly)))
 354                (*  0.00002   (solar-sin-degrees (* 4 moon-anomaly)))))
 355          (additional
 356             (+ (* 0.000325 (solar-sin-degrees A1))
 357                (* 0.000165 (solar-sin-degrees A2))
 358                (* 0.000164 (solar-sin-degrees A3))
 359                (* 0.000126 (solar-sin-degrees A4))
 360                (* 0.000110 (solar-sin-degrees A5))
 361                (* 0.000062 (solar-sin-degrees A6))
 362                (* 0.000060 (solar-sin-degrees A7))
 363                (* 0.000056 (solar-sin-degrees A8))
 364                (* 0.000047 (solar-sin-degrees A9))
 365                (* 0.000042 (solar-sin-degrees A10))
 366                (* 0.000040 (solar-sin-degrees A11))
 367                (* 0.000037 (solar-sin-degrees A12))
 368                (* 0.000035 (solar-sin-degrees A13))
 369                (* 0.000023 (solar-sin-degrees A14))))
 370          (newJDE (+ JDE correction additional)))
 371     (+ newJDE
 372        (- (solar-ephemeris-correction
 373            (extract-calendar-year
 374             (calendar-gregorian-from-absolute
 375              (floor (calendar-absolute-from-astro newJDE))))))
 376        (/ calendar-time-zone 60.0 24.0))))
 377
 378 (defun lunar-new-moon-on-or-after (d)
 379   "Astronomical (Julian) day number of first new moon on or after astronomical
 380 \(Julian) day number d.  The fractional part is the time of day.
 381
 382 The date and time are local time, including any daylight saving rules,
 383 as governed by the values of calendar-daylight-savings-starts,
 384 calendar-daylight-savings-starts-time, calendar-daylight-savings-ends,
 385 calendar-daylight-savings-ends-time, calendar-daylight-time-offset, and
 386 calendar-time-zone."
 387   (let* ((date (calendar-gregorian-from-absolute
 388                 (floor (calendar-absolute-from-astro d))))
 389          (year (+ (extract-calendar-year date)
 390                   (/ (calendar-day-number date) 365.25)))
 391          (k (floor (* (- year 2000.0) 12.3685)))
 392          (date (lunar-new-moon-time k)))
 393     (while (< date d)
 394       (setq k (1+ k))
 395       (setq date (lunar-new-moon-time k)))
 396     (let* ((a-date (calendar-absolute-from-astro date))
 397            (time (* 24 (- a-date (truncate a-date))))
 398            (date (calendar-gregorian-from-absolute (truncate a-date)))
 399            (adj (dst-adjust-time date time)))
 400       (calendar-astro-from-absolute
 401        (+ (calendar-absolute-from-gregorian (car adj))
 402           (/ (car (cdr adj)) 24.0))))))
 403
 404 (provide 'lunar)
 405
 406 ;;; arch-tag: 72f0b8a4-7bcc-4a1b-b67a-ff53c4a1d222
 407 ;;; lunar.el ends here