cgit.sxemacs.org Git - riece/blob - lisp/riece-misc.el

   1 ;;; riece-misc.el --- miscellaneous functions (not inlined)
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Created: 1998-09-28
   6 ;; Keywords: IRC, riece
   7
   8 ;; This file is part of Riece.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Code:
  26
  27 (require 'riece-options)
  28 (require 'riece-coding)
  29 (require 'riece-identity)
  30 (require 'riece-version)
  31 (require 'riece-channel)
  32 (require 'riece-server)
  33 (require 'riece-user)
  34
  35 (defun riece-get-buffer-create (name &optional init-major-mode)
  36   (let ((buffer (get-buffer name)))
  37     (unless (and buffer
  38                  (or (null init-major-mode)
  39                      (eq (with-current-buffer buffer
  40                            major-mode)
  41                          init-major-mode)))
  42       (setq buffer (generate-new-buffer name)))
  43     (unless (memq buffer riece-buffer-list)
  44       (setq riece-buffer-list (cons buffer riece-buffer-list)))
  45     buffer))
  46
  47 (defun riece-scan-property-region (property start end function)
  48   (catch 'done
  49     (while t
  50       ;; Search for the beginning of the property region.
  51       (unless (get-text-property start property)
  52         (setq start (next-single-property-change start property nil end)))
  53       (if (= start end)
  54           (throw 'done nil))
  55       ;; Search for the end of the property region.
  56       (let ((region-end (next-single-property-change start property nil end)))
  57         (if (= region-end end)
  58             (throw 'done nil))
  59         (funcall function start region-end)
  60         (setq start region-end)))))
  61
  62 (defun riece-insert (buffers string)
  63   (unless (listp buffers)
  64     (setq buffers (list buffers)))
  65   (while buffers
  66     (run-hooks 'riece-before-insert-functions)
  67     (save-excursion
  68       (set-buffer (car buffers))
  69       (let ((inhibit-read-only t)
  70             buffer-read-only
  71             (start (goto-char (point-max))))
  72         (insert (format-time-string "%H:%M") " " string)
  73         (if (and (not (riece-frozen (current-buffer)))
  74                  (get-buffer-window (current-buffer)))
  75             (set-window-point (get-buffer-window (current-buffer))
  76                               (point)))
  77         (run-hook-with-args 'riece-after-insert-functions start (point))))
  78     (setq buffers (cdr buffers))))
  79
  80 (defun riece-insert-change (buffer message)
  81   (riece-insert buffer (concat riece-change-prefix message)))
  82
  83 (defun riece-insert-notice (buffer message)
  84   (riece-insert buffer (concat riece-notice-prefix message)))
  85
  86 (defun riece-insert-wallops (buffer message)
  87   (riece-insert buffer (concat riece-wallops-prefix message)))
  88
  89 (defun riece-insert-error (buffer message)
  90   (riece-insert buffer (concat riece-error-prefix message)))
  91
  92 (defun riece-insert-info (buffer message)
  93   (riece-insert buffer (concat riece-info-prefix message)))
  94
  95 (defun riece-frozen (buffer)
  96   (with-current-buffer buffer
  97     riece-freeze))
  98
  99 (defun riece-own-frozen (buffer)
 100   (with-current-buffer buffer
 101     (eq riece-freeze 'own)))
 102
 103 (defun riece-channel-p (string)
 104   "Return t if STRING is a channel.
 105 \(i.e. it matches `riece-channel-regexp')"
 106   (string-match (concat "^" riece-channel-regexp) string))
 107
 108 (defun riece-current-nickname ()
 109   "Return the current nickname."
 110   (riece-with-server-buffer (riece-identity-server riece-current-channel)
 111     (if riece-real-nickname
 112         (riece-make-identity riece-real-nickname riece-server-name))))
 113
 114 (defun riece-split-parameters (string)
 115   (if (eq ?: (aref string 0))
 116       (list (substring string 1))
 117     (let (parameters)
 118       (catch 'done
 119         (while (string-match "^\\([^ ]+\\) +" string)
 120           (setq parameters (nconc parameters (list (match-string 1 string)))
 121                 string (substring string (match-end 0)))
 122           (and (not (equal "" string)) (eq ?: (aref string 0))
 123                (setq string (substring string 1))
 124                (throw 'done nil))))
 125       (or (equal "" string)
 126           (setq parameters (nconc parameters (list string))))
 127       parameters)))
 128
 129 (defun riece-concat-channel-topic (target string)
 130   (riece-with-server-buffer (riece-identity-server target)
 131     (let ((topic (riece-channel-get-topic (riece-identity-prefix target))))
 132       (if (or (null topic)
 133               (equal topic ""))
 134           string
 135         (concat string ": " topic)))))
 136
 137 (defun riece-concat-channel-modes (target string)
 138   (riece-with-server-buffer (riece-identity-server target)
 139     (let ((modes (riece-channel-get-modes (riece-identity-prefix target))))
 140       (if modes
 141           (concat string " [" (apply #'string modes) "]")
 142         string))))
 143
 144 (defun riece-concat-message (string message)
 145   (if (or (null message)
 146           (equal message ""))
 147       string
 148     (concat string " (" message ")")))
 149
 150 (defun riece-concat-server-name (string)
 151   (if (equal riece-server-name "")
 152       string
 153     (concat string " (from " riece-server-name ")")))
 154
 155 (defun riece-prefix-user-at-host (prefix)
 156   (if (string-match "!" prefix)
 157       (substring prefix (match-end 0))
 158     prefix))
 159
 160 (defun riece-prefix-nickname (prefix)
 161   (if (string-match "!" prefix)
 162       (substring prefix 0 (match-beginning 0))
 163     prefix))
 164
 165 (defun riece-parse-user-at-host (user-at-host)
 166   (if (memq (aref user-at-host 0) '(?^ ?= ?~ ?- ?+))
 167       (progn
 168         (if (memq (aref user-at-host 0) '(?^ ?=))
 169             (setq riece-user-at-host-type 'fake)
 170           (if (memq (aref user-at-host 0) '(?~ ?-))
 171               (setq riece-user-at-host-type 'not-verified)
 172             (if (eq (aref user-at-host 0) ?+)
 173                 (setq riece-user-at-host-type 'ok))))
 174         (substring user-at-host 1))
 175     (setq riece-user-at-host-type 'ok)
 176     user-at-host))
 177
 178 (defun riece-strip-user-at-host (user-at-host)
 179   (if (memq (aref user-at-host 0) '(?^ ?= ?~ ?- ?+))
 180       (substring user-at-host 1)
 181     user-at-host))
 182
 183 (defun riece-get-users-on-server ()
 184   (riece-with-server-buffer (riece-identity-server riece-current-channel)
 185     (let (users)
 186       (mapatoms
 187        (lambda (atom)
 188          (unless (riece-channel-p (symbol-name atom))
 189            (setq users (cons (symbol-name atom) users))))
 190        riece-obarray)
 191       (if (member riece-real-nickname users)
 192           users
 193         (cons riece-real-nickname users)))))
 194
 195 (provide 'riece-misc)
 196
 197 ;;; riece-misc.el ends here