cgit.sxemacs.org Git - riece/blob - lisp/riece-rdcc.el

   1 ;;; riece-rdcc.el --- Ruby implementation of DCC add-on
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Keywords: IRC, riece
   6
   7 ;; This file is part of Riece.
   8
   9 ;; This program is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; This program is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Code:
  25
  26 (require 'riece-globals)
  27 (require 'riece-misc)
  28 (require 'riece-channel)
  29 (require 'riece-identity)
  30 (require 'riece-ctcp)                   ;for riece-ctcp-additional-clientinfo
  31 (require 'riece-ruby)
  32
  33 (defgroup riece-rdcc nil
  34   "DCC written in Ruby."
  35   :prefix "riece-"
  36   :group 'riece)
  37
  38 (defcustom riece-rdcc-server-address nil
  39   "Local address of the DCC server.
  40 Only used for sending files."
  41   :type 'string
  42   :group 'riece-rdcc)
  43
  44 (defcustom riece-rdcc-send-program
  45   '("\
  46 require 'socket'
  47 address = " address "
  48 unless address
  49   sock = UDPSocket.new
  50   sock.connect('164.46.176.4', 7)               # www.unixuser.org/echo
  51   address = sock.getsockname[4 .. 7].unpack('CCCC').join('.')
  52 end
  53 server = TCPServer.new(address, 0)
  54 output(\"#{server.addr[3].split(/\\./).collect{|c| c.to_i}.pack('CCCC').unpack('N')[0]} #{server.addr[1]}\")
  55 session = server.accept
  56 if session
  57   total = 0
  58   File.open(" file ") {|file|
  59     while (bytes = file.read(" block-size "))
  60       total += bytes.length
  61       output(total)
  62       session.write(bytes)
  63       begin
  64         buf = session.read(4)
  65       end until buf.unpack('N')[0] == total
  66     end
  67   }
  68   session.close
  69 end
  70 ")
  71   "Ruby program to send file with DCC."
  72   :type 'list
  73   :group 'riece-rdcc)
  74
  75 (defcustom riece-rdcc-decode-address-program
  76   '("\"#{" address " >> 24 & 0xFF}.#{" address " >> 16 & 0xFF}.#{"
  77     address " >> 8 & 0xFF}.#{" address " & 0xFF}\"")
  78   "Ruby program to numeric IP address."
  79   :type 'list
  80   :group 'riece-rdcc)
  81
  82 (defcustom riece-rdcc-save-directory nil
  83   "Default directory where received files are saved in."
  84   :type 'directory
  85   :group 'riece-rdcc)
  86
  87 (defcustom riece-rdcc-block-size 1024
  88   "Number of bytes sent as a block."
  89   :type 'integer
  90   :group 'riece-rdcc)
  91
  92 (defvar riece-rdcc-requests nil)
  93
  94 (defvar riece-rdcc-request-user nil)
  95 (defvar riece-rdcc-request-file nil)
  96 (defvar riece-rdcc-request-size nil)
  97
  98 (defvar riece-rdcc-temp-file nil)
  99 (defvar riece-rdcc-received-size nil)
 100
 101 (defvar riece-rdcc-enabled nil)
 102
 103 (defconst riece-rdcc-description
 104   "DCC file sending extension implemented in Ruby")
 105
 106 (defvar temporary-file-directory)
 107 (defvar jka-compr-compression-info-list)
 108 (defvar jam-zcat-filename-list)
 109
 110 (defun riece-rdcc-output-handler (name output time)
 111   (if (string-match "\\([0-9]+\\) \\([0-9]+\\)" output)
 112       (let ((address (match-string 1 output))
 113             (port (match-string 2 output)))
 114         (riece-send-string
 115          (format "PRIVMSG %s :\1DCC SEND %s %s %s %d\1\r\n"
 116                  (riece-identity-prefix
 117                   (riece-ruby-property name 'riece-rdcc-request-user))
 118                  (file-name-nondirectory
 119                   (riece-ruby-property name 'riece-rdcc-request-file))
 120                  address port
 121                  (riece-ruby-property name 'riece-rdcc-request-size)))))
 122   (riece-ruby-set-output-handler name #'riece-rdcc-output-handler-2))
 123
 124 (defun riece-rdcc-output-handler-2 (name output time)
 125   (message "Sending %s...(%s/%d)"
 126            (riece-ruby-property name 'riece-rdcc-request-file)
 127            (string-to-number output)
 128            (riece-ruby-property name 'riece-rdcc-request-size)))
 129
 130 (defun riece-rdcc-exit-handler (name)
 131   (message "Sending %s...done"
 132            (riece-ruby-property name 'riece-rdcc-request-file)))
 133
 134 (defun riece-command-dcc-send (user file)
 135   (interactive
 136    (let ((completion-ignore-case t))
 137      (list (riece-completing-read-identity
 138             "User: "
 139             (riece-get-users-on-server (riece-current-server-name)))
 140            (expand-file-name (read-file-name "File: ")))))
 141   (let ((name (riece-ruby-execute
 142                (riece-ruby-substitute-variables
 143                 riece-rdcc-send-program
 144                 (list (cons 'address
 145                             (if riece-rdcc-server-address
 146                                 (concat "'" riece-rdcc-server-address
 147                                         "'")
 148                               "nil"))
 149                       (cons 'file
 150                             (concat "'" file "'"))
 151                       (cons 'block-size
 152                             (number-to-string
 153                              riece-rdcc-block-size)))))))
 154     (riece-ruby-set-property name 'riece-rdcc-request-user user)
 155     (riece-ruby-set-property name 'riece-rdcc-request-file file)
 156     (riece-ruby-set-property name 'riece-rdcc-request-size
 157                              (nth 7 (file-attributes file)))
 158     (riece-ruby-set-output-handler name #'riece-rdcc-output-handler)
 159     (riece-ruby-set-exit-handler name #'riece-rdcc-exit-handler)))
 160
 161 (defun riece-rdcc-filter (process input)
 162   (save-excursion
 163     (set-buffer (process-buffer process))
 164     (erase-buffer)
 165     (insert input)
 166     (let ((coding-system-for-write 'binary)
 167           jka-compr-compression-info-list jam-zcat-filename-list)
 168       (write-region (point-min) (point-max) riece-rdcc-temp-file t 0))
 169     (setq riece-rdcc-received-size (+ (buffer-size) riece-rdcc-received-size))
 170     (process-send-string
 171      process
 172      (format "%c%c%c%c"
 173              (lsh riece-rdcc-received-size -24)
 174              (logand (lsh riece-rdcc-received-size -16) 255)
 175              (logand (lsh riece-rdcc-received-size -8) 255)
 176              (logand riece-rdcc-received-size 255)))
 177     (message "Receiving %s from %s...(%s/%s)"
 178              (file-name-nondirectory riece-rdcc-request-file)
 179              riece-rdcc-request-user
 180              (riece-rdcc-format-size riece-rdcc-received-size)
 181              (riece-rdcc-format-size riece-rdcc-request-size))
 182     (if (= riece-rdcc-received-size riece-rdcc-request-size)
 183         (set-process-filter process nil))))
 184
 185 (defun riece-rdcc-sentinel (process status)
 186   (save-excursion
 187     (set-buffer (process-buffer process))
 188     (unless (= riece-rdcc-received-size riece-rdcc-request-size)
 189       (error "Premature end of file"))
 190     (message "Receiving %s from %s...done"
 191              (file-name-nondirectory riece-rdcc-request-file)
 192              riece-rdcc-request-user)
 193     (condition-case nil
 194         (progn
 195           (rename-file riece-rdcc-temp-file riece-rdcc-request-file)
 196           (delete-directory (file-name-directory riece-rdcc-temp-file)))
 197       (file-already-exists
 198        (error "Can't save %s.  Temporarily saved in %s"
 199               riece-rdcc-request-file riece-rdcc-temp-file))))
 200   (kill-buffer (process-buffer process)))
 201
 202 (defun riece-rdcc-decode-address (address)
 203   (let ((name (riece-ruby-execute
 204                (riece-ruby-substitute-variables
 205                 riece-rdcc-decode-address-program
 206                 (list (cons 'address address)))))
 207         response)
 208     (while (equal (nth 2 (setq response (riece-ruby-inspect name))) "running")
 209       (accept-process-output riece-ruby-process))
 210     (riece-ruby-clear name)
 211     (nth 1 response)))
 212
 213 (defun riece-command-dcc-receive (request file)
 214   (interactive
 215    (progn
 216      (unless riece-rdcc-requests
 217        (error "No request"))
 218      (let* ((request
 219              (if (= (length riece-rdcc-requests) 1)
 220                  (car riece-rdcc-requests)
 221                (with-output-to-temp-buffer "*Help*"
 222                  (let ((requests riece-rdcc-requests)
 223                        (index 1))
 224                    (while requests
 225                      (princ (format "%2d: %s %s (%d bytes)\n"
 226                                     index
 227                                     (car (car requests))
 228                                     (nth 1 (car requests))
 229                                     (nth 4 (car requests))))
 230                      (setq index (1+ index)
 231                            requests (cdr requests)))))
 232                (let ((number (read-string "Request#: ")))
 233                  (unless (string-match "^[0-9]+$" number)
 234                    (error "Not a number"))
 235                  (if (or (> (setq number (string-to-number number))
 236                             (length riece-rdcc-requests))
 237                          (< number 1))
 238                      (error "Invalid number"))
 239                  (nth (1- number) riece-rdcc-requests))))
 240             (default-name (expand-file-name
 241                            (convert-standard-filename (nth 1 request))
 242                            (or riece-rdcc-save-directory
 243                                default-directory))))
 244        (list request
 245              (expand-file-name
 246               (read-file-name
 247                (concat "Save as (default "
 248                        (file-name-nondirectory default-name) ") ")
 249                (file-name-directory default-name)
 250                default-name))))))
 251   (let* ((temp-file (expand-file-name
 252                      (file-name-nondirectory file)
 253                      (expand-file-name (make-temp-name "riece-rdcc")
 254                                        (if (featurep 'xemacs)
 255                                            (temp-directory)
 256                                          temporary-file-directory))))
 257          (orig-mode (default-file-modes))
 258          selective-display
 259          (coding-system-for-read 'binary)
 260          (coding-system-for-write 'binary)
 261          process)
 262     (unwind-protect
 263         (progn
 264           (set-default-file-modes 448)
 265           ;; This may throw an error.
 266           (make-directory (file-name-directory temp-file)))
 267       (set-default-file-modes orig-mode))
 268     (setq process (open-network-stream
 269                    "DCC" (generate-new-buffer " *DCC*")
 270                    (riece-rdcc-decode-address (nth 2 request))
 271                    (nth 3 request)))
 272     (setq riece-rdcc-requests (delq request riece-rdcc-requests))
 273     (with-current-buffer (process-buffer process)
 274       (if (fboundp 'set-buffer-multibyte)
 275           (set-buffer-multibyte nil))
 276       (buffer-disable-undo)
 277       (erase-buffer)
 278       (make-local-variable 'riece-rdcc-request-user)
 279       (setq riece-rdcc-request-user (car request))
 280       (make-local-variable 'riece-rdcc-request-file)
 281       (setq riece-rdcc-request-file file)
 282       (make-local-variable 'riece-rdcc-request-size)
 283       (setq riece-rdcc-request-size (nth 4 request))
 284       (make-local-variable 'riece-rdcc-temp-file)
 285       (setq riece-rdcc-temp-file temp-file)
 286       (make-local-variable 'riece-rdcc-received-size)
 287       (setq riece-rdcc-received-size 0))
 288     (set-process-filter process #'riece-rdcc-filter)
 289     (set-process-sentinel process #'riece-rdcc-sentinel)))
 290
 291 (defun riece-rdcc-format-size (size)
 292   (if (< size 1024)
 293       (format "%0.1f" size)
 294     (setq size (/ size 1024.0))
 295     (if (< size 1024)
 296         (format "%0.1fKB" size)
 297       (setq size (/ size 1024.0))
 298       (if (< size 1024)
 299           (format "%0.1fMB" size)
 300         (format "%0.1fGB" (/ size 1024.0))))))
 301
 302 (defun riece-handle-dcc-request (prefix target message)
 303   (let ((case-fold-search t))
 304     (when (and riece-rdcc-enabled
 305                (string-match
 306                 "SEND \\(\\([^ ]+\\)\\|\"\\(.+\\)\"\\) \\([^ ]+\\) \\([^ ]+\\) \\([^ ]+\\)"
 307                 message))
 308       (let ((file (or (match-string 2 message)
 309                       (match-string 3 message)))
 310             (address (match-string 4 message))
 311             (port (string-to-number (match-string 5 message)))
 312             (size (string-to-number (match-string 6 message)))
 313             (buffer (if (riece-channel-p target)
 314                         (riece-channel-buffer (riece-make-identity
 315                                                target riece-server-name))))
 316             (user (riece-prefix-nickname prefix)))
 317         (setq riece-rdcc-requests
 318               (cons (list user file address port size)
 319                     riece-rdcc-requests))
 320         (message "%s"
 321                  (with-current-buffer (window-buffer (selected-window))
 322                    (substitute-command-keys
 323                     (format
 324                      "Type \\[riece-command-dcc-receive] to receive"
 325                      user))))
 326         (riece-insert-change buffer (format "DCC SEND from %s: %s (%s)\n"
 327                                             user file
 328                                             (riece-rdcc-format-size size)))
 329         (riece-insert-change
 330          (if (and riece-channel-buffer-mode
 331                   (not (eq buffer riece-channel-buffer)))
 332              (list riece-dialogue-buffer riece-others-buffer)
 333            riece-dialogue-buffer)
 334          (concat
 335           (riece-concat-server-name
 336            (format "DCC SEND from %s (%s) to %s: %s (%s)"
 337                    user
 338                    (riece-strip-user-at-host
 339                     (riece-prefix-user-at-host prefix))
 340                    (riece-decode-coding-string target)
 341                    file
 342                    (riece-rdcc-format-size size)))
 343           "\n")))
 344       t)))
 345
 346 (defun riece-rdcc-requires ()
 347   '(riece-ctcp))
 348
 349 (defvar riece-dialogue-mode-map)
 350 (defun riece-rdcc-insinuate ()
 351   (add-to-list 'riece-ctcp-additional-clientinfo "DCC")
 352   (add-hook 'riece-ctcp-dcc-request-hook 'riece-handle-dcc-request))
 353
 354 (defun riece-rdcc-enable ()
 355   (define-key riece-dialogue-mode-map "\C-ds" 'riece-command-dcc-send)
 356   (define-key riece-dialogue-mode-map "\C-dr" 'riece-command-dcc-receive)
 357   (setq riece-rdcc-enabled t))
 358
 359 (defun riece-rdcc-disable ()
 360   (define-key riece-dialogue-mode-map "\C-ds" nil)
 361   (define-key riece-dialogue-mode-map "\C-dr" nil)
 362   (setq riece-rdcc-enabled nil))
 363
 364 (provide 'riece-rdcc)
 365
 366 ;;; riece-rdcc.el ends here