cgit.sxemacs.org Git - riece/blob - lisp/riece-unread.el

   1 ;;; riece-unread.el --- "unread message mark" add-on
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Keywords: IRC, riece
   6
   7 ;; This file is part of Riece.
   8
   9 ;; This program is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; This program is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; This add-on marks channels where new messages are arrived.
  27
  28 ;; You can check the unread channels via `C-c g' in the commands
  29 ;; buffer, by adding the following lines to ~/.riece/init.el:
  30
  31 ;;   (add-hook 'riece-guess-channel-try-functions
  32 ;;             'riece-guess-channel-from-unread)
  33
  34 ;;; Code:
  35
  36 (require 'riece-message)
  37 (require 'riece-commands)
  38
  39 (eval-when-compile (require 'riece-highlight))
  40
  41 (defgroup riece-unread nil
  42   "Mark unread channels"
  43   :tag "Unread"
  44   :prefix "riece-"
  45   :group 'riece)
  46
  47 (defface riece-channel-list-unread-face
  48   '((((class color)
  49       (background dark))
  50      (:foreground "orange"))
  51     (((class color)
  52       (background light))
  53      (:foreground "firebrick"))
  54     (t
  55      (:bold t)))
  56   "Face used for displaying unread channels."
  57   :group 'riece-highlight-faces)
  58 (defvar riece-channel-list-unread-face 'riece-channel-list-unread-face)
  59
  60 (defvar riece-unread-channels nil)
  61
  62 (defun riece-unread-after-display-message-function (message)
  63   (unless (or (riece-message-own-p message)
  64               (riece-identity-equal (riece-message-target message)
  65                                     riece-current-channel)
  66               (riece-identity-member (riece-message-target message)
  67                                      riece-unread-channels))
  68     (setq riece-unread-channels
  69           (cons (riece-message-target message) riece-unread-channels))
  70     (riece-redisplay-buffers)))
  71
  72 (defun riece-unread-after-switch-to-channel-function (last)
  73   (setq riece-unread-channels
  74         (delete riece-current-channel
  75                 riece-unread-channels)))
  76
  77 (defun riece-unread-format-channel-list-line (index channel)
  78   (if (riece-identity-member channel riece-unread-channels)
  79       (concat (format "%2d:!" index)
  80               (riece-format-identity channel)
  81               "\n")))
  82
  83 (defun riece-unread-switch-to-channel ()
  84   (interactive)
  85   (if riece-unread-channels
  86       (let ((channel (car riece-unread-channels)))
  87         (if (riece-identity-member channel riece-current-channels)
  88             (riece-command-switch-to-channel channel)
  89           (setq riece-unread-channels
  90                 (delete channel riece-unread-channels))
  91           (riece-unread-switch-to-channel)))
  92     (error "No unread channel!")))
  93
  94 (defun riece-guess-channel-from-unread ()
  95   riece-unread-channels)
  96
  97 (defvar riece-command-mode-map)
  98 (defvar riece-dialogue-mode-map)
  99 (defvar riece-channel-list-mode-map)
 100
 101 (defun riece-unread-requires ()
 102   (let (requires)
 103     (if (memq 'riece-highlight riece-addons)
 104         (setq requires (cons 'riece-highlight requires)))
 105 ;;;    (if (memq 'riece-guess riece-addons)
 106 ;;;     (setq requires (cons 'riece-guess requires)))
 107     requires))
 108
 109 (defun riece-unread-insinuate ()
 110   (add-hook 'riece-after-display-message-functions
 111             'riece-unread-after-display-message-function)
 112   (add-hook 'riece-after-switch-to-channel-functions
 113             'riece-unread-after-switch-to-channel-function)
 114   (add-hook 'riece-format-channel-list-line-functions
 115             'riece-unread-format-channel-list-line)
 116   (define-key riece-command-mode-map
 117     "\C-c\C-u" 'riece-unread-switch-to-channel)
 118   (define-key riece-dialogue-mode-map
 119     "u" 'riece-unread-switch-to-channel)
 120   (define-key riece-channel-list-mode-map
 121     "u" 'riece-unread-switch-to-channel)
 122   (if (memq 'riece-highlight riece-addons)
 123       (setq riece-channel-list-mark-face-alist
 124             (cons '(?! . riece-channel-list-unread-face)
 125                   riece-channel-list-mark-face-alist)))
 126 ;;;  (if (memq 'riece-guess riece-addons)
 127 ;;;      (add-hook 'riece-guess-channel-try-functions
 128 ;;;             'riece-guess-channel-from-unread))
 129   )
 130
 131 (provide 'riece-unread)
 132
 133 ;;; riece-unread.el ends here