cgit.sxemacs.org Git - riece/blob - lisp/riece-mini.el

   1 ;;; riece-mini.el --- "riece on minibuffer" add-on
   2 ;; Copyright (C) 2003 OHASHI Akira
   3
   4 ;; Author: OHASHI Akira <bg66@koka-in.org>
   5 ;; Keywords: IRC, riece
   6
   7 ;; This file is part of Riece.
   8
   9 ;; This program is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; This program is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; This add-on shows arrival messages to minibuffer. And you can send
  27 ;; message using minibuffer.
  28 ;;
  29 ;; By using this add-on, you can use always "mini riece", even if you
  30 ;; are visiting other buffers.
  31
  32 ;; To use, add the following line to your ~/.riece/init.el:
  33 ;; (add-to-list 'riece-addons 'riece-mini)
  34 ;;
  35 ;; And for using conveniently, bind any global key to
  36 ;; `riece-mini-send-message'.
  37 ;; For example:
  38 ;; (global-set-key "\C-cm" 'riece-mini-send-message)
  39
  40 ;;; Code:
  41
  42 (eval-when-compile (require 'riece-message))
  43
  44 (defvar riece-mini-last-channel nil)
  45
  46 (defvar riece-mini-enabled nil)
  47
  48 (defmacro riece-mini-message-no-log (string &rest args)
  49   "Like `message', except that message logging is disabled."
  50   (if (featurep 'xemacs)
  51       (if args
  52           `(display-message 'no-log (format ,string ,@args))
  53         `(display-message 'no-log ,string))
  54     `(let (message-log-max)
  55        (message ,string ,@args))))
  56
  57 (defun riece-mini-display-message-function (message)
  58   "Show arrival messages to minibuffer."
  59   (when (and riece-mini-enabled
  60              (not (or (eq (window-buffer (selected-window))
  61                           (get-buffer riece-command-buffer))
  62                       (riece-message-own-p message)
  63                       (active-minibuffer-window))))
  64     (unless (riece-message-type message)
  65       (setq riece-mini-last-channel (riece-message-target message)))
  66     (riece-mini-message-no-log
  67      "%s" (concat (format-time-string "%H:%M") " "
  68                   (riece-format-message message t)))))
  69
  70 (defun riece-mini-send-message (arg)
  71   "Send message using minibuffer.
  72 Prefix argument onece (C-u), send message to last received channel.
  73 If twice (C-u C-u), then ask the channel."
  74   (interactive "P")
  75   (let* ((completion-ignore-case t)
  76          (target
  77           (cond
  78            ((equal arg '(16))
  79             (riece-completing-read-identity
  80              "Channel/User: " riece-current-channels nil t))
  81            (arg (or riece-mini-last-channel riece-current-channel))
  82            (t riece-current-channel)))
  83          (message (read-string (format "Message to %s: " target))))
  84     (unless (equal message "")
  85       (riece-switch-to-channel target)
  86       (riece-send-string
  87        (format "PRIVMSG %s :%s\r\n"
  88                (riece-identity-prefix target)
  89                message))
  90       (riece-display-message
  91        (riece-make-message (riece-current-nickname) target
  92                            message nil t)))))
  93
  94 (defun riece-mini-insinuate ()
  95   (add-hook 'riece-after-display-message-functions
  96             'riece-mini-display-message-function))
  97
  98 (defun riece-mini-enable ()
  99   (setq riece-mini-enabled t))
 100
 101 (defun riece-mini-disable ()
 102   (setq riece-mini-enabled nil))
 103
 104 (provide 'riece-mini)
 105
 106 ;;; riece-mini.el ends here