cgit.sxemacs.org Git - riece/blob - lisp/riece-ndcc.el

   1 ;;; riece-ndcc.el --- elisp native DCC add-on
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Keywords: IRC, riece
   6
   7 ;; This file is part of Riece.
   8
   9 ;; This program is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; This program is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Code:
  25
  26 (require 'riece-globals)
  27 (require 'riece-options)
  28 (require 'riece-display)
  29
  30 (require 'calc)
  31
  32 (defgroup riece-ndcc nil
  33   "Elisp native DCC implementation"
  34   :prefix "riece-"
  35   :group 'riece)
  36
  37 (defcustom riece-ndcc-server-address "127.0.0.1"
  38   "Local address of the DCC server.
  39 Only used for sending files."
  40   :type 'vector
  41   :group 'riece-ndcc)
  42
  43 (defvar riece-ndcc-requests nil)
  44
  45 (defvar riece-ndcc-request-user nil)
  46 (defvar riece-ndcc-request-size nil)
  47
  48 (defun riece-ndcc-encode-address (address)
  49   (unless (string-match
  50            "^\\([0-9]+\\)\\.\\([0-9]+\\)\\.\\([0-9]+\\)\\.\\([0-9]+\\)$"
  51            address)
  52     (error "% is not an IP address" address))
  53   (let ((calc-number-radix 10))
  54     (calc-eval (format "%s * (2 ** 24) + %s * (2 **16) + %s * (2 ** 8) + %s"
  55                        (match-string 1 address)
  56                        (match-string 2 address)
  57                        (match-string 3 address)
  58                        (match-string 4 address)))))
  59
  60 (defun riece-ndcc-decode-address (address)
  61   (format "%d.%d.%d.%d"
  62           (floor (string-to-number
  63                   (calc-eval (format "(%s / (2 ** 24)) %% 256" address))))
  64           (floor (string-to-number
  65                   (calc-eval (format "(%s / (2 ** 16)) %% 256" address))))
  66           (floor (string-to-number
  67                   (calc-eval (format "(%s / (2 ** 8)) %% 256" address))))
  68           (floor (string-to-number
  69                   (calc-eval (format "%s %% 256" address))))))
  70
  71 (defun riece-ndcc-server-sentinel (process status)
  72   (when (string-match "^open from " status)
  73     (let ((parent-name
  74            (if (string-match " <[^>]+>$" (process-name process))
  75                (substring (process-name process) 0 (match-beginning 0)))))
  76       (save-excursion
  77         (set-buffer (process-buffer (get-process parent-name)))
  78         (goto-char (point-min))
  79         (while (not (eobp))
  80           (process-send-region process
  81                                (point)
  82                                (goto-char (min (+ 1024 (point)) (point-max))))
  83           (message "Sending %s...(%d/%d)"
  84                    (buffer-file-name) (1- (point)) (buffer-size)))
  85         (message "Sending %s...done"
  86                  (buffer-file-name)))
  87       (kill-buffer (process-buffer (get-process parent-name))))
  88     (kill-buffer (process-buffer process))))
  89
  90 (defun riece-command-dcc-send (user file)
  91   (interactive
  92    (let ((completion-ignore-case t))
  93      (unless riece-ndcc-server-address
  94        (error "Set riece-ndcc-server-address to your host"))
  95      (list (riece-completing-read-identity
  96             "User: "
  97             (riece-get-users-on-server (riece-current-server-name)))
  98            (expand-file-name (read-file-name "File: ")))))
  99   (let* (selective-display
 100          (coding-system-for-read 'binary)
 101          format-alist
 102          jka-compr-compression-info-list
 103          (buffer (find-file-noselect file))
 104          process)
 105     (with-current-buffer buffer         ;To throw an error when the
 106       (setq buffer-read-only t))        ;process has input.
 107     (setq process (make-network-process :name "DCC" :buffer buffer
 108                                         :host riece-ndcc-server-address
 109                                         :server t :service t
 110                                         :coding 'binary
 111                                         :sentinel 'riece-ndcc-server-sentinel))
 112     (riece-send-string
 113      (format "PRIVMSG %s :\1DCC SEND %s %s %d %d\1\r\n"
 114              (riece-identity-prefix user)
 115              (file-name-nondirectory file)
 116              (riece-ndcc-encode-address riece-ndcc-server-address)
 117              (nth 1 (process-contact process))
 118              (nth 7 (file-attributes file))))))
 119
 120 (defun riece-ndcc-filter (process input)
 121   (save-excursion
 122     (set-buffer (process-buffer process))
 123     (goto-char (point-max))
 124     (insert input)
 125     (message "Receiving %s from %s...(%d/%d)"
 126              (file-name-nondirectory buffer-file-name)
 127              riece-ndcc-request-user
 128              (1- (point))
 129              riece-ndcc-request-size)))
 130
 131 (defun riece-ndcc-sentinel (process status)
 132   (save-excursion
 133     (set-buffer (process-buffer process))
 134     (unless (= (buffer-size) riece-ndcc-request-size)
 135       (error "Premature end of file"))
 136     (message "Receiving %s from %s...done"
 137              (file-name-nondirectory buffer-file-name)
 138              riece-ndcc-request-user)
 139     (let ((coding-system-for-write 'binary))
 140       (save-buffer))))
 141
 142 (defun riece-command-dcc-receive (request file)
 143   (interactive
 144    (progn
 145      (unless riece-ndcc-requests
 146        (error "No request"))
 147      (list
 148       (if (= (length riece-ndcc-requests) 1)
 149           (car riece-ndcc-requests)
 150         (with-output-to-temp-buffer "*Help*"
 151           (let ((requests riece-ndcc-requests)
 152                 (index 1))
 153             (while requests
 154               (princ (format "%2d: %s %s (%d bytes)\n"
 155                              index
 156                              (car (car requests))
 157                              (nth 1 (car requests))
 158                              (nth 4 (car requests))))
 159               (setq index (1+ index)
 160                     requests (cdr requests)))))
 161         (let ((number (read-string "Request#: ")))
 162           (unless (string-match "^[0-9]+$" number)
 163             (error "Not a number"))
 164           (if (or (> (setq number (string-to-number number))
 165                      (length riece-ndcc-requests))
 166                   (< number 1))
 167               (error "Invalid number"))
 168           (nth (1- number) riece-ndcc-requests)))
 169       (expand-file-name (read-file-name "Save as: ")))))
 170   (let* (selective-display
 171          (coding-system-for-read 'binary)
 172          (coding-system-for-write 'binary)
 173          (process (open-network-stream
 174                    "DCC" " *DCC*"
 175                    (riece-ndcc-decode-address (nth 2 request))
 176                    (nth 3 request))))
 177     (setq riece-ndcc-requests (delq request riece-ndcc-requests))
 178     (with-current-buffer (process-buffer process)
 179       (set-buffer-multibyte nil)
 180       (buffer-disable-undo)
 181       (setq buffer-file-name file)
 182       (make-local-variable 'riece-ndcc-request-user)
 183       (setq riece-ndcc-request-user (car request))
 184       (make-local-variable 'riece-ndcc-request-size)
 185       (setq riece-ndcc-request-size (nth 4 request)))
 186     (set-process-filter process #'riece-ndcc-filter)
 187     (set-process-sentinel process #'riece-ndcc-sentinel)))
 188
 189 (defun riece-handle-dcc-request (prefix target message)
 190   (let ((case-fold-search t))
 191     (when (string-match
 192            "SEND \\([^ ]+\\) \\([^ ]+\\) \\([^ ]+\\) \\([^ ]+\\)"
 193            message)
 194       (let ((file (match-string 1 message))
 195             (address (match-string 2 message))
 196             (port (string-to-number (match-string 3 message)))
 197             (size (string-to-number (match-string 4 message)))
 198             (buffer (if (riece-channel-p target)
 199                         (riece-channel-buffer (riece-make-identity
 200                                                target riece-server-name))))
 201             (user (riece-prefix-nickname prefix)))
 202         (setq riece-ndcc-requests
 203               (cons (list user file address port size)
 204                     riece-ndcc-requests))
 205         (riece-insert-change buffer (format "DCC SEND from %s\n" user))
 206         (riece-insert-change
 207          (if (and riece-channel-buffer-mode
 208                   (not (eq buffer riece-channel-buffer)))
 209              (list riece-dialogue-buffer riece-others-buffer)
 210            riece-dialogue-buffer)
 211          (concat
 212           (riece-concat-server-name
 213            (format "DCC SEND from %s (%s) to %s"
 214                    user
 215                    (riece-strip-user-at-host
 216                     (riece-prefix-user-at-host prefix))
 217                    target))
 218           "\n")))
 219       t)))
 220
 221 (defun riece-ndcc-requires ()
 222   '(riece-ctcp))
 223
 224 (defvar riece-dialogue-mode-map)
 225 (defun riece-ndcc-insinuate ()
 226   (add-hook 'riece-ctcp-dcc-request-hook 'riece-handle-dcc-request)
 227   (define-key riece-dialogue-mode-map "\C-ds" 'riece-command-dcc-send)
 228   (define-key riece-dialogue-mode-map "\C-dr" 'riece-command-dcc-receive))
 229
 230 (provide 'riece-ndcc)
 231
 232 ;;; riece-ndcc.el ends here