cgit.sxemacs.org Git - riece/blob - lisp/riece.el

   1 ;;; riece.el --- IRC client for Emacsen
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Created: 1998-09-28
   6 ;; Keywords: IRC, riece
   7
   8 ;; This file is part of Riece.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Code:
  26
  27 (if (featurep 'xemacs)
  28     (require 'riece-xemacs)
  29   (require 'riece-emacs))
  30
  31 (require 'riece-filter)
  32 (require 'riece-display)
  33 (require 'riece-server)
  34 (require 'riece-compat)
  35 (require 'riece-commands)
  36
  37 (defvar riece-channel-list-mode-map (make-sparse-keymap))
  38 (defvar riece-user-list-mode-map (make-sparse-keymap))
  39
  40 (defvar riece-dialogue-mode-map
  41   (let ((keymap (make-keymap)))
  42     (suppress-keymap keymap 'nodigit)
  43     keymap))
  44
  45 (defvar riece-command-mode-map (make-keymap))
  46 (defvar riece-command-map (make-sparse-keymap))
  47
  48 (defvar riece-command-mode-syntax-table nil)
  49
  50 (put 'riece-command-mode 'mode-class 'special)
  51 (put 'riece-dialogue-mode 'mode-class 'special)
  52 (put 'riece-channel-list-mode 'mode-class 'special)
  53 (put 'riece-user-list-mode 'mode-class 'special)
  54 (put 'riece-channel-mode 'derived-mode-parent 'riece-dialogue-mode)
  55 (put 'riece-others-mode 'derived-mode-parent 'riece-dialogue-mode)
  56
  57 (defvar riece-buffer-mode-alist
  58   '((riece-dialogue-buffer . riece-dialogue-mode)
  59     (riece-others-buffer . riece-others-mode)
  60     (riece-channel-list-buffer . riece-channel-list-mode)
  61     (riece-private-buffer . riece-dialogue-mode)
  62     (riece-wallops-buffer)))
  63
  64 (defvar riece-select-keys
  65   '("1" riece-command-switch-to-channel-by-number-1
  66     "2" riece-command-switch-to-channel-by-number-2
  67     "3" riece-command-switch-to-channel-by-number-3
  68     "4" riece-command-switch-to-channel-by-number-4
  69     "5" riece-command-switch-to-channel-by-number-5
  70     "6" riece-command-switch-to-channel-by-number-6
  71     "7" riece-command-switch-to-channel-by-number-7
  72     "8" riece-command-switch-to-channel-by-number-8
  73     "9" riece-command-switch-to-channel-by-number-9
  74     "0" riece-command-switch-to-channel-by-number-10
  75     "\C-c1" riece-command-switch-to-channel-by-number-11
  76     "\C-c2" riece-command-switch-to-channel-by-number-12
  77     "\C-c3" riece-command-switch-to-channel-by-number-13
  78     "\C-c4" riece-command-switch-to-channel-by-number-14
  79     "\C-c5" riece-command-switch-to-channel-by-number-15
  80     "\C-c6" riece-command-switch-to-channel-by-number-16
  81     "\C-c7" riece-command-switch-to-channel-by-number-17
  82     "\C-c8" riece-command-switch-to-channel-by-number-18
  83     "\C-c9" riece-command-switch-to-channel-by-number-19
  84     "\C-c0" riece-command-switch-to-channel-by-number-20))
  85
  86 ;;; Keymap macros. -- borrowed from `gnus-util.el'.
  87 (defmacro riece-local-set-keys (&rest plist)
  88   "Set the keys in PLIST in the current keymap."
  89   `(riece-define-keys-1 (current-local-map) ',plist))
  90
  91 (defmacro riece-define-keys (keymap &rest plist)
  92   "Assign KEYMAP keys from PLIST."
  93   `(riece-define-keys-1 ',keymap ',plist))
  94
  95 (defmacro riece-define-keys-safe (keymap &rest plist)
  96   "Assign KEYMAP keys from PLIST without overwriting previous definitions."
  97   `(riece-define-keys-1 ',keymap ',plist t))
  98
  99 (put 'riece-define-keys 'lisp-indent-function 1)
 100 (put 'riece-define-keys-safe 'lisp-indent-function 1)
 101 (put 'riece-local-set-keys 'lisp-indent-function 1)
 102
 103 (defun riece-define-keys-1 (keymap plist &optional safe)
 104   "Assign KEYMAP keys from PLIST.
 105 If optional argument SAFE is nil, overwrite previous definitions."
 106   (unless keymap
 107     (error "Can't set keys in a null keymap"))
 108   (cond
 109    ((symbolp keymap)
 110     (setq keymap (symbol-value keymap)))
 111    ((keymapp keymap))
 112    ((listp keymap)
 113     (set (car keymap) nil)
 114     (define-prefix-command (car keymap))
 115     (define-key (symbol-value (nth 2 keymap)) (nth 1 keymap) (car keymap))
 116     (setq keymap (symbol-value (car keymap)))))
 117   (let (key)
 118     (while plist
 119       (if (symbolp (setq key (car plist)))
 120           (setq key (symbol-value key)))
 121       (setq plist (cdr plist))
 122       (if (or (not safe)
 123               (eq (lookup-key keymap key) 'undefined))
 124           (define-key keymap key (car plist))
 125         (car plist))
 126       (setq plist (cdr plist)))))
 127
 128 (when t
 129   (riece-define-keys riece-dialogue-mode-map
 130     "\177" scroll-down
 131     [delete] scroll-down
 132     [backspace] scroll-down
 133     [return] scroll-up
 134     " " scroll-up
 135     "$" end-of-buffer
 136     "/" riece-command-raw
 137     ">" end-of-buffer
 138     "<" beginning-of-buffer
 139     "\C-ta" riece-command-toggle-away
 140     "c" riece-command-select-command-buffer
 141     "f" riece-command-finger
 142     "\C-tf" riece-command-toggle-freeze
 143     "\C-to" riece-command-toggle-own-freeze
 144     "\C-tu" riece-command-toggle-user-list-buffer-mode
 145     "\C-tc" riece-command-toggle-channel-buffer-mode
 146     "\C-tC" riece-command-toggle-channel-list-buffer-mode
 147     "i" riece-command-invite
 148     "j" riece-command-join
 149     "\C-k" riece-command-kick
 150     "l" riece-command-list
 151     "m" riece-dialogue-enter-message
 152     "M" riece-command-change-mode
 153     "n" riece-command-change-nickname
 154     "\C-n" riece-command-names
 155     "o" other-window
 156     "O" riece-command-open-server
 157     "C" riece-command-close-server
 158     "M" riece-command-universal-server-name-argument
 159     "q" riece-command-quit
 160     "r" riece-command-configure-windows
 161     "x" riece-command-copy-region
 162     "t" riece-command-topic
 163     "w" riece-command-who)
 164
 165   (riece-define-keys riece-command-mode-map
 166     "\r" riece-command-enter-message
 167     [(control return)] riece-command-enter-message-as-notice)
 168
 169   (riece-define-keys (riece-command-map "\C-c" riece-command-mode-map)
 170     "\177" riece-command-scroll-down
 171     [delete] riece-command-scroll-down
 172     [backspace] riece-command-scroll-down
 173     " " riece-command-scroll-up
 174     "$" riece-command-end-of-buffer
 175     ">" riece-command-next-channel
 176     "<" riece-command-previous-channel
 177     "\C-j" riece-command-next-channel
 178     "\C-n" riece-command-names
 179     "l" riece-command-list
 180     "\C-m" riece-command-change-mode
 181     "o" riece-command-set-operators
 182     "\C-p" riece-command-part
 183     "r" riece-command-configure-windows
 184     "v" riece-command-set-speakers)
 185   (set-keymap-parent riece-command-map riece-dialogue-mode-map)
 186
 187   (riece-define-keys riece-user-list-mode-map
 188     "o" riece-command-set-operators
 189     "v" riece-command-set-voices
 190     "f" riece-command-finger
 191     " " riece-command-nick-scroll-up
 192     "\177" riece-command-nick-scroll-down
 193     [delete] riece-command-nick-scroll-down
 194     [backspace] riece-command-nick-scroll-down
 195     "c" riece-command-select-command-buffer)
 196
 197   (riece-define-keys riece-channel-list-mode-map
 198     ">" riece-command-next-channel
 199     "<" riece-command-previous-channel
 200     "u" riece-command-unread-channel
 201     "o" other-window
 202     "c" riece-command-select-command-buffer)
 203
 204   (riece-define-keys-1 riece-dialogue-mode-map riece-select-keys)
 205   (riece-define-keys-1 riece-channel-list-mode-map riece-select-keys))
 206
 207 (defun riece-read-variables-files (&optional file)
 208   "Read variables FILEs."
 209   (or (file-directory-p riece-directory)
 210       (make-directory riece-directory))
 211   (let ((files (if file
 212                    (setq riece-variables-file file
 213                          riece-variables-files (list file))
 214                  riece-variables-files)))
 215     (while files
 216       (condition-case nil
 217           (load (expand-file-name (car files)))
 218         (file-error nil))
 219       (setq files (cdr files)))))
 220
 221 (defvar print-quoted)
 222 (defvar print-escape-multibyte)
 223 (defun riece-save-variables-files ()
 224   "Save current settings to `riece-variables-file'."
 225   (with-temp-file riece-saved-variables-file
 226     (let ((print-quoted t)
 227           (print-readably t)
 228           print-escape-multibyte
 229           print-level
 230           print-length
 231           (variables riece-saved-forms))
 232       (while variables
 233         (prin1 `(setq ,(car variables)
 234                       ',(symbol-value (car variables)))
 235                (current-buffer))
 236         (insert "\n")
 237         (setq variables (cdr variables)))))
 238   (setq riece-save-variables-are-dirty nil))
 239
 240 ;;;###autoload
 241 (defun riece (&optional confirm)
 242   "Connect to the IRC server and start chatting.
 243 If optional argument CONFIRM is non-nil, ask which IRC server to connect.
 244 If already connected, just pop up the windows."
 245   (interactive "P")
 246   (riece-read-variables-files (if noninteractive
 247                                   (car command-line-args-left)))
 248   (riece-insinuate-addons riece-addons)
 249   (run-hooks 'riece-after-load-startup-hook)
 250   (if (riece-server-opened)
 251       (riece-configure-windows)
 252     (switch-to-buffer (riece-get-buffer-create riece-command-buffer))
 253     (unless (eq major-mode 'riece-command-mode)
 254       (riece-command-mode))
 255     (if (or confirm (null riece-server))
 256         (setq riece-server (completing-read "Server: " riece-server-alist)))
 257     (if (stringp riece-server)
 258         (setq riece-server (riece-server-name-to-server riece-server)))
 259     (riece-open-server riece-server)
 260     (riece-create-buffers)
 261     (riece-configure-windows)
 262     (let ((channel-list riece-startup-channel-list))
 263       (while channel-list
 264         (if (listp (car channel-list))
 265             (riece-command-join (car (car channel-list))
 266                                 (cadr (car channel-list)))
 267           (riece-command-join (car channel-list)))
 268         (setq channel-list (cdr channel-list))))
 269     (run-hooks 'riece-startup-hook)
 270     (message "%s" (substitute-command-keys
 271                    "Type \\[describe-mode] for help"))))
 272
 273 (defun riece-exit ()
 274   (setq riece-server nil)
 275   (if riece-save-variables-are-dirty
 276       (riece-save-variables-files))
 277   (riece-clear-system)
 278   (run-hooks 'riece-exit-hook))
 279
 280 (defun riece-command-mode ()
 281   "Major mode for Riece.  Normal edit function are available.
 282 Typing Return or Linefeed enters the current line in the dialogue.
 283 The following special commands are available:
 284 For a list of the generic commands type \\[riece-command-generic] ? RET.
 285 \\{riece-command-mode-map}"
 286   (interactive)
 287   (kill-all-local-variables)
 288
 289   (setq riece-away-indicator "-"
 290         riece-operator-indicator "-"
 291         major-mode 'riece-command-mode
 292         mode-name "Commands"
 293         mode-line-buffer-identification
 294         (riece-mode-line-buffer-identification
 295          '("Riece: "
 296            riece-away-indicator
 297            riece-operator-indicator
 298            riece-freeze-indicator
 299            " "
 300            riece-user-indicator
 301            " "
 302            riece-current-channel)))
 303   (riece-simplify-mode-line-format)
 304   (use-local-map riece-command-mode-map)
 305
 306   (unless riece-command-mode-syntax-table
 307     (setq riece-command-mode-syntax-table
 308           (copy-syntax-table (syntax-table)))
 309     (set-syntax-table riece-command-mode-syntax-table)
 310     (mapcar
 311      (lambda (c) (modify-syntax-entry c "w"))
 312      "^[]{}'`"))
 313
 314   (run-hooks 'riece-command-mode-hook))
 315
 316 (defun riece-dialogue-mode ()
 317   "Major mode for displaying the IRC dialogue.
 318 All normal editing commands are turned off.
 319 Instead, these commands are available:
 320 \\{riece-dialogue-mode-map}"
 321   (kill-all-local-variables)
 322
 323   (make-local-variable 'riece-freeze)
 324   (make-local-variable 'tab-stop-list)
 325
 326   (setq riece-freeze riece-default-freeze
 327         riece-away-indicator "-"
 328         riece-operator-indicator "-"
 329         major-mode 'riece-dialogue-mode
 330         mode-name "Dialogue"
 331         mode-line-buffer-identification
 332         (riece-mode-line-buffer-identification
 333          '("Riece: "
 334            riece-away-indicator
 335            riece-operator-indicator
 336            riece-freeze-indicator
 337            " "
 338            riece-channel-list-indicator " "))
 339         buffer-read-only t
 340         tab-stop-list riece-tab-stop-list)
 341   (riece-update-status-indicators)
 342   (riece-simplify-mode-line-format)
 343   (use-local-map riece-dialogue-mode-map)
 344   (buffer-disable-undo)
 345   (run-hooks 'riece-dialogue-mode-hook))
 346
 347 (define-derived-mode riece-others-mode riece-dialogue-mode
 348   "Others"
 349   "Major mode for displaying the IRC others message except current channel.
 350 All normal editing commands are turned off.
 351 Instead, these commands are available:
 352 \\{riece-others-mode-map}")
 353
 354 (define-derived-mode riece-channel-mode riece-dialogue-mode
 355   "Channel"
 356   "Major mode for displaying the IRC current channel buffer.
 357 All normal editing commands are turned off.
 358 Instead, these commands are available:
 359 \\{riece-channel-mode-map}"
 360   (setq mode-line-buffer-identification
 361         (riece-mode-line-buffer-identification
 362          '("Riece: "
 363            riece-away-indicator
 364            riece-operator-indicator
 365            riece-freeze-indicator
 366            " "
 367            riece-channel-indicator))))
 368
 369 (defun riece-channel-list-mode ()
 370   "Major mode for displaying channel list.
 371 All normal editing commands are turned off."
 372   (kill-all-local-variables)
 373   (setq major-mode 'riece-channel-list-mode
 374         mode-name "Channels"
 375         mode-line-buffer-identification
 376         (riece-mode-line-buffer-identification '("Riece: "))
 377         truncate-lines t
 378         buffer-read-only t)
 379   (use-local-map riece-channel-list-mode-map)
 380   (run-hooks 'riece-channel-list-mode-hook))
 381
 382 (defun riece-user-list-mode ()
 383   "Major mode for displaying members in the IRC current channel buffer.
 384 All normal editing commands are turned off.
 385 Instead, these commands are available:
 386 \\{riece-user-list-mode-map}"
 387   (kill-all-local-variables)
 388   (setq major-mode 'riece-user-list-mode
 389         mode-name "User list"
 390         mode-line-buffer-identification
 391         (riece-mode-line-buffer-identification
 392          '("Riece: " riece-channel-indicator " "))
 393         truncate-lines t
 394         buffer-read-only t)
 395   (if (boundp 'transient-mark-mode)
 396       (set (make-local-variable 'transient-mark-mode) t))
 397   (use-local-map riece-user-list-mode-map)
 398   (run-hooks 'riece-user-list-mode-hook))
 399
 400 (defun riece-create-buffers ()
 401   (let ((alist riece-buffer-mode-alist))
 402     (while alist
 403       (save-excursion
 404         (set-buffer (riece-get-buffer-create
 405                      (symbol-value (car (car alist)))))
 406         (unless (or (null (cdr (car alist)))
 407                     (eq major-mode (cdr (car alist))))
 408           (funcall (cdr (car alist))))
 409         (setq alist (cdr alist))))))
 410
 411 (defun riece-load-and-build-addon-dependencies (addons)
 412   (let ((load-path (cons riece-addon-directory load-path))
 413         dependencies)
 414     (while addons
 415       (require (car addons))            ;error will be reported here
 416       (let* ((requires
 417               (funcall (or (intern-soft
 418                             (concat (symbol-name (car addons)) "-requires"))
 419                            #'ignore)))
 420              (pointer requires)
 421              entry)
 422         ;; Increment succs' pred count.
 423         (if (setq entry (assq (car addons) dependencies))
 424             (setcar (cdr entry) (+ (length requires) (nth 1 entry)))
 425           (setq dependencies (cons (list (car addons) (length requires))
 426                                    dependencies)))
 427         ;; Merge pred's succs.
 428         (while pointer
 429           (if (setq entry (assq (car pointer) dependencies))
 430               (setcdr (cdr entry)
 431                       (cons (car addons) (nthcdr 2 entry)))
 432             (setq dependencies (cons (list (car pointer) 0 (car addons))
 433                                      dependencies)))
 434           (setq pointer (cdr pointer))))
 435       (setq addons (cdr addons)))
 436     dependencies))
 437
 438 (defun riece-insinuate-addons (addons)
 439   (let ((pointer addons)
 440         dependencies queue)
 441     ;; Uniquify, first.
 442     (while pointer
 443       (if (memq (car pointer) (cdr pointer))
 444           (setcar pointer nil))
 445       (setq pointer (cdr pointer)))
 446     (setq dependencies (riece-load-and-build-addon-dependencies
 447                         (delq nil addons))
 448           pointer dependencies)
 449     ;; Sort them.
 450     (while pointer
 451       (if (zerop (nth 1 (car pointer)))
 452           (setq dependencies (delq (car pointer) dependencies)
 453                 queue (cons (car pointer) queue)))
 454       (setq pointer (cdr pointer)))
 455     (setq addons nil)
 456     (while queue
 457       (setq addons (cons (car (car queue)) addons)
 458             pointer (nthcdr 2 (car queue)))
 459       (while pointer
 460         (let* ((entry (assq (car pointer) dependencies))
 461                (count (1- (nth 1 entry))))
 462           (if (zerop count)
 463               (progn
 464                 (setq dependencies (delq entry dependencies)
 465                       queue (nconc queue (list entry))))
 466             (setcar (cdr entry) count)))
 467         (setq pointer (cdr pointer)))
 468       (setq queue (cdr queue)))
 469     (if dependencies
 470         (error "Circular add-on dependency found"))
 471     (while addons
 472       (require (car addons))            ;implicit dependency
 473       (funcall (intern (concat (symbol-name (car addons)) "-insinuate")))
 474       (setq addons (cdr addons)))))
 475
 476 (provide 'riece)
 477
 478 ;;; riece.el ends here