cgit.sxemacs.org Git - riece/blob - lisp/riece-mini.el

   1 ;;; riece-mini.el --- use Riece only on the minibuffer
   2 ;; Copyright (C) 2003 OHASHI Akira
   3
   4 ;; Author: OHASHI Akira <bg66@koka-in.org>
   5 ;; Keywords: IRC, riece
   6
   7 ;; This file is part of Riece.
   8
   9 ;; This program is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; This program is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; NOTE: This is an add-on module for Riece.
  27
  28 ;; This add-on shows arrival messages to minibuffer. And you can send
  29 ;; message using minibuffer.
  30 ;;
  31 ;; By using this add-on, you can use always "mini riece", even if you
  32 ;; are visiting other buffers.
  33
  34 ;; To use, add the following line to your ~/.riece/init.el:
  35 ;; (add-to-list 'riece-addons 'riece-mini)
  36 ;;
  37 ;; For using conveniently, bind any global key to
  38 ;; `riece-mini-send-message' and `riece-mini-show-backlog'.
  39 ;; For example:
  40 ;; (global-set-key "\C-cm" 'riece-mini-send-message)
  41 ;; (global-set-key "\C-cb" 'riece-mini-show-backlog)
  42
  43 ;;; Code:
  44
  45 (require 'riece-message)
  46 (require 'riece-biff)
  47
  48 (defgroup riece-mini nil
  49   "Use Riece only on the minibuffer."
  50   :group 'riece)
  51
  52 (defcustom riece-mini-backlog-size 5
  53   "*Line numbers for logging back log."
  54   :type 'integer
  55   :group 'riece-mini)
  56
  57 (defvar riece-mini-last-channel nil)
  58 (defvar riece-mini-backlog-history nil)
  59 (defvar riece-mini-backlog-shown nil)
  60
  61 (defconst riece-mini-description
  62   "Use Riece only on the minibuffer.")
  63
  64 (defun riece-mini-message-no-log (string &rest args)
  65   "Like `message', except that message logging is disabled."
  66   (if (featurep 'xemacs)
  67       (if args
  68           (display-message 'no-log (apply #'format string args))
  69         (display-message 'no-log string))
  70     (let (message-log-max)
  71       (apply #'message string args))))
  72
  73 (defun riece-mini-display-message-function (message)
  74   "Show arrival messages to minibuffer."
  75   (let ((string (concat (format-time-string "%H:%M") " "
  76                         (riece-format-message message t))))
  77     (when (string-match "\\(.*\\)$" string)
  78       (setq string (riece-match-string-no-properties 1 string)))
  79     (while (>= (length riece-mini-backlog-history)
  80                riece-mini-backlog-size)
  81       (setq riece-mini-backlog-history
  82             (cdr riece-mini-backlog-history)))
  83     (setq riece-mini-backlog-history
  84           (reverse (cons string (reverse riece-mini-backlog-history))))
  85     (when (and (get 'riece-mini 'riece-addon-enabled)
  86                (not (or (eq (window-buffer (selected-window))
  87                             (get-buffer riece-command-buffer))
  88                         (riece-message-own-p message)
  89                         (active-minibuffer-window))))
  90       (unless (riece-message-type message)
  91         (setq riece-mini-last-channel (riece-message-target message)))
  92       (riece-mini-message-no-log "%s" string))))
  93
  94 (defun riece-mini-send-message (arg)
  95   "Send message using minibuffer.
  96 Prefix argument onece (C-u), send message to last received channel.
  97 If twice (C-u C-u), then ask the channel."
  98   (interactive "P")
  99   (let* ((completion-ignore-case t)
 100          (target
 101           (cond
 102            ((equal arg '(16))
 103             (riece-completing-read-identity
 104              "Channel/User: " riece-current-channels nil t))
 105            (arg (or riece-mini-last-channel riece-current-channel))
 106            (t riece-current-channel)))
 107          (message (read-string (format "Message to %s: " target))))
 108     (unless (equal message "")
 109       (riece-switch-to-channel target)
 110       (riece-send-string
 111        (format "PRIVMSG %s :%s\r\n"
 112                (riece-identity-prefix target)
 113                message))
 114       (riece-display-message
 115        (riece-make-message (riece-current-nickname) target
 116                            message nil t)))))
 117
 118 (defun riece-mini-show-backlog ()
 119   "Send back logs to minibuffer."
 120   (interactive)
 121   (when riece-mini-backlog-history
 122     (let ((height (1+ riece-mini-backlog-size)))
 123       (mapc #'(lambda (string)
 124                 (setq height (+ height
 125                                 (/ (length string) (window-width)))))
 126             riece-mini-backlog-history)
 127       (let ((max-mini-window-height height)
 128             (resize-mini-windows t))
 129         (setq riece-mini-backlog-shown t)
 130         (when (and (memq 'riece-biff riece-addons)
 131                    (get 'riece-biff 'riece-addon-enabled))
 132           (riece-biff-clear))
 133         (riece-mini-message-no-log
 134          "%s" (mapconcat #'identity riece-mini-backlog-history "\n"))))))
 135
 136 (defun riece-mini-pre-command ()
 137   (when riece-mini-backlog-shown
 138     (let ((resize-mini-windows t))
 139       (setq riece-mini-backlog-shown nil)
 140       (riece-mini-message-no-log ""))))
 141
 142 (defun riece-mini-requires ()
 143   (if (memq 'riece-biff riece-addons)
 144       '(riece-biff)))
 145
 146 (defun riece-mini-insinuate ()
 147   (add-hook 'riece-after-display-message-functions
 148             'riece-mini-display-message-function)
 149   (add-hook 'pre-command-hook 'riece-mini-pre-command))
 150
 151 (defun riece-mini-uninstall ()
 152   (remove-hook 'riece-after-display-message-functions
 153                'riece-mini-display-message-function)
 154   (remove-hook 'pre-command-hook 'riece-mini-pre-command))
 155
 156 (provide 'riece-mini)
 157
 158 ;;; riece-mini.el ends here