cgit.sxemacs.org Git - riece/blob - lisp/riece-rdcc.el

   1 ;;; riece-rdcc.el --- DCC file sending protocol support (written in Ruby)
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Keywords: IRC, riece
   6
   7 ;; This file is part of Riece.
   8
   9 ;; This program is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; This program is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; NOTE: This is an add-on module for Riece.
  27
  28 ;;; Code:
  29
  30 (require 'riece-globals)
  31 (require 'riece-misc)
  32 (require 'riece-channel)
  33 (require 'riece-identity)
  34 (require 'riece-ctcp)                   ;for riece-ctcp-additional-clientinfo
  35 (require 'riece-ruby)
  36
  37 (defgroup riece-rdcc nil
  38   "DCC written in Ruby."
  39   :prefix "riece-"
  40   :group 'riece)
  41
  42 (defcustom riece-rdcc-server-address nil
  43   "Local address of the DCC server.
  44 Only used for sending files."
  45   :type 'string
  46   :group 'riece-rdcc)
  47
  48 (defcustom riece-rdcc-send-program
  49   '("\
  50 require 'socket'
  51 address = " address "
  52 unless address
  53   sock = UDPSocket.new
  54   sock.connect('164.46.176.4', 7)               # www.unixuser.org/echo
  55   address = sock.getsockname[4 .. 7].unpack('CCCC').join('.')
  56 end
  57 server = TCPServer.new(address, 0)
  58 output(\"#{server.addr[3].split(/\\./).collect{|c| c.to_i}.pack('CCCC').unpack('N')[0]} #{server.addr[1]}\")
  59 session = server.accept
  60 if session
  61   total = 0
  62   File.open(" file ") {|file|
  63     while (bytes = file.read(" block-size "))
  64       total += bytes.length
  65       output(total)
  66       session.write(bytes)
  67       begin
  68         buf = session.read(4)
  69       end until buf.unpack('N')[0] == total
  70     end
  71   }
  72   session.close
  73 end
  74 ")
  75   "Ruby program to send file with DCC."
  76   :type 'list
  77   :group 'riece-rdcc)
  78
  79 (defcustom riece-rdcc-decode-address-program
  80   '("\"#{" address " >> 24 & 0xFF}.#{" address " >> 16 & 0xFF}.#{"
  81     address " >> 8 & 0xFF}.#{" address " & 0xFF}\"")
  82   "Ruby program to numeric IP address."
  83   :type 'list
  84   :group 'riece-rdcc)
  85
  86 (defcustom riece-rdcc-save-directory nil
  87   "Default directory where received files are saved in."
  88   :type 'directory
  89   :group 'riece-rdcc)
  90
  91 (defcustom riece-rdcc-block-size 1024
  92   "Number of bytes sent as a block."
  93   :type 'integer
  94   :group 'riece-rdcc)
  95
  96 (defvar riece-rdcc-requests nil)
  97
  98 (defvar riece-rdcc-request-user nil)
  99 (defvar riece-rdcc-request-file nil)
 100 (defvar riece-rdcc-request-size nil)
 101
 102 (defvar riece-rdcc-temp-file nil)
 103 (defvar riece-rdcc-received-size nil)
 104
 105 (defvar riece-rdcc-enabled nil)
 106
 107 (defconst riece-rdcc-description
 108   "DCC file sending protocol support (written in Ruby.)")
 109
 110 (defvar temporary-file-directory)
 111 (defvar jka-compr-compression-info-list)
 112 (defvar jam-zcat-filename-list)
 113
 114 (defun riece-rdcc-output-handler (name output time)
 115   (if (string-match "\\([0-9]+\\) \\([0-9]+\\)" output)
 116       (let ((address (match-string 1 output))
 117             (port (match-string 2 output)))
 118         (riece-send-string
 119          (format "PRIVMSG %s :\1DCC SEND %s %s %s %d\1\r\n"
 120                  (riece-identity-prefix
 121                   (riece-ruby-property name 'riece-rdcc-request-user))
 122                  (file-name-nondirectory
 123                   (riece-ruby-property name 'riece-rdcc-request-file))
 124                  address port
 125                  (riece-ruby-property name 'riece-rdcc-request-size)))))
 126   (riece-ruby-set-output-handler name #'riece-rdcc-output-handler-2))
 127
 128 (defun riece-rdcc-output-handler-2 (name output time)
 129   (message "Sending %s...(%s/%d)"
 130            (riece-ruby-property name 'riece-rdcc-request-file)
 131            (string-to-number output)
 132            (riece-ruby-property name 'riece-rdcc-request-size)))
 133
 134 (defun riece-rdcc-exit-handler (name)
 135   (message "Sending %s...done"
 136            (riece-ruby-property name 'riece-rdcc-request-file)))
 137
 138 (defun riece-command-dcc-send (user file)
 139   (interactive
 140    (let ((completion-ignore-case t))
 141      (list (riece-completing-read-identity
 142             "User: "
 143             (riece-get-users-on-server (riece-current-server-name)))
 144            (expand-file-name (read-file-name "File: ")))))
 145   (let ((name (riece-ruby-execute
 146                (riece-ruby-substitute-variables
 147                 riece-rdcc-send-program
 148                 (list (cons 'address
 149                             (if riece-rdcc-server-address
 150                                 (concat "'" riece-rdcc-server-address
 151                                         "'")
 152                               "nil"))
 153                       (cons 'file
 154                             (concat "'" file "'"))
 155                       (cons 'block-size
 156                             (number-to-string
 157                              riece-rdcc-block-size)))))))
 158     (riece-ruby-set-property name 'riece-rdcc-request-user user)
 159     (riece-ruby-set-property name 'riece-rdcc-request-file file)
 160     (riece-ruby-set-property name 'riece-rdcc-request-size
 161                              (nth 7 (file-attributes file)))
 162     (riece-ruby-set-output-handler name #'riece-rdcc-output-handler)
 163     (riece-ruby-set-exit-handler name #'riece-rdcc-exit-handler)))
 164
 165 (defun riece-rdcc-filter (process input)
 166   (save-excursion
 167     (set-buffer (process-buffer process))
 168     (erase-buffer)
 169     (insert input)
 170     (let ((coding-system-for-write 'binary)
 171           jka-compr-compression-info-list jam-zcat-filename-list)
 172       (write-region (point-min) (point-max) riece-rdcc-temp-file t 0))
 173     (setq riece-rdcc-received-size (+ (buffer-size) riece-rdcc-received-size))
 174     (process-send-string
 175      process
 176      (format "%c%c%c%c"
 177              (lsh riece-rdcc-received-size -24)
 178              (logand (lsh riece-rdcc-received-size -16) 255)
 179              (logand (lsh riece-rdcc-received-size -8) 255)
 180              (logand riece-rdcc-received-size 255)))
 181     (message "Receiving %s from %s...(%s/%s)"
 182              (file-name-nondirectory riece-rdcc-request-file)
 183              riece-rdcc-request-user
 184              (riece-rdcc-format-size riece-rdcc-received-size)
 185              (riece-rdcc-format-size riece-rdcc-request-size))
 186     (if (= riece-rdcc-received-size riece-rdcc-request-size)
 187         (set-process-filter process nil))))
 188
 189 (defun riece-rdcc-sentinel (process status)
 190   (save-excursion
 191     (set-buffer (process-buffer process))
 192     (unless (= riece-rdcc-received-size riece-rdcc-request-size)
 193       (error "Premature end of file"))
 194     (message "Receiving %s from %s...done"
 195              (file-name-nondirectory riece-rdcc-request-file)
 196              riece-rdcc-request-user)
 197     (condition-case nil
 198         (progn
 199           (rename-file riece-rdcc-temp-file riece-rdcc-request-file)
 200           (delete-directory (file-name-directory riece-rdcc-temp-file)))
 201       (file-already-exists
 202        (error "Can't save %s.  Temporarily saved in %s"
 203               riece-rdcc-request-file riece-rdcc-temp-file))))
 204   (kill-buffer (process-buffer process)))
 205
 206 (defun riece-rdcc-decode-address (address)
 207   (let ((name (riece-ruby-execute
 208                (riece-ruby-substitute-variables
 209                 riece-rdcc-decode-address-program
 210                 (list (cons 'address address)))))
 211         response)
 212     (while (equal (nth 2 (setq response (riece-ruby-inspect name))) "running")
 213       (accept-process-output riece-ruby-process))
 214     (riece-ruby-clear name)
 215     (nth 1 response)))
 216
 217 (defun riece-command-dcc-receive (request file)
 218   (interactive
 219    (progn
 220      (unless riece-rdcc-requests
 221        (error "No request"))
 222      (let* ((request
 223              (if (= (length riece-rdcc-requests) 1)
 224                  (car riece-rdcc-requests)
 225                (with-output-to-temp-buffer "*Help*"
 226                  (let ((requests riece-rdcc-requests)
 227                        (index 1))
 228                    (while requests
 229                      (princ (format "%2d: %s %s (%d bytes)\n"
 230                                     index
 231                                     (car (car requests))
 232                                     (nth 1 (car requests))
 233                                     (nth 4 (car requests))))
 234                      (setq index (1+ index)
 235                            requests (cdr requests)))))
 236                (let ((number (read-string "Request#: ")))
 237                  (unless (string-match "^[0-9]+$" number)
 238                    (error "Not a number"))
 239                  (if (or (> (setq number (string-to-number number))
 240                             (length riece-rdcc-requests))
 241                          (< number 1))
 242                      (error "Invalid number"))
 243                  (nth (1- number) riece-rdcc-requests))))
 244             (default-name (expand-file-name
 245                            (convert-standard-filename (nth 1 request))
 246                            (or riece-rdcc-save-directory
 247                                default-directory))))
 248        (list request
 249              (expand-file-name
 250               (read-file-name
 251                (concat "Save as (default "
 252                        (file-name-nondirectory default-name) ") ")
 253                (file-name-directory default-name)
 254                default-name))))))
 255   (let* ((temp-file (expand-file-name
 256                      (file-name-nondirectory file)
 257                      (expand-file-name (make-temp-name "riece-rdcc")
 258                                        (if (featurep 'xemacs)
 259                                            (temp-directory)
 260                                          temporary-file-directory))))
 261          (orig-mode (default-file-modes))
 262          selective-display
 263          (coding-system-for-read 'binary)
 264          (coding-system-for-write 'binary)
 265          process)
 266     (unwind-protect
 267         (progn
 268           (set-default-file-modes 448)
 269           ;; This may throw an error.
 270           (make-directory (file-name-directory temp-file)))
 271       (set-default-file-modes orig-mode))
 272     (setq process (open-network-stream
 273                    "DCC" (generate-new-buffer " *DCC*")
 274                    (riece-rdcc-decode-address (nth 2 request))
 275                    (nth 3 request)))
 276     (setq riece-rdcc-requests (delq request riece-rdcc-requests))
 277     (with-current-buffer (process-buffer process)
 278       (if (fboundp 'set-buffer-multibyte)
 279           (set-buffer-multibyte nil))
 280       (buffer-disable-undo)
 281       (erase-buffer)
 282       (make-local-variable 'riece-rdcc-request-user)
 283       (setq riece-rdcc-request-user (car request))
 284       (make-local-variable 'riece-rdcc-request-file)
 285       (setq riece-rdcc-request-file file)
 286       (make-local-variable 'riece-rdcc-request-size)
 287       (setq riece-rdcc-request-size (nth 4 request))
 288       (make-local-variable 'riece-rdcc-temp-file)
 289       (setq riece-rdcc-temp-file temp-file)
 290       (make-local-variable 'riece-rdcc-received-size)
 291       (setq riece-rdcc-received-size 0))
 292     (set-process-filter process #'riece-rdcc-filter)
 293     (set-process-sentinel process #'riece-rdcc-sentinel)))
 294
 295 (defun riece-rdcc-format-size (size)
 296   (if (< size 1024)
 297       (format "%0.1f" size)
 298     (setq size (/ size 1024.0))
 299     (if (< size 1024)
 300         (format "%0.1fKB" size)
 301       (setq size (/ size 1024.0))
 302       (if (< size 1024)
 303           (format "%0.1fMB" size)
 304         (format "%0.1fGB" (/ size 1024.0))))))
 305
 306 (defun riece-handle-dcc-request (prefix target message)
 307   (let ((case-fold-search t))
 308     (when (and riece-rdcc-enabled
 309                (string-match
 310                 "SEND \\(\\([^ ]+\\)\\|\"\\(.+\\)\"\\) \\([^ ]+\\) \\([^ ]+\\) \\([^ ]+\\)"
 311                 message))
 312       (let ((file (or (match-string 2 message)
 313                       (match-string 3 message)))
 314             (address (match-string 4 message))
 315             (port (string-to-number (match-string 5 message)))
 316             (size (string-to-number (match-string 6 message)))
 317             (buffer (if (riece-channel-p target)
 318                         (riece-channel-buffer (riece-make-identity
 319                                                target riece-server-name))))
 320             (user (riece-prefix-nickname prefix)))
 321         (setq riece-rdcc-requests
 322               (cons (list user file address port size)
 323                     riece-rdcc-requests))
 324         (message "%s"
 325                  (with-current-buffer (window-buffer (selected-window))
 326                    (substitute-command-keys
 327                     (format
 328                      "Type \\[riece-command-dcc-receive] to receive"
 329                      user))))
 330         (riece-insert-change buffer (format "DCC SEND from %s: %s (%s)\n"
 331                                             user file
 332                                             (riece-rdcc-format-size size)))
 333         (riece-insert-change
 334          (if (and riece-channel-buffer-mode
 335                   (not (eq buffer riece-channel-buffer)))
 336              (list riece-dialogue-buffer riece-others-buffer)
 337            riece-dialogue-buffer)
 338          (concat
 339           (riece-concat-server-name
 340            (format "DCC SEND from %s (%s) to %s: %s (%s)"
 341                    user
 342                    (riece-strip-user-at-host
 343                     (riece-prefix-user-at-host prefix))
 344                    (riece-decode-coding-string target)
 345                    file
 346                    (riece-rdcc-format-size size)))
 347           "\n")))
 348       t)))
 349
 350 (defun riece-rdcc-requires ()
 351   '(riece-ctcp))
 352
 353 (defvar riece-dialogue-mode-map)
 354 (defun riece-rdcc-insinuate ()
 355   (add-to-list 'riece-ctcp-additional-clientinfo "DCC")
 356   (add-hook 'riece-ctcp-dcc-request-hook 'riece-handle-dcc-request))
 357
 358 (defun riece-rdcc-uninstall ()
 359   (setq riece-ctcp-additional-clientinfo
 360         (delete "DCC" riece-ctcp-additional-clientinfo))
 361   (remove-hook 'riece-ctcp-dcc-request-hook 'riece-handle-dcc-request))
 362
 363 (defun riece-rdcc-enable ()
 364   (define-key riece-dialogue-mode-map "\C-ds" 'riece-command-dcc-send)
 365   (define-key riece-dialogue-mode-map "\C-dr" 'riece-command-dcc-receive)
 366   (setq riece-rdcc-enabled t))
 367
 368 (defun riece-rdcc-disable ()
 369   (define-key riece-dialogue-mode-map "\C-ds" nil)
 370   (define-key riece-dialogue-mode-map "\C-dr" nil)
 371   (setq riece-rdcc-enabled nil))
 372
 373 (provide 'riece-rdcc)
 374
 375 ;;; riece-rdcc.el ends here