cgit.sxemacs.org Git - riece/blob - lisp/riece.el

   1 ;;; riece.el --- IRC client for Emacsen
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Created: 1998-09-28
   6 ;; Keywords: IRC, riece
   7
   8 ;; This file is part of Riece.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Code:
  26
  27 (eval-when-compile (require 'riece-inlines))
  28
  29 (if (featurep 'xemacs)
  30     (require 'riece-xemacs)
  31   (require 'riece-emacs))
  32
  33 (require 'riece-filter)
  34 (require 'riece-highlight)
  35 (require 'riece-display)
  36 (require 'riece-server)
  37 (require 'riece-compat)
  38 (require 'riece-commands)
  39
  40 (defvar riece-channel-list-mode-map (make-sparse-keymap))
  41 (defvar riece-user-list-mode-map (make-sparse-keymap))
  42
  43 (defvar riece-dialogue-mode-map
  44   (let ((keymap (make-keymap)))
  45     (suppress-keymap keymap 'nodigit)
  46     keymap))
  47
  48 (defvar riece-command-mode-map (make-keymap))
  49 (defvar riece-command-map (make-sparse-keymap))
  50
  51 (defvar riece-command-mode-syntax-table nil)
  52
  53 (put 'riece-command-mode 'mode-class 'special)
  54 (put 'riece-dialogue-mode 'mode-class 'special)
  55 (put 'riece-channel-list-mode 'mode-class 'special)
  56 (put 'riece-user-list-mode 'mode-class 'special)
  57 (put 'riece-channel-mode 'derived-mode-parent 'riece-dialogue-mode)
  58 (put 'riece-others-mode 'derived-mode-parent 'riece-dialogue-mode)
  59
  60 (defvar riece-buffer-mode-alist
  61   '((riece-dialogue-buffer . riece-dialogue-mode)
  62     (riece-others-buffer . riece-others-mode)
  63     (riece-channel-list-buffer . riece-channel-list-mode)
  64     (riece-private-buffer . riece-dialogue-mode)
  65     (riece-wallops-buffer)))
  66
  67 (defvar riece-select-keys
  68   '("1" riece-command-switch-to-channel-by-number-1
  69     "2" riece-command-switch-to-channel-by-number-2
  70     "3" riece-command-switch-to-channel-by-number-3
  71     "4" riece-command-switch-to-channel-by-number-4
  72     "5" riece-command-switch-to-channel-by-number-5
  73     "6" riece-command-switch-to-channel-by-number-6
  74     "7" riece-command-switch-to-channel-by-number-7
  75     "8" riece-command-switch-to-channel-by-number-8
  76     "9" riece-command-switch-to-channel-by-number-9
  77     "0" riece-command-switch-to-channel-by-number-10
  78     "\C-c1" riece-command-switch-to-channel-by-number-11
  79     "\C-c2" riece-command-switch-to-channel-by-number-12
  80     "\C-c3" riece-command-switch-to-channel-by-number-13
  81     "\C-c4" riece-command-switch-to-channel-by-number-14
  82     "\C-c5" riece-command-switch-to-channel-by-number-15
  83     "\C-c6" riece-command-switch-to-channel-by-number-16
  84     "\C-c7" riece-command-switch-to-channel-by-number-17
  85     "\C-c8" riece-command-switch-to-channel-by-number-18
  86     "\C-c9" riece-command-switch-to-channel-by-number-19
  87     "\C-c0" riece-command-switch-to-channel-by-number-20))
  88
  89 ;;; Keymap macros. -- borrowed from `gnus-util.el'.
  90 (defmacro riece-local-set-keys (&rest plist)
  91   "Set the keys in PLIST in the current keymap."
  92   `(riece-define-keys-1 (current-local-map) ',plist))
  93
  94 (defmacro riece-define-keys (keymap &rest plist)
  95   "Assign KEYMAP keys from PLIST."
  96   `(riece-define-keys-1 ',keymap ',plist))
  97
  98 (defmacro riece-define-keys-safe (keymap &rest plist)
  99   "Assign KEYMAP keys from PLIST without overwriting previous definitions."
 100   `(riece-define-keys-1 ',keymap ',plist t))
 101
 102 (put 'riece-define-keys 'lisp-indent-function 1)
 103 (put 'riece-define-keys-safe 'lisp-indent-function 1)
 104 (put 'riece-local-set-keys 'lisp-indent-function 1)
 105
 106 (defun riece-define-keys-1 (keymap plist &optional safe)
 107   "Assign KEYMAP keys from PLIST.
 108 If optional argument SAFE is nil, overwrite previous definitions."
 109   (unless keymap
 110     (error "Can't set keys in a null keymap"))
 111   (cond
 112    ((symbolp keymap)
 113     (setq keymap (symbol-value keymap)))
 114    ((keymapp keymap))
 115    ((listp keymap)
 116     (set (car keymap) nil)
 117     (define-prefix-command (car keymap))
 118     (define-key (symbol-value (nth 2 keymap)) (nth 1 keymap) (car keymap))
 119     (setq keymap (symbol-value (car keymap)))))
 120   (let (key)
 121     (while plist
 122       (when (symbolp (setq key (pop plist)))
 123         (setq key (symbol-value key)))
 124       (if (or (not safe)
 125               (eq (lookup-key keymap key) 'undefined))
 126           (define-key keymap key (pop plist))
 127         (pop plist)))))
 128
 129 (when t
 130   (riece-define-keys riece-dialogue-mode-map
 131     "\177" scroll-down
 132     [delete] scroll-down
 133     [backspace] scroll-down
 134     [return] scroll-up
 135     " " scroll-up
 136     "$" end-of-buffer
 137     "/" riece-command-raw
 138     ">" end-of-buffer
 139     "<" beginning-of-buffer
 140     "\C-ta" riece-command-toggle-away
 141     "c" riece-command-select-command-buffer
 142     "f" riece-command-finger
 143     "\C-tf" riece-command-toggle-freeze
 144     "\C-to" riece-command-toggle-own-freeze
 145     "\C-tu" riece-command-toggle-user-list-buffer-mode
 146     "\C-tc" riece-command-toggle-channel-buffer-mode
 147     "i" riece-command-invite
 148     "j" riece-command-join
 149     "\C-k" riece-command-kick
 150     "l" riece-command-list
 151     "m" riece-dialogue-enter-message
 152     "M" riece-command-change-mode
 153     "n" riece-command-change-nickname
 154     "\C-n" riece-command-names
 155     "o" other-window
 156     "O" riece-command-open-server
 157     "C" riece-command-close-server
 158     "M" riece-command-universal-server-name-argument
 159     "q" riece-command-quit
 160     "r" riece-command-configure-windows
 161     "x" riece-command-copy-region
 162     "t" riece-command-topic
 163     "w" riece-command-who)
 164
 165   (riece-define-keys riece-command-mode-map
 166     "\r" riece-command-enter-message
 167     [tab] riece-command-complete
 168     [(meta control c) >] riece-command-push
 169     [(meta control c) <] riece-command-pop)
 170
 171   (riece-define-keys (riece-command-map "\C-c" riece-command-mode-map)
 172     "\177" riece-command-scroll-down
 173     [delete] riece-command-scroll-down
 174     [backspace] riece-command-scroll-down
 175     " " riece-command-scroll-up
 176     "$" riece-command-end-of-buffer
 177     ">" riece-command-next-channel
 178     "<" riece-command-previous-channel
 179     "\C-j" riece-command-next-channel
 180     "\C-n" riece-command-names
 181     "l" riece-command-list
 182     "\C-m" riece-command-change-mode
 183     "o" riece-command-set-operators
 184     "\C-p" riece-command-part
 185     "r" riece-command-configure-windows
 186     "v" riece-command-set-voices)
 187   (set-keymap-parent riece-command-map riece-dialogue-mode-map)
 188
 189   (riece-define-keys riece-user-list-mode-map
 190     "o" riece-command-set-operators
 191     "v" riece-command-set-voices
 192     "f" riece-command-finger
 193     " " riece-command-nick-scroll-up
 194     "\177" riece-command-nick-scroll-down
 195     [delete] riece-command-nick-scroll-down
 196     [backspace] riece-command-nick-scroll-down
 197     "c" riece-command-select-command-buffer)
 198
 199   (riece-define-keys riece-channel-list-mode-map
 200     ">" riece-command-next-channel
 201     "<" riece-command-previous-channel
 202     "u" riece-command-unread-channel
 203     "o" other-window
 204     "c" riece-command-select-command-buffer)
 205
 206   (riece-define-keys-1 riece-dialogue-mode-map riece-select-keys)
 207   (riece-define-keys-1 riece-channel-list-mode-map riece-select-keys))
 208
 209 (defun riece-read-variables-files (&optional file)
 210   "Read variables FILEs."
 211   (or (file-directory-p riece-directory)
 212       (make-directory riece-directory))
 213   (let ((files (if file
 214                    (setq riece-variables-file file
 215                          riece-variables-files (list file))
 216                  riece-variables-files)))
 217     (while files
 218       (condition-case nil
 219           (load (expand-file-name (car files)))
 220         (file-error nil))
 221       (setq files (cdr files)))))
 222
 223 (defvar print-quoted)
 224 (defvar print-escape-multibyte)
 225 (defun riece-save-variables-files ()
 226   "Save current settings to `riece-variables-file'."
 227   (with-temp-file riece-saved-variables-file
 228     (let ((print-quoted t)
 229           (print-readably t)
 230           print-escape-multibyte
 231           print-level
 232           print-length
 233           (variables riece-saved-forms))
 234       (while variables
 235         (prin1 `(setq ,(car variables)
 236                       ',(symbol-value (car variables)))
 237                (current-buffer))
 238         (insert "\n")
 239         (setq variables (cdr variables)))))
 240   (setq riece-save-variables-are-dirty nil))
 241
 242 ;;;###autoload
 243 (defun riece (&optional confirm)
 244   "Connect to the IRC server and start chatting.
 245 If optional argument CONFIRM is non-nil, ask which IRC server to connect.
 246 If already connected, just pop up the windows."
 247   (interactive "P")
 248   (riece-read-variables-files
 249    (car command-line-args-left))
 250   (pop command-line-args-left)
 251   (run-hooks 'riece-after-load-startup-hook)
 252   (if (riece-server-opened)
 253       (riece-configure-windows)
 254     (switch-to-buffer (riece-get-buffer-create riece-command-buffer))
 255     (unless (eq major-mode 'riece-command-mode)
 256       (riece-command-mode))
 257     (if (or confirm (null riece-server))
 258         (setq riece-server (completing-read "Server: " riece-server-alist)))
 259     (if (stringp riece-server)
 260         (setq riece-server (riece-server-name-to-server riece-server)))
 261     (setq riece-server-process (riece-start-server riece-server))
 262     (riece-create-buffers)
 263     (riece-configure-windows)
 264     (let ((channel-list riece-startup-channel-list))
 265       (while channel-list
 266         (if (listp (car channel-list))
 267             (riece-command-join (car (car channel-list))
 268                                 (cadr (car channel-list)))
 269           (riece-command-join (car channel-list)))
 270         (setq channel-list (cdr channel-list))))
 271     (run-hooks 'riece-startup-hook)
 272     (message "%s" (substitute-command-keys
 273                    "Type \\[describe-mode] for help"))))
 274
 275 (defun riece-exit ()
 276   (setq riece-server nil)
 277   (if riece-save-variables-are-dirty
 278       (riece-save-variables-files))
 279   (riece-clear-system)
 280   (run-hooks 'riece-exit-hook))
 281
 282 (defun riece-command-mode ()
 283   "Major mode for Riece.  Normal edit function are available.
 284 Typing Return or Linefeed enters the current line in the dialogue.
 285 The following special commands are available:
 286 For a list of the generic commands type \\[riece-command-generic] ? RET.
 287 \\{riece-command-mode-map}"
 288   (interactive)
 289   (kill-all-local-variables)
 290
 291   (setq major-mode 'riece-command-mode
 292         mode-name "Commands"
 293         riece-away-indicator "-"
 294         riece-freeze-indicator "-"
 295         riece-own-freeze-indicator "-"
 296         mode-line-buffer-identification
 297         (riece-mode-line-buffer-identification
 298          '("Riece: "
 299            mode-line-modified
 300            riece-away-indicator
 301            "-- " riece-current-channel " " riece-real-nickname)))
 302   (riece-simplify-mode-line-format)
 303   (use-local-map riece-command-mode-map)
 304
 305   (unless riece-command-mode-syntax-table
 306     (setq riece-command-mode-syntax-table
 307           (copy-syntax-table (syntax-table)))
 308     (set-syntax-table riece-command-mode-syntax-table)
 309     (mapcar
 310      (lambda (c) (modify-syntax-entry c "w"))
 311      "^[]{}'`"))
 312
 313   (run-hooks 'riece-command-mode-hook))
 314
 315 (defun riece-dialogue-mode ()
 316   "Major mode for displaying the IRC dialogue.
 317 All normal editing commands are turned off.
 318 Instead, these commands are available:
 319 \\{riece-dialogue-mode-map}"
 320   (kill-all-local-variables)
 321
 322   (make-local-variable 'riece-freeze)
 323   (make-local-variable 'riece-freeze-indicator)
 324   (make-local-variable 'riece-own-freeze)
 325   (make-local-variable 'riece-own-freeze-indicator)
 326   (make-local-variable 'tab-stop-list)
 327
 328   (setq riece-freeze riece-default-freeze
 329         riece-freeze-indicator (if riece-freeze "F" "-")
 330         riece-own-freeze riece-default-own-freeze
 331         riece-own-freeze-indicator (if riece-own-freeze "M" "-")
 332
 333         major-mode 'riece-dialogue-mode
 334         mode-name "Dialogue"
 335         mode-line-buffer-identification
 336         (riece-mode-line-buffer-identification
 337          '("Riece: "
 338            mode-line-modified
 339            riece-away-indicator
 340            riece-freeze-indicator
 341            riece-own-freeze-indicator
 342            " " riece-channel-list-indicator " "))
 343         buffer-read-only t
 344         tab-stop-list riece-tab-stop-list)
 345   (riece-simplify-mode-line-format)
 346   (use-local-map riece-dialogue-mode-map)
 347   (buffer-disable-undo)
 348   (run-hooks 'riece-dialogue-mode-hook))
 349
 350 (define-derived-mode riece-others-mode riece-dialogue-mode
 351   "Others"
 352   "Major mode for displaying the IRC others message except current channel.
 353 All normal editing commands are turned off.
 354 Instead, these commands are available:
 355 \\{riece-others-mode-map}")
 356
 357 (define-derived-mode riece-channel-mode riece-dialogue-mode
 358   "Channel"
 359   "Major mode for displaying the IRC current channel buffer.
 360 All normal editing commands are turned off.
 361 Instead, these commands are available:
 362 \\{riece-channel-mode-map}"
 363   (setq mode-line-buffer-identification
 364         (riece-mode-line-buffer-identification
 365          '("Riece: "
 366            mode-line-modified
 367            riece-away-indicator
 368            riece-freeze-indicator
 369            riece-own-freeze-indicator
 370            " "
 371            riece-channel-indicator))))
 372
 373 (defun riece-channel-list-mode ()
 374   "Major mode for displaying channel list.
 375 All normal editing commands are turned off."
 376   (kill-all-local-variables)
 377   (setq major-mode 'riece-channel-list-mode
 378         mode-name "Channels"
 379         mode-line-buffer-identification
 380         (riece-mode-line-buffer-identification '("Riece: "))
 381         truncate-lines t
 382         buffer-read-only t)
 383   (use-local-map riece-channel-list-mode-map)
 384   (run-hooks 'riece-channel-list-mode-hook))
 385
 386 (defun riece-user-list-mode ()
 387   "Major mode for displaying members in the IRC current channel buffer.
 388 All normal editing commands are turned off.
 389 Instead, these commands are available:
 390 \\{riece-user-list-mode-map}"
 391   (kill-all-local-variables)
 392   (setq mode-line-modified "--- "
 393         major-mode 'riece-user-list-mode
 394         mode-name "Riece Channel member"
 395         mode-line-buffer-identification
 396         (riece-mode-line-buffer-identification
 397          '("Riece: " riece-channel-indicator " "))
 398         truncate-lines t
 399         buffer-read-only t)
 400   (if (boundp 'transient-mark-mode)
 401       (set (make-local-variable 'transient-mark-mode) t))
 402   (use-local-map riece-user-list-mode-map)
 403   (run-hooks 'riece-user-list-mode-hook))
 404
 405 (defun riece-create-buffers ()
 406   (let ((alist riece-buffer-mode-alist))
 407     (while alist
 408       (save-excursion
 409         (set-buffer (riece-get-buffer-create
 410                      (symbol-value (car (car alist)))))
 411         (unless (or (null (cdr (car alist)))
 412                     (eq major-mode (cdr (car alist))))
 413           (funcall (cdr (car alist))))
 414         (setq alist (cdr alist))))))
 415
 416 (provide 'riece)
 417
 418 ;;; riece.el ends here