cgit.sxemacs.org Git - riece/blob - lisp/riece-ndcc.el

   1 ;;; riece-ndcc.el --- DCC file sending protocol support (written in elisp)
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Keywords: IRC, riece
   6
   7 ;; This file is part of Riece.
   8
   9 ;; This program is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; This program is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; NOTE: This is an add-on module for Riece.
  27
  28 ;;; Code:
  29
  30 (require 'riece-globals)
  31 (require 'riece-options)
  32
  33 (require 'calc)
  34
  35 (defgroup riece-ndcc nil
  36   "DCC written in elisp."
  37   :prefix "riece-"
  38   :group 'riece)
  39
  40 (defcustom riece-ndcc-server-address "127.0.0.1"
  41   "Local address of the DCC server.
  42 Only used for sending files."
  43   :type 'vector
  44   :group 'riece-ndcc)
  45
  46 (defvar riece-ndcc-requests nil)
  47
  48 (defvar riece-ndcc-request-user nil)
  49 (defvar riece-ndcc-request-size nil)
  50
  51 (defconst riece-ndcc-description
  52   "DCC file sending protocol support (written in elisp.)")
  53
  54 (defun riece-ndcc-encode-address (address)
  55   (unless (string-match
  56            "^\\([0-9]+\\)\\.\\([0-9]+\\)\\.\\([0-9]+\\)\\.\\([0-9]+\\)$"
  57            address)
  58     (error "% is not an IP address" address))
  59   (let ((calc-number-radix 10))
  60     (calc-eval (format "%s * (2 ** 24) + %s * (2 **16) + %s * (2 ** 8) + %s"
  61                        (match-string 1 address)
  62                        (match-string 2 address)
  63                        (match-string 3 address)
  64                        (match-string 4 address)))))
  65
  66 (defun riece-ndcc-decode-address (address)
  67   (format "%d.%d.%d.%d"
  68           (floor (string-to-number
  69                   (calc-eval (format "(%s / (2 ** 24)) %% 256" address))))
  70           (floor (string-to-number
  71                   (calc-eval (format "(%s / (2 ** 16)) %% 256" address))))
  72           (floor (string-to-number
  73                   (calc-eval (format "(%s / (2 ** 8)) %% 256" address))))
  74           (floor (string-to-number
  75                   (calc-eval (format "%s %% 256" address))))))
  76
  77 (defun riece-ndcc-server-sentinel (process status)
  78   (when (string-match "^open from " status)
  79     (let ((parent-name
  80            (if (string-match " <[^>]+>$" (process-name process))
  81                (substring (process-name process) 0 (match-beginning 0)))))
  82       (save-excursion
  83         (set-buffer (process-buffer (get-process parent-name)))
  84         (goto-char (point-min))
  85         (while (not (eobp))
  86           (process-send-region process
  87                                (point)
  88                                (goto-char (min (+ 1024 (point)) (point-max))))
  89           (message "Sending %s...(%d/%d)"
  90                    (buffer-file-name) (1- (point)) (buffer-size)))
  91         (message "Sending %s...done"
  92                  (buffer-file-name)))
  93       (kill-buffer (process-buffer (get-process parent-name))))
  94     (kill-buffer (process-buffer process))))
  95
  96 (defun riece-command-dcc-send (user file)
  97   (interactive
  98    (let ((completion-ignore-case t))
  99      (unless riece-ndcc-server-address
 100        (error "Set riece-ndcc-server-address to your host"))
 101      (list (riece-completing-read-identity
 102             "User: "
 103             (riece-get-users-on-server (riece-current-server-name)))
 104            (expand-file-name (read-file-name "File: ")))))
 105   (let* (selective-display
 106          (coding-system-for-read 'binary)
 107          format-alist
 108          jka-compr-compression-info-list
 109          (buffer (find-file-noselect file))
 110          process)
 111     (with-current-buffer buffer         ;To throw an error when the
 112       (setq buffer-read-only t))        ;process has input.
 113     (setq process (make-network-process :name "DCC" :buffer buffer
 114                                         :host riece-ndcc-server-address
 115                                         :server t :service t
 116                                         :coding 'binary
 117                                         :sentinel 'riece-ndcc-server-sentinel))
 118     (riece-send-string
 119      (format "PRIVMSG %s :\1DCC SEND %s %s %d %d\1\r\n"
 120              (riece-identity-prefix user)
 121              (file-name-nondirectory file)
 122              (riece-ndcc-encode-address riece-ndcc-server-address)
 123              (nth 1 (process-contact process))
 124              (nth 7 (file-attributes file))))))
 125
 126 (defun riece-ndcc-filter (process input)
 127   (save-excursion
 128     (set-buffer (process-buffer process))
 129     (goto-char (point-max))
 130     (insert input)
 131     (message "Receiving %s from %s...(%d/%d)"
 132              (file-name-nondirectory buffer-file-name)
 133              riece-ndcc-request-user
 134              (1- (point))
 135              riece-ndcc-request-size)))
 136
 137 (defun riece-ndcc-sentinel (process status)
 138   (save-excursion
 139     (set-buffer (process-buffer process))
 140     (unless (= (buffer-size) riece-ndcc-request-size)
 141       (error "Premature end of file"))
 142     (message "Receiving %s from %s...done"
 143              (file-name-nondirectory buffer-file-name)
 144              riece-ndcc-request-user)
 145     (let ((coding-system-for-write 'binary))
 146       (save-buffer))))
 147
 148 (defun riece-command-dcc-receive (request file)
 149   (interactive
 150    (progn
 151      (unless riece-ndcc-requests
 152        (error "No request"))
 153      (list
 154       (if (= (length riece-ndcc-requests) 1)
 155           (car riece-ndcc-requests)
 156         (with-output-to-temp-buffer "*Help*"
 157           (let ((requests riece-ndcc-requests)
 158                 (index 1))
 159             (while requests
 160               (princ (format "%2d: %s %s (%d bytes)\n"
 161                              index
 162                              (car (car requests))
 163                              (nth 1 (car requests))
 164                              (nth 4 (car requests))))
 165               (setq index (1+ index)
 166                     requests (cdr requests)))))
 167         (let ((number (read-string "Request#: ")))
 168           (unless (string-match "^[0-9]+$" number)
 169             (error "Not a number"))
 170           (if (or (> (setq number (string-to-number number))
 171                      (length riece-ndcc-requests))
 172                   (< number 1))
 173               (error "Invalid number"))
 174           (nth (1- number) riece-ndcc-requests)))
 175       (expand-file-name (read-file-name "Save as: ")))))
 176   (let* (selective-display
 177          (coding-system-for-read 'binary)
 178          (coding-system-for-write 'binary)
 179          (process (open-network-stream
 180                    "DCC" " *DCC*"
 181                    (riece-ndcc-decode-address (nth 2 request))
 182                    (nth 3 request))))
 183     (setq riece-ndcc-requests (delq request riece-ndcc-requests))
 184     (with-current-buffer (process-buffer process)
 185       (set-buffer-multibyte nil)
 186       (buffer-disable-undo)
 187       (setq buffer-file-name file)
 188       (make-local-variable 'riece-ndcc-request-user)
 189       (setq riece-ndcc-request-user (car request))
 190       (make-local-variable 'riece-ndcc-request-size)
 191       (setq riece-ndcc-request-size (nth 4 request)))
 192     (set-process-filter process #'riece-ndcc-filter)
 193     (set-process-sentinel process #'riece-ndcc-sentinel)))
 194
 195 (defun riece-handle-dcc-request (prefix target message)
 196   (let ((case-fold-search t))
 197     (when (and (get 'riece-ndcc 'riece-addon-enabled)
 198                (string-match
 199                 "SEND \\([^ ]+\\) \\([^ ]+\\) \\([^ ]+\\) \\([^ ]+\\)"
 200                 message))
 201       (let ((file (match-string 1 message))
 202             (address (match-string 2 message))
 203             (port (string-to-number (match-string 3 message)))
 204             (size (string-to-number (match-string 4 message)))
 205             (buffer (if (riece-channel-p target)
 206                         (riece-channel-buffer (riece-make-identity
 207                                                target riece-server-name))))
 208             (user (riece-prefix-nickname prefix)))
 209         (setq riece-ndcc-requests
 210               (cons (list user file address port size)
 211                     riece-ndcc-requests))
 212         (riece-insert-change buffer (format "DCC SEND from %s\n" user))
 213         (riece-insert-change
 214          (if (and riece-channel-buffer-mode
 215                   (not (eq buffer riece-channel-buffer)))
 216              (list riece-dialogue-buffer riece-others-buffer)
 217            riece-dialogue-buffer)
 218          (concat
 219           (riece-concat-server-name
 220            (format "DCC SEND from %s (%s) to %s"
 221                    user
 222                    (riece-strip-user-at-host
 223                     (riece-prefix-user-at-host prefix))
 224                    target))
 225           "\n")))
 226       t)))
 227
 228 (defun riece-ndcc-requires ()
 229   '(riece-ctcp))
 230
 231 (defvar riece-dialogue-mode-map)
 232 (defun riece-ndcc-insinuate ()
 233   (unless (fboundp 'make-network-process)
 234     (error "This Emacs does not have make-network-process"))
 235   (add-hook 'riece-ctcp-dcc-request-hook 'riece-handle-dcc-request))
 236
 237 (defun riece-ndcc-uninstall ()
 238   (remove-hook 'riece-ctcp-dcc-request-hook 'riece-handle-dcc-request))
 239
 240 (defun riece-ndcc-enable ()
 241   (define-key riece-dialogue-mode-map "\C-ds" 'riece-command-dcc-send)
 242   (define-key riece-dialogue-mode-map "\C-dr" 'riece-command-dcc-receive))
 243
 244 (defun riece-ndcc-disable ()
 245   (define-key riece-dialogue-mode-map "\C-ds" nil)
 246   (define-key riece-dialogue-mode-map "\C-dr" nil))
 247
 248 (provide 'riece-ndcc)
 249
 250 ;;; riece-ndcc.el ends here