cgit.sxemacs.org Git - riece/blob - lisp/riece-rdcc.el

   1 ;;; riece-rdcc.el --- ruby implementation of DCC add-on
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Keywords: IRC, riece
   6
   7 ;; This file is part of Riece.
   8
   9 ;; This program is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; This program is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Code:
  25
  26 (require 'riece-globals)
  27 (require 'riece-misc)
  28 (require 'riece-channel)
  29 (require 'riece-identity)
  30 (require 'riece-ctcp)                   ;for riece-ctcp-additional-clientinfo
  31
  32 (defgroup riece-rdcc nil
  33   "DCC implementation using ruby"
  34   :prefix "riece-"
  35   :group 'riece)
  36
  37 (defcustom riece-rdcc-server-address nil
  38   "Local address of the DCC server.
  39 Only used for sending files."
  40   :type 'string
  41   :group 'riece-rdcc)
  42
  43 (defcustom riece-rdcc-ruby-command "ruby"
  44   "Command name for Ruby interpreter."
  45   :type 'string
  46   :group 'riece-rdcc)
  47
  48 (defcustom riece-rdcc-send-program
  49   '("\
  50 address = " address "
  51 unless address
  52   sock = UDPSocket.new
  53   sock.connect('164.46.176.4', 7)               # www.unixuser.org/echo
  54   address = sock.getsockname[4 .. 7].unpack('CCCC').join('.')
  55 end
  56 server = TCPServer.new(address, 0)
  57 puts(\"#{server.addr[3].split(/\\./).collect{|c| c.to_i}.pack('CCCC').unpack('N')[0]} #{server.addr[1]}\")
  58 $stdout.flush
  59 session = server.accept
  60 if session
  61   total = 0
  62   File.open(" file ") {|file|
  63     while (bytes = file.read(" block-size "))
  64       total += bytes.length
  65       puts(\"#{total}\")
  66       session.write(bytes)
  67     end
  68   }
  69   session.close
  70 end
  71 ")
  72   "Ruby program to send file with DCC."
  73   :type 'list
  74   :group 'riece-rdcc)
  75
  76 (defcustom riece-rdcc-decode-address-program
  77   '("\
  78 puts(\"#{" address " >> 24 & 0xFF}.#{" address " >> 16 & 0xFF}.#{"
  79     address " >> 8 & 0xFF}.#{" address " & 0xFF}\")")
  80   "Ruby program to numeric IP address."
  81   :type 'list
  82   :group 'riece-rdcc)
  83
  84 (defcustom riece-rdcc-save-directory nil
  85   "Default directory where received files are saved in."
  86   :type 'directory
  87   :group 'riece-rdcc)
  88
  89 (defcustom riece-rdcc-block-size 4096
  90   "Number of bytes sent as a block."
  91   :type 'integer
  92   :group 'riece-rdcc)
  93
  94 (defvar riece-rdcc-requests nil)
  95
  96 (defvar riece-rdcc-request-user nil)
  97 (defvar riece-rdcc-request-file nil)
  98 (defvar riece-rdcc-request-size nil)
  99
 100 (defvar riece-rdcc-temp-file nil)
 101 (defvar riece-rdcc-received-size nil)
 102
 103 (defvar temporary-file-directory)
 104 (defvar jka-compr-compression-info-list)
 105 (defvar jam-zcat-filename-list)
 106 (defun riece-rdcc-substitute-variables (program variable value)
 107   (setq program (copy-sequence program))
 108   (let ((pointer program))
 109     (while pointer
 110       (setq pointer (memq variable program))
 111       (if pointer
 112           (setcar pointer value)))
 113     program))
 114
 115 (defun riece-rdcc-server-filter (process input)
 116   (save-excursion
 117     (set-buffer (process-buffer process))
 118     (goto-char (point-max))
 119     (insert input)
 120     (goto-char (point-min))
 121     (while (and (not (eobp))
 122                 (looking-at "\\([0-9]+\\)\n"))
 123       (message "Sending %s...(%s/%d)"
 124                riece-rdcc-request-file
 125                (match-string 1) riece-rdcc-request-size)
 126       (forward-line))
 127     (unless (eobp)
 128       (delete-region (point-min) (point)))))
 129
 130 (defun riece-rdcc-server-sentinel (process status)
 131   (with-current-buffer (process-buffer process)
 132     (message "Sending %s...done" riece-rdcc-request-file))
 133   (kill-buffer (process-buffer process)))
 134
 135 (defun riece-command-dcc-send (user file)
 136   (interactive
 137    (let ((completion-ignore-case t))
 138      (list (riece-completing-read-identity
 139             "User: "
 140             (riece-get-users-on-server (riece-current-server-name)))
 141            (expand-file-name (read-file-name "File: ")))))
 142   (let* ((process-connection-type nil)
 143          (process (start-process "DCC" (generate-new-buffer " *DCC*")
 144                                  "ruby" "-rsocket")))
 145     (process-send-string process
 146                          (apply #'concat
 147                                 (riece-rdcc-substitute-variables
 148                                  (riece-rdcc-substitute-variables
 149                                   (riece-rdcc-substitute-variables
 150                                    riece-rdcc-send-program
 151                                    'address
 152                                    (if riece-rdcc-server-address
 153                                        (concat "'" riece-rdcc-server-address
 154                                                "'")
 155                                      "nil"))
 156                                   'file
 157                                   (concat "'" file "'"))
 158                                  'block-size
 159                                  (number-to-string riece-rdcc-block-size))))
 160     (process-send-eof process)
 161     (save-excursion
 162       (set-buffer (process-buffer process))
 163       (while (and (eq (process-status process) 'run)
 164                   (progn
 165                     (goto-char (point-min))
 166                     (not (looking-at "\\([0-9]+\\) \\([0-9]+\\)"))))
 167         (accept-process-output process))
 168       (if (eq (process-status process) 'run)
 169           (let ((address (match-string 1))
 170                 (port (match-string 2)))
 171             (erase-buffer)
 172             (make-local-variable 'riece-rdcc-request-size)
 173             (setq riece-rdcc-request-file file
 174                   riece-rdcc-request-size (nth 7 (file-attributes file)))
 175             (set-buffer-modified-p nil)
 176             (set-process-filter process #'riece-rdcc-server-filter)
 177             (set-process-sentinel process #'riece-rdcc-server-sentinel)
 178             (riece-send-string
 179              (format "PRIVMSG %s :\1DCC SEND %s %s %s %d\1\r\n"
 180                      (riece-identity-prefix user)
 181                      (file-name-nondirectory file)
 182                      address port
 183                      riece-rdcc-request-size)))))))
 184
 185 (defun riece-rdcc-filter (process input)
 186   (save-excursion
 187     (set-buffer (process-buffer process))
 188     (erase-buffer)
 189     (insert input)
 190     (let ((coding-system-for-write 'binary)
 191           jka-compr-compression-info-list jam-zcat-filename-list)
 192       (write-region (point-min) (point-max) riece-rdcc-temp-file t 0))
 193     (message "Receiving %s from %s...(%s/%s)"
 194              (file-name-nondirectory riece-rdcc-request-file)
 195              riece-rdcc-request-user
 196              (riece-rdcc-format-size
 197               (setq riece-rdcc-received-size (+ (buffer-size)
 198                                                 riece-rdcc-received-size)))
 199              (riece-rdcc-format-size riece-rdcc-request-size))))
 200
 201 (defun riece-rdcc-sentinel (process status)
 202   (save-excursion
 203     (set-buffer (process-buffer process))
 204     (unless (= riece-rdcc-received-size riece-rdcc-request-size)
 205       (error "Premature end of file"))
 206     (message "Receiving %s from %s...done"
 207              (file-name-nondirectory riece-rdcc-request-file)
 208              riece-rdcc-request-user)
 209     (condition-case nil
 210         (progn
 211           (rename-file riece-rdcc-temp-file riece-rdcc-request-file)
 212           (delete-directory (file-name-directory riece-rdcc-temp-file)))
 213       (file-already-exists
 214        (error "Can't save %s.  Temporarily saved in %s"
 215               riece-rdcc-request-file riece-rdcc-temp-file))))
 216   (kill-buffer (process-buffer process)))
 217
 218 (defun riece-rdcc-decode-address (address)
 219   (with-temp-buffer
 220     (call-process riece-rdcc-ruby-command nil t nil "-e"
 221                   (apply #'concat
 222                          (riece-rdcc-substitute-variables
 223                           riece-rdcc-decode-address-program
 224                           'address
 225                           address)))
 226     (buffer-substring (point-min) (1- (point-max)))))
 227
 228 (defun riece-command-dcc-receive (request file)
 229   (interactive
 230    (progn
 231      (unless riece-rdcc-requests
 232        (error "No request"))
 233      (let* ((request
 234              (if (= (length riece-rdcc-requests) 1)
 235                  (car riece-rdcc-requests)
 236                (with-output-to-temp-buffer "*Help*"
 237                  (let ((requests riece-rdcc-requests)
 238                        (index 1))
 239                    (while requests
 240                      (princ (format "%2d: %s %s (%d bytes)\n"
 241                                     index
 242                                     (car (car requests))
 243                                     (nth 1 (car requests))
 244                                     (nth 4 (car requests))))
 245                      (setq index (1+ index)
 246                            requests (cdr requests)))))
 247                (let ((number (read-string "Request#: ")))
 248                  (unless (string-match "^[0-9]+$" number)
 249                    (error "Not a number"))
 250                  (if (or (> (setq number (string-to-number number))
 251                             (length riece-rdcc-requests))
 252                          (< number 1))
 253                      (error "Invalid number"))
 254                  (nth (1- number) riece-rdcc-requests))))
 255             (default-name (expand-file-name
 256                            (nth 1 request) (or riece-rdcc-save-directory
 257                                                default-directory))))
 258        (list request
 259              (expand-file-name
 260               (read-file-name
 261                (concat "Save as (default "
 262                        (file-name-nondirectory default-name) ") ")
 263                (file-name-directory default-name)
 264                default-name))))))
 265   (let* ((temp-file (expand-file-name
 266                      (file-name-nondirectory file)
 267                      (expand-file-name (make-temp-name "riece-rdcc")
 268                                        (if (featurep 'xemacs)
 269                                            (temp-directory)
 270                                          temporary-file-directory))))
 271          (orig-mode (default-file-modes))
 272          selective-display
 273          (coding-system-for-read 'binary)
 274          (coding-system-for-write 'binary)
 275          process)
 276     (unwind-protect
 277         (progn
 278           (set-default-file-modes 448)
 279           ;; This may throw an error.
 280           (make-directory (file-name-directory temp-file)))
 281       (set-default-file-modes orig-mode))
 282     (setq process (open-network-stream
 283                    "DCC" (generate-new-buffer " *DCC*")
 284                    (riece-rdcc-decode-address (nth 2 request))
 285                    (nth 3 request)))
 286     (setq riece-rdcc-requests (delq request riece-rdcc-requests))
 287     (with-current-buffer (process-buffer process)
 288       (if (fboundp 'set-buffer-multibyte)
 289           (set-buffer-multibyte nil))
 290       (buffer-disable-undo)
 291       (erase-buffer)
 292       (make-local-variable 'riece-rdcc-request-user)
 293       (setq riece-rdcc-request-user (car request))
 294       (make-local-variable 'riece-rdcc-request-file)
 295       (setq riece-rdcc-request-file file)
 296       (make-local-variable 'riece-rdcc-request-size)
 297       (setq riece-rdcc-request-size (nth 4 request))
 298       (make-local-variable 'riece-rdcc-temp-file)
 299       (setq riece-rdcc-temp-file temp-file)
 300       (make-local-variable 'riece-rdcc-received-size)
 301       (setq riece-rdcc-received-size 0))
 302     (set-process-filter process #'riece-rdcc-filter)
 303     (set-process-sentinel process #'riece-rdcc-sentinel)))
 304
 305 (defun riece-rdcc-format-size (size)
 306   (if (< size 1024)
 307       (format "%0.1f" size)
 308     (setq size (/ size 1024.0))
 309     (if (< size 1024)
 310         (format "%0.1fKB" size)
 311       (setq size (/ size 1024.0))
 312       (if (< size 1024)
 313           (format "%0.1fMB" size)
 314         (format "%0.1fGB" (/ size 1024.0))))))
 315
 316 (defun riece-handle-dcc-request (prefix target message)
 317   (let ((case-fold-search t))
 318     (when (string-match
 319            "SEND \\([^ ]+\\) \\([^ ]+\\) \\([^ ]+\\) \\([^ ]+\\)"
 320            message)
 321       (let ((file (match-string 1 message))
 322             (address (match-string 2 message))
 323             (port (string-to-number (match-string 3 message)))
 324             (size (string-to-number (match-string 4 message)))
 325             (buffer (if (riece-channel-p target)
 326                         (riece-channel-buffer (riece-make-identity
 327                                                target riece-server-name))))
 328             (user (riece-prefix-nickname prefix)))
 329         (setq riece-rdcc-requests
 330               (cons (list user file address port size)
 331                     riece-rdcc-requests))
 332         (message "%s"
 333                  (with-current-buffer (window-buffer (selected-window))
 334                    (substitute-command-keys
 335                     (format
 336                      "Type \\[riece-command-dcc-receive] to receive"
 337                      user))))
 338         (riece-insert-change buffer (format "DCC SEND from %s: %s (%s)\n"
 339                                             user file
 340                                             (riece-rdcc-format-size size)))
 341         (riece-insert-change
 342          (if (and riece-channel-buffer-mode
 343                   (not (eq buffer riece-channel-buffer)))
 344              (list riece-dialogue-buffer riece-others-buffer)
 345            riece-dialogue-buffer)
 346          (concat
 347           (riece-concat-server-name
 348            (format "DCC SEND from %s (%s) to %s: %s (%s)"
 349                    user
 350                    (riece-strip-user-at-host
 351                     (riece-prefix-user-at-host prefix))
 352                    (riece-decode-coding-string target)
 353                    file
 354                    (riece-rdcc-format-size size)))
 355           "\n")))
 356       t)))
 357
 358 (defun riece-rdcc-requires ()
 359   '(riece-ctcp))
 360
 361 (defvar riece-dialogue-mode-map)
 362 (defun riece-rdcc-insinuate ()
 363   (add-to-list 'riece-ctcp-additional-clientinfo "DCC")
 364   (add-hook 'riece-ctcp-dcc-request-hook 'riece-handle-dcc-request)
 365   (define-key riece-dialogue-mode-map "\C-ds" 'riece-command-dcc-send)
 366   (define-key riece-dialogue-mode-map "\C-dr" 'riece-command-dcc-receive))
 367
 368 (provide 'riece-rdcc)
 369
 370 ;;; riece-rdcc.el ends here