cgit.sxemacs.org Git - riece/blob - lisp/riece.el

   1 ;;; riece.el --- IRC client for Emacsen
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Created: 1998-09-28
   6 ;; Keywords: IRC, riece
   7
   8 ;; This file is part of Riece.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Code:
  26
  27 (require 'riece-display)
  28 (require 'riece-server)
  29 (require 'riece-compat)
  30 (require 'riece-commands)
  31 (require 'riece-addon)
  32 (require 'riece-signal)
  33
  34 (autoload 'derived-mode-class "derived")
  35
  36 (defvar riece-channel-list-mode-map (make-sparse-keymap))
  37 (defvar riece-user-list-mode-map (make-sparse-keymap))
  38
  39 (defvar riece-dialogue-mode-map
  40   (let ((keymap (make-keymap)))
  41     (suppress-keymap keymap 'nodigit)
  42     keymap))
  43
  44 (defvar riece-command-mode-map (make-keymap))
  45 (defvar riece-command-map (make-sparse-keymap))
  46
  47 (defvar riece-command-mode-syntax-table nil)
  48
  49 (put 'riece-command-mode 'mode-class 'special)
  50 (put 'riece-dialogue-mode 'mode-class 'special)
  51 (put 'riece-others-mode 'derived-mode-parent 'riece-dialogue-mode)
  52 (put 'riece-channel-list-mode 'mode-class 'special)
  53 (put 'riece-user-list-mode 'mode-class 'special)
  54 (put 'riece-channel-mode 'derived-mode-parent 'riece-dialogue-mode)
  55
  56 (defvar riece-buffer-alist
  57   '((riece-command-buffer "*Command*" riece-command-mode)
  58     (riece-dialogue-buffer "*Dialogue*" riece-dialogue-mode)
  59     (riece-others-buffer "*Others*" riece-others-mode)
  60     (riece-channel-list-buffer "*Channels*" riece-channel-list-mode)
  61     (riece-user-list-buffer " *Users*" riece-user-list-mode)
  62     (riece-temp-buffer " *Temp*")))
  63
  64 (defvar riece-shrink-buffer-idle-timer nil
  65   "Timer object to periodically shrink channel buffers.")
  66
  67 (defvar riece-addons-insinuated nil
  68   "Non nil if add-ons are already insinuated.")
  69
  70 (defvar riece-select-keys
  71   `("#" riece-command-switch-to-channel-by-number
  72     "1" riece-command-switch-to-channel-by-number-1
  73     "2" riece-command-switch-to-channel-by-number-2
  74     "3" riece-command-switch-to-channel-by-number-3
  75     "4" riece-command-switch-to-channel-by-number-4
  76     "5" riece-command-switch-to-channel-by-number-5
  77     "6" riece-command-switch-to-channel-by-number-6
  78     "7" riece-command-switch-to-channel-by-number-7
  79     "8" riece-command-switch-to-channel-by-number-8
  80     "9" riece-command-switch-to-channel-by-number-9
  81     "0" riece-command-switch-to-channel-by-number-10
  82     ,(concat riece-command-prefix "1")
  83     riece-command-switch-to-channel-by-number-11
  84     ,(concat riece-command-prefix "2")
  85     riece-command-switch-to-channel-by-number-12
  86     ,(concat riece-command-prefix "3")
  87     riece-command-switch-to-channel-by-number-13
  88     ,(concat riece-command-prefix "4")
  89     riece-command-switch-to-channel-by-number-14
  90     ,(concat riece-command-prefix "5")
  91     riece-command-switch-to-channel-by-number-15
  92     ,(concat riece-command-prefix "6")
  93     riece-command-switch-to-channel-by-number-16
  94     ,(concat riece-command-prefix "7")
  95     riece-command-switch-to-channel-by-number-17
  96     ,(concat riece-command-prefix "8")
  97     riece-command-switch-to-channel-by-number-18
  98     ,(concat riece-command-prefix "9")
  99     riece-command-switch-to-channel-by-number-19
 100     ,(concat riece-command-prefix "0")
 101     riece-command-switch-to-channel-by-number-20))
 102
 103 ;;; Keymap macros. -- borrowed from `gnus-util.el'.
 104 (defmacro riece-local-set-keys (&rest plist)
 105   "Set the keys in PLIST in the current keymap."
 106   `(riece-define-keys-1 (current-local-map) ',plist))
 107
 108 (defmacro riece-define-keys (keymap &rest plist)
 109   "Assign KEYMAP keys from PLIST."
 110   `(riece-define-keys-1 ',keymap ',plist))
 111
 112 (defmacro riece-define-keys-safe (keymap &rest plist)
 113   "Assign KEYMAP keys from PLIST without overwriting previous definitions."
 114   `(riece-define-keys-1 ',keymap ',plist t))
 115
 116 (put 'riece-define-keys 'lisp-indent-function 1)
 117 (put 'riece-define-keys-safe 'lisp-indent-function 1)
 118 (put 'riece-local-set-keys 'lisp-indent-function 1)
 119
 120 (defun riece-define-keys-1 (keymap plist &optional safe)
 121   "Assign KEYMAP keys from PLIST.
 122 If optional argument SAFE is nil, overwrite previous definitions."
 123   (unless keymap
 124     (error "Can't set keys in a null keymap"))
 125   (cond
 126    ((symbolp keymap)
 127     (setq keymap (symbol-value keymap)))
 128    ((keymapp keymap))
 129    ((listp keymap)
 130     (set (car keymap) nil)
 131     (define-prefix-command (car keymap))
 132     (define-key (symbol-value (nth 2 keymap))
 133       (if (symbolp (nth 1 keymap))
 134           (symbol-value (nth 1 keymap))
 135         (nth 1 keymap))
 136       (car keymap))
 137     (setq keymap (symbol-value (car keymap)))))
 138   (let (key)
 139     (while plist
 140       (if (symbolp (setq key (car plist)))
 141           (setq key (symbol-value key)))
 142       (setq plist (cdr plist))
 143       (if (or (not safe)
 144               (eq (lookup-key keymap key) 'undefined))
 145           (define-key keymap key (car plist))
 146         (car plist))
 147       (setq plist (cdr plist)))))
 148
 149 (when t
 150   (riece-define-keys riece-dialogue-mode-map
 151     "\177" scroll-down
 152     [delete] scroll-down
 153     [backspace] scroll-down
 154     [return] scroll-up
 155     " " scroll-up
 156     [home] beginning-of-buffer
 157     "$" end-of-buffer
 158     [end] end-of-buffer
 159     "/" riece-command-raw
 160     ">" end-of-buffer
 161     "<" beginning-of-buffer
 162     "^" riece-command-list-addons
 163     "\C-ta" riece-command-toggle-away
 164     "c" riece-command-select-command-buffer
 165     "f" riece-command-finger
 166     "\C-tf" riece-command-toggle-freeze
 167     "\C-to" riece-command-toggle-own-freeze
 168     "\C-tu" riece-command-toggle-user-list-buffer-mode
 169     "\C-tc" riece-command-toggle-channel-buffer-mode
 170     "\C-tC" riece-command-toggle-channel-list-buffer-mode
 171     "\C-tl" riece-command-change-layout
 172     "i" riece-command-invite
 173     "j" riece-command-join
 174     "\C-k" riece-command-kick
 175     "l" riece-command-list
 176     "M" riece-command-change-mode
 177     "n" riece-command-change-nickname
 178     "N" riece-command-names
 179     "o" other-window
 180     "O" riece-command-open-server
 181     "C" riece-command-close-server
 182     "M" riece-command-universal-server-name-argument
 183     "p" riece-command-enter-message-to-user
 184     "q" riece-command-quit
 185     "r" riece-command-configure-windows
 186     "x" riece-command-copy-region
 187     "t" riece-command-topic
 188     "w" riece-command-who
 189     "z" riece-command-suspend-resume)
 190
 191   (riece-define-keys riece-command-mode-map
 192     "\r" riece-command-enter-message
 193     [(control return)] riece-command-enter-message-as-notice
 194     [tab] riece-command-complete-user)
 195
 196   (riece-define-keys (riece-command-map riece-command-prefix
 197                                         riece-command-mode-map)
 198     "\177" riece-command-scroll-down
 199     [delete] riece-command-scroll-down
 200     [backspace] riece-command-scroll-down
 201     " " riece-command-scroll-up
 202     [home] riece-command-beginning-of-buffer
 203     "$" riece-command-end-of-buffer
 204     [end] riece-command-end-of-buffer
 205     ">" riece-command-next-channel
 206     "<" riece-command-previous-channel
 207     "\C-j" riece-command-next-channel
 208     "\C-n" riece-command-names
 209     "l" riece-command-list
 210     "\C-m" riece-command-change-mode
 211     "o" riece-command-set-operators
 212     "\C-p" riece-command-part
 213     "r" riece-command-configure-windows
 214     "v" riece-command-set-speakers
 215     "V" riece-version)
 216   (set-keymap-parent riece-command-map riece-dialogue-mode-map)
 217
 218   (riece-define-keys riece-user-list-mode-map
 219     "o" riece-command-set-operators
 220     "v" riece-command-set-voices
 221     "f" riece-command-finger
 222     " " riece-command-user-list-scroll-up
 223     "\177" riece-command-user-list-scroll-down
 224     [delete] riece-command-user-list-scroll-down
 225     [backspace] riece-command-user-list-scroll-down
 226     "c" riece-command-select-command-buffer)
 227
 228   (riece-define-keys riece-channel-list-mode-map
 229     ">" riece-command-next-channel
 230     "<" riece-command-previous-channel
 231     "o" other-window
 232     "c" riece-command-select-command-buffer)
 233
 234   (riece-define-keys-1 riece-dialogue-mode-map riece-select-keys)
 235   (riece-define-keys-1 riece-channel-list-mode-map riece-select-keys))
 236
 237 (defun riece-read-variables-files (&optional file)
 238   "Read variables FILEs."
 239   (or (file-directory-p riece-directory)
 240       (make-directory riece-directory))
 241   (let ((files (if file
 242                    (setq riece-variables-file file
 243                          riece-variables-files (list file))
 244                  riece-variables-files)))
 245     (while files
 246       (condition-case nil
 247           (load (expand-file-name (car files)))
 248         (file-error nil))
 249       (setq files (cdr files)))))
 250
 251 (defvar print-quoted)
 252 (defvar print-escape-multibyte)
 253 (defun riece-save-variables-files ()
 254   "Save current settings to `riece-variables-file'."
 255   (with-temp-file riece-saved-variables-file
 256     (let ((print-quoted t)
 257           (print-readably t)
 258           print-escape-multibyte
 259           print-level
 260           print-length
 261           (variables riece-saved-forms))
 262       (while variables
 263         (prin1 `(setq ,(car variables)
 264                       ',(symbol-value (car variables)))
 265                (current-buffer))
 266         (insert "\n")
 267         (setq variables (cdr variables)))))
 268   (setq riece-save-variables-are-dirty nil))
 269
 270 ;;;###autoload
 271 (defun riece (&optional confirm)
 272   "Connect to the IRC server and start chatting.
 273 If optional argument CONFIRM is non-nil, ask which IRC server to connect."
 274   (interactive "P")
 275   (riece-read-variables-files (if noninteractive
 276                                   (car command-line-args-left)))
 277   (run-hooks 'riece-after-load-startup-hook)
 278   (if (riece-server-opened)
 279       (riece-command-configure-windows)
 280     (modify-frame-parameters (selected-frame)
 281                              (list (cons 'riece-window-configuration
 282                                          (current-window-configuration))))
 283     (unless riece-addons-insinuated
 284       (setq riece-addons (riece-resolve-addons riece-addons))
 285       (let ((pointer riece-addons))
 286         (while pointer
 287           (riece-insinuate-addon (car pointer) riece-debug)
 288           (setq pointer (cdr pointer))))
 289       (setq riece-addons-insinuated t))
 290     (if (or confirm (null riece-server))
 291         (setq riece-server (completing-read "Server: " riece-server-alist)))
 292     (if (stringp riece-server)
 293         (setq riece-server (riece-server-name-to-server riece-server)))
 294     (riece-create-buffers)
 295     (if riece-max-buffer-size
 296         (setq riece-shrink-buffer-idle-timer
 297               (riece-run-with-idle-timer
 298                riece-shrink-buffer-idle-time-delay t
 299                (lambda ()
 300                  (let ((buffers riece-buffer-list))
 301                    (while buffers
 302                      (if (buffer-live-p (car buffers))
 303                          (if (eq (derived-mode-class
 304                                   (with-current-buffer (car buffers)
 305                                     major-mode))
 306                                  'riece-dialogue-mode)
 307                              (riece-shrink-buffer (car buffers)))
 308                        (delq (car buffers) riece-buffer-list))
 309                      (setq buffers (cdr buffers))))))))
 310     (switch-to-buffer riece-command-buffer)
 311     (riece-display-connect-signals)
 312     (riece-redisplay-buffers)
 313     (riece-open-server riece-server "")
 314     ;; If no server process is available, exit.
 315     (if (null riece-server-process-alist)
 316         (riece-exit)
 317       (let ((server-list riece-startup-server-list))
 318         (while server-list
 319           (riece-command-open-server (car server-list))
 320           (setq server-list (cdr server-list))))
 321       (let ((channel-list riece-startup-channel-list)
 322             server)
 323         (while channel-list
 324           (setq server (riece-identity-server
 325                         (riece-parse-identity (car channel-list))))
 326           (unless (riece-server-opened server)
 327             (riece-command-open-server server))
 328           (setq channel-list (cdr channel-list))))
 329       (let ((pointer riece-addons))
 330         (while pointer
 331           (unless (get (car pointer) 'riece-addon-default-disabled)
 332             (riece-enable-addon (car pointer) riece-debug))
 333           (setq pointer (cdr pointer))))
 334       (run-hooks 'riece-startup-hook)
 335       (message "%s" (substitute-command-keys
 336                      "Type \\[describe-mode] for help")))))
 337
 338 (defun riece-shrink-buffer (buffer)
 339   (save-excursion
 340     (set-buffer buffer)
 341     (goto-char (point-min))
 342     (while (> (buffer-size) riece-max-buffer-size)
 343       (let* ((inhibit-read-only t)
 344              buffer-read-only
 345              (end (progn
 346                     (goto-char riece-shrink-buffer-remove-chars)
 347                     (beginning-of-line 2)
 348                     (point)))
 349              (overlays (riece-overlays-in (point-min) end)))
 350         (while overlays
 351           (riece-delete-overlay (car overlays))
 352           (setq overlays (cdr overlays)))
 353         (delete-region (point-min) end)))))
 354
 355 (defun riece-exit ()
 356   (if riece-save-variables-are-dirty
 357       (riece-save-variables-files))
 358   (while riece-buffer-list
 359     (if (and (get-buffer (car riece-buffer-list))
 360              (buffer-live-p (car riece-buffer-list)))
 361         (funcall riece-buffer-dispose-function (car riece-buffer-list)))
 362     (setq riece-buffer-list (cdr riece-buffer-list)))
 363   (if riece-shrink-buffer-idle-timer
 364       (riece-cancel-timer riece-shrink-buffer-idle-timer))
 365   (riece-clear-signal-slots)
 366   (setq riece-server nil
 367         riece-current-channels nil
 368         riece-current-channel nil
 369         riece-channel-buffer nil
 370         riece-channel-buffer-alist nil
 371         riece-user-indicator nil
 372         riece-long-channel-indicator "None"
 373         riece-channel-list-indicator "No channel"
 374         riece-away-indicator "-"
 375         riece-operator-indicator "-"
 376         riece-channel-status-indicator "-"
 377         riece-freeze-indicator "-")
 378   (modify-frame-parameters (selected-frame)
 379                            (list (list 'riece-window-configuration)))
 380   (delete-other-windows)
 381   (run-hooks 'riece-exit-hook))
 382
 383 (defun riece-command-mode ()
 384   "Major mode for Riece.  Normal edit function are available.
 385 Typing Return or Linefeed enters the current line in the dialogue.
 386 The following special commands are available:
 387 For a list of the generic commands type \\[riece-command-generic] ? RET.
 388 \\{riece-command-mode-map}"
 389   (interactive)
 390   (kill-all-local-variables)
 391
 392   ;; Make `truncate-partial-width-windows' buffer local and set it to
 393   ;; nil.  This causes `truncate-lines' to directly control line
 394   ;; truncation.
 395   (make-local-variable 'truncate-partial-width-windows)
 396   (setq truncate-partial-width-windows nil)
 397
 398   (setq riece-away-indicator "-"
 399         riece-operator-indicator "-"
 400         riece-channel-status-indicator "-"
 401         major-mode 'riece-command-mode
 402         mode-name "Command"
 403         mode-line-buffer-identification
 404         (riece-mode-line-buffer-identification
 405          '("Riece: "
 406            riece-away-indicator
 407            riece-operator-indicator
 408            riece-channel-status-indicator
 409            " "
 410            riece-user-indicator
 411            " "
 412            riece-channel-indicator))
 413         truncate-lines nil)
 414   (riece-simplify-mode-line-format)
 415   (use-local-map riece-command-mode-map)
 416
 417   (unless riece-command-mode-syntax-table
 418     (setq riece-command-mode-syntax-table
 419           (copy-syntax-table (syntax-table)))
 420     (set-syntax-table riece-command-mode-syntax-table)
 421     (mapcar
 422      (lambda (c) (modify-syntax-entry c "w"))
 423      "^[]{}'`"))
 424
 425   (run-hooks 'riece-command-mode-hook))
 426
 427 (defun riece-dialogue-mode ()
 428   "Major mode for displaying the IRC dialogue.
 429 All normal editing commands are turned off.
 430 Instead, these commands are available:
 431 \\{riece-dialogue-mode-map}"
 432   (kill-all-local-variables)
 433   (make-local-variable 'riece-freeze)
 434   (make-local-variable 'riece-freeze-indicator)
 435
 436   ;; Make `truncate-partial-width-windows' buffer local and set it to
 437   ;; nil.  This causes `truncate-lines' to directly control line truncation.
 438   (make-local-variable 'truncate-partial-width-windows)
 439   (setq truncate-partial-width-windows nil)
 440
 441   (setq riece-freeze riece-default-freeze
 442         riece-away-indicator "-"
 443         riece-operator-indicator "-"
 444         riece-channel-status-indicator "-"
 445         major-mode 'riece-dialogue-mode
 446         mode-name "Dialogue"
 447         mode-line-buffer-identification
 448         (riece-mode-line-buffer-identification
 449          '("Riece: "
 450            riece-away-indicator
 451            riece-operator-indicator
 452            riece-freeze-indicator
 453            riece-channel-status-indicator
 454            " "
 455            riece-channel-list-indicator " "))
 456         truncate-lines nil
 457         buffer-read-only t)
 458   (riece-simplify-mode-line-format)
 459   (use-local-map riece-dialogue-mode-map)
 460   (buffer-disable-undo)
 461   (run-hooks 'riece-dialogue-mode-hook))
 462
 463 (define-derived-mode riece-others-mode riece-dialogue-mode
 464   "Others"
 465   "Major mode for displaying the IRC others message except current channel.
 466 All normal editing commands are turned off.
 467 Instead, these commands are available:
 468 \\{riece-others-mode-map}")
 469
 470 (define-derived-mode riece-channel-mode riece-dialogue-mode
 471   "Channel"
 472   "Major mode for displaying the IRC current channel buffer.
 473 All normal editing commands are turned off.
 474 Instead, these commands are available:
 475 \\{riece-channel-mode-map}"
 476   (make-local-variable 'riece-channel-buffer-window-point)
 477   (setq mode-line-buffer-identification
 478         (riece-mode-line-buffer-identification
 479          '("Riece: "
 480            riece-away-indicator
 481            riece-operator-indicator
 482            riece-freeze-indicator
 483            riece-channel-status-indicator
 484            " "
 485            riece-long-channel-indicator))))
 486
 487 (defun riece-channel-list-mode ()
 488   "Major mode for displaying channel list.
 489 All normal editing commands are turned off."
 490   (kill-all-local-variables)
 491   (buffer-disable-undo)
 492
 493   ;; Make `truncate-partial-width-windows' buffer local and set it to
 494   ;; nil.  This causes `truncate-lines' to directly control line truncation.
 495   (make-local-variable 'truncate-partial-width-windows)
 496   (setq truncate-partial-width-windows nil)
 497
 498   (setq major-mode 'riece-channel-list-mode
 499         mode-name "Channels"
 500         mode-line-buffer-identification
 501         (riece-mode-line-buffer-identification '("Riece: "))
 502         truncate-lines t
 503         buffer-read-only t)
 504   (make-local-hook 'riece-update-buffer-functions)
 505   (add-hook 'riece-update-buffer-functions
 506             'riece-update-channel-list-buffer nil t)
 507   (use-local-map riece-channel-list-mode-map)
 508   (run-hooks 'riece-channel-list-mode-hook))
 509
 510 (defun riece-user-list-mode ()
 511   "Major mode for displaying members in the IRC current channel buffer.
 512 All normal editing commands are turned off.
 513 Instead, these commands are available:
 514 \\{riece-user-list-mode-map}"
 515   (kill-all-local-variables)
 516   (buffer-disable-undo)
 517
 518   ;; Make `truncate-partial-width-windows' buffer local and set it to
 519   ;; nil.  This causes `truncate-lines' to directly control line truncation.
 520   (make-local-variable 'truncate-partial-width-windows)
 521   (setq truncate-partial-width-windows nil)
 522
 523   (setq major-mode 'riece-user-list-mode
 524         mode-name "Users"
 525         mode-line-buffer-identification
 526         (riece-mode-line-buffer-identification
 527          '("Riece: " riece-long-channel-indicator " "))
 528         truncate-lines t
 529         buffer-read-only t)
 530   (if (boundp 'transient-mark-mode)
 531       (set (make-local-variable 'transient-mark-mode) t))
 532   (make-local-hook 'riece-update-buffer-functions)
 533   (add-hook 'riece-update-buffer-functions
 534             'riece-update-user-list-buffer nil t)
 535   (use-local-map riece-user-list-mode-map)
 536   (run-hooks 'riece-user-list-mode-hook))
 537
 538 (defun riece-create-buffers ()
 539   (let ((alist riece-buffer-alist))
 540     (while alist
 541       (save-excursion
 542         (set-buffer (apply #'riece-get-buffer-create
 543                            (cdr (car alist))))
 544         (set (car (car alist)) (current-buffer))
 545         (unless (or (null (nth 2 (car alist)))
 546                     (eq major-mode (nth 2 (car alist))))
 547           (funcall (nth 2 (car alist))))
 548         (setq alist (cdr alist))))))
 549
 550 (defvar reporter-prompt-for-summary-p)
 551 (defun riece-submit-bug-report (&optional recent-messages recent-keys)
 552   "Submit via mail a bug report on Riece."
 553   ;; This strange form ensures that (recent-keys) is the value before
 554   ;; the bug subject string is read.
 555   (interactive (list (riece-recent-messages 20) (recent-keys)))
 556   (message "Querying server version...")
 557   (let ((pointer riece-server-process-alist)
 558         nickname)
 559     (while pointer
 560       (when (riece-server-process-opened (cdr (car pointer)))
 561         (process-send-string (cdr (car pointer)) "VERSION\r\n")
 562         (if (setq nickname
 563                   (with-current-buffer (process-buffer (cdr (car pointer)))
 564                     riece-real-nickname))
 565             (process-send-string
 566              (cdr (car pointer))
 567              (format "PRIVMSG %s :\1VERSION\1\r\n" nickname))))
 568       (setq pointer (cdr pointer))))
 569   (sit-for 3)
 570   (message "Querying server version...done")
 571   (require 'reporter)
 572   (let ((reporter-prompt-for-summary-p t))
 573     (unless riece-debug
 574       (error "Please turn on riece-debug and restart Riece."))
 575     (reporter-submit-bug-report
 576      "liece@unixuser.org"
 577      (riece-version)
 578      '(riece-debug)
 579      nil
 580      nil
 581      "This bug report will be sent to the Riece Development Team,
 582 not to your local site managers!!
 583
 584 Please write in Japanese or English, because the Riece maintainers do
 585 not have translators to read other languages for them.
 586
 587 Please describe as succinctly as possible:
 588 \t- What happened.
 589 \t- What you thought should have happened.
 590 \t- Precisely what you were doing at the time.
 591
 592 Also include a reliable recipe for triggering the bug, as well as
 593 any lisp back-traces that you may have.
 594 \(setq stack-trace-on-error t\), or \(setq debug-on-error t\) if you
 595 are familiar with the debugger, to get a lisp back-trace.")
 596     (delete-other-windows)
 597     (save-excursion
 598       (goto-char (point-max))
 599       (insert
 600        "\nAdd-on state:\n"
 601        "------------\n"
 602        (save-window-excursion
 603          (save-excursion
 604            (riece-command-list-addons)
 605            (search-forward "\n\n")
 606            (buffer-substring (point-min) (point)))))
 607       (insert "Recent messages from servers:\n"
 608               "--------------------------")
 609       (let ((pointer riece-server-process-alist))
 610         (while pointer
 611           (insert "\n- \"" (car (car pointer)) "\", \n"
 612                   (format "%S" (if (equal (car (car pointer)) "")
 613                                    riece-server
 614                                  (cdr (assoc (car (car pointer))
 615                                              riece-server-alist))))
 616                   "\n"
 617                   (if (riece-server-process-opened (cdr (car pointer)))
 618                       (save-excursion
 619                         (set-buffer (process-buffer (cdr (car pointer))))
 620                         (goto-char (point-max))
 621                         (beginning-of-line -60)
 622                         (buffer-substring (point) (point-max)))
 623                     "(closed server)"))
 624           (setq pointer (cdr pointer))))
 625       ;; Insert recent keystrokes.
 626       (insert "\n\nRecent keystrokes:\n"
 627               "-----------------\n\n")
 628       (let ((before-keys (point)))
 629         (insert (key-description recent-keys))
 630         (save-restriction
 631           (narrow-to-region before-keys (point))
 632           (goto-char before-keys)
 633           (while (progn (move-to-column 50) (not (eobp)))
 634             (search-forward " " nil t)
 635             (insert "\n"))))
 636       ;; Insert recent minibuffer messages.
 637       (insert "\n\nRecent messages (most recent first):\n"
 638               "-----------------------------------\n"
 639               recent-messages))))
 640
 641 (provide 'riece)
 642
 643 ;;; riece.el ends here