cgit.sxemacs.org Git - riece/blob - lisp/riece-server.el

   1 ;;; riece-server.el --- functions to open and close servers
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Created: 1998-09-28
   6 ;; Keywords: IRC, riece
   7
   8 ;; This file is part of Riece.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Code:
  26
  27 (require 'riece-options)
  28 (require 'riece-globals)                ;for server local variables.
  29 (require 'riece-coding)                 ;riece-default-coding-system
  30 (require 'riece-identity)
  31 (require 'riece-compat)
  32
  33 (eval-and-compile
  34   (defvar riece-server-keyword-map
  35     '((:host)
  36       (:service 6667)
  37       (:nickname riece-nickname)
  38       (:username riece-username)
  39       (:password)
  40       (:function riece-default-open-connection-function)
  41       (:coding riece-default-coding-system))
  42     "Mapping from keywords to default values.
  43 All keywords that can be used must be listed here."))
  44
  45 (defmacro riece-server-keyword-bind (plist &rest body)
  46   "Return a `let' form that binds all variables in PLIST.
  47 After this is done, BODY will be executed in the scope
  48 of the `let' form.
  49
  50 The variables bound and their default values are described by
  51 the `riece-server-keyword-map' variable."
  52   `(let ,(mapcar
  53           (lambda (keyword)
  54             (list (intern (substring (symbol-name (car keyword)) 1))
  55                   (if (cadr keyword)
  56                       `(or (plist-get ,plist ',(car keyword))
  57                            ,(cadr keyword))
  58                     `(plist-get ,plist ',(car keyword)))))
  59           riece-server-keyword-map)
  60      ,@body))
  61
  62 (put 'riece-server-keyword-bind 'lisp-indent-function 1)
  63 (put 'riece-server-keyword-bind 'edebug-form-spec '(form body))
  64
  65 (defun riece-server-parse-string (string)
  66   "Convert a STRING set as `riece-server' and return a property list."
  67   (when (or (string-match "^\\[\\([^]]+\\)\\]:?\\([0-9]*\\)" string)
  68             (string-match "^\\([^:]+\\):?\\([0-9]*\\)" string))
  69     (let ((host (match-string 1 string))
  70           (service (match-string 2 string))
  71           (password (substring string (match-end 0)))
  72           plist)
  73       (setq plist (cons `(:host ,host) plist))
  74       (unless (equal service "")
  75         (setq plist (cons `(:service ,(string-to-int service)) plist)))
  76       (unless (equal password "")
  77         (setq plist (cons `(:password ,(substring password 1)) plist)))
  78       (apply #'nconc plist))))
  79
  80 (defun riece-server-name-to-server (server-name)
  81   (let ((entry (assoc server-name riece-server-alist)))
  82     (if entry
  83         (unless (listp (cdr entry))
  84           (setcdr entry (riece-server-parse-string (cdr entry))))
  85       (setq entry (cons server-name (riece-server-parse-string server-name))
  86             riece-server-alist (cons entry riece-server-alist)
  87             riece-save-variables-are-dirty t))
  88     (cdr entry)))
  89
  90 (defun riece-server-process-name (server-name)
  91   (if (equal server-name "")
  92       "IRC"
  93     (format "IRC<%s>" server-name)))
  94
  95 (defun riece-server-process (server-name)
  96   (cdr (assoc server-name riece-server-process-alist)))
  97
  98 (defmacro riece-with-server-buffer (server-name &rest body)
  99   `(let ((process (riece-server-process ,server-name)))
 100      (if process
 101          (with-current-buffer (process-buffer process)
 102            ,@body)
 103        (error "Server closed"))))
 104
 105 (put 'riece-with-server-buffer 'lisp-indent-function 1)
 106 (put 'riece-with-server-buffer 'edebug-form-spec '(form body))
 107
 108 (defun riece-flush-send-queue (process &optional reset)
 109   (with-current-buffer (process-buffer process)
 110     (let ((length 0)
 111           string)
 112       (if reset
 113           (setq riece-send-size 0))
 114       (while (and riece-send-queue
 115                   (<= riece-send-size riece-max-send-size))
 116         (setq string (riece-encode-coding-string (car riece-send-queue))
 117               length (length string))
 118         (if (> length riece-max-send-size)
 119             (message "Long message (%d > %d)" length riece-max-send-size)
 120           (setq riece-send-size (+ riece-send-size length))
 121           (when (<= riece-send-size riece-max-send-size)
 122             (process-send-string process string)
 123             (setq riece-last-send-time (current-time))))
 124         (setq riece-send-queue (cdr riece-send-queue)))
 125       (if riece-send-queue
 126           (riece-run-at-time riece-send-delay nil
 127                              #'riece-flush-send-queue process t)))))
 128
 129 (defun riece-process-send-string (process string)
 130   (with-current-buffer (process-buffer process)
 131     (setq riece-send-queue (nconc riece-send-queue (list string))))
 132   (riece-flush-send-queue process nil))
 133
 134 (defun riece-current-server-name ()
 135   (or riece-overriding-server-name
 136                                         ;already in the server buffer
 137       (if (local-variable-p 'riece-server-name (current-buffer))
 138           riece-server-name
 139         (if riece-current-channel
 140             (riece-identity-server riece-current-channel)
 141           (if (riece-server-opened "")
 142               "")))))
 143
 144 (defun riece-send-string (string)
 145   (let* ((server-name (riece-current-server-name))
 146          (process (riece-server-process server-name)))
 147     (unless process
 148       (error "%s" (substitute-command-keys
 149                    "Type \\[riece-command-open-server] to open server.")))
 150     (riece-process-send-string process string)))
 151
 152 (defun riece-open-server (server server-name)
 153   (let ((protocol (or (plist-get server :protocol)
 154                       riece-protocol))
 155         function
 156         process)
 157     (condition-case nil
 158         (require (intern (concat "riece-" (symbol-name protocol))))
 159       (error))
 160     (setq function (intern-soft (concat "riece-"
 161                                         (symbol-name protocol)
 162                                         "-open-server")))
 163     (unless function
 164       (error "\"%S\" is not supported" protocol))
 165     (condition-case nil
 166         (setq process (funcall function server server-name))
 167       (error))
 168     (when process
 169       (with-current-buffer (process-buffer process)
 170         (make-local-variable 'riece-protocol)
 171         (setq riece-protocol protocol))
 172       (setq riece-server-process-alist
 173             (cons (cons server-name process)
 174                   riece-server-process-alist)))))
 175
 176 (defun riece-quit-server-process (process &optional message)
 177   (let ((function (intern-soft
 178                    (concat "riece-"
 179                            (with-current-buffer (process-buffer process)
 180                              (symbol-name riece-protocol))
 181                            "-quit-server-process"))))
 182     (if function
 183         (funcall function process message))))
 184
 185 (defun riece-reset-process-buffer (process)
 186   (save-excursion
 187     (set-buffer (process-buffer process))
 188     (if (fboundp 'set-buffer-multibyte)
 189         (set-buffer-multibyte nil))
 190     (kill-all-local-variables)
 191     (make-local-variable 'riece-real-nickname)
 192     (make-local-variable 'riece-last-nickname)
 193     (make-local-variable 'riece-nick-accepted)
 194     (make-local-variable 'riece-real-server-name)
 195     (make-local-variable 'riece-real-userhost)
 196     (make-local-variable 'riece-user-at-host)
 197     (make-local-variable 'riece-user-at-host-type)
 198     (make-local-variable 'riece-supported-user-modes)
 199     (make-local-variable 'riece-supported-channel-modes)
 200     (make-local-variable 'riece-channel-filter)
 201     (make-local-variable 'riece-server-name)
 202     (make-local-variable 'riece-read-point)
 203     (make-local-variable 'riece-send-queue)
 204     (make-local-variable 'riece-last-send-time)
 205     (setq riece-last-send-time '(0 0 0))
 206     (make-local-variable 'riece-send-size)
 207     (setq riece-send-size 0)
 208     (setq riece-read-point (point-min))
 209     (make-local-variable 'riece-obarray)
 210     (setq riece-obarray (make-vector riece-obarray-size 0))
 211     (make-local-variable 'riece-coding-system)
 212     (buffer-disable-undo)
 213     (erase-buffer)))
 214
 215 (defun riece-close-server-process (process)
 216   (kill-buffer (process-buffer process))
 217   (setq riece-server-process-alist
 218         (delq (rassq process riece-server-process-alist)
 219               riece-server-process-alist)))
 220
 221 (defun riece-server-process-opened (process)
 222   (not (null (memq (process-status process) '(open run)))))
 223
 224 (defun riece-server-opened (&optional server-name)
 225   (if server-name
 226       (let ((process (riece-server-process server-name)))
 227         (and process
 228              (riece-server-process-opened process)))
 229     (let ((alist riece-server-process-alist))
 230       (catch 'found
 231         (while alist
 232           (if (riece-server-process-opened (cdr (car alist)))
 233               (throw 'found t))
 234           (setq alist (cdr alist)))))))
 235
 236 (provide 'riece-server)
 237
 238 ;;; riece-server.el ends here