cgit.sxemacs.org Git - riece/blob - lisp/riece-server.el

   1 ;;; riece-server.el --- functions to open and close servers
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Created: 1998-09-28
   6 ;; Keywords: IRC, riece
   7
   8 ;; This file is part of Riece.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Code:
  26
  27 (require 'riece-options)
  28 (require 'riece-globals)                ;for server local variables.
  29 (require 'riece-coding)                 ;riece-default-coding-system
  30 (require 'riece-identity)
  31 (require 'riece-compat)
  32
  33 (eval-and-compile
  34   (defvar riece-server-keyword-map
  35     '((:host)
  36       (:service 6667)
  37       (:nickname riece-nickname)
  38       (:username riece-username)
  39       (:password)
  40       (:function #'open-network-stream)
  41       (:coding riece-default-coding-system))
  42     "Mapping from keywords to default values.
  43 All keywords that can be used must be listed here."))
  44
  45 (defmacro riece-server-keyword-bind (plist &rest body)
  46   "Return a `let' form that binds all variables in PLIST.
  47 After this is done, BODY will be executed in the scope
  48 of the `let' form.
  49
  50 The variables bound and their default values are described by
  51 the `riece-server-keyword-map' variable."
  52   `(let ,(mapcar
  53           (lambda (keyword)
  54             (list (intern (substring (symbol-name (car keyword)) 1))
  55                   (if (cadr keyword)
  56                       `(or (plist-get ,plist ',(car keyword))
  57                            ,(cadr keyword))
  58                     `(plist-get ,plist ',(car keyword)))))
  59           riece-server-keyword-map)
  60      ,@body))
  61
  62 (put 'riece-server-keyword-bind 'lisp-indent-function 1)
  63 (put 'riece-server-keyword-bind 'edebug-form-spec '(form body))
  64
  65 (defun riece-server-parse-string (string)
  66   "Convert a STRING set as `riece-server' and return a property list."
  67   (when (or (string-match "^\\[\\([^]]+\\)\\]:?\\([0-9]*\\)" string)
  68             (string-match "^\\([^:]+\\):?\\([0-9]*\\)" string))
  69     (let ((host (match-string 1 string))
  70           (service (match-string 2 string))
  71           (password (substring string (match-end 0)))
  72           plist)
  73       (setq plist (cons `(:host ,host) plist))
  74       (unless (equal service "")
  75         (setq plist (cons `(:service ,(string-to-int service)) plist)))
  76       (unless (equal password "")
  77         (setq plist (cons `(:password ,(substring password 1)) plist)))
  78       (apply #'nconc plist))))
  79
  80 (defun riece-server-name-to-server (server-name)
  81   (let ((entry (assoc server-name riece-server-alist)))
  82     (if entry
  83         (unless (listp (cdr entry))
  84           (setcdr entry (riece-server-parse-string (cdr entry))))
  85       (setq entry (cons server-name (riece-server-parse-string server-name))
  86             riece-server-alist (cons entry riece-server-alist)
  87             riece-save-variables-are-dirty t))
  88     (cdr entry)))
  89
  90 (defun riece-server-process-name (server-name)
  91   (if (equal server-name "")
  92       "IRC"
  93     (format "IRC<%s>" server-name)))
  94
  95 (defun riece-server-process (server-name)
  96   (get-process (riece-server-process-name server-name)))
  97
  98 (defmacro riece-with-server-buffer (server-name &rest body)
  99   `(let ((process (riece-server-process ,server-name)))
 100      (if process
 101          (with-current-buffer (process-buffer process)
 102            ,@body)
 103        (error "Server closed"))))
 104
 105 (put 'riece-with-server-buffer 'lisp-indent-function 1)
 106
 107 (defun riece-process-send-string (process string)
 108   (with-current-buffer (process-buffer process)
 109     (process-send-string process (riece-encode-coding-string string))))
 110
 111 (defun riece-send-string (string)
 112   (let* ((server-name
 113           (or riece-overriding-server-name
 114                                         ;already in the server buffer
 115               (if (local-variable-p 'riece-server-name (current-buffer))
 116                   riece-server-name
 117                 (if riece-current-channel
 118                     (riece-identity-server riece-current-channel)
 119                   (if (riece-server-opened "")
 120                       "")))))
 121          (process (riece-server-process server-name)))
 122     (unless process
 123       (error "%s" (substitute-command-keys
 124                    "Type \\[riece-command-open-server] to open server.")))
 125     (riece-process-send-string process string)))
 126
 127 (defun riece-open-server (server server-name)
 128   (riece-server-keyword-bind server
 129     (let (selective-display
 130           (coding-system-for-read 'binary)
 131           (coding-system-for-write 'binary)
 132           process)
 133       (if (equal server-name "")
 134           (message "Connecting to IRC server...")
 135         (message "Connecting to %s..." server-name))
 136       (setq process
 137             (funcall function (riece-server-process-name server-name)
 138                      (concat " *IRC*" server-name)
 139                      host service))
 140       (if (equal server-name "")
 141           (message "Connecting to IRC server...done")
 142         (message "Connecting to %s...done" server-name))
 143       (riece-reset-process-buffer process)
 144       (with-current-buffer (process-buffer process)
 145         (setq riece-server-name server-name))
 146       (set-process-sentinel process 'riece-sentinel)
 147       (set-process-filter process 'riece-filter)
 148       (if (equal server-name "")
 149           (message "Logging in to IRC server...")
 150         (message "Logging in to %s..." server-name))
 151       (if riece-reconnect-with-password ;password incorrect or not set.
 152           (unwind-protect
 153               (setq password (riece-read-passwd "Password: "))
 154             (setq riece-reconnect-with-password nil)))
 155       (if password
 156           (riece-process-send-string process
 157                                      (format "PASS %s\r\n" password)))
 158       (riece-process-send-string process
 159                                  (format "USER %s * * :%s\r\n"
 160                                          (user-real-login-name)
 161                                          (or username
 162                                              "No information given")))
 163       (riece-process-send-string process (format "NICK %s\r\n" nickname))
 164       (with-current-buffer (process-buffer process)
 165         (setq riece-last-nickname riece-real-nickname
 166               riece-nick-accepted 'sent
 167               riece-coding-system coding))
 168       (setq riece-process-list
 169             (cons process riece-process-list)))))
 170
 171 (defun riece-reset-process-buffer (process)
 172   (save-excursion
 173     (set-buffer (process-buffer process))
 174     (if (fboundp 'set-buffer-multibyte)
 175         (set-buffer-multibyte nil))
 176     (kill-all-local-variables)
 177     (make-local-variable 'riece-real-nickname)
 178     (make-local-variable 'riece-last-nickname)
 179     (make-local-variable 'riece-nick-accepted)
 180     (make-local-variable 'riece-real-server-name)
 181     (make-local-variable 'riece-real-userhost)
 182     (make-local-variable 'riece-user-at-host)
 183     (make-local-variable 'riece-user-at-host-type)
 184     (make-local-variable 'riece-supported-user-modes)
 185     (make-local-variable 'riece-supported-channel-modes)
 186     (make-local-variable 'riece-channel-filter)
 187     (make-local-variable 'riece-server-name)
 188     (make-local-variable 'riece-read-point)
 189     (setq riece-read-point (point-min))
 190     (make-local-variable 'riece-obarray)
 191     (setq riece-obarray (make-vector riece-obarray-size 0))
 192     (make-local-variable 'riece-coding-system)
 193     (buffer-disable-undo)
 194     (erase-buffer)))
 195
 196 (eval-when-compile
 197   (autoload 'riece-exit "riece"))
 198 (defun riece-close-server-process (process)
 199   (if riece-debug
 200       (delete-process process)
 201     (kill-buffer (process-buffer process)))
 202   (setq riece-process-list (delq process riece-process-list))
 203   ;; If no server process is available, exit.
 204   (unless riece-process-list
 205     (riece-exit)))
 206
 207 (defun riece-server-opened (&optional server-name)
 208   (let ((process-list riece-process-list))
 209     (catch 'found
 210       (while process-list
 211         (if (memq (process-status (car process-list)) '(open run))
 212             (throw 'found t))
 213         (setq process-list (cdr process-list))))))
 214
 215 (defun riece-quit-server-process (process &optional message)
 216   (run-at-time riece-quit-timeout nil
 217                (lambda (process)
 218                  (if (memq process riece-process-list)
 219                      (riece-close-server-process process)))
 220                process)
 221   (riece-process-send-string process
 222                              (if message
 223                                  (format "QUIT :%s\r\n" message)
 224                                "QUIT\r\n")))
 225
 226 (provide 'riece-server)
 227
 228 ;;; riece-server.el ends here