cgit.sxemacs.org Git - riece/blob - lisp/riece.el

   1 ;;; riece.el --- IRC client for Emacsen
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Created: 1998-09-28
   6 ;; Keywords: IRC, riece
   7
   8 ;; This file is part of Riece.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Code:
  26
  27 (require 'riece-filter)
  28 (require 'riece-display)
  29 (require 'riece-server)
  30 (require 'riece-compat)
  31 (require 'riece-commands)
  32
  33 (autoload 'derived-mode-class "derived")
  34
  35 (defvar riece-channel-list-mode-map (make-sparse-keymap))
  36 (defvar riece-user-list-mode-map (make-sparse-keymap))
  37
  38 (defvar riece-dialogue-mode-map
  39   (let ((keymap (make-keymap)))
  40     (suppress-keymap keymap 'nodigit)
  41     keymap))
  42
  43 (defvar riece-command-mode-map (make-keymap))
  44 (defvar riece-command-map (make-sparse-keymap))
  45
  46 (defvar riece-command-mode-syntax-table nil)
  47
  48 (put 'riece-command-mode 'mode-class 'special)
  49 (put 'riece-dialogue-mode 'mode-class 'special)
  50 (put 'riece-others-mode 'derived-mode-parent 'riece-dialogue-mode)
  51 (put 'riece-channel-list-mode 'mode-class 'special)
  52 (put 'riece-user-list-mode 'mode-class 'special)
  53 (put 'riece-channel-mode 'derived-mode-parent 'riece-dialogue-mode)
  54
  55 (defvar riece-buffer-alist
  56   '((riece-command-buffer "*Command*" riece-command-mode)
  57     (riece-dialogue-buffer "*Dialogue*" riece-dialogue-mode)
  58     (riece-others-buffer "*Others*" riece-others-mode)
  59     (riece-channel-list-buffer "*Channels*" riece-channel-list-mode)
  60     (riece-user-list-buffer " *Users*" riece-user-list-mode)))
  61
  62 (defvar riece-shrink-buffer-idle-timer nil
  63   "Timer object to periodically shrink channel buffers.")
  64
  65 (defvar riece-select-keys
  66   `("1" riece-command-switch-to-channel-by-number-1
  67     "2" riece-command-switch-to-channel-by-number-2
  68     "3" riece-command-switch-to-channel-by-number-3
  69     "4" riece-command-switch-to-channel-by-number-4
  70     "5" riece-command-switch-to-channel-by-number-5
  71     "6" riece-command-switch-to-channel-by-number-6
  72     "7" riece-command-switch-to-channel-by-number-7
  73     "8" riece-command-switch-to-channel-by-number-8
  74     "9" riece-command-switch-to-channel-by-number-9
  75     "0" riece-command-switch-to-channel-by-number-10
  76     ,(concat riece-command-prefix "1")
  77     riece-command-switch-to-channel-by-number-11
  78     ,(concat riece-command-prefix "2")
  79     riece-command-switch-to-channel-by-number-12
  80     ,(concat riece-command-prefix "3")
  81     riece-command-switch-to-channel-by-number-13
  82     ,(concat riece-command-prefix "4")
  83     riece-command-switch-to-channel-by-number-14
  84     ,(concat riece-command-prefix "5")
  85     riece-command-switch-to-channel-by-number-15
  86     ,(concat riece-command-prefix "6")
  87     riece-command-switch-to-channel-by-number-16
  88     ,(concat riece-command-prefix "7")
  89     riece-command-switch-to-channel-by-number-17
  90     ,(concat riece-command-prefix "8")
  91     riece-command-switch-to-channel-by-number-18
  92     ,(concat riece-command-prefix "9")
  93     riece-command-switch-to-channel-by-number-19
  94     ,(concat riece-command-prefix "0")
  95     riece-command-switch-to-channel-by-number-20))
  96
  97 ;;; Keymap macros. -- borrowed from `gnus-util.el'.
  98 (defmacro riece-local-set-keys (&rest plist)
  99   "Set the keys in PLIST in the current keymap."
 100   `(riece-define-keys-1 (current-local-map) ',plist))
 101
 102 (defmacro riece-define-keys (keymap &rest plist)
 103   "Assign KEYMAP keys from PLIST."
 104   `(riece-define-keys-1 ',keymap ',plist))
 105
 106 (defmacro riece-define-keys-safe (keymap &rest plist)
 107   "Assign KEYMAP keys from PLIST without overwriting previous definitions."
 108   `(riece-define-keys-1 ',keymap ',plist t))
 109
 110 (put 'riece-define-keys 'lisp-indent-function 1)
 111 (put 'riece-define-keys-safe 'lisp-indent-function 1)
 112 (put 'riece-local-set-keys 'lisp-indent-function 1)
 113
 114 (defun riece-define-keys-1 (keymap plist &optional safe)
 115   "Assign KEYMAP keys from PLIST.
 116 If optional argument SAFE is nil, overwrite previous definitions."
 117   (unless keymap
 118     (error "Can't set keys in a null keymap"))
 119   (cond
 120    ((symbolp keymap)
 121     (setq keymap (symbol-value keymap)))
 122    ((keymapp keymap))
 123    ((listp keymap)
 124     (set (car keymap) nil)
 125     (define-prefix-command (car keymap))
 126     (define-key (symbol-value (nth 2 keymap))
 127       (if (symbolp (nth 1 keymap))
 128           (symbol-value (nth 1 keymap))
 129         (nth 1 keymap))
 130       (car keymap))
 131     (setq keymap (symbol-value (car keymap)))))
 132   (let (key)
 133     (while plist
 134       (if (symbolp (setq key (car plist)))
 135           (setq key (symbol-value key)))
 136       (setq plist (cdr plist))
 137       (if (or (not safe)
 138               (eq (lookup-key keymap key) 'undefined))
 139           (define-key keymap key (car plist))
 140         (car plist))
 141       (setq plist (cdr plist)))))
 142
 143 (when t
 144   (riece-define-keys riece-dialogue-mode-map
 145     "\177" scroll-down
 146     [delete] scroll-down
 147     [backspace] scroll-down
 148     [return] scroll-up
 149     " " scroll-up
 150     "$" end-of-buffer
 151     "/" riece-command-raw
 152     ">" end-of-buffer
 153     "<" beginning-of-buffer
 154     "\C-ta" riece-command-toggle-away
 155     "c" riece-command-select-command-buffer
 156     "f" riece-command-finger
 157     "\C-tf" riece-command-toggle-freeze
 158     "\C-to" riece-command-toggle-own-freeze
 159     "\C-tu" riece-command-toggle-user-list-buffer-mode
 160     "\C-tc" riece-command-toggle-channel-buffer-mode
 161     "\C-tC" riece-command-toggle-channel-list-buffer-mode
 162     "\C-tl" riece-command-change-layout
 163     "i" riece-command-invite
 164     "j" riece-command-join
 165     "\C-k" riece-command-kick
 166     "l" riece-command-list
 167     "M" riece-command-change-mode
 168     "n" riece-command-change-nickname
 169     "N" riece-command-names
 170     "o" other-window
 171     "O" riece-command-open-server
 172     "C" riece-command-close-server
 173     "M" riece-command-universal-server-name-argument
 174     "p" riece-command-enter-message-to-user
 175     "q" riece-command-quit
 176     "r" riece-command-configure-windows
 177     "x" riece-command-copy-region
 178     "t" riece-command-topic
 179     "w" riece-command-who)
 180
 181   (riece-define-keys riece-command-mode-map
 182     "\r" riece-command-enter-message
 183     [(control return)] riece-command-enter-message-as-notice
 184     [tab] riece-command-complete-user)
 185
 186   (riece-define-keys (riece-command-map riece-command-prefix
 187                                         riece-command-mode-map)
 188     "\177" riece-command-scroll-down
 189     [delete] riece-command-scroll-down
 190     [backspace] riece-command-scroll-down
 191     " " riece-command-scroll-up
 192     "$" riece-command-end-of-buffer
 193     ">" riece-command-next-channel
 194     "<" riece-command-previous-channel
 195     "\C-j" riece-command-next-channel
 196     "\C-n" riece-command-names
 197     "l" riece-command-list
 198     "\C-m" riece-command-change-mode
 199     "o" riece-command-set-operators
 200     "\C-p" riece-command-part
 201     "r" riece-command-configure-windows
 202     "v" riece-command-set-speakers
 203     "V" riece-version)
 204   (set-keymap-parent riece-command-map riece-dialogue-mode-map)
 205
 206   (riece-define-keys riece-user-list-mode-map
 207     "o" riece-command-set-operators
 208     "v" riece-command-set-voices
 209     "f" riece-command-finger
 210     " " riece-command-user-list-scroll-up
 211     "\177" riece-command-user-list-scroll-down
 212     [delete] riece-command-user-list-scroll-down
 213     [backspace] riece-command-user-list-scroll-down
 214     "c" riece-command-select-command-buffer)
 215
 216   (riece-define-keys riece-channel-list-mode-map
 217     ">" riece-command-next-channel
 218     "<" riece-command-previous-channel
 219     "o" other-window
 220     "c" riece-command-select-command-buffer)
 221
 222   (riece-define-keys-1 riece-dialogue-mode-map riece-select-keys)
 223   (riece-define-keys-1 riece-channel-list-mode-map riece-select-keys))
 224
 225 (defun riece-read-variables-files (&optional file)
 226   "Read variables FILEs."
 227   (or (file-directory-p riece-directory)
 228       (make-directory riece-directory))
 229   (let ((files (if file
 230                    (setq riece-variables-file file
 231                          riece-variables-files (list file))
 232                  riece-variables-files)))
 233     (while files
 234       (condition-case nil
 235           (load (expand-file-name (car files)))
 236         (file-error nil))
 237       (setq files (cdr files)))))
 238
 239 (defvar print-quoted)
 240 (defvar print-escape-multibyte)
 241 (defun riece-save-variables-files ()
 242   "Save current settings to `riece-variables-file'."
 243   (with-temp-file riece-saved-variables-file
 244     (let ((print-quoted t)
 245           (print-readably t)
 246           print-escape-multibyte
 247           print-level
 248           print-length
 249           (variables riece-saved-forms))
 250       (while variables
 251         (prin1 `(setq ,(car variables)
 252                       ',(symbol-value (car variables)))
 253                (current-buffer))
 254         (insert "\n")
 255         (setq variables (cdr variables)))))
 256   (setq riece-save-variables-are-dirty nil))
 257
 258 ;;;###autoload
 259 (defun riece (&optional confirm)
 260   "Connect to the IRC server and start chatting.
 261 If optional argument CONFIRM is non-nil, ask which IRC server to connect."
 262   (interactive "P")
 263   (riece-read-variables-files (if noninteractive
 264                                   (car command-line-args-left)))
 265   (riece-insinuate-addons riece-addons)
 266   (run-hooks 'riece-after-load-startup-hook)
 267   (if (riece-server-opened)
 268       (riece-command-configure-windows)
 269     (if (or confirm (null riece-server))
 270         (setq riece-server (completing-read "Server: " riece-server-alist)))
 271     (if (stringp riece-server)
 272         (setq riece-server (riece-server-name-to-server riece-server)))
 273     (riece-create-buffers)
 274     (if riece-max-buffer-size
 275         (setq riece-shrink-buffer-idle-timer
 276               (riece-run-with-idle-timer
 277                riece-shrink-buffer-idle-time-delay t
 278                (lambda ()
 279                  (let ((buffers riece-buffer-list))
 280                    (while buffers
 281                      (if (eq (derived-mode-class
 282                               (with-current-buffer (car buffers)
 283                                 major-mode))
 284                              'riece-dialogue-mode)
 285                          (riece-shrink-buffer (car buffers)))
 286                      (setq buffers (cdr buffers))))))))
 287     (switch-to-buffer riece-command-buffer)
 288     (riece-display-connect-signals)
 289     (riece-redisplay-buffers)
 290     (riece-open-server riece-server "")
 291     (let ((server-list riece-startup-server-list))
 292       (while server-list
 293         (riece-command-open-server (car server-list))
 294         (setq server-list (cdr server-list))))
 295     (run-hooks 'riece-startup-hook)
 296     (message "%s" (substitute-command-keys
 297                    "Type \\[describe-mode] for help"))))
 298
 299 (defun riece-shrink-buffer (buffer)
 300   (save-excursion
 301     (set-buffer buffer)
 302     (goto-char (point-min))
 303     (while (> (buffer-size) riece-max-buffer-size)
 304       (let* ((inhibit-read-only t)
 305              buffer-read-only
 306              (start (point))
 307              (end (progn (beginning-of-line 2) (point)))
 308              (overlays (riece-overlays-in start end)))
 309         (while overlays
 310           (riece-delete-overlay (car overlays))
 311           (setq overlays (cdr overlays)))
 312         (delete-region start end)))))
 313
 314 (defun riece-exit ()
 315   (if riece-save-variables-are-dirty
 316       (riece-save-variables-files))
 317   (while riece-buffer-list
 318     (if (and (get-buffer (car riece-buffer-list))
 319              (buffer-live-p (car riece-buffer-list)))
 320         (funcall riece-buffer-dispose-function (car riece-buffer-list)))
 321     (setq riece-buffer-list (cdr riece-buffer-list)))
 322   (if riece-shrink-buffer-idle-timer
 323       (riece-cancel-timer riece-shrink-buffer-idle-timer))
 324   (setq riece-server nil
 325         riece-current-channels nil
 326         riece-current-channel nil
 327         riece-channel-buffer nil
 328         riece-channel-buffer-alist nil
 329         riece-user-indicator nil
 330         riece-long-channel-indicator "None"
 331         riece-channel-list-indicator "No channel"
 332         riece-away-indicator "-"
 333         riece-operator-indicator "-"
 334         riece-freeze-indicator "-")
 335   (delete-other-windows)
 336   (run-hooks 'riece-exit-hook))
 337
 338 (defun riece-command-mode ()
 339   "Major mode for Riece.  Normal edit function are available.
 340 Typing Return or Linefeed enters the current line in the dialogue.
 341 The following special commands are available:
 342 For a list of the generic commands type \\[riece-command-generic] ? RET.
 343 \\{riece-command-mode-map}"
 344   (interactive)
 345   (kill-all-local-variables)
 346
 347   (setq riece-away-indicator "-"
 348         riece-operator-indicator "-"
 349         major-mode 'riece-command-mode
 350         mode-name "Command"
 351         mode-line-buffer-identification
 352         (riece-mode-line-buffer-identification
 353          '("Riece: "
 354            riece-away-indicator
 355            riece-operator-indicator
 356            " "
 357            riece-user-indicator
 358            " "
 359            riece-channel-indicator)))
 360   (riece-simplify-mode-line-format)
 361   (use-local-map riece-command-mode-map)
 362
 363   (unless riece-command-mode-syntax-table
 364     (setq riece-command-mode-syntax-table
 365           (copy-syntax-table (syntax-table)))
 366     (set-syntax-table riece-command-mode-syntax-table)
 367     (mapcar
 368      (lambda (c) (modify-syntax-entry c "w"))
 369      "^[]{}'`"))
 370
 371   (run-hooks 'riece-command-mode-hook))
 372
 373 (defun riece-dialogue-mode ()
 374   "Major mode for displaying the IRC dialogue.
 375 All normal editing commands are turned off.
 376 Instead, these commands are available:
 377 \\{riece-dialogue-mode-map}"
 378   (kill-all-local-variables)
 379   (make-local-variable 'riece-freeze)
 380   (make-local-variable 'riece-freeze-indicator)
 381   (setq riece-freeze riece-default-freeze
 382         riece-away-indicator "-"
 383         riece-operator-indicator "-"
 384         major-mode 'riece-dialogue-mode
 385         mode-name "Dialogue"
 386         mode-line-buffer-identification
 387         (riece-mode-line-buffer-identification
 388          '("Riece: "
 389            riece-away-indicator
 390            riece-operator-indicator
 391            riece-freeze-indicator
 392            " "
 393            riece-channel-list-indicator " "))
 394         buffer-read-only t)
 395   (riece-simplify-mode-line-format)
 396   (use-local-map riece-dialogue-mode-map)
 397   (buffer-disable-undo)
 398   (run-hooks 'riece-dialogue-mode-hook))
 399
 400 (define-derived-mode riece-others-mode riece-dialogue-mode
 401   "Others"
 402   "Major mode for displaying the IRC others message except current channel.
 403 All normal editing commands are turned off.
 404 Instead, these commands are available:
 405 \\{riece-others-mode-map}")
 406
 407 (define-derived-mode riece-channel-mode riece-dialogue-mode
 408   "Channel"
 409   "Major mode for displaying the IRC current channel buffer.
 410 All normal editing commands are turned off.
 411 Instead, these commands are available:
 412 \\{riece-channel-mode-map}"
 413   (setq mode-line-buffer-identification
 414         (riece-mode-line-buffer-identification
 415          '("Riece: "
 416            riece-away-indicator
 417            riece-operator-indicator
 418            riece-freeze-indicator
 419            " "
 420            riece-long-channel-indicator))))
 421
 422 (defun riece-channel-list-mode ()
 423   "Major mode for displaying channel list.
 424 All normal editing commands are turned off."
 425   (kill-all-local-variables)
 426   (buffer-disable-undo)
 427   (setq major-mode 'riece-channel-list-mode
 428         mode-name "Channels"
 429         mode-line-buffer-identification
 430         (riece-mode-line-buffer-identification '("Riece: "))
 431         truncate-lines t
 432         buffer-read-only t)
 433   (make-local-hook 'riece-update-buffer-functions)
 434   (add-hook 'riece-update-buffer-functions
 435             'riece-update-channel-list-buffer nil t)
 436   (use-local-map riece-channel-list-mode-map)
 437   (run-hooks 'riece-channel-list-mode-hook))
 438
 439 (defun riece-user-list-mode ()
 440   "Major mode for displaying members in the IRC current channel buffer.
 441 All normal editing commands are turned off.
 442 Instead, these commands are available:
 443 \\{riece-user-list-mode-map}"
 444   (kill-all-local-variables)
 445   (buffer-disable-undo)
 446   (setq major-mode 'riece-user-list-mode
 447         mode-name "Users"
 448         mode-line-buffer-identification
 449         (riece-mode-line-buffer-identification
 450          '("Riece: " riece-long-channel-indicator " "))
 451         truncate-lines t
 452         buffer-read-only t)
 453   (if (boundp 'transient-mark-mode)
 454       (set (make-local-variable 'transient-mark-mode) t))
 455   (make-local-hook 'riece-update-buffer-functions)
 456   (add-hook 'riece-update-buffer-functions
 457             'riece-update-user-list-buffer nil t)
 458   (use-local-map riece-user-list-mode-map)
 459   (run-hooks 'riece-user-list-mode-hook))
 460
 461 (defun riece-create-buffers ()
 462   (let ((alist riece-buffer-alist))
 463     (while alist
 464       (save-excursion
 465         (set-buffer (apply #'riece-get-buffer-create
 466                            (cdr (car alist))))
 467         (set (car (car alist)) (current-buffer))
 468         (unless (or (null (nth 2 (car alist)))
 469                     (eq major-mode (nth 2 (car alist))))
 470           (funcall (nth 2 (car alist))))
 471         (setq alist (cdr alist))))))
 472
 473 (defun riece-load-and-build-addon-dependencies (addons)
 474   (let ((load-path (cons riece-addon-directory load-path))
 475         dependencies)
 476     (while addons
 477       (require (car addons))            ;error will be reported here
 478       (let* ((requires
 479               (funcall (or (intern-soft
 480                             (concat (symbol-name (car addons)) "-requires"))
 481                            #'ignore)))
 482              (pointer requires)
 483              entry)
 484         ;; Increment succs' pred count.
 485         (if (setq entry (assq (car addons) dependencies))
 486             (setcar (cdr entry) (+ (length requires) (nth 1 entry)))
 487           (setq dependencies (cons (list (car addons) (length requires))
 488                                    dependencies)))
 489         ;; Merge pred's succs.
 490         (while pointer
 491           (if (setq entry (assq (car pointer) dependencies))
 492               (setcdr (cdr entry)
 493                       (cons (car addons) (nthcdr 2 entry)))
 494             (setq dependencies (cons (list (car pointer) 0 (car addons))
 495                                      dependencies)))
 496           (setq pointer (cdr pointer))))
 497       (setq addons (cdr addons)))
 498     dependencies))
 499
 500 (defun riece-insinuate-addons (addons)
 501   (let ((pointer addons)
 502         dependencies queue)
 503     ;; Uniquify, first.
 504     (while pointer
 505       (if (memq (car pointer) (cdr pointer))
 506           (setcar pointer nil))
 507       (setq pointer (cdr pointer)))
 508     (setq dependencies (riece-load-and-build-addon-dependencies
 509                         (delq nil addons))
 510           pointer dependencies)
 511     ;; Sort them.
 512     (while pointer
 513       (if (zerop (nth 1 (car pointer)))
 514           (setq dependencies (delq (car pointer) dependencies)
 515                 queue (cons (car pointer) queue)))
 516       (setq pointer (cdr pointer)))
 517     (setq addons nil)
 518     (while queue
 519       (setq addons (cons (car (car queue)) addons)
 520             pointer (nthcdr 2 (car queue)))
 521       (while pointer
 522         (let* ((entry (assq (car pointer) dependencies))
 523                (count (1- (nth 1 entry))))
 524           (if (zerop count)
 525               (progn
 526                 (setq dependencies (delq entry dependencies)
 527                       queue (nconc queue (list entry))))
 528             (setcar (cdr entry) count)))
 529         (setq pointer (cdr pointer)))
 530       (setq queue (cdr queue)))
 531     (if dependencies
 532         (error "Circular add-on dependency found"))
 533     (setq addons (nreverse addons))
 534     (while addons
 535       (require (car addons))            ;implicit dependency
 536       (funcall (intern (concat (symbol-name (car addons)) "-insinuate")))
 537       (if riece-debug
 538           (message "Add-on %S is loaded" (car addons)))
 539       (setq addons (cdr addons)))))
 540
 541 (provide 'riece)
 542
 543 ;;; riece.el ends here