cgit.sxemacs.org Git - riece/blob - lisp/riece-rdcc.el

   1 ;;; riece-rdcc.el --- ruby implementation of DCC add-on
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Keywords: IRC, riece
   6
   7 ;; This file is part of Riece.
   8
   9 ;; This program is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; This program is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Code:
  25
  26 (require 'riece-globals)
  27 (require 'riece-misc)
  28 (require 'riece-channel)
  29 (require 'riece-identity)
  30 (require 'riece-ctcp)                   ;for riece-ctcp-additional-clientinfo
  31
  32 (defgroup riece-rdcc nil
  33   "DCC implementation using ruby"
  34   :prefix "riece-"
  35   :group 'riece)
  36
  37 (defcustom riece-rdcc-server-address nil
  38   "Local address of the DCC server.
  39 Only used for sending files."
  40   :type 'string
  41   :group 'riece-rdcc)
  42
  43 (defcustom riece-rdcc-ruby-command "ruby"
  44   "Command name for Ruby interpreter."
  45   :type 'string
  46   :group 'riece-rdcc)
  47
  48 (defcustom riece-rdcc-send-program
  49   '("\
  50 address = " address "
  51 unless address
  52   sock = UDPSocket.new
  53   sock.connect('164.46.176.4', 7)               # www.unixuser.org/echo
  54   address = sock.getsockname[4 .. 7].unpack('CCCC').join('.')
  55 end
  56 server = TCPServer.new(address, 0)
  57 puts(\"#{server.addr[3].split(/\\./).collect{|c| c.to_i}.pack('CCCC').unpack('N')[0]} #{server.addr[1]}\")
  58 $stdout.flush
  59 session = server.accept
  60 if session
  61   total = 0
  62   File.open(" file ") {|file|
  63     while (bytes = file.read(" block-size "))
  64       total += bytes.length
  65       puts(total)
  66       session.write(bytes)
  67       begin
  68         buf = session.read(4)
  69       end until buf.unpack('N')[0] == total
  70     end
  71   }
  72   session.close
  73 end
  74 ")
  75   "Ruby program to send file with DCC."
  76   :type 'list
  77   :group 'riece-rdcc)
  78
  79 (defcustom riece-rdcc-decode-address-program
  80   '("\
  81 puts(\"#{" address " >> 24 & 0xFF}.#{" address " >> 16 & 0xFF}.#{"
  82     address " >> 8 & 0xFF}.#{" address " & 0xFF}\")")
  83   "Ruby program to numeric IP address."
  84   :type 'list
  85   :group 'riece-rdcc)
  86
  87 (defcustom riece-rdcc-save-directory nil
  88   "Default directory where received files are saved in."
  89   :type 'directory
  90   :group 'riece-rdcc)
  91
  92 (defcustom riece-rdcc-block-size 1024
  93   "Number of bytes sent as a block."
  94   :type 'integer
  95   :group 'riece-rdcc)
  96
  97 (defvar riece-rdcc-requests nil)
  98
  99 (defvar riece-rdcc-request-user nil)
 100 (defvar riece-rdcc-request-file nil)
 101 (defvar riece-rdcc-request-size nil)
 102
 103 (defvar riece-rdcc-temp-file nil)
 104 (defvar riece-rdcc-received-size nil)
 105
 106 (defvar riece-rdcc-enabled nil)
 107
 108 (defconst riece-rdcc-description
 109   "DCC file sending extension implemented in Ruby")
 110
 111 (defvar temporary-file-directory)
 112 (defvar jka-compr-compression-info-list)
 113 (defvar jam-zcat-filename-list)
 114 (defun riece-rdcc-substitute-variables (program variable value)
 115   (setq program (copy-sequence program))
 116   (let ((pointer program))
 117     (while pointer
 118       (setq pointer (memq variable program))
 119       (if pointer
 120           (setcar pointer value)))
 121     program))
 122
 123 (defun riece-rdcc-server-filter (process input)
 124   (save-excursion
 125     (set-buffer (process-buffer process))
 126     (goto-char (point-max))
 127     (insert input)
 128     (goto-char (point-min))
 129     (while (and (not (eobp))
 130                 (looking-at "\\([0-9]+\\)\n"))
 131       (message "Sending %s...(%s/%d)"
 132                riece-rdcc-request-file
 133                (match-string 1) riece-rdcc-request-size)
 134       (forward-line))
 135     (unless (eobp)
 136       (delete-region (point-min) (point)))))
 137
 138 (defun riece-rdcc-server-sentinel (process status)
 139   (with-current-buffer (process-buffer process)
 140     (message "Sending %s...done" riece-rdcc-request-file))
 141   (kill-buffer (process-buffer process)))
 142
 143 (defun riece-command-dcc-send (user file)
 144   (interactive
 145    (let ((completion-ignore-case t))
 146      (list (riece-completing-read-identity
 147             "User: "
 148             (riece-get-users-on-server (riece-current-server-name)))
 149            (expand-file-name (read-file-name "File: ")))))
 150   (let* ((process-connection-type nil)
 151          (process (start-process "DCC" (generate-new-buffer " *DCC*")
 152                                  "ruby" "-rsocket")))
 153     (process-send-string process
 154                          (apply #'concat
 155                                 (riece-rdcc-substitute-variables
 156                                  (riece-rdcc-substitute-variables
 157                                   (riece-rdcc-substitute-variables
 158                                    riece-rdcc-send-program
 159                                    'address
 160                                    (if riece-rdcc-server-address
 161                                        (concat "'" riece-rdcc-server-address
 162                                                "'")
 163                                      "nil"))
 164                                   'file
 165                                   (concat "'" file "'"))
 166                                  'block-size
 167                                  (number-to-string riece-rdcc-block-size))))
 168     (process-send-eof process)
 169     (save-excursion
 170       (set-buffer (process-buffer process))
 171       (while (and (eq (process-status process) 'run)
 172                   (progn
 173                     (goto-char (point-min))
 174                     (not (looking-at "\\([0-9]+\\) \\([0-9]+\\)"))))
 175         (accept-process-output process))
 176       (if (eq (process-status process) 'run)
 177           (let ((address (match-string 1))
 178                 (port (match-string 2))
 179                 (filename (file-name-nondirectory file)))
 180             (while (string-match "[ \t]+" filename)
 181               (setq filename (replace-match "_" nil nil filename)))
 182             (erase-buffer)
 183             (make-local-variable 'riece-rdcc-request-size)
 184             (setq riece-rdcc-request-file file
 185                   riece-rdcc-request-size (nth 7 (file-attributes file)))
 186             (set-buffer-modified-p nil)
 187             (set-process-filter process #'riece-rdcc-server-filter)
 188             (set-process-sentinel process #'riece-rdcc-server-sentinel)
 189             (riece-send-string
 190              (format "PRIVMSG %s :\1DCC SEND %s %s %s %d\1\r\n"
 191                      (riece-identity-prefix user)
 192                      filename
 193                      address port
 194                      riece-rdcc-request-size)))))))
 195
 196 (defun riece-rdcc-filter (process input)
 197   (save-excursion
 198     (set-buffer (process-buffer process))
 199     (erase-buffer)
 200     (insert input)
 201     (let ((coding-system-for-write 'binary)
 202           jka-compr-compression-info-list jam-zcat-filename-list)
 203       (write-region (point-min) (point-max) riece-rdcc-temp-file t 0))
 204     (setq riece-rdcc-received-size (+ (buffer-size) riece-rdcc-received-size))
 205     (process-send-string
 206      process
 207      (format "%c%c%c%c"
 208              (lsh riece-rdcc-received-size -24)
 209              (logand (lsh riece-rdcc-received-size -16) 255)
 210              (logand (lsh riece-rdcc-received-size -8) 255)
 211              (logand riece-rdcc-received-size 255)))
 212     (message "Receiving %s from %s...(%s/%s)"
 213              (file-name-nondirectory riece-rdcc-request-file)
 214              riece-rdcc-request-user
 215              (riece-rdcc-format-size riece-rdcc-received-size)
 216              (riece-rdcc-format-size riece-rdcc-request-size))
 217     (if (= riece-rdcc-received-size riece-rdcc-request-size)
 218         (set-process-filter process nil))))
 219
 220 (defun riece-rdcc-sentinel (process status)
 221   (save-excursion
 222     (set-buffer (process-buffer process))
 223     (unless (= riece-rdcc-received-size riece-rdcc-request-size)
 224       (error "Premature end of file"))
 225     (message "Receiving %s from %s...done"
 226              (file-name-nondirectory riece-rdcc-request-file)
 227              riece-rdcc-request-user)
 228     (condition-case nil
 229         (progn
 230           (rename-file riece-rdcc-temp-file riece-rdcc-request-file)
 231           (delete-directory (file-name-directory riece-rdcc-temp-file)))
 232       (file-already-exists
 233        (error "Can't save %s.  Temporarily saved in %s"
 234               riece-rdcc-request-file riece-rdcc-temp-file))))
 235   (kill-buffer (process-buffer process)))
 236
 237 (defun riece-rdcc-decode-address (address)
 238   (with-temp-buffer
 239     (call-process riece-rdcc-ruby-command nil t nil "-e"
 240                   (apply #'concat
 241                          (riece-rdcc-substitute-variables
 242                           riece-rdcc-decode-address-program
 243                           'address
 244                           address)))
 245     (buffer-substring (point-min) (1- (point-max)))))
 246
 247 (defun riece-command-dcc-receive (request file)
 248   (interactive
 249    (progn
 250      (unless riece-rdcc-requests
 251        (error "No request"))
 252      (let* ((request
 253              (if (= (length riece-rdcc-requests) 1)
 254                  (car riece-rdcc-requests)
 255                (with-output-to-temp-buffer "*Help*"
 256                  (let ((requests riece-rdcc-requests)
 257                        (index 1))
 258                    (while requests
 259                      (princ (format "%2d: %s %s (%d bytes)\n"
 260                                     index
 261                                     (car (car requests))
 262                                     (nth 1 (car requests))
 263                                     (nth 4 (car requests))))
 264                      (setq index (1+ index)
 265                            requests (cdr requests)))))
 266                (let ((number (read-string "Request#: ")))
 267                  (unless (string-match "^[0-9]+$" number)
 268                    (error "Not a number"))
 269                  (if (or (> (setq number (string-to-number number))
 270                             (length riece-rdcc-requests))
 271                          (< number 1))
 272                      (error "Invalid number"))
 273                  (nth (1- number) riece-rdcc-requests))))
 274             (default-name (expand-file-name
 275                            (convert-standard-filename (nth 1 request))
 276                            (or riece-rdcc-save-directory
 277                                default-directory))))
 278        (list request
 279              (expand-file-name
 280               (read-file-name
 281                (concat "Save as (default "
 282                        (file-name-nondirectory default-name) ") ")
 283                (file-name-directory default-name)
 284                default-name))))))
 285   (let* ((temp-file (expand-file-name
 286                      (file-name-nondirectory file)
 287                      (expand-file-name (make-temp-name "riece-rdcc")
 288                                        (if (featurep 'xemacs)
 289                                            (temp-directory)
 290                                          temporary-file-directory))))
 291          (orig-mode (default-file-modes))
 292          selective-display
 293          (coding-system-for-read 'binary)
 294          (coding-system-for-write 'binary)
 295          process)
 296     (unwind-protect
 297         (progn
 298           (set-default-file-modes 448)
 299           ;; This may throw an error.
 300           (make-directory (file-name-directory temp-file)))
 301       (set-default-file-modes orig-mode))
 302     (setq process (open-network-stream
 303                    "DCC" (generate-new-buffer " *DCC*")
 304                    (riece-rdcc-decode-address (nth 2 request))
 305                    (nth 3 request)))
 306     (setq riece-rdcc-requests (delq request riece-rdcc-requests))
 307     (with-current-buffer (process-buffer process)
 308       (if (fboundp 'set-buffer-multibyte)
 309           (set-buffer-multibyte nil))
 310       (buffer-disable-undo)
 311       (erase-buffer)
 312       (make-local-variable 'riece-rdcc-request-user)
 313       (setq riece-rdcc-request-user (car request))
 314       (make-local-variable 'riece-rdcc-request-file)
 315       (setq riece-rdcc-request-file file)
 316       (make-local-variable 'riece-rdcc-request-size)
 317       (setq riece-rdcc-request-size (nth 4 request))
 318       (make-local-variable 'riece-rdcc-temp-file)
 319       (setq riece-rdcc-temp-file temp-file)
 320       (make-local-variable 'riece-rdcc-received-size)
 321       (setq riece-rdcc-received-size 0))
 322     (set-process-filter process #'riece-rdcc-filter)
 323     (set-process-sentinel process #'riece-rdcc-sentinel)))
 324
 325 (defun riece-rdcc-format-size (size)
 326   (if (< size 1024)
 327       (format "%0.1f" size)
 328     (setq size (/ size 1024.0))
 329     (if (< size 1024)
 330         (format "%0.1fKB" size)
 331       (setq size (/ size 1024.0))
 332       (if (< size 1024)
 333           (format "%0.1fMB" size)
 334         (format "%0.1fGB" (/ size 1024.0))))))
 335
 336 (defun riece-handle-dcc-request (prefix target message)
 337   (let ((case-fold-search t))
 338     (when (and riece-rdcc-enabled
 339                (string-match
 340                 "SEND \\(\\([^ ]+\\)\\|\"\\(.+\\)\"\\) \\([^ ]+\\) \\([^ ]+\\) \\([^ ]+\\)"
 341                 message))
 342       (let ((file (or (match-string 2 message)
 343                       (match-string 3 message)))
 344             (address (match-string 4 message))
 345             (port (string-to-number (match-string 5 message)))
 346             (size (string-to-number (match-string 6 message)))
 347             (buffer (if (riece-channel-p target)
 348                         (riece-channel-buffer (riece-make-identity
 349                                                target riece-server-name))))
 350             (user (riece-prefix-nickname prefix)))
 351         (setq riece-rdcc-requests
 352               (cons (list user file address port size)
 353                     riece-rdcc-requests))
 354         (message "%s"
 355                  (with-current-buffer (window-buffer (selected-window))
 356                    (substitute-command-keys
 357                     (format
 358                      "Type \\[riece-command-dcc-receive] to receive"
 359                      user))))
 360         (riece-insert-change buffer (format "DCC SEND from %s: %s (%s)\n"
 361                                             user file
 362                                             (riece-rdcc-format-size size)))
 363         (riece-insert-change
 364          (if (and riece-channel-buffer-mode
 365                   (not (eq buffer riece-channel-buffer)))
 366              (list riece-dialogue-buffer riece-others-buffer)
 367            riece-dialogue-buffer)
 368          (concat
 369           (riece-concat-server-name
 370            (format "DCC SEND from %s (%s) to %s: %s (%s)"
 371                    user
 372                    (riece-strip-user-at-host
 373                     (riece-prefix-user-at-host prefix))
 374                    (riece-decode-coding-string target)
 375                    file
 376                    (riece-rdcc-format-size size)))
 377           "\n")))
 378       t)))
 379
 380 (defun riece-rdcc-requires ()
 381   '(riece-ctcp))
 382
 383 (defvar riece-dialogue-mode-map)
 384 (defun riece-rdcc-insinuate ()
 385   (add-to-list 'riece-ctcp-additional-clientinfo "DCC")
 386   (add-hook 'riece-ctcp-dcc-request-hook 'riece-handle-dcc-request))
 387
 388 (defun riece-rdcc-enable ()
 389   (define-key riece-dialogue-mode-map "\C-ds" 'riece-command-dcc-send)
 390   (define-key riece-dialogue-mode-map "\C-dr" 'riece-command-dcc-receive)
 391   (setq riece-rdcc-enabled t))
 392
 393 (defun riece-rdcc-disable ()
 394   (define-key riece-dialogue-mode-map "\C-ds" nil)
 395   (define-key riece-dialogue-mode-map "\C-dr" nil)
 396   (setq riece-rdcc-enabled nil))
 397
 398 (provide 'riece-rdcc)
 399
 400 ;;; riece-rdcc.el ends here