3addde535155f9036059fba4019fe68eec0f6fcb
[riece] / lisp / riece.el
1 ;;; riece.el --- IRC client for Emacsen
2 ;; Copyright (C) 1998-2003 Daiki Ueno
3
4 ;; Author: Daiki Ueno <ueno@unixuser.org>
5 ;; Created: 1998-09-28
6 ;; Keywords: IRC, riece
7
8 ;; This file is part of Riece.
9
10 ;; This program is free software; you can redistribute it and/or modify
11 ;; it under the terms of the GNU General Public License as published by
12 ;; the Free Software Foundation; either version 2, or (at your option)
13 ;; any later version.
14
15 ;; This program is distributed in the hope that it will be useful,
16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
18 ;; GNU General Public License for more details.
19
20 ;; You should have received a copy of the GNU General Public License
21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
23 ;; Boston, MA 02111-1307, USA.
24
25 ;;; Code:
26
27 (require 'riece-display)
28 (require 'riece-server)
29 (require 'riece-compat)
30 (require 'riece-commands)
31 (require 'riece-addon)
32 (require 'riece-signal)
33
34 (autoload 'derived-mode-class "derived")
35
36 (defvar riece-channel-list-mode-map (make-sparse-keymap))
37 (defvar riece-user-list-mode-map (make-sparse-keymap))
38
39 (defvar riece-dialogue-mode-map
40   (let ((keymap (make-keymap)))
41     (suppress-keymap keymap 'nodigit)
42     keymap))
43
44 (defvar riece-command-mode-map (make-keymap))
45 (defvar riece-command-map (make-sparse-keymap))
46
47 (defvar riece-command-mode-syntax-table nil)
48
49 (put 'riece-command-mode 'mode-class 'special)
50 (put 'riece-dialogue-mode 'mode-class 'special)
51 (put 'riece-others-mode 'derived-mode-parent 'riece-dialogue-mode)
52 (put 'riece-channel-list-mode 'mode-class 'special)
53 (put 'riece-user-list-mode 'mode-class 'special)
54 (put 'riece-channel-mode 'derived-mode-parent 'riece-dialogue-mode)
55
56 (defvar riece-buffer-alist
57   '((riece-command-buffer "*Command*" riece-command-mode)
58     (riece-dialogue-buffer "*Dialogue*" riece-dialogue-mode)
59     (riece-others-buffer "*Others*" riece-others-mode)
60     (riece-channel-list-buffer "*Channels*" riece-channel-list-mode)
61     (riece-user-list-buffer " *Users*" riece-user-list-mode)
62     (riece-temp-buffer " *Temp*"))
63
64 (defvar riece-shrink-buffer-idle-timer nil
65   "Timer object to periodically shrink channel buffers.")
66
67 (defvar riece-addons-insinuated nil
68   "Non nil if add-ons are already insinuated.")
69
70 (defvar riece-select-keys
71   `("#" riece-command-switch-to-channel-by-number
72     "1" riece-command-switch-to-channel-by-number-1
73     "2" riece-command-switch-to-channel-by-number-2
74     "3" riece-command-switch-to-channel-by-number-3
75     "4" riece-command-switch-to-channel-by-number-4
76     "5" riece-command-switch-to-channel-by-number-5
77     "6" riece-command-switch-to-channel-by-number-6
78     "7" riece-command-switch-to-channel-by-number-7
79     "8" riece-command-switch-to-channel-by-number-8
80     "9" riece-command-switch-to-channel-by-number-9
81     "0" riece-command-switch-to-channel-by-number-10
82     ,(concat riece-command-prefix "1")
83     riece-command-switch-to-channel-by-number-11
84     ,(concat riece-command-prefix "2")
85     riece-command-switch-to-channel-by-number-12
86     ,(concat riece-command-prefix "3")
87     riece-command-switch-to-channel-by-number-13
88     ,(concat riece-command-prefix "4")
89     riece-command-switch-to-channel-by-number-14
90     ,(concat riece-command-prefix "5")
91     riece-command-switch-to-channel-by-number-15
92     ,(concat riece-command-prefix "6")
93     riece-command-switch-to-channel-by-number-16
94     ,(concat riece-command-prefix "7")
95     riece-command-switch-to-channel-by-number-17
96     ,(concat riece-command-prefix "8")
97     riece-command-switch-to-channel-by-number-18
98     ,(concat riece-command-prefix "9")
99     riece-command-switch-to-channel-by-number-19
100     ,(concat riece-command-prefix "0")
101     riece-command-switch-to-channel-by-number-20))
102
103 ;;; Keymap macros. -- borrowed from `gnus-util.el'.
104 (defmacro riece-local-set-keys (&rest plist)
105   "Set the keys in PLIST in the current keymap."
106   `(riece-define-keys-1 (current-local-map) ',plist))
107
108 (defmacro riece-define-keys (keymap &rest plist)
109   "Assign KEYMAP keys from PLIST."
110   `(riece-define-keys-1 ',keymap ',plist))
111
112 (defmacro riece-define-keys-safe (keymap &rest plist)
113   "Assign KEYMAP keys from PLIST without overwriting previous definitions."
114   `(riece-define-keys-1 ',keymap ',plist t))
115
116 (put 'riece-define-keys 'lisp-indent-function 1)
117 (put 'riece-define-keys-safe 'lisp-indent-function 1)
118 (put 'riece-local-set-keys 'lisp-indent-function 1)
119
120 (defun riece-define-keys-1 (keymap plist &optional safe)
121   "Assign KEYMAP keys from PLIST.
122 If optional argument SAFE is nil, overwrite previous definitions."
123   (unless keymap
124     (error "Can't set keys in a null keymap"))
125   (cond
126    ((symbolp keymap)
127     (setq keymap (symbol-value keymap)))
128    ((keymapp keymap))
129    ((listp keymap)
130     (set (car keymap) nil)
131     (define-prefix-command (car keymap))
132     (define-key (symbol-value (nth 2 keymap))
133       (if (symbolp (nth 1 keymap))
134           (symbol-value (nth 1 keymap))
135         (nth 1 keymap))
136       (car keymap))
137     (setq keymap (symbol-value (car keymap)))))
138   (let (key)
139     (while plist
140       (if (symbolp (setq key (car plist)))
141           (setq key (symbol-value key)))
142       (setq plist (cdr plist))
143       (if (or (not safe)
144               (eq (lookup-key keymap key) 'undefined))
145           (define-key keymap key (car plist))
146         (car plist))
147       (setq plist (cdr plist)))))
148
149 (when t
150   (riece-define-keys riece-dialogue-mode-map
151     "\177" scroll-down
152     [delete] scroll-down
153     [backspace] scroll-down
154     [return] scroll-up
155     " " scroll-up
156     [home] beginning-of-buffer
157     "$" end-of-buffer
158     [end] end-of-buffer
159     "/" riece-command-raw
160     ">" end-of-buffer
161     "<" beginning-of-buffer
162     "^" riece-command-list-addons
163     "\C-ta" riece-command-toggle-away
164     "c" riece-command-select-command-buffer
165     "f" riece-command-finger
166     "\C-tf" riece-command-toggle-freeze
167     "\C-to" riece-command-toggle-own-freeze
168     "\C-tu" riece-command-toggle-user-list-buffer-mode
169     "\C-tc" riece-command-toggle-channel-buffer-mode
170     "\C-tC" riece-command-toggle-channel-list-buffer-mode
171     "\C-tl" riece-command-change-layout
172     "i" riece-command-invite
173     "j" riece-command-join
174     "\C-k" riece-command-kick
175     "l" riece-command-list
176     "M" riece-command-change-mode
177     "n" riece-command-change-nickname
178     "N" riece-command-names
179     "o" other-window
180     "O" riece-command-open-server
181     "C" riece-command-close-server
182     "M" riece-command-universal-server-name-argument
183     "p" riece-command-enter-message-to-user
184     "q" riece-command-quit
185     "r" riece-command-configure-windows
186     "x" riece-command-copy-region
187     "t" riece-command-topic
188     "w" riece-command-who)
189
190   (riece-define-keys riece-command-mode-map
191     "\r" riece-command-enter-message
192     [(control return)] riece-command-enter-message-as-notice
193     [tab] riece-command-complete-user)
194
195   (riece-define-keys (riece-command-map riece-command-prefix
196                                         riece-command-mode-map)
197     "\177" riece-command-scroll-down
198     [delete] riece-command-scroll-down
199     [backspace] riece-command-scroll-down
200     " " riece-command-scroll-up
201     [home] riece-command-beginning-of-buffer
202     "$" riece-command-end-of-buffer
203     [end] riece-command-end-of-buffer
204     ">" riece-command-next-channel
205     "<" riece-command-previous-channel
206     "\C-j" riece-command-next-channel
207     "\C-n" riece-command-names
208     "l" riece-command-list
209     "\C-m" riece-command-change-mode
210     "o" riece-command-set-operators
211     "\C-p" riece-command-part
212     "r" riece-command-configure-windows
213     "v" riece-command-set-speakers
214     "V" riece-version)
215   (set-keymap-parent riece-command-map riece-dialogue-mode-map)
216
217   (riece-define-keys riece-user-list-mode-map
218     "o" riece-command-set-operators
219     "v" riece-command-set-voices
220     "f" riece-command-finger
221     " " riece-command-user-list-scroll-up
222     "\177" riece-command-user-list-scroll-down
223     [delete] riece-command-user-list-scroll-down
224     [backspace] riece-command-user-list-scroll-down
225     "c" riece-command-select-command-buffer)
226
227   (riece-define-keys riece-channel-list-mode-map
228     ">" riece-command-next-channel
229     "<" riece-command-previous-channel
230     "o" other-window
231     "c" riece-command-select-command-buffer)
232
233   (riece-define-keys-1 riece-dialogue-mode-map riece-select-keys)
234   (riece-define-keys-1 riece-channel-list-mode-map riece-select-keys))
235
236 (defun riece-read-variables-files (&optional file)
237   "Read variables FILEs."
238   (or (file-directory-p riece-directory)
239       (make-directory riece-directory))
240   (let ((files (if file
241                    (setq riece-variables-file file
242                          riece-variables-files (list file))
243                  riece-variables-files)))
244     (while files
245       (condition-case nil
246           (load (expand-file-name (car files)))
247         (file-error nil))
248       (setq files (cdr files)))))
249
250 (defvar print-quoted)
251 (defvar print-escape-multibyte)
252 (defun riece-save-variables-files ()
253   "Save current settings to `riece-variables-file'."
254   (with-temp-file riece-saved-variables-file
255     (let ((print-quoted t)
256           (print-readably t)
257           print-escape-multibyte
258           print-level
259           print-length
260           (variables riece-saved-forms))
261       (while variables
262         (prin1 `(setq ,(car variables)
263                       ',(symbol-value (car variables)))
264                (current-buffer))
265         (insert "\n")
266         (setq variables (cdr variables)))))
267   (setq riece-save-variables-are-dirty nil))
268
269 ;;;###autoload
270 (defun riece (&optional confirm)
271   "Connect to the IRC server and start chatting.
272 If optional argument CONFIRM is non-nil, ask which IRC server to connect."
273   (interactive "P")
274   (riece-read-variables-files (if noninteractive
275                                   (car command-line-args-left)))
276   (run-hooks 'riece-after-load-startup-hook)
277   (if (riece-server-opened)
278       (riece-command-configure-windows)
279     (unless riece-addons-insinuated
280       (setq riece-addons (riece-resolve-addons riece-addons))
281       (let ((pointer riece-addons))
282         (while pointer
283           (riece-insinuate-addon (car pointer) riece-debug)
284           (setq pointer (cdr pointer))))
285       (setq riece-addons-insinuated t))
286     (if (or confirm (null riece-server))
287         (setq riece-server (completing-read "Server: " riece-server-alist)))
288     (if (stringp riece-server)
289         (setq riece-server (riece-server-name-to-server riece-server)))
290     (riece-create-buffers)
291     (if riece-max-buffer-size
292         (setq riece-shrink-buffer-idle-timer
293               (riece-run-with-idle-timer
294                riece-shrink-buffer-idle-time-delay t
295                (lambda ()
296                  (let ((buffers riece-buffer-list))
297                    (while buffers
298                      (if (buffer-live-p (car buffers))
299                          (if (eq (derived-mode-class
300                                   (with-current-buffer (car buffers)
301                                     major-mode))
302                                  'riece-dialogue-mode)
303                              (riece-shrink-buffer (car buffers)))
304                        (delq (car buffers) riece-buffer-list))
305                      (setq buffers (cdr buffers))))))))
306     (switch-to-buffer riece-command-buffer)
307     (riece-display-connect-signals)
308     (riece-redisplay-buffers)
309     (riece-open-server riece-server "")
310     ;; If no server process is available, exit.
311     (if (null riece-server-process-alist)
312         (riece-exit)
313       (let ((server-list riece-startup-server-list))
314         (while server-list
315           (riece-command-open-server (car server-list))
316           (setq server-list (cdr server-list))))
317       (let ((channel-list riece-startup-channel-list)
318             server)
319         (while channel-list
320           (setq server (riece-identity-server
321                         (riece-parse-identity (car channel-list))))
322           (unless (riece-server-opened server)
323             (riece-command-open-server server))
324           (setq channel-list (cdr channel-list))))
325       (let ((pointer riece-addons))
326         (while pointer
327           (unless (get (car pointer) 'riece-addon-default-disabled)
328             (riece-enable-addon (car pointer) riece-debug))
329           (setq pointer (cdr pointer))))
330       (run-hooks 'riece-startup-hook)
331       (message "%s" (substitute-command-keys
332                      "Type \\[describe-mode] for help")))))
333
334 (defun riece-shrink-buffer (buffer)
335   (save-excursion
336     (set-buffer buffer)
337     (goto-char (point-min))
338     (while (> (buffer-size) riece-max-buffer-size)
339       (let* ((inhibit-read-only t)
340              buffer-read-only
341              (end (progn
342                     (goto-char riece-shrink-buffer-remove-chars)
343                     (beginning-of-line 2)
344                     (point)))
345              (overlays (riece-overlays-in (point-min) end)))
346         (while overlays
347           (riece-delete-overlay (car overlays))
348           (setq overlays (cdr overlays)))
349         (delete-region (point-min) end)))))
350
351 (defun riece-exit ()
352   (if riece-save-variables-are-dirty
353       (riece-save-variables-files))
354   (while riece-buffer-list
355     (if (and (get-buffer (car riece-buffer-list))
356              (buffer-live-p (car riece-buffer-list)))
357         (funcall riece-buffer-dispose-function (car riece-buffer-list)))
358     (setq riece-buffer-list (cdr riece-buffer-list)))
359   (if riece-shrink-buffer-idle-timer
360       (riece-cancel-timer riece-shrink-buffer-idle-timer))
361   (riece-clear-signal-slots)
362   (setq riece-server nil
363         riece-current-channels nil
364         riece-current-channel nil
365         riece-channel-buffer nil
366         riece-channel-buffer-alist nil
367         riece-user-indicator nil
368         riece-long-channel-indicator "None"
369         riece-channel-list-indicator "No channel"
370         riece-away-indicator "-"
371         riece-operator-indicator "-"
372         riece-channel-status-indicator "-"
373         riece-freeze-indicator "-")
374   (delete-other-windows)
375   (run-hooks 'riece-exit-hook))
376
377 (defun riece-command-mode ()
378   "Major mode for Riece.  Normal edit function are available.
379 Typing Return or Linefeed enters the current line in the dialogue.
380 The following special commands are available:
381 For a list of the generic commands type \\[riece-command-generic] ? RET.
382 \\{riece-command-mode-map}"
383   (interactive)
384   (kill-all-local-variables)
385
386   ;; Make `truncate-partial-width-windows' buffer local and set it to
387   ;; nil.  This causes `truncate-lines' to directly control line
388   ;; truncation.
389   (make-local-variable 'truncate-partial-width-windows)
390   (setq truncate-partial-width-windows nil)
391
392   (setq riece-away-indicator "-"
393         riece-operator-indicator "-"
394         riece-channel-status-indicator "-"
395         major-mode 'riece-command-mode
396         mode-name "Command"
397         mode-line-buffer-identification
398         (riece-mode-line-buffer-identification
399          '("Riece: "
400            riece-away-indicator
401            riece-operator-indicator
402            riece-channel-status-indicator
403            " "
404            riece-user-indicator
405            " "
406            riece-channel-indicator))
407         truncate-lines nil)
408   (riece-simplify-mode-line-format)
409   (use-local-map riece-command-mode-map)
410
411   (unless riece-command-mode-syntax-table
412     (setq riece-command-mode-syntax-table
413           (copy-syntax-table (syntax-table)))
414     (set-syntax-table riece-command-mode-syntax-table)
415     (mapcar
416      (lambda (c) (modify-syntax-entry c "w"))
417      "^[]{}'`"))
418
419   (run-hooks 'riece-command-mode-hook))
420
421 (defun riece-dialogue-mode ()
422   "Major mode for displaying the IRC dialogue.
423 All normal editing commands are turned off.
424 Instead, these commands are available:
425 \\{riece-dialogue-mode-map}"
426   (kill-all-local-variables)
427   (make-local-variable 'riece-freeze)
428   (make-local-variable 'riece-freeze-indicator)
429
430   ;; Make `truncate-partial-width-windows' buffer local and set it to
431   ;; nil.  This causes `truncate-lines' to directly control line truncation.
432   (make-local-variable 'truncate-partial-width-windows)
433   (setq truncate-partial-width-windows nil)
434
435   (setq riece-freeze riece-default-freeze
436         riece-away-indicator "-"
437         riece-operator-indicator "-"
438         riece-channel-status-indicator "-"
439         major-mode 'riece-dialogue-mode
440         mode-name "Dialogue"
441         mode-line-buffer-identification
442         (riece-mode-line-buffer-identification
443          '("Riece: "
444            riece-away-indicator
445            riece-operator-indicator
446            riece-freeze-indicator
447            riece-channel-status-indicator
448            " "
449            riece-channel-list-indicator " "))
450         truncate-lines nil
451         buffer-read-only t)
452   (riece-simplify-mode-line-format)
453   (use-local-map riece-dialogue-mode-map)
454   (buffer-disable-undo)
455   (run-hooks 'riece-dialogue-mode-hook))
456
457 (define-derived-mode riece-others-mode riece-dialogue-mode
458   "Others"
459   "Major mode for displaying the IRC others message except current channel.
460 All normal editing commands are turned off.
461 Instead, these commands are available:
462 \\{riece-others-mode-map}")
463
464 (define-derived-mode riece-channel-mode riece-dialogue-mode
465   "Channel"
466   "Major mode for displaying the IRC current channel buffer.
467 All normal editing commands are turned off.
468 Instead, these commands are available:
469 \\{riece-channel-mode-map}"
470   (make-local-variable 'riece-channel-buffer-window-point)
471   (setq mode-line-buffer-identification
472         (riece-mode-line-buffer-identification
473          '("Riece: "
474            riece-away-indicator
475            riece-operator-indicator
476            riece-freeze-indicator
477            riece-channel-status-indicator
478            " "
479            riece-long-channel-indicator))))
480
481 (defun riece-channel-list-mode ()
482   "Major mode for displaying channel list.
483 All normal editing commands are turned off."
484   (kill-all-local-variables)
485   (buffer-disable-undo)
486
487   ;; Make `truncate-partial-width-windows' buffer local and set it to
488   ;; nil.  This causes `truncate-lines' to directly control line truncation.
489   (make-local-variable 'truncate-partial-width-windows)
490   (setq truncate-partial-width-windows nil)
491
492   (setq major-mode 'riece-channel-list-mode
493         mode-name "Channels"
494         mode-line-buffer-identification
495         (riece-mode-line-buffer-identification '("Riece: "))
496         truncate-lines t
497         buffer-read-only t)
498   (make-local-hook 'riece-update-buffer-functions)
499   (add-hook 'riece-update-buffer-functions
500             'riece-update-channel-list-buffer nil t)
501   (use-local-map riece-channel-list-mode-map)
502   (run-hooks 'riece-channel-list-mode-hook))
503
504 (defun riece-user-list-mode ()
505   "Major mode for displaying members in the IRC current channel buffer.
506 All normal editing commands are turned off.
507 Instead, these commands are available:
508 \\{riece-user-list-mode-map}"
509   (kill-all-local-variables)
510   (buffer-disable-undo)
511
512   ;; Make `truncate-partial-width-windows' buffer local and set it to
513   ;; nil.  This causes `truncate-lines' to directly control line truncation.
514   (make-local-variable 'truncate-partial-width-windows)
515   (setq truncate-partial-width-windows nil)
516
517   (setq major-mode 'riece-user-list-mode
518         mode-name "Users"
519         mode-line-buffer-identification
520         (riece-mode-line-buffer-identification
521          '("Riece: " riece-long-channel-indicator " "))
522         truncate-lines t
523         buffer-read-only t)
524   (if (boundp 'transient-mark-mode)
525       (set (make-local-variable 'transient-mark-mode) t))
526   (make-local-hook 'riece-update-buffer-functions)
527   (add-hook 'riece-update-buffer-functions
528             'riece-update-user-list-buffer nil t)
529   (use-local-map riece-user-list-mode-map)
530   (run-hooks 'riece-user-list-mode-hook))
531
532 (defun riece-create-buffers ()
533   (let ((alist riece-buffer-alist))
534     (while alist
535       (save-excursion
536         (set-buffer (apply #'riece-get-buffer-create
537                            (cdr (car alist))))
538         (set (car (car alist)) (current-buffer))
539         (unless (or (null (nth 2 (car alist)))
540                     (eq major-mode (nth 2 (car alist))))
541           (funcall (nth 2 (car alist))))
542         (setq alist (cdr alist))))))
543
544 (defvar reporter-prompt-for-summary-p)
545 (defun riece-submit-bug-report (&optional recent-messages recent-keys)
546   "Submit via mail a bug report on Riece."
547   ;; This strange form ensures that (recent-keys) is the value before
548   ;; the bug subject string is read.
549   (interactive (list (riece-recent-messages 20) (recent-keys)))
550   (message "Querying server version...")
551   (let ((pointer riece-server-process-alist)
552         nickname)
553     (while pointer
554       (when (riece-server-process-opened (cdr (car pointer)))
555         (process-send-string (cdr (car pointer)) "VERSION\r\n")
556         (if (setq nickname
557                   (with-current-buffer (process-buffer (cdr (car pointer)))
558                     riece-real-nickname))
559             (process-send-string
560              (cdr (car pointer))
561              (format "PRIVMSG %s :\1VERSION\1\r\n" nickname))))
562       (setq pointer (cdr pointer))))
563   (sit-for 3)
564   (message "Querying server version...done")
565   (require 'reporter)
566   (let ((reporter-prompt-for-summary-p t))
567     (unless riece-debug
568       (error "Please turn on riece-debug and restart Riece."))
569     (reporter-submit-bug-report
570      "liece@unixuser.org"
571      (riece-version)
572      '(riece-debug)
573      nil
574      nil
575      "This bug report will be sent to the Riece Development Team,
576 not to your local site managers!!
577
578 Please write in Japanese or English, because the Riece maintainers do
579 not have translators to read other languages for them.
580
581 Please describe as succinctly as possible:
582 \t- What happened.
583 \t- What you thought should have happened.
584 \t- Precisely what you were doing at the time.
585
586 Also include a reliable recipe for triggering the bug, as well as
587 any lisp back-traces that you may have.
588 \(setq stack-trace-on-error t\), or \(setq debug-on-error t\) if you
589 are familiar with the debugger, to get a lisp back-trace.")
590     (delete-other-windows)
591     (save-excursion
592       (goto-char (point-max))
593       (insert
594        "\nAdd-on state:\n"
595        "------------\n"
596        (save-window-excursion
597          (save-excursion
598            (riece-command-list-addons)
599            (search-forward "\n\n")
600            (buffer-substring (point-min) (point)))))
601       (insert "Recent messages from servers:\n"
602               "--------------------------")
603       (let ((pointer riece-server-process-alist))
604         (while pointer
605           (insert "\n- \"" (car (car pointer)) "\", \n"
606                   (format "%S" (if (equal (car (car pointer)) "")
607                                    riece-server
608                                  (cdr (assoc (car (car pointer))
609                                              riece-server-alist))))
610                   "\n"
611                   (if (riece-server-process-opened (cdr (car pointer)))
612                       (save-excursion
613                         (set-buffer (process-buffer (cdr (car pointer))))
614                         (goto-char (point-max))
615                         (beginning-of-line -60)
616                         (buffer-substring (point) (point-max)))
617                     "(closed server)"))
618           (setq pointer (cdr pointer))))
619       ;; Insert recent keystrokes.
620       (insert "\n\nRecent keystrokes:\n"
621               "-----------------\n\n")
622       (let ((before-keys (point)))
623         (insert (key-description recent-keys))
624         (save-restriction
625           (narrow-to-region before-keys (point))
626           (goto-char before-keys)
627           (while (progn (move-to-column 50) (not (eobp)))
628             (search-forward " " nil t)
629             (insert "\n"))))
630       ;; Insert recent minibuffer messages.
631       (insert "\n\nRecent messages (most recent first):\n"
632               "-----------------------------------\n"
633               recent-messages))))
634
635 (provide 'riece)
636
637 ;;; riece.el ends here