cgit.sxemacs.org Git - riece/blob - lisp/test/lunit.el

   1 ;;; lunit.el --- simple testing framework for luna
   2
   3 ;; Copyright (C) 2000 Daiki Ueno.
   4
   5 ;; Author: Daiki Ueno <ueno@unixuser.org>
   6 ;; Keywords: OOP, XP
   7
   8 ;; This file is part of FLIM (Faithful Library about Internet Message).
   9
  10 ;; This program is free software; you can redistribute it and/or
  11 ;; modify it under the terms of the GNU General Public License as
  12 ;; published by the Free Software Foundation; either version 2, or (at
  13 ;; your option) any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful, but
  16 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18 ;; General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This module is inspired by "JUnit A Cook's Tour".
  28 ;; <URL:http://www.junit.org/junit/doc/cookstour/cookstour.htm>
  29
  30 ;; (require 'lunit)
  31 ;;
  32 ;; (luna-define-class silly-test-case (lunit-test-case))
  33 ;;
  34 ;; (luna-define-method test-1 ((case silly-test-case))
  35 ;;   (lunit-assert-2 case (integerp "a")))
  36 ;;
  37 ;; (luna-define-method test-2 ((case silly-test-case))
  38 ;;   (lunit-assert-2 case (stringp "b")))
  39 ;;
  40 ;; (with-output-to-temp-buffer "*Lunit Results*"
  41 ;;   (lunit (lunit-make-test-suite-from-class 'silly-test-case)))
  42 ;; ______________________________________________________________________
  43 ;; Running `silly-test-case#test-1'... failure: (integerp "a")
  44 ;; Running `silly-test-case#test-2'...
  45 ;; 2 runs, 2 assertions, 1 failures, 0 errors
  46
  47 ;;; Code:
  48
  49 (require 'luna)
  50
  51 (eval-when-compile (require 'cl))
  52
  53 ;;; @ test
  54 ;;;
  55
  56 (eval-and-compile
  57   (luna-define-class lunit-test ()
  58                      (name))
  59
  60   (luna-define-internal-accessors 'lunit-test))
  61
  62 (luna-define-generic lunit-test-number-of-tests (test)
  63   "Count the number of test cases that will be run by the test.")
  64
  65 (luna-define-generic lunit-test-run (test result)
  66   "Run the test and collects its result in result.")
  67
  68 (luna-define-generic lunit-test-suite-add-test (suite test)
  69   "Add the test to the suite.")
  70
  71 ;;; @ test listener
  72 ;;;
  73
  74 (luna-define-class lunit-test-listener)
  75
  76 ;;; @ test result
  77 ;;;
  78
  79 (put 'lunit-error 'error-message "test error")
  80 (put 'lunit-error 'error-conditions '(lunit-error error))
  81
  82 (put 'lunit-failure 'error-message "test failure")
  83 (put 'lunit-failure 'error-conditions '(lunit-failure lunit-error error))
  84
  85 (eval-and-compile
  86   (luna-define-class lunit-test-result ()
  87                      (errors
  88                       failures
  89                       listeners
  90                       assert-count))
  91
  92   (luna-define-internal-accessors 'lunit-test-result))
  93
  94 (luna-define-generic lunit-test-result-run (result case)
  95   "Run the test case.")
  96
  97 (luna-define-generic lunit-test-result-notify (result message &rest args)
  98   "Report the current state of execution.")
  99
 100 (luna-define-generic lunit-test-result-add-listener (result listener)
 101   "Add listener to the list of listeners.")
 102
 103 (defun lunit-make-test-result (&rest listeners)
 104   "Return a newly allocated `lunit-test-result' instance with LISTENERS."
 105   (luna-make-entity 'lunit-test-result :listeners listeners :assert-count 0))
 106
 107 (luna-define-method lunit-test-result-notify ((result lunit-test-result)
 108                                               message args)
 109   (let ((listeners
 110          (lunit-test-result-listeners-internal result)))
 111     (dolist (listener listeners)
 112       (apply #'luna-send listener message listener args))))
 113
 114 (luna-define-method lunit-test-result-run ((result lunit-test-result) case)
 115   (lunit-test-result-notify result 'lunit-test-listener-start case)
 116   (condition-case error
 117       (lunit-test-case-run case)
 118     (lunit-failure
 119      (lunit-test-result-set-failures-internal
 120       result
 121       (nconc (lunit-test-result-failures-internal result)
 122              (list (cons case (cdr error)))))
 123      (lunit-test-result-notify
 124       result 'lunit-test-listener-failure case (cdr error)))
 125     (lunit-error
 126      (lunit-test-result-set-errors-internal
 127       result
 128       (nconc (lunit-test-result-errors-internal result)
 129              (list (cons case (cdr error)))))
 130      (lunit-test-result-notify
 131       result 'lunit-test-listener-error case error)))
 132   (lunit-test-result-set-assert-count-internal
 133    result
 134    (+ (lunit-test-result-assert-count-internal result)
 135       (lunit-test-case-assert-count-internal case)))
 136   (lunit-test-result-notify result 'lunit-test-listener-end case))
 137
 138 (luna-define-method lunit-test-result-add-listener ((result lunit-test-result)
 139                                                     listener)
 140   (let ((listeners
 141          (lunit-test-result-listeners-internal result)))
 142     (setq listeners (nconc listeners (list listener)))
 143     (lunit-test-result-set-listeners-internal result listeners)))
 144
 145 ;;; @ test case
 146 ;;;
 147
 148 (eval-and-compile
 149   (luna-define-class lunit-test-case (lunit-test)
 150                      (assert-count))
 151
 152   (luna-define-internal-accessors 'lunit-test-case))
 153
 154 (luna-define-generic lunit-test-case-run (case)
 155   "Run the test case.")
 156
 157 (luna-define-generic lunit-test-case-setup (case)
 158   "Setup the test case.")
 159
 160 (luna-define-generic lunit-test-case-teardown (case)
 161   "Clear the test case.")
 162
 163 (defun lunit-make-test-case (class name)
 164   "Return a newly allocated `lunit-test-case'.
 165 CLASS is a symbol for class derived from `lunit-test-case'.
 166 NAME is name of the method to be tested."
 167   (luna-make-entity class :name name :assert-count 0))
 168
 169 (luna-define-method lunit-test-number-of-tests ((case lunit-test-case))
 170   1)
 171
 172 (luna-define-method lunit-test-run ((case lunit-test-case) result)
 173   (lunit-test-result-run result case))
 174
 175 (luna-define-method lunit-test-case-setup ((case lunit-test-case)))
 176 (luna-define-method lunit-test-case-teardown ((case lunit-test-case)))
 177
 178 (luna-define-method lunit-test-case-run ((case lunit-test-case))
 179   (lunit-test-case-setup case)
 180   (unwind-protect
 181       (let* ((name
 182               (lunit-test-name-internal case))
 183              (functions
 184               (luna-find-functions case name)))
 185         (unless functions
 186           (error "Method \"%S\" not found" name))
 187         (condition-case error
 188             (funcall (car functions) case)
 189           (lunit-failure
 190            (signal (car error)(cdr error)))
 191           (error
 192            (signal 'lunit-error error))))
 193     (lunit-test-case-teardown case)))
 194
 195 ;;; @ test suite
 196 ;;;
 197
 198 (eval-and-compile
 199   (luna-define-class lunit-test-suite (lunit-test)
 200                      (tests))
 201
 202   (luna-define-internal-accessors 'lunit-test-suite))
 203
 204 (defun lunit-make-test-suite (&rest tests)
 205   "Return a newly allocated `lunit-test-suite' instance.
 206 TESTS holds a number of instances of `lunit-test'."
 207   (luna-make-entity 'lunit-test-suite :tests tests))
 208
 209 (luna-define-method lunit-test-suite-add-test ((suite lunit-test-suite) test)
 210   (let ((tests (lunit-test-suite-tests-internal suite)))
 211     (lunit-test-suite-set-tests-internal suite (nconc tests (list test)))))
 212
 213 (luna-define-method lunit-test-number-of-tests ((suite lunit-test-suite))
 214   (let ((tests (lunit-test-suite-tests-internal suite))
 215         (accu 0))
 216     (dolist (test tests)
 217       (setq accu (+ accu (lunit-test-number-of-tests test))))
 218     accu))
 219
 220 (luna-define-method lunit-test-run ((suite lunit-test-suite) result)
 221   (let ((tests (lunit-test-suite-tests-internal suite)))
 222     (dolist (test tests)
 223       (lunit-test-run test result))))
 224
 225 ;;; @ test runner
 226 ;;;
 227
 228 (defmacro lunit-assert (condition-expr)
 229   "Verify that CONDITION-EXPR returns non-nil; signal an error if not."
 230   `(unless ,condition-expr
 231      (signal 'lunit-failure (list ',condition-expr))))
 232
 233 (defmacro lunit-assert-2 (case condition-expr)
 234   "In regard to CASE, verify that CONDITION-EXPR returns non-nil;
 235 signal an error if not."
 236   `(let ((case ,case))
 237      (lunit-test-case-set-assert-count-internal
 238       case
 239       (1+ (lunit-test-case-assert-count-internal case)))
 240      (unless ,condition-expr
 241        (signal 'lunit-failure (list ',condition-expr)))))
 242
 243 (luna-define-class lunit-test-printer (lunit-test-listener))
 244
 245 (luna-define-method lunit-test-listener-error ((printer lunit-test-printer)
 246                                                case error)
 247   (princ (format " error: %S" error)))
 248
 249 (luna-define-method lunit-test-listener-failure ((printer lunit-test-printer)
 250                                                  case failure)
 251   (princ (format " failure: %S" failure)))
 252
 253 (luna-define-method lunit-test-listener-start ((printer lunit-test-printer)
 254                                                case)
 255   (princ (format "Running `%S#%S'..."
 256                  (luna-class-name case)
 257                  (lunit-test-name-internal case))))
 258
 259 (luna-define-method lunit-test-listener-end ((printer lunit-test-printer) case)
 260   (princ "\n"))
 261
 262 (defun lunit-make-test-suite-from-class (class)
 263   "Make a test suite from all test methods of the CLASS."
 264   (let (tests)
 265     (mapatoms
 266      (lambda (symbol)
 267        (if (and (fboundp symbol)
 268                 (string-match "^test" (symbol-name symbol))
 269                 (null (get symbol 'luna-method-qualifier)))
 270            (push (lunit-make-test-case class symbol) tests)))
 271      (luna-class-obarray (luna-find-class class)))
 272     (apply #'lunit-make-test-suite tests)))
 273
 274 (defun lunit (test)
 275   "Run TEST and display the result."
 276   (let* ((printer
 277           (luna-make-entity 'lunit-test-printer))
 278          (result
 279           (lunit-make-test-result printer)))
 280     (lunit-test-run test result)
 281     (let ((assert-count
 282            (lunit-test-result-assert-count-internal result))
 283           (failures
 284            (lunit-test-result-failures-internal result))
 285           (errors
 286            (lunit-test-result-errors-internal result)))
 287       (princ (format "%d runs, %d assertions, %d failures, %d errors\n"
 288                      (lunit-test-number-of-tests test)
 289                      assert-count
 290                      (length failures)
 291                      (length errors))))))
 292
 293 (defvar imenu-create-index-function)
 294 (defun lunit-create-index-function ()
 295   (require 'imenu)
 296   (save-excursion
 297     (unwind-protect
 298         (progn
 299           (goto-char (point-min))
 300           (setq imenu-generic-expression
 301                 '((nil "^\\s-*(def\\(un\\|subst\\|macro\\)\\s-+\\([-A-Za-z0-9+*|:]+\\)" 2)))
 302           (funcall imenu-create-index-function))
 303       (setq imenu-create-index-function lisp-imenu-generic-expression))))
 304
 305 (defun lunit-generate-template (file)
 306   (interactive "fGenerate lunit template for: ")
 307   (save-excursion
 308     (set-buffer (find-file-noselect file))
 309     (let ((index-alist
 310            (lunit-create-index-function)))
 311       (with-output-to-temp-buffer "*Lunit template*"
 312         (let* ((feature
 313                 (file-name-sans-extension
 314                  (file-name-nondirectory file)))
 315                (class
 316                 (concat "test-" feature)))
 317           (set-buffer standard-output)
 318           (insert "\
 319 \(require 'lunit)
 320 \(require '" feature ")
 321
 322 \(luna-define-class " class " (lunit-test-case))
 323
 324 ")
 325           (dolist (index index-alist)
 326             (insert "\
 327 \(luna-define-method " class "-" (car index) " ((case " class "))
 328   (lunit-assert nil))
 329
 330 ")))))))
 331
 332 (provide 'lunit)
 333
 334 ;;; lunit.el ends here