* riece-addon.el (riece-insinuate-addon): Add optional 2nd
[riece] / lisp / riece.el
1 ;;; riece.el --- IRC client for Emacsen
2 ;; Copyright (C) 1998-2003 Daiki Ueno
3
4 ;; Author: Daiki Ueno <ueno@unixuser.org>
5 ;; Created: 1998-09-28
6 ;; Keywords: IRC, riece
7
8 ;; This file is part of Riece.
9
10 ;; This program is free software; you can redistribute it and/or modify
11 ;; it under the terms of the GNU General Public License as published by
12 ;; the Free Software Foundation; either version 2, or (at your option)
13 ;; any later version.
14
15 ;; This program is distributed in the hope that it will be useful,
16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
18 ;; GNU General Public License for more details.
19
20 ;; You should have received a copy of the GNU General Public License
21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
23 ;; Boston, MA 02111-1307, USA.
24
25 ;;; Code:
26
27 (require 'riece-filter)
28 (require 'riece-display)
29 (require 'riece-server)
30 (require 'riece-compat)
31 (require 'riece-commands)
32 (require 'riece-addon)
33
34 (autoload 'derived-mode-class "derived")
35
36 (defvar riece-channel-list-mode-map (make-sparse-keymap))
37 (defvar riece-user-list-mode-map (make-sparse-keymap))
38
39 (defvar riece-dialogue-mode-map
40   (let ((keymap (make-keymap)))
41     (suppress-keymap keymap 'nodigit)
42     keymap))
43
44 (defvar riece-command-mode-map (make-keymap))
45 (defvar riece-command-map (make-sparse-keymap))
46
47 (defvar riece-command-mode-syntax-table nil)
48
49 (put 'riece-command-mode 'mode-class 'special)
50 (put 'riece-dialogue-mode 'mode-class 'special)
51 (put 'riece-others-mode 'derived-mode-parent 'riece-dialogue-mode)
52 (put 'riece-channel-list-mode 'mode-class 'special)
53 (put 'riece-user-list-mode 'mode-class 'special)
54 (put 'riece-channel-mode 'derived-mode-parent 'riece-dialogue-mode)
55
56 (defvar riece-buffer-alist
57   '((riece-command-buffer "*Command*" riece-command-mode)
58     (riece-dialogue-buffer "*Dialogue*" riece-dialogue-mode)
59     (riece-others-buffer "*Others*" riece-others-mode)
60     (riece-channel-list-buffer "*Channels*" riece-channel-list-mode)
61     (riece-user-list-buffer " *Users*" riece-user-list-mode)))
62
63 (defvar riece-shrink-buffer-idle-timer nil
64   "Timer object to periodically shrink channel buffers.")
65
66 (defvar riece-addons-insinuated nil
67   "Non nil if add-ons are already insinuated.")
68
69 (defvar riece-select-keys
70   `("1" riece-command-switch-to-channel-by-number-1
71     "2" riece-command-switch-to-channel-by-number-2
72     "3" riece-command-switch-to-channel-by-number-3
73     "4" riece-command-switch-to-channel-by-number-4
74     "5" riece-command-switch-to-channel-by-number-5
75     "6" riece-command-switch-to-channel-by-number-6
76     "7" riece-command-switch-to-channel-by-number-7
77     "8" riece-command-switch-to-channel-by-number-8
78     "9" riece-command-switch-to-channel-by-number-9
79     "0" riece-command-switch-to-channel-by-number-10
80     ,(concat riece-command-prefix "1")
81     riece-command-switch-to-channel-by-number-11
82     ,(concat riece-command-prefix "2")
83     riece-command-switch-to-channel-by-number-12
84     ,(concat riece-command-prefix "3")
85     riece-command-switch-to-channel-by-number-13
86     ,(concat riece-command-prefix "4")
87     riece-command-switch-to-channel-by-number-14
88     ,(concat riece-command-prefix "5")
89     riece-command-switch-to-channel-by-number-15
90     ,(concat riece-command-prefix "6")
91     riece-command-switch-to-channel-by-number-16
92     ,(concat riece-command-prefix "7")
93     riece-command-switch-to-channel-by-number-17
94     ,(concat riece-command-prefix "8")
95     riece-command-switch-to-channel-by-number-18
96     ,(concat riece-command-prefix "9")
97     riece-command-switch-to-channel-by-number-19
98     ,(concat riece-command-prefix "0")
99     riece-command-switch-to-channel-by-number-20))
100
101 ;;; Keymap macros. -- borrowed from `gnus-util.el'.
102 (defmacro riece-local-set-keys (&rest plist)
103   "Set the keys in PLIST in the current keymap."
104   `(riece-define-keys-1 (current-local-map) ',plist))
105
106 (defmacro riece-define-keys (keymap &rest plist)
107   "Assign KEYMAP keys from PLIST."
108   `(riece-define-keys-1 ',keymap ',plist))
109
110 (defmacro riece-define-keys-safe (keymap &rest plist)
111   "Assign KEYMAP keys from PLIST without overwriting previous definitions."
112   `(riece-define-keys-1 ',keymap ',plist t))
113
114 (put 'riece-define-keys 'lisp-indent-function 1)
115 (put 'riece-define-keys-safe 'lisp-indent-function 1)
116 (put 'riece-local-set-keys 'lisp-indent-function 1)
117
118 (defun riece-define-keys-1 (keymap plist &optional safe)
119   "Assign KEYMAP keys from PLIST.
120 If optional argument SAFE is nil, overwrite previous definitions."
121   (unless keymap
122     (error "Can't set keys in a null keymap"))
123   (cond
124    ((symbolp keymap)
125     (setq keymap (symbol-value keymap)))
126    ((keymapp keymap))
127    ((listp keymap)
128     (set (car keymap) nil)
129     (define-prefix-command (car keymap))
130     (define-key (symbol-value (nth 2 keymap))
131       (if (symbolp (nth 1 keymap))
132           (symbol-value (nth 1 keymap))
133         (nth 1 keymap))
134       (car keymap))
135     (setq keymap (symbol-value (car keymap)))))
136   (let (key)
137     (while plist
138       (if (symbolp (setq key (car plist)))
139           (setq key (symbol-value key)))
140       (setq plist (cdr plist))
141       (if (or (not safe)
142               (eq (lookup-key keymap key) 'undefined))
143           (define-key keymap key (car plist))
144         (car plist))
145       (setq plist (cdr plist)))))
146
147 (when t
148   (riece-define-keys riece-dialogue-mode-map
149     "\177" scroll-down
150     [delete] scroll-down
151     [backspace] scroll-down
152     [return] scroll-up
153     " " scroll-up
154     "$" end-of-buffer
155     "/" riece-command-raw
156     ">" end-of-buffer
157     "<" beginning-of-buffer
158     "\C-ta" riece-command-toggle-away
159     "c" riece-command-select-command-buffer
160     "f" riece-command-finger
161     "\C-tf" riece-command-toggle-freeze
162     "\C-to" riece-command-toggle-own-freeze
163     "\C-tu" riece-command-toggle-user-list-buffer-mode
164     "\C-tc" riece-command-toggle-channel-buffer-mode
165     "\C-tC" riece-command-toggle-channel-list-buffer-mode
166     "\C-tl" riece-command-change-layout
167     "i" riece-command-invite
168     "j" riece-command-join
169     "\C-k" riece-command-kick
170     "l" riece-command-list
171     "M" riece-command-change-mode
172     "n" riece-command-change-nickname
173     "N" riece-command-names
174     "o" other-window
175     "O" riece-command-open-server
176     "C" riece-command-close-server
177     "M" riece-command-universal-server-name-argument
178     "p" riece-command-enter-message-to-user
179     "q" riece-command-quit
180     "r" riece-command-configure-windows
181     "x" riece-command-copy-region
182     "t" riece-command-topic
183     "w" riece-command-who)
184
185   (riece-define-keys riece-command-mode-map
186     "\r" riece-command-enter-message
187     [(control return)] riece-command-enter-message-as-notice
188     [tab] riece-command-complete-user)
189
190   (riece-define-keys (riece-command-map riece-command-prefix
191                                         riece-command-mode-map)
192     "\177" riece-command-scroll-down
193     [delete] riece-command-scroll-down
194     [backspace] riece-command-scroll-down
195     " " riece-command-scroll-up
196     "$" riece-command-end-of-buffer
197     ">" riece-command-next-channel
198     "<" riece-command-previous-channel
199     "\C-j" riece-command-next-channel
200     "\C-n" riece-command-names
201     "l" riece-command-list
202     "\C-m" riece-command-change-mode
203     "o" riece-command-set-operators
204     "\C-p" riece-command-part
205     "r" riece-command-configure-windows
206     "v" riece-command-set-speakers
207     "V" riece-version)
208   (set-keymap-parent riece-command-map riece-dialogue-mode-map)
209
210   (riece-define-keys riece-user-list-mode-map
211     "o" riece-command-set-operators
212     "v" riece-command-set-voices
213     "f" riece-command-finger
214     " " riece-command-user-list-scroll-up
215     "\177" riece-command-user-list-scroll-down
216     [delete] riece-command-user-list-scroll-down
217     [backspace] riece-command-user-list-scroll-down
218     "c" riece-command-select-command-buffer)
219
220   (riece-define-keys riece-channel-list-mode-map
221     ">" riece-command-next-channel
222     "<" riece-command-previous-channel
223     "o" other-window
224     "c" riece-command-select-command-buffer)
225
226   (riece-define-keys-1 riece-dialogue-mode-map riece-select-keys)
227   (riece-define-keys-1 riece-channel-list-mode-map riece-select-keys))
228
229 (defun riece-read-variables-files (&optional file)
230   "Read variables FILEs."
231   (or (file-directory-p riece-directory)
232       (make-directory riece-directory))
233   (let ((files (if file
234                    (setq riece-variables-file file
235                          riece-variables-files (list file))
236                  riece-variables-files)))
237     (while files
238       (condition-case nil
239           (load (expand-file-name (car files)))
240         (file-error nil))
241       (setq files (cdr files)))))
242
243 (defvar print-quoted)
244 (defvar print-escape-multibyte)
245 (defun riece-save-variables-files ()
246   "Save current settings to `riece-variables-file'."
247   (with-temp-file riece-saved-variables-file
248     (let ((print-quoted t)
249           (print-readably t)
250           print-escape-multibyte
251           print-level
252           print-length
253           (variables riece-saved-forms))
254       (while variables
255         (prin1 `(setq ,(car variables)
256                       ',(symbol-value (car variables)))
257                (current-buffer))
258         (insert "\n")
259         (setq variables (cdr variables)))))
260   (setq riece-save-variables-are-dirty nil))
261
262 ;;;###autoload
263 (defun riece (&optional confirm)
264   "Connect to the IRC server and start chatting.
265 If optional argument CONFIRM is non-nil, ask which IRC server to connect."
266   (interactive "P")
267   (riece-read-variables-files (if noninteractive
268                                   (car command-line-args-left)))
269   (run-hooks 'riece-after-load-startup-hook)
270   (if (riece-server-opened)
271       (riece-command-configure-windows)
272     (unless riece-addons-insinuated
273       (setq riece-addons (riece-resolve-addons riece-addons))
274       (let ((pointer riece-addons))
275         (while pointer
276           (riece-insinuate-addon (car pointer) riece-debug)
277           (setq pointer (cdr pointer))))
278       (setq riece-addons-insinuated t))
279     (if (or confirm (null riece-server))
280         (setq riece-server (completing-read "Server: " riece-server-alist)))
281     (if (stringp riece-server)
282         (setq riece-server (riece-server-name-to-server riece-server)))
283     (riece-create-buffers)
284     (if riece-max-buffer-size
285         (setq riece-shrink-buffer-idle-timer
286               (riece-run-with-idle-timer
287                riece-shrink-buffer-idle-time-delay t
288                (lambda ()
289                  (let ((buffers riece-buffer-list))
290                    (while buffers
291                      (if (eq (derived-mode-class
292                               (with-current-buffer (car buffers)
293                                 major-mode))
294                              'riece-dialogue-mode)
295                          (riece-shrink-buffer (car buffers)))
296                      (setq buffers (cdr buffers))))))))
297     (switch-to-buffer riece-command-buffer)
298     (riece-display-connect-signals)
299     (riece-redisplay-buffers)
300     (riece-open-server riece-server "")
301     (let ((server-list riece-startup-server-list))
302       (while server-list
303         (riece-command-open-server (car server-list))
304         (setq server-list (cdr server-list))))
305     (run-hooks 'riece-startup-hook)
306     (let ((pointer riece-addons))
307       (while pointer
308         (riece-enable-addon (car pointer) riece-debug)
309         (setq pointer (cdr pointer))))
310     (message "%s" (substitute-command-keys
311                    "Type \\[describe-mode] for help"))))
312
313 (defun riece-shrink-buffer (buffer)
314   (save-excursion
315     (set-buffer buffer)
316     (goto-char (point-min))
317     (while (> (buffer-size) riece-max-buffer-size)
318       (let* ((inhibit-read-only t)
319              buffer-read-only
320              (start (point))
321              (end (progn (beginning-of-line 2) (point)))
322              (overlays (riece-overlays-in start end)))
323         (while overlays
324           (riece-delete-overlay (car overlays))
325           (setq overlays (cdr overlays)))
326         (delete-region start end)))))
327
328 (defun riece-exit ()
329   (if riece-save-variables-are-dirty
330       (riece-save-variables-files))
331   (while riece-buffer-list
332     (if (and (get-buffer (car riece-buffer-list))
333              (buffer-live-p (car riece-buffer-list)))
334         (funcall riece-buffer-dispose-function (car riece-buffer-list)))
335     (setq riece-buffer-list (cdr riece-buffer-list)))
336   (if riece-shrink-buffer-idle-timer
337       (riece-cancel-timer riece-shrink-buffer-idle-timer))
338   (setq riece-server nil
339         riece-current-channels nil
340         riece-current-channel nil
341         riece-channel-buffer nil
342         riece-channel-buffer-alist nil
343         riece-user-indicator nil
344         riece-long-channel-indicator "None"
345         riece-channel-list-indicator "No channel"
346         riece-away-indicator "-"
347         riece-operator-indicator "-"
348         riece-freeze-indicator "-")
349   (delete-other-windows)
350   (run-hooks 'riece-exit-hook))
351
352 (defun riece-command-mode ()
353   "Major mode for Riece.  Normal edit function are available.
354 Typing Return or Linefeed enters the current line in the dialogue.
355 The following special commands are available:
356 For a list of the generic commands type \\[riece-command-generic] ? RET.
357 \\{riece-command-mode-map}"
358   (interactive)
359   (kill-all-local-variables)
360
361   (setq riece-away-indicator "-"
362         riece-operator-indicator "-"
363         major-mode 'riece-command-mode
364         mode-name "Command"
365         mode-line-buffer-identification
366         (riece-mode-line-buffer-identification
367          '("Riece: "
368            riece-away-indicator
369            riece-operator-indicator
370            " "
371            riece-user-indicator
372            " "
373            riece-channel-indicator)))
374   (riece-simplify-mode-line-format)
375   (use-local-map riece-command-mode-map)
376
377   (unless riece-command-mode-syntax-table
378     (setq riece-command-mode-syntax-table
379           (copy-syntax-table (syntax-table)))
380     (set-syntax-table riece-command-mode-syntax-table)
381     (mapcar
382      (lambda (c) (modify-syntax-entry c "w"))
383      "^[]{}'`"))
384
385   (run-hooks 'riece-command-mode-hook))
386   
387 (defun riece-dialogue-mode ()
388   "Major mode for displaying the IRC dialogue.
389 All normal editing commands are turned off.
390 Instead, these commands are available:
391 \\{riece-dialogue-mode-map}"
392   (kill-all-local-variables)
393   (make-local-variable 'riece-freeze)
394   (make-local-variable 'riece-freeze-indicator)
395   (setq riece-freeze riece-default-freeze
396         riece-away-indicator "-"
397         riece-operator-indicator "-"
398         major-mode 'riece-dialogue-mode
399         mode-name "Dialogue"
400         mode-line-buffer-identification
401         (riece-mode-line-buffer-identification
402          '("Riece: "
403            riece-away-indicator
404            riece-operator-indicator
405            riece-freeze-indicator
406            " "
407            riece-channel-list-indicator " "))
408         buffer-read-only t)
409   (riece-simplify-mode-line-format)
410   (use-local-map riece-dialogue-mode-map)
411   (buffer-disable-undo)
412   (run-hooks 'riece-dialogue-mode-hook))
413
414 (define-derived-mode riece-others-mode riece-dialogue-mode
415   "Others"
416   "Major mode for displaying the IRC others message except current channel.
417 All normal editing commands are turned off.
418 Instead, these commands are available:
419 \\{riece-others-mode-map}")
420
421 (define-derived-mode riece-channel-mode riece-dialogue-mode
422   "Channel"
423   "Major mode for displaying the IRC current channel buffer.
424 All normal editing commands are turned off.
425 Instead, these commands are available:
426 \\{riece-channel-mode-map}"
427   (setq mode-line-buffer-identification
428         (riece-mode-line-buffer-identification
429          '("Riece: "
430            riece-away-indicator
431            riece-operator-indicator
432            riece-freeze-indicator
433            " "
434            riece-long-channel-indicator))))
435
436 (defun riece-channel-list-mode ()
437   "Major mode for displaying channel list.
438 All normal editing commands are turned off."
439   (kill-all-local-variables)
440   (buffer-disable-undo)
441   (setq major-mode 'riece-channel-list-mode
442         mode-name "Channels"
443         mode-line-buffer-identification
444         (riece-mode-line-buffer-identification '("Riece: "))
445         truncate-lines t
446         buffer-read-only t)
447   (make-local-hook 'riece-update-buffer-functions)
448   (add-hook 'riece-update-buffer-functions
449             'riece-update-channel-list-buffer nil t)
450   (use-local-map riece-channel-list-mode-map)
451   (run-hooks 'riece-channel-list-mode-hook))
452
453 (defun riece-user-list-mode ()
454   "Major mode for displaying members in the IRC current channel buffer.
455 All normal editing commands are turned off.
456 Instead, these commands are available:
457 \\{riece-user-list-mode-map}"
458   (kill-all-local-variables)
459   (buffer-disable-undo)
460   (setq major-mode 'riece-user-list-mode
461         mode-name "Users"
462         mode-line-buffer-identification
463         (riece-mode-line-buffer-identification
464          '("Riece: " riece-long-channel-indicator " "))
465         truncate-lines t
466         buffer-read-only t)
467   (if (boundp 'transient-mark-mode)
468       (set (make-local-variable 'transient-mark-mode) t))
469   (make-local-hook 'riece-update-buffer-functions)
470   (add-hook 'riece-update-buffer-functions
471             'riece-update-user-list-buffer nil t)
472   (use-local-map riece-user-list-mode-map)
473   (run-hooks 'riece-user-list-mode-hook))
474
475 (defun riece-create-buffers ()
476   (let ((alist riece-buffer-alist))
477     (while alist
478       (save-excursion
479         (set-buffer (apply #'riece-get-buffer-create
480                            (cdr (car alist))))
481         (set (car (car alist)) (current-buffer))
482         (unless (or (null (nth 2 (car alist)))
483                     (eq major-mode (nth 2 (car alist))))
484           (funcall (nth 2 (car alist))))
485         (setq alist (cdr alist))))))
486       
487 (provide 'riece)
488
489 ;;; riece.el ends here