cgit.sxemacs.org Git - riece/blob - lisp/riece.el

   1 ;;; riece.el --- IRC client for Emacsen
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Created: 1998-09-28
   6 ;; Keywords: IRC, riece
   7
   8 ;; This file is part of Riece.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Code:
  26
  27 (require 'riece-display)
  28 (require 'riece-server)
  29 (require 'riece-compat)
  30 (require 'riece-commands)
  31 (require 'riece-addon)
  32 (require 'riece-signal)
  33
  34 (autoload 'derived-mode-class "derived")
  35
  36 (defvar riece-channel-list-mode-map (make-sparse-keymap))
  37 (defvar riece-user-list-mode-map (make-sparse-keymap))
  38
  39 (defvar riece-dialogue-mode-map
  40   (let ((keymap (make-keymap)))
  41     (suppress-keymap keymap 'nodigit)
  42     keymap))
  43
  44 (defvar riece-command-mode-map (make-keymap))
  45 (defvar riece-command-map (make-sparse-keymap))
  46
  47 (defvar riece-command-mode-syntax-table nil)
  48
  49 (put 'riece-command-mode 'mode-class 'special)
  50 (put 'riece-dialogue-mode 'mode-class 'special)
  51 (put 'riece-others-mode 'derived-mode-parent 'riece-dialogue-mode)
  52 (put 'riece-channel-list-mode 'mode-class 'special)
  53 (put 'riece-user-list-mode 'mode-class 'special)
  54 (put 'riece-channel-mode 'derived-mode-parent 'riece-dialogue-mode)
  55
  56 (defvar riece-buffer-alist
  57   '((riece-command-buffer "*Command*" riece-command-mode)
  58     (riece-dialogue-buffer "*Dialogue*" riece-dialogue-mode)
  59     (riece-others-buffer "*Others*" riece-others-mode)
  60     (riece-channel-list-buffer "*Channels*" riece-channel-list-mode)
  61     (riece-user-list-buffer " *Users*" riece-user-list-mode)
  62     (riece-temp-buffer " *Temp*")
  63     (riece-debug-buffer " *Debug*")))
  64
  65 (defvar riece-shrink-buffer-idle-timer nil
  66   "Timer object to periodically shrink channel buffers.")
  67
  68 (defvar riece-addons-insinuated nil
  69   "Non nil if add-ons are already insinuated.")
  70
  71 (defvar riece-select-keys
  72   `("#" riece-command-switch-to-channel-by-number
  73     "1" riece-command-switch-to-channel-by-number-1
  74     "2" riece-command-switch-to-channel-by-number-2
  75     "3" riece-command-switch-to-channel-by-number-3
  76     "4" riece-command-switch-to-channel-by-number-4
  77     "5" riece-command-switch-to-channel-by-number-5
  78     "6" riece-command-switch-to-channel-by-number-6
  79     "7" riece-command-switch-to-channel-by-number-7
  80     "8" riece-command-switch-to-channel-by-number-8
  81     "9" riece-command-switch-to-channel-by-number-9
  82     "0" riece-command-switch-to-channel-by-number-10
  83     ,(concat riece-command-prefix "1")
  84     riece-command-switch-to-channel-by-number-11
  85     ,(concat riece-command-prefix "2")
  86     riece-command-switch-to-channel-by-number-12
  87     ,(concat riece-command-prefix "3")
  88     riece-command-switch-to-channel-by-number-13
  89     ,(concat riece-command-prefix "4")
  90     riece-command-switch-to-channel-by-number-14
  91     ,(concat riece-command-prefix "5")
  92     riece-command-switch-to-channel-by-number-15
  93     ,(concat riece-command-prefix "6")
  94     riece-command-switch-to-channel-by-number-16
  95     ,(concat riece-command-prefix "7")
  96     riece-command-switch-to-channel-by-number-17
  97     ,(concat riece-command-prefix "8")
  98     riece-command-switch-to-channel-by-number-18
  99     ,(concat riece-command-prefix "9")
 100     riece-command-switch-to-channel-by-number-19
 101     ,(concat riece-command-prefix "0")
 102     riece-command-switch-to-channel-by-number-20))
 103
 104 ;;; Keymap macros. -- borrowed from `gnus-util.el'.
 105 (defmacro riece-local-set-keys (&rest plist)
 106   "Set the keys in PLIST in the current keymap."
 107   `(riece-define-keys-1 (current-local-map) ',plist))
 108
 109 (defmacro riece-define-keys (keymap &rest plist)
 110   "Assign KEYMAP keys from PLIST."
 111   `(riece-define-keys-1 ',keymap ',plist))
 112
 113 (defmacro riece-define-keys-safe (keymap &rest plist)
 114   "Assign KEYMAP keys from PLIST without overwriting previous definitions."
 115   `(riece-define-keys-1 ',keymap ',plist t))
 116
 117 (put 'riece-define-keys 'lisp-indent-function 1)
 118 (put 'riece-define-keys-safe 'lisp-indent-function 1)
 119 (put 'riece-local-set-keys 'lisp-indent-function 1)
 120
 121 (defun riece-define-keys-1 (keymap plist &optional safe)
 122   "Assign KEYMAP keys from PLIST.
 123 If optional argument SAFE is nil, overwrite previous definitions."
 124   (unless keymap
 125     (error "Can't set keys in a null keymap"))
 126   (cond
 127    ((symbolp keymap)
 128     (setq keymap (symbol-value keymap)))
 129    ((keymapp keymap))
 130    ((listp keymap)
 131     (set (car keymap) nil)
 132     (define-prefix-command (car keymap))
 133     (define-key (symbol-value (nth 2 keymap))
 134       (if (symbolp (nth 1 keymap))
 135           (symbol-value (nth 1 keymap))
 136         (nth 1 keymap))
 137       (car keymap))
 138     (setq keymap (symbol-value (car keymap)))))
 139   (let (key)
 140     (while plist
 141       (if (symbolp (setq key (car plist)))
 142           (setq key (symbol-value key)))
 143       (setq plist (cdr plist))
 144       (if (or (not safe)
 145               (eq (lookup-key keymap key) 'undefined))
 146           (define-key keymap key (car plist))
 147         (car plist))
 148       (setq plist (cdr plist)))))
 149
 150 (when t
 151   (riece-define-keys riece-dialogue-mode-map
 152     "\177" scroll-down
 153     [delete] scroll-down
 154     [backspace] scroll-down
 155     [return] scroll-up
 156     " " scroll-up
 157     [home] beginning-of-buffer
 158     "$" end-of-buffer
 159     [end] end-of-buffer
 160     "/" riece-command-raw
 161     ">" end-of-buffer
 162     "<" beginning-of-buffer
 163     "^" riece-command-list-addons
 164     "\C-ta" riece-command-toggle-away
 165     "c" riece-command-select-command-buffer
 166     "f" riece-command-finger
 167     "\C-tf" riece-command-toggle-freeze
 168     "\C-to" riece-command-toggle-own-freeze
 169     "\C-tO" riece-command-toggle-others-buffer-mode
 170     "\C-tu" riece-command-toggle-user-list-buffer-mode
 171     "\C-tc" riece-command-toggle-channel-buffer-mode
 172     "\C-tC" riece-command-toggle-channel-list-buffer-mode
 173     "\C-tl" riece-command-change-layout
 174     "i" riece-command-invite
 175     "j" riece-command-join
 176     "\C-k" riece-command-kick
 177     "l" riece-command-list
 178     "M" riece-command-change-mode
 179     "n" riece-command-change-nickname
 180     "N" riece-command-names
 181     "o" other-window
 182     "O" riece-command-open-server
 183     "C" riece-command-close-server
 184     "M" riece-command-universal-server-name-argument
 185     "p" riece-command-enter-message-to-user
 186     "q" riece-command-quit
 187     "r" riece-command-configure-windows
 188     "x" riece-command-copy-region
 189     "t" riece-command-topic
 190     "w" riece-command-who
 191     "z" riece-command-suspend-resume)
 192
 193   (riece-define-keys riece-command-mode-map
 194     "\r" riece-command-enter-message
 195     [(control return)] riece-command-enter-message-as-notice
 196     [tab] riece-command-complete-user)
 197
 198   (riece-define-keys (riece-command-map riece-command-prefix
 199                                         riece-command-mode-map)
 200     "\177" riece-command-scroll-down
 201     [delete] riece-command-scroll-down
 202     [backspace] riece-command-scroll-down
 203     " " riece-command-scroll-up
 204     [home] riece-command-beginning-of-buffer
 205     "$" riece-command-end-of-buffer
 206     [end] riece-command-end-of-buffer
 207     ">" riece-command-next-channel
 208     "<" riece-command-previous-channel
 209     "\C-j" riece-command-next-channel
 210     "\C-n" riece-command-names
 211     "l" riece-command-list
 212     "\C-m" riece-command-change-mode
 213     "o" riece-command-set-operators
 214     "\C-p" riece-command-part
 215     "r" riece-command-configure-windows
 216     "v" riece-command-set-speakers
 217     "V" riece-version)
 218   (set-keymap-parent riece-command-map riece-dialogue-mode-map)
 219
 220   (riece-define-keys riece-user-list-mode-map
 221     "o" riece-command-set-operators
 222     "v" riece-command-set-voices
 223     "f" riece-command-finger
 224     " " riece-command-user-list-scroll-up
 225     "\177" riece-command-user-list-scroll-down
 226     [delete] riece-command-user-list-scroll-down
 227     [backspace] riece-command-user-list-scroll-down
 228     "c" riece-command-select-command-buffer)
 229
 230   (riece-define-keys riece-channel-list-mode-map
 231     ">" riece-command-next-channel
 232     "<" riece-command-previous-channel
 233     "o" other-window
 234     "c" riece-command-select-command-buffer)
 235
 236   (riece-define-keys-1 riece-dialogue-mode-map riece-select-keys)
 237   (riece-define-keys-1 riece-channel-list-mode-map riece-select-keys))
 238
 239 (defun riece-read-variables-files (&optional file)
 240   "Read variables FILEs."
 241   (or (file-directory-p riece-directory)
 242       (make-directory riece-directory))
 243   (let ((files (if file
 244                    (setq riece-variables-file file
 245                          riece-variables-files (list file))
 246                  riece-variables-files)))
 247     (while files
 248       (condition-case nil
 249           (load (expand-file-name (car files)))
 250         (file-error nil))
 251       (setq files (cdr files)))))
 252
 253 (defvar print-quoted)
 254 (defvar print-escape-multibyte)
 255 (defun riece-save-variables-files ()
 256   "Save current settings to `riece-variables-file'."
 257   (with-temp-file riece-saved-variables-file
 258     (let ((print-quoted t)
 259           (print-readably t)
 260           print-escape-multibyte
 261           print-level
 262           print-length
 263           (variables riece-saved-forms))
 264       (while variables
 265         (prin1 `(setq ,(car variables)
 266                       ',(symbol-value (car variables)))
 267                (current-buffer))
 268         (insert "\n")
 269         (setq variables (cdr variables)))))
 270   (setq riece-save-variables-are-dirty nil))
 271
 272 ;;;###autoload
 273 (defun riece (&optional confirm)
 274   "Connect to the IRC server and start chatting.
 275 If optional argument CONFIRM is non-nil, ask which IRC server to connect."
 276   (interactive "P")
 277   (riece-read-variables-files (if noninteractive
 278                                   (car command-line-args-left)))
 279   (run-hooks 'riece-after-load-startup-hook)
 280   (if (riece-server-opened)
 281       (riece-command-configure-windows)
 282     (modify-frame-parameters (selected-frame)
 283                              (list (cons 'riece-window-configuration
 284                                          (current-window-configuration))))
 285     (unless riece-addons-insinuated
 286       (setq riece-addons (riece-resolve-addons riece-addons))
 287       (let ((pointer riece-addons))
 288         (while pointer
 289           (riece-insinuate-addon (car pointer) riece-debug)
 290           (setq pointer (cdr pointer))))
 291       (setq riece-addons-insinuated t))
 292     (if (or confirm (null riece-server))
 293         (setq riece-server (completing-read "Server: " riece-server-alist)))
 294     (if (stringp riece-server)
 295         (setq riece-server (riece-server-name-to-server riece-server)))
 296     (riece-create-buffers)
 297     (if riece-max-buffer-size
 298         (setq riece-shrink-buffer-idle-timer
 299               (riece-run-with-idle-timer
 300                riece-shrink-buffer-idle-time-delay t
 301                (lambda ()
 302                  (let ((buffers riece-buffer-list))
 303                    (while buffers
 304                      (if (buffer-live-p (car buffers))
 305                          (if (eq (derived-mode-class
 306                                   (with-current-buffer (car buffers)
 307                                     major-mode))
 308                                  'riece-dialogue-mode)
 309                              (riece-shrink-buffer (car buffers)))
 310                        (delq (car buffers) riece-buffer-list))
 311                      (setq buffers (cdr buffers))))))))
 312     (switch-to-buffer riece-command-buffer)
 313     (riece-display-connect-signals)
 314     (riece-redisplay-buffers)
 315     (riece-open-server riece-server "")
 316     ;; If no server process is available, exit.
 317     (if (null riece-server-process-alist)
 318         (riece-exit)
 319       (let ((server-list riece-startup-server-list))
 320         (while server-list
 321           (riece-command-open-server (car server-list))
 322           (setq server-list (cdr server-list))))
 323       (let ((channel-list riece-startup-channel-list)
 324             server)
 325         (while channel-list
 326           (setq server (riece-identity-server
 327                         (riece-parse-identity (car channel-list))))
 328           (unless (riece-server-opened server)
 329             (riece-command-open-server server))
 330           (setq channel-list (cdr channel-list))))
 331       (let ((pointer riece-addons))
 332         (while pointer
 333           (unless (get (car pointer) 'riece-addon-default-disabled)
 334             (riece-enable-addon (car pointer) riece-debug))
 335           (setq pointer (cdr pointer))))
 336       (run-hooks 'riece-startup-hook)
 337       (message "%s" (substitute-command-keys
 338                      "Type \\[describe-mode] for help")))))
 339
 340 (defun riece-shrink-buffer (buffer)
 341   (save-excursion
 342     (set-buffer buffer)
 343     (goto-char (point-min))
 344     (while (> (buffer-size) riece-max-buffer-size)
 345       (let* ((inhibit-read-only t)
 346              buffer-read-only
 347              (end (progn
 348                     (goto-char riece-shrink-buffer-remove-chars)
 349                     (beginning-of-line 2)
 350                     (point)))
 351              (overlays (riece-overlays-in (point-min) end)))
 352         (while overlays
 353           (riece-delete-overlay (car overlays))
 354           (setq overlays (cdr overlays)))
 355         (delete-region (point-min) end)))))
 356
 357 (defun riece-exit ()
 358   (if riece-save-variables-are-dirty
 359       (riece-save-variables-files))
 360   (while riece-buffer-list
 361     (if (and (get-buffer (car riece-buffer-list))
 362              (buffer-live-p (car riece-buffer-list)))
 363         (funcall riece-buffer-dispose-function (car riece-buffer-list)))
 364     (setq riece-buffer-list (cdr riece-buffer-list)))
 365   (if riece-shrink-buffer-idle-timer
 366       (riece-cancel-timer riece-shrink-buffer-idle-timer))
 367   (riece-clear-signal-slots)
 368   (setq riece-server nil
 369         riece-current-channels nil
 370         riece-current-channel nil
 371         riece-channel-buffer nil
 372         riece-channel-buffer-alist nil
 373         riece-user-indicator nil
 374         riece-long-channel-indicator "None"
 375         riece-channel-list-indicator "No channel"
 376         riece-away-indicator "-"
 377         riece-operator-indicator "-"
 378         riece-channel-status-indicator "-"
 379         riece-freeze-indicator "-")
 380   (modify-frame-parameters (selected-frame)
 381                            (list (list 'riece-window-configuration)))
 382   (delete-other-windows)
 383   (run-hooks 'riece-exit-hook))
 384
 385 (defun riece-command-mode ()
 386   "Major mode for Riece.  Normal edit function are available.
 387 Typing Return or Linefeed enters the current line in the dialogue.
 388 The following special commands are available:
 389 For a list of the generic commands type \\[riece-command-generic] ? RET.
 390 \\{riece-command-mode-map}"
 391   (interactive)
 392   (kill-all-local-variables)
 393
 394   ;; Make `truncate-partial-width-windows' buffer local and set it to
 395   ;; nil.  This causes `truncate-lines' to directly control line
 396   ;; truncation.
 397   (make-local-variable 'truncate-partial-width-windows)
 398   (setq truncate-partial-width-windows nil)
 399
 400   (setq riece-away-indicator "-"
 401         riece-operator-indicator "-"
 402         riece-channel-status-indicator "-"
 403         major-mode 'riece-command-mode
 404         mode-name "Command"
 405         mode-line-buffer-identification
 406         (riece-mode-line-buffer-identification
 407          '("Riece: "
 408            riece-away-indicator
 409            riece-operator-indicator
 410            riece-channel-status-indicator
 411            " "
 412            riece-user-indicator
 413            " "
 414            riece-channel-indicator))
 415         truncate-lines nil)
 416   (riece-simplify-mode-line-format)
 417   (use-local-map riece-command-mode-map)
 418
 419   (unless riece-command-mode-syntax-table
 420     (setq riece-command-mode-syntax-table
 421           (copy-syntax-table (syntax-table)))
 422     (set-syntax-table riece-command-mode-syntax-table)
 423     (mapcar
 424      (lambda (c) (modify-syntax-entry c "w"))
 425      "^[]{}'`"))
 426
 427   (run-hooks 'riece-command-mode-hook))
 428
 429 (defun riece-dialogue-mode ()
 430   "Major mode for displaying the IRC dialogue.
 431 All normal editing commands are turned off.
 432 Instead, these commands are available:
 433 \\{riece-dialogue-mode-map}"
 434   (kill-all-local-variables)
 435   (make-local-variable 'riece-freeze)
 436   (make-local-variable 'riece-freeze-indicator)
 437
 438   ;; Make `truncate-partial-width-windows' buffer local and set it to
 439   ;; nil.  This causes `truncate-lines' to directly control line truncation.
 440   (make-local-variable 'truncate-partial-width-windows)
 441   (setq truncate-partial-width-windows nil)
 442
 443   (setq riece-freeze riece-default-freeze
 444         riece-away-indicator "-"
 445         riece-operator-indicator "-"
 446         riece-channel-status-indicator "-"
 447         major-mode 'riece-dialogue-mode
 448         mode-name "Dialogue"
 449         mode-line-buffer-identification
 450         (riece-mode-line-buffer-identification
 451          '("Riece: "
 452            riece-away-indicator
 453            riece-operator-indicator
 454            riece-freeze-indicator
 455            riece-channel-status-indicator
 456            " "
 457            riece-channel-list-indicator " "))
 458         truncate-lines nil
 459         buffer-read-only t)
 460   (riece-simplify-mode-line-format)
 461   (use-local-map riece-dialogue-mode-map)
 462   (buffer-disable-undo)
 463   (run-hooks 'riece-dialogue-mode-hook))
 464
 465 (define-derived-mode riece-others-mode riece-dialogue-mode
 466   "Others"
 467   "Major mode for displaying the IRC others message except current channel.
 468 All normal editing commands are turned off.
 469 Instead, these commands are available:
 470 \\{riece-others-mode-map}")
 471
 472 (define-derived-mode riece-channel-mode riece-dialogue-mode
 473   "Channel"
 474   "Major mode for displaying the IRC current channel buffer.
 475 All normal editing commands are turned off.
 476 Instead, these commands are available:
 477 \\{riece-channel-mode-map}"
 478   (make-local-variable 'riece-channel-buffer-window-point)
 479   (setq mode-line-buffer-identification
 480         (riece-mode-line-buffer-identification
 481          '("Riece: "
 482            riece-away-indicator
 483            riece-operator-indicator
 484            riece-freeze-indicator
 485            riece-channel-status-indicator
 486            " "
 487            riece-long-channel-indicator))))
 488
 489 (defun riece-channel-list-mode ()
 490   "Major mode for displaying channel list.
 491 All normal editing commands are turned off."
 492   (kill-all-local-variables)
 493   (buffer-disable-undo)
 494
 495   ;; Make `truncate-partial-width-windows' buffer local and set it to
 496   ;; nil.  This causes `truncate-lines' to directly control line truncation.
 497   (make-local-variable 'truncate-partial-width-windows)
 498   (setq truncate-partial-width-windows nil)
 499
 500   (setq major-mode 'riece-channel-list-mode
 501         mode-name "Channels"
 502         mode-line-buffer-identification
 503         (riece-mode-line-buffer-identification '("Riece: "))
 504         truncate-lines t
 505         buffer-read-only t)
 506   (make-local-hook 'riece-update-buffer-functions)
 507   (add-hook 'riece-update-buffer-functions
 508             'riece-update-channel-list-buffer nil t)
 509   (use-local-map riece-channel-list-mode-map)
 510   (run-hooks 'riece-channel-list-mode-hook))
 511
 512 (defun riece-user-list-mode ()
 513   "Major mode for displaying members in the IRC current channel buffer.
 514 All normal editing commands are turned off.
 515 Instead, these commands are available:
 516 \\{riece-user-list-mode-map}"
 517   (kill-all-local-variables)
 518   (buffer-disable-undo)
 519
 520   ;; Make `truncate-partial-width-windows' buffer local and set it to
 521   ;; nil.  This causes `truncate-lines' to directly control line truncation.
 522   (make-local-variable 'truncate-partial-width-windows)
 523   (setq truncate-partial-width-windows nil)
 524
 525   (setq major-mode 'riece-user-list-mode
 526         mode-name "Users"
 527         mode-line-buffer-identification
 528         (riece-mode-line-buffer-identification
 529          '("Riece: " riece-long-channel-indicator " "))
 530         truncate-lines t
 531         buffer-read-only t)
 532   (if (boundp 'transient-mark-mode)
 533       (set (make-local-variable 'transient-mark-mode) t))
 534   (make-local-hook 'riece-update-buffer-functions)
 535   (add-hook 'riece-update-buffer-functions
 536             'riece-update-user-list-buffer nil t)
 537   (use-local-map riece-user-list-mode-map)
 538   (run-hooks 'riece-user-list-mode-hook))
 539
 540 (defun riece-create-buffers ()
 541   (let ((alist riece-buffer-alist))
 542     (while alist
 543       (save-excursion
 544         (set-buffer (apply #'riece-get-buffer-create
 545                            (cdr (car alist))))
 546         (set (car (car alist)) (current-buffer))
 547         (unless (or (null (nth 2 (car alist)))
 548                     (eq major-mode (nth 2 (car alist))))
 549           (funcall (nth 2 (car alist))))
 550         (setq alist (cdr alist))))))
 551
 552 (defvar reporter-prompt-for-summary-p)
 553 (defun riece-submit-bug-report (&optional recent-messages recent-keys)
 554   "Submit via mail a bug report on Riece."
 555   ;; This strange form ensures that (recent-keys) is the value before
 556   ;; the bug subject string is read.
 557   (interactive (list (riece-recent-messages 20) (recent-keys)))
 558   (message "Querying server version...")
 559   (let ((pointer riece-server-process-alist)
 560         nickname)
 561     (while pointer
 562       (when (riece-server-process-opened (cdr (car pointer)))
 563         (process-send-string (cdr (car pointer)) "VERSION\r\n")
 564         (if (setq nickname
 565                   (with-current-buffer (process-buffer (cdr (car pointer)))
 566                     riece-real-nickname))
 567             (process-send-string
 568              (cdr (car pointer))
 569              (format "PRIVMSG %s :\1VERSION\1\r\n" nickname))))
 570       (setq pointer (cdr pointer))))
 571   (sit-for 3)
 572   (message "Querying server version...done")
 573   (require 'reporter)
 574   (let ((reporter-prompt-for-summary-p t))
 575     (unless riece-debug
 576       (error "Please turn on riece-debug and restart Riece."))
 577     (reporter-submit-bug-report
 578      "liece@unixuser.org"
 579      (riece-version)
 580      '(riece-debug)
 581      nil
 582      nil
 583      "This bug report will be sent to the Riece Development Team,
 584 not to your local site managers!!
 585
 586 Please write in Japanese or English, because the Riece maintainers do
 587 not have translators to read other languages for them.
 588
 589 Please describe as succinctly as possible:
 590 \t- What happened.
 591 \t- What you thought should have happened.
 592 \t- Precisely what you were doing at the time.
 593
 594 Also include a reliable recipe for triggering the bug, as well as
 595 any lisp back-traces that you may have.
 596 \(setq stack-trace-on-error t\), or \(setq debug-on-error t\) if you
 597 are familiar with the debugger, to get a lisp back-trace.")
 598     (delete-other-windows)
 599     (save-excursion
 600       (goto-char (point-max))
 601       (insert
 602        "\nAdd-on state:\n"
 603        "------------\n"
 604        (save-window-excursion
 605          (save-excursion
 606            (riece-command-list-addons)
 607            (search-forward "\n\n")
 608            (buffer-substring (point-min) (point)))))
 609       (insert "Recent messages from servers:\n"
 610               "--------------------------")
 611       (let ((pointer riece-server-process-alist))
 612         (while pointer
 613           (insert "\n- \"" (car (car pointer)) "\", \n"
 614                   (format "%S" (if (equal (car (car pointer)) "")
 615                                    riece-server
 616                                  (cdr (assoc (car (car pointer))
 617                                              riece-server-alist))))
 618                   "\n"
 619                   (if (riece-server-process-opened (cdr (car pointer)))
 620                       (save-excursion
 621                         (set-buffer (process-buffer (cdr (car pointer))))
 622                         (goto-char (point-max))
 623                         (beginning-of-line -60)
 624                         (buffer-substring (point) (point-max)))
 625                     "(closed server)"))
 626           (setq pointer (cdr pointer))))
 627       (insert "\n\nRecent debug messages:\n"
 628               "-----------------------------------\n"
 629               (with-current-buffer riece-debug-buffer
 630                 (buffer-string)))
 631       ;; Insert recent keystrokes.
 632       (insert "\n\nRecent keystrokes:\n"
 633               "-----------------\n\n")
 634       (let ((before-keys (point)))
 635         (insert (key-description recent-keys))
 636         (save-restriction
 637           (narrow-to-region before-keys (point))
 638           (goto-char before-keys)
 639           (while (progn (move-to-column 50) (not (eobp)))
 640             (search-forward " " nil t)
 641             (insert "\n"))))
 642       ;; Insert recent minibuffer messages.
 643       (insert "\n\nRecent messages (most recent first):\n"
 644               "-----------------------------------\n"
 645               recent-messages))))
 646
 647 (provide 'riece)
 648
 649 ;;; riece.el ends here