cgit.sxemacs.org Git - riece/blob - lisp/riece.el

   1 ;;; riece.el --- IRC client for Emacsen
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Created: 1998-09-28
   6 ;; Keywords: IRC, riece
   7
   8 ;; This file is part of Riece.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Code:
  26
  27 (require 'riece-display)
  28 (require 'riece-server)
  29 (require 'riece-compat)
  30 (require 'riece-commands)
  31 (require 'riece-addon)
  32 (require 'riece-signal)
  33
  34 (autoload 'derived-mode-class "derived")
  35
  36 (defvar riece-channel-list-mode-map (make-sparse-keymap))
  37 (defvar riece-user-list-mode-map (make-sparse-keymap))
  38
  39 (defvar riece-dialogue-mode-map
  40   (let ((keymap (make-keymap)))
  41     (suppress-keymap keymap 'nodigit)
  42     keymap))
  43
  44 (defvar riece-command-mode-map (make-keymap))
  45 (defvar riece-command-map (make-sparse-keymap))
  46
  47 (defvar riece-command-mode-syntax-table nil)
  48
  49 (put 'riece-command-mode 'mode-class 'special)
  50 (put 'riece-dialogue-mode 'mode-class 'special)
  51 (put 'riece-others-mode 'derived-mode-parent 'riece-dialogue-mode)
  52 (put 'riece-channel-list-mode 'mode-class 'special)
  53 (put 'riece-user-list-mode 'mode-class 'special)
  54 (put 'riece-channel-mode 'derived-mode-parent 'riece-dialogue-mode)
  55
  56 (defvar riece-buffer-alist
  57   '((riece-command-buffer "*Command*" riece-command-mode)
  58     (riece-dialogue-buffer "*Dialogue*" riece-dialogue-mode)
  59     (riece-others-buffer "*Others*" riece-others-mode)
  60     (riece-channel-list-buffer "*Channels*" riece-channel-list-mode)
  61     (riece-user-list-buffer " *Users*" riece-user-list-mode)))
  62
  63 (defvar riece-shrink-buffer-idle-timer nil
  64   "Timer object to periodically shrink channel buffers.")
  65
  66 (defvar riece-addons-insinuated nil
  67   "Non nil if add-ons are already insinuated.")
  68
  69 (defvar riece-select-keys
  70   `("#" riece-command-switch-to-channel-by-number
  71     "1" riece-command-switch-to-channel-by-number-1
  72     "2" riece-command-switch-to-channel-by-number-2
  73     "3" riece-command-switch-to-channel-by-number-3
  74     "4" riece-command-switch-to-channel-by-number-4
  75     "5" riece-command-switch-to-channel-by-number-5
  76     "6" riece-command-switch-to-channel-by-number-6
  77     "7" riece-command-switch-to-channel-by-number-7
  78     "8" riece-command-switch-to-channel-by-number-8
  79     "9" riece-command-switch-to-channel-by-number-9
  80     "0" riece-command-switch-to-channel-by-number-10
  81     ,(concat riece-command-prefix "1")
  82     riece-command-switch-to-channel-by-number-11
  83     ,(concat riece-command-prefix "2")
  84     riece-command-switch-to-channel-by-number-12
  85     ,(concat riece-command-prefix "3")
  86     riece-command-switch-to-channel-by-number-13
  87     ,(concat riece-command-prefix "4")
  88     riece-command-switch-to-channel-by-number-14
  89     ,(concat riece-command-prefix "5")
  90     riece-command-switch-to-channel-by-number-15
  91     ,(concat riece-command-prefix "6")
  92     riece-command-switch-to-channel-by-number-16
  93     ,(concat riece-command-prefix "7")
  94     riece-command-switch-to-channel-by-number-17
  95     ,(concat riece-command-prefix "8")
  96     riece-command-switch-to-channel-by-number-18
  97     ,(concat riece-command-prefix "9")
  98     riece-command-switch-to-channel-by-number-19
  99     ,(concat riece-command-prefix "0")
 100     riece-command-switch-to-channel-by-number-20))
 101
 102 ;;; Keymap macros. -- borrowed from `gnus-util.el'.
 103 (defmacro riece-local-set-keys (&rest plist)
 104   "Set the keys in PLIST in the current keymap."
 105   `(riece-define-keys-1 (current-local-map) ',plist))
 106
 107 (defmacro riece-define-keys (keymap &rest plist)
 108   "Assign KEYMAP keys from PLIST."
 109   `(riece-define-keys-1 ',keymap ',plist))
 110
 111 (defmacro riece-define-keys-safe (keymap &rest plist)
 112   "Assign KEYMAP keys from PLIST without overwriting previous definitions."
 113   `(riece-define-keys-1 ',keymap ',plist t))
 114
 115 (put 'riece-define-keys 'lisp-indent-function 1)
 116 (put 'riece-define-keys-safe 'lisp-indent-function 1)
 117 (put 'riece-local-set-keys 'lisp-indent-function 1)
 118
 119 (defun riece-define-keys-1 (keymap plist &optional safe)
 120   "Assign KEYMAP keys from PLIST.
 121 If optional argument SAFE is nil, overwrite previous definitions."
 122   (unless keymap
 123     (error "Can't set keys in a null keymap"))
 124   (cond
 125    ((symbolp keymap)
 126     (setq keymap (symbol-value keymap)))
 127    ((keymapp keymap))
 128    ((listp keymap)
 129     (set (car keymap) nil)
 130     (define-prefix-command (car keymap))
 131     (define-key (symbol-value (nth 2 keymap))
 132       (if (symbolp (nth 1 keymap))
 133           (symbol-value (nth 1 keymap))
 134         (nth 1 keymap))
 135       (car keymap))
 136     (setq keymap (symbol-value (car keymap)))))
 137   (let (key)
 138     (while plist
 139       (if (symbolp (setq key (car plist)))
 140           (setq key (symbol-value key)))
 141       (setq plist (cdr plist))
 142       (if (or (not safe)
 143               (eq (lookup-key keymap key) 'undefined))
 144           (define-key keymap key (car plist))
 145         (car plist))
 146       (setq plist (cdr plist)))))
 147
 148 (when t
 149   (riece-define-keys riece-dialogue-mode-map
 150     "\177" scroll-down
 151     [delete] scroll-down
 152     [backspace] scroll-down
 153     [return] scroll-up
 154     " " scroll-up
 155     [home] beginning-of-buffer
 156     "$" end-of-buffer
 157     [end] end-of-buffer
 158     "/" riece-command-raw
 159     ">" end-of-buffer
 160     "<" beginning-of-buffer
 161     "^" riece-command-list-addons
 162     "\C-ta" riece-command-toggle-away
 163     "c" riece-command-select-command-buffer
 164     "f" riece-command-finger
 165     "\C-tf" riece-command-toggle-freeze
 166     "\C-to" riece-command-toggle-own-freeze
 167     "\C-tu" riece-command-toggle-user-list-buffer-mode
 168     "\C-tc" riece-command-toggle-channel-buffer-mode
 169     "\C-tC" riece-command-toggle-channel-list-buffer-mode
 170     "\C-tl" riece-command-change-layout
 171     "i" riece-command-invite
 172     "j" riece-command-join
 173     "\C-k" riece-command-kick
 174     "l" riece-command-list
 175     "M" riece-command-change-mode
 176     "n" riece-command-change-nickname
 177     "N" riece-command-names
 178     "o" other-window
 179     "O" riece-command-open-server
 180     "C" riece-command-close-server
 181     "M" riece-command-universal-server-name-argument
 182     "p" riece-command-enter-message-to-user
 183     "q" riece-command-quit
 184     "r" riece-command-configure-windows
 185     "x" riece-command-copy-region
 186     "t" riece-command-topic
 187     "w" riece-command-who)
 188
 189   (riece-define-keys riece-command-mode-map
 190     "\r" riece-command-enter-message
 191     [(control return)] riece-command-enter-message-as-notice
 192     [tab] riece-command-complete-user)
 193
 194   (riece-define-keys (riece-command-map riece-command-prefix
 195                                         riece-command-mode-map)
 196     "\177" riece-command-scroll-down
 197     [delete] riece-command-scroll-down
 198     [backspace] riece-command-scroll-down
 199     " " riece-command-scroll-up
 200     [home] riece-command-beginning-of-buffer
 201     "$" riece-command-end-of-buffer
 202     [end] riece-command-end-of-buffer
 203     ">" riece-command-next-channel
 204     "<" riece-command-previous-channel
 205     "\C-j" riece-command-next-channel
 206     "\C-n" riece-command-names
 207     "l" riece-command-list
 208     "\C-m" riece-command-change-mode
 209     "o" riece-command-set-operators
 210     "\C-p" riece-command-part
 211     "r" riece-command-configure-windows
 212     "v" riece-command-set-speakers
 213     "V" riece-version)
 214   (set-keymap-parent riece-command-map riece-dialogue-mode-map)
 215
 216   (riece-define-keys riece-user-list-mode-map
 217     "o" riece-command-set-operators
 218     "v" riece-command-set-voices
 219     "f" riece-command-finger
 220     " " riece-command-user-list-scroll-up
 221     "\177" riece-command-user-list-scroll-down
 222     [delete] riece-command-user-list-scroll-down
 223     [backspace] riece-command-user-list-scroll-down
 224     "c" riece-command-select-command-buffer)
 225
 226   (riece-define-keys riece-channel-list-mode-map
 227     ">" riece-command-next-channel
 228     "<" riece-command-previous-channel
 229     "o" other-window
 230     "c" riece-command-select-command-buffer)
 231
 232   (riece-define-keys-1 riece-dialogue-mode-map riece-select-keys)
 233   (riece-define-keys-1 riece-channel-list-mode-map riece-select-keys))
 234
 235 (defun riece-read-variables-files (&optional file)
 236   "Read variables FILEs."
 237   (or (file-directory-p riece-directory)
 238       (make-directory riece-directory))
 239   (let ((files (if file
 240                    (setq riece-variables-file file
 241                          riece-variables-files (list file))
 242                  riece-variables-files)))
 243     (while files
 244       (condition-case nil
 245           (load (expand-file-name (car files)))
 246         (file-error nil))
 247       (setq files (cdr files)))))
 248
 249 (defvar print-quoted)
 250 (defvar print-escape-multibyte)
 251 (defun riece-save-variables-files ()
 252   "Save current settings to `riece-variables-file'."
 253   (with-temp-file riece-saved-variables-file
 254     (let ((print-quoted t)
 255           (print-readably t)
 256           print-escape-multibyte
 257           print-level
 258           print-length
 259           (variables riece-saved-forms))
 260       (while variables
 261         (prin1 `(setq ,(car variables)
 262                       ',(symbol-value (car variables)))
 263                (current-buffer))
 264         (insert "\n")
 265         (setq variables (cdr variables)))))
 266   (setq riece-save-variables-are-dirty nil))
 267
 268 ;;;###autoload
 269 (defun riece (&optional confirm)
 270   "Connect to the IRC server and start chatting.
 271 If optional argument CONFIRM is non-nil, ask which IRC server to connect."
 272   (interactive "P")
 273   (riece-read-variables-files (if noninteractive
 274                                   (car command-line-args-left)))
 275   (run-hooks 'riece-after-load-startup-hook)
 276   (if (riece-server-opened)
 277       (riece-command-configure-windows)
 278     (unless riece-addons-insinuated
 279       (setq riece-addons (riece-resolve-addons riece-addons))
 280       (let ((pointer riece-addons))
 281         (while pointer
 282           (riece-insinuate-addon (car pointer) riece-debug)
 283           (setq pointer (cdr pointer))))
 284       (setq riece-addons-insinuated t))
 285     (if (or confirm (null riece-server))
 286         (setq riece-server (completing-read "Server: " riece-server-alist)))
 287     (if (stringp riece-server)
 288         (setq riece-server (riece-server-name-to-server riece-server)))
 289     (riece-create-buffers)
 290     (if riece-max-buffer-size
 291         (setq riece-shrink-buffer-idle-timer
 292               (riece-run-with-idle-timer
 293                riece-shrink-buffer-idle-time-delay t
 294                (lambda ()
 295                  (let ((buffers riece-buffer-list))
 296                    (while buffers
 297                      (if (eq (derived-mode-class
 298                               (with-current-buffer (car buffers)
 299                                 major-mode))
 300                              'riece-dialogue-mode)
 301                          (riece-shrink-buffer (car buffers)))
 302                      (setq buffers (cdr buffers))))))))
 303     (switch-to-buffer riece-command-buffer)
 304     (riece-display-connect-signals)
 305     (riece-redisplay-buffers)
 306     (riece-open-server riece-server "")
 307     ;; If no server process is available, exit.
 308     (if (null riece-server-process-alist)
 309         (riece-exit)
 310       (let ((server-list riece-startup-server-list))
 311         (while server-list
 312           (riece-command-open-server (car server-list))
 313           (setq server-list (cdr server-list))))
 314       (let ((channel-list riece-startup-channel-list)
 315             server)
 316         (while channel-list
 317           (setq server (riece-identity-server
 318                         (riece-parse-identity (car channel-list))))
 319           (unless (riece-server-opened server)
 320             (riece-command-open-server server))
 321           (setq channel-list (cdr channel-list))))
 322       (let ((pointer riece-addons))
 323         (while pointer
 324           (unless (get (car pointer) 'riece-addon-default-disabled)
 325             (riece-enable-addon (car pointer) riece-debug))
 326           (setq pointer (cdr pointer))))
 327       (run-hooks 'riece-startup-hook)
 328       (message "%s" (substitute-command-keys
 329                      "Type \\[describe-mode] for help")))))
 330
 331 (defun riece-shrink-buffer (buffer)
 332   (save-excursion
 333     (set-buffer buffer)
 334     (goto-char (point-min))
 335     (while (> (buffer-size) riece-max-buffer-size)
 336       (let* ((inhibit-read-only t)
 337              buffer-read-only
 338              (start (point))
 339              (end (progn (beginning-of-line 2) (point)))
 340              (overlays (riece-overlays-in start end)))
 341         (while overlays
 342           (riece-delete-overlay (car overlays))
 343           (setq overlays (cdr overlays)))
 344         (delete-region start end)))))
 345
 346 (defun riece-exit ()
 347   (if riece-save-variables-are-dirty
 348       (riece-save-variables-files))
 349   (while riece-buffer-list
 350     (if (and (get-buffer (car riece-buffer-list))
 351              (buffer-live-p (car riece-buffer-list)))
 352         (funcall riece-buffer-dispose-function (car riece-buffer-list)))
 353     (setq riece-buffer-list (cdr riece-buffer-list)))
 354   (if riece-shrink-buffer-idle-timer
 355       (riece-cancel-timer riece-shrink-buffer-idle-timer))
 356   (riece-clear-signal-slots)
 357   (setq riece-server nil
 358         riece-current-channels nil
 359         riece-current-channel nil
 360         riece-channel-buffer nil
 361         riece-channel-buffer-alist nil
 362         riece-user-indicator nil
 363         riece-long-channel-indicator "None"
 364         riece-channel-list-indicator "No channel"
 365         riece-away-indicator "-"
 366         riece-operator-indicator "-"
 367         riece-channel-status-indicator "-"
 368         riece-freeze-indicator "-")
 369   (delete-other-windows)
 370   (run-hooks 'riece-exit-hook))
 371
 372 (defun riece-command-mode ()
 373   "Major mode for Riece.  Normal edit function are available.
 374 Typing Return or Linefeed enters the current line in the dialogue.
 375 The following special commands are available:
 376 For a list of the generic commands type \\[riece-command-generic] ? RET.
 377 \\{riece-command-mode-map}"
 378   (interactive)
 379   (kill-all-local-variables)
 380
 381   ;; Make `truncate-partial-width-windows' buffer local and set it to
 382   ;; nil.  This causes `truncate-lines' to directly control line
 383   ;; truncation.
 384   (make-local-variable 'truncate-partial-width-windows)
 385   (setq truncate-partial-width-windows nil)
 386
 387   (setq riece-away-indicator "-"
 388         riece-operator-indicator "-"
 389         riece-channel-status-indicator "-"
 390         major-mode 'riece-command-mode
 391         mode-name "Command"
 392         mode-line-buffer-identification
 393         (riece-mode-line-buffer-identification
 394          '("Riece: "
 395            riece-away-indicator
 396            riece-operator-indicator
 397            riece-channel-status-indicator
 398            " "
 399            riece-user-indicator
 400            " "
 401            riece-channel-indicator))
 402         truncate-lines nil)
 403   (riece-simplify-mode-line-format)
 404   (use-local-map riece-command-mode-map)
 405
 406   (unless riece-command-mode-syntax-table
 407     (setq riece-command-mode-syntax-table
 408           (copy-syntax-table (syntax-table)))
 409     (set-syntax-table riece-command-mode-syntax-table)
 410     (mapcar
 411      (lambda (c) (modify-syntax-entry c "w"))
 412      "^[]{}'`"))
 413
 414   (run-hooks 'riece-command-mode-hook))
 415
 416 (defun riece-dialogue-mode ()
 417   "Major mode for displaying the IRC dialogue.
 418 All normal editing commands are turned off.
 419 Instead, these commands are available:
 420 \\{riece-dialogue-mode-map}"
 421   (kill-all-local-variables)
 422   (make-local-variable 'riece-freeze)
 423   (make-local-variable 'riece-freeze-indicator)
 424
 425   ;; Make `truncate-partial-width-windows' buffer local and set it to
 426   ;; nil.  This causes `truncate-lines' to directly control line truncation.
 427   (make-local-variable 'truncate-partial-width-windows)
 428   (setq truncate-partial-width-windows nil)
 429
 430   (setq riece-freeze riece-default-freeze
 431         riece-away-indicator "-"
 432         riece-operator-indicator "-"
 433         riece-channel-status-indicator "-"
 434         major-mode 'riece-dialogue-mode
 435         mode-name "Dialogue"
 436         mode-line-buffer-identification
 437         (riece-mode-line-buffer-identification
 438          '("Riece: "
 439            riece-away-indicator
 440            riece-operator-indicator
 441            riece-freeze-indicator
 442            riece-channel-status-indicator
 443            " "
 444            riece-channel-list-indicator " "))
 445         truncate-lines nil
 446         buffer-read-only t)
 447   (riece-simplify-mode-line-format)
 448   (use-local-map riece-dialogue-mode-map)
 449   (buffer-disable-undo)
 450   (run-hooks 'riece-dialogue-mode-hook))
 451
 452 (define-derived-mode riece-others-mode riece-dialogue-mode
 453   "Others"
 454   "Major mode for displaying the IRC others message except current channel.
 455 All normal editing commands are turned off.
 456 Instead, these commands are available:
 457 \\{riece-others-mode-map}")
 458
 459 (define-derived-mode riece-channel-mode riece-dialogue-mode
 460   "Channel"
 461   "Major mode for displaying the IRC current channel buffer.
 462 All normal editing commands are turned off.
 463 Instead, these commands are available:
 464 \\{riece-channel-mode-map}"
 465   (make-local-variable 'riece-channel-buffer-window-point)
 466   (setq mode-line-buffer-identification
 467         (riece-mode-line-buffer-identification
 468          '("Riece: "
 469            riece-away-indicator
 470            riece-operator-indicator
 471            riece-freeze-indicator
 472            riece-channel-status-indicator
 473            " "
 474            riece-long-channel-indicator))))
 475
 476 (defun riece-channel-list-mode ()
 477   "Major mode for displaying channel list.
 478 All normal editing commands are turned off."
 479   (kill-all-local-variables)
 480   (buffer-disable-undo)
 481
 482   ;; Make `truncate-partial-width-windows' buffer local and set it to
 483   ;; nil.  This causes `truncate-lines' to directly control line truncation.
 484   (make-local-variable 'truncate-partial-width-windows)
 485   (setq truncate-partial-width-windows nil)
 486
 487   (setq major-mode 'riece-channel-list-mode
 488         mode-name "Channels"
 489         mode-line-buffer-identification
 490         (riece-mode-line-buffer-identification '("Riece: "))
 491         truncate-lines t
 492         buffer-read-only t)
 493   (make-local-hook 'riece-update-buffer-functions)
 494   (add-hook 'riece-update-buffer-functions
 495             'riece-update-channel-list-buffer nil t)
 496   (use-local-map riece-channel-list-mode-map)
 497   (run-hooks 'riece-channel-list-mode-hook))
 498
 499 (defun riece-user-list-mode ()
 500   "Major mode for displaying members in the IRC current channel buffer.
 501 All normal editing commands are turned off.
 502 Instead, these commands are available:
 503 \\{riece-user-list-mode-map}"
 504   (kill-all-local-variables)
 505   (buffer-disable-undo)
 506
 507   ;; Make `truncate-partial-width-windows' buffer local and set it to
 508   ;; nil.  This causes `truncate-lines' to directly control line truncation.
 509   (make-local-variable 'truncate-partial-width-windows)
 510   (setq truncate-partial-width-windows nil)
 511
 512   (setq major-mode 'riece-user-list-mode
 513         mode-name "Users"
 514         mode-line-buffer-identification
 515         (riece-mode-line-buffer-identification
 516          '("Riece: " riece-long-channel-indicator " "))
 517         truncate-lines t
 518         buffer-read-only t)
 519   (if (boundp 'transient-mark-mode)
 520       (set (make-local-variable 'transient-mark-mode) t))
 521   (make-local-hook 'riece-update-buffer-functions)
 522   (add-hook 'riece-update-buffer-functions
 523             'riece-update-user-list-buffer nil t)
 524   (use-local-map riece-user-list-mode-map)
 525   (run-hooks 'riece-user-list-mode-hook))
 526
 527 (defun riece-create-buffers ()
 528   (let ((alist riece-buffer-alist))
 529     (while alist
 530       (save-excursion
 531         (set-buffer (apply #'riece-get-buffer-create
 532                            (cdr (car alist))))
 533         (set (car (car alist)) (current-buffer))
 534         (unless (or (null (nth 2 (car alist)))
 535                     (eq major-mode (nth 2 (car alist))))
 536           (funcall (nth 2 (car alist))))
 537         (setq alist (cdr alist))))))
 538
 539 (defvar reporter-prompt-for-summary-p)
 540 (defun riece-submit-bug-report (&optional recent-messages recent-keys)
 541   "Submit via mail a bug report on Riece."
 542   ;; This strange form ensures that (recent-keys) is the value before
 543   ;; the bug subject string is read.
 544   (interactive (list (riece-recent-messages 20) (recent-keys)))
 545   (message "Querying server version...")
 546   (let ((pointer riece-server-process-alist)
 547         nickname)
 548     (while pointer
 549       (if (and (riece-server-process-opened (cdr (car pointer)))
 550                (setq nickname
 551                      (with-current-buffer (process-buffer (cdr (car pointer)))
 552                      riece-real-nickname)))
 553           (process-send-string
 554            (cdr (car pointer))
 555            "VERSION\r\n")
 556           (process-send-string
 557            (cdr (car pointer))
 558            (format "PRIVMSG %s :\1VERSION\1\r\n" nickname)))
 559       (setq pointer (cdr pointer))))
 560   (sit-for 3)
 561   (message "Querying server version...done")
 562   (require 'reporter)
 563   (let ((reporter-prompt-for-summary-p t))
 564     (unless riece-debug
 565       (error "Please turn on riece-debug and restart Riece."))
 566     (reporter-submit-bug-report
 567      "liece@unixuser.org"
 568      (riece-version)
 569      '(riece-debug)
 570      nil
 571      nil
 572      "This bug report will be sent to the Riece Development Team,
 573 not to your local site managers!!
 574
 575 Please write in Japanese or English, because the Riece maintainers do
 576 not have translators to read other languages for them.
 577
 578 Please describe as succinctly as possible:
 579 \t- What happened.
 580 \t- What you thought should have happened.
 581 \t- Precisely what you were doing at the time.
 582
 583 Also include a reliable recipe for triggering the bug, as well as
 584 any lisp back-traces that you may have.
 585 \(setq stack-trace-on-error t\), or \(setq debug-on-error t\) if you
 586 are familiar with the debugger, to get a lisp back-trace.")
 587       (save-excursion
 588         (goto-char (point-max))
 589         (insert
 590          "\nAdd-on state:\n"
 591          "------------\n"
 592          (save-window-excursion
 593            (save-excursion
 594              (riece-command-list-addons)
 595              (search-forward "\n\n")
 596              (buffer-substring (point-min) (point)))))
 597         (insert "Recent messages from servers:\n"
 598                 "--------------------------")
 599         (let ((pointer riece-server-process-alist))
 600           (while pointer
 601             (insert "\n- \"" (car (car pointer)) "\", \n"
 602                     (format "%S" (if (equal (car (car pointer)) "")
 603                                      riece-server
 604                                    (cdr (assoc (car (car pointer))
 605                                                riece-server-alist))))
 606                     "\n"
 607                     (if (riece-server-process-opened (cdr (car pointer)))
 608                         (save-excursion
 609                           (set-buffer (process-buffer (cdr (car pointer))))
 610                           (goto-char (point-max))
 611                           (beginning-of-line -60)
 612                           (buffer-substring (point) (point-max)))
 613                       "(closed server)"))
 614             (setq pointer (cdr pointer))))
 615         ;; Insert recent keystrokes.
 616         (insert "\n\nRecent keystrokes:\n"
 617                 "-----------------\n\n")
 618         (let ((before-keys (point)))
 619         (insert (key-description recent-keys))
 620         (save-restriction
 621           (narrow-to-region before-keys (point))
 622           (goto-char before-keys)
 623           (while (progn (move-to-column 50) (not (eobp)))
 624             (search-forward " " nil t)
 625             (insert "\n"))))
 626         ;; Insert recent minibuffer messages.
 627         (insert "\n\nRecent messages (most recent first):\n"
 628                 "-----------------------------------\n"
 629                 recent-messages))))
 630
 631 (provide 'riece)
 632
 633 ;;; riece.el ends here