cgit.sxemacs.org Git - riece/blob - lisp/riece-message.el

   1 ;;; riece-message.el --- generate and display message line
   2 ;; Copyright (C) 1999-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Keywords: message
   6
   7 ;; This file is part of Riece.
   8
   9 ;; This program is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; This program is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Code:
  25
  26 (eval-when-compile (require 'riece-inlines))
  27
  28 (require 'riece-identity)
  29 (require 'riece-channel)
  30 (require 'riece-user)
  31 (require 'riece-display)
  32 (require 'riece-misc)
  33
  34 (defgroup riece-message nil
  35   "Messages"
  36   :tag "Message"
  37   :prefix "riece-"
  38   :group 'riece)
  39
  40 (defcustom riece-message-make-open-bracket-function
  41   #'riece-message-make-open-bracket
  42   "Function which makes `open-bracket' string for each message."
  43   :type 'function
  44   :group 'riece-message)
  45
  46 (defcustom riece-message-make-close-bracket-function
  47   #'riece-message-make-close-bracket
  48   "Function which makes `close-bracket' string for each message."
  49   :type 'function
  50   :group 'riece-message)
  51
  52 (defcustom riece-message-make-name-function
  53   #'riece-message-make-name
  54   "Function which makes local identity for each message."
  55   :type 'function
  56   :group 'riece-message)
  57
  58 (defcustom riece-message-make-global-name-function
  59   #'riece-message-make-global-name
  60   "Function which makes global identity for each message."
  61   :type 'function
  62   :group 'riece-message)
  63
  64 (defun riece-message-make-open-bracket (message)
  65   "Makes `open-bracket' string for MESSAGE."
  66   (riece-message-make-bracket message t))
  67
  68 (defun riece-message-make-close-bracket (message)
  69   "Makes `close-bracket' string for MESSAGE."
  70   (riece-message-make-bracket message nil))
  71
  72 (defun riece-message-make-bracket (message open-p)
  73   (if (eq open-p (riece-message-own-p message))
  74       (if (eq (riece-message-type message) 'notice)
  75           "-"
  76         (if (riece-message-private-p message)
  77             (if (riece-message-own-p message)
  78                 ">"
  79               "=")
  80           (if (riece-message-external-p message)
  81               ")"
  82             ">")))
  83     (if (eq (riece-message-type message) 'notice)
  84         "-"
  85       (if (riece-message-private-p message)
  86           (if (riece-message-own-p message)
  87               "<"
  88             "=")
  89         (if (riece-message-external-p message)
  90             "("
  91           "<")))))
  92
  93 (defun riece-message-make-name (message)
  94   "Makes local identity for MESSAGE."
  95   (riece-identity-prefix
  96    (if (and (riece-message-private-p message)
  97             (riece-message-own-p message))
  98        (riece-message-target message)
  99      (riece-message-speaker message))))
 100
 101 (defun riece-message-make-global-name (message)
 102   "Makes global identity for MESSAGE."
 103   (if (riece-message-private-p message)
 104       (if (riece-message-own-p message)
 105           (riece-identity-prefix (riece-message-target message))
 106         (riece-identity-prefix (riece-message-speaker message)))
 107     (concat (riece-identity-prefix (riece-message-target message)) ":"
 108             (riece-identity-prefix (riece-message-speaker message)))))
 109
 110 (defun riece-message-buffer (message)
 111   "Return the buffer where MESSAGE should appear."
 112   (let* ((target (if (riece-identity-equal-no-server
 113                       (riece-message-target message)
 114                       (riece-current-nickname))
 115                      (riece-message-speaker message)
 116                    (riece-message-target message)))
 117          (entry (riece-identity-assoc-no-server
 118                  target riece-channel-buffer-alist)))
 119     (unless entry
 120       (riece-join-channel target)
 121       ;; If you are not joined any channel,
 122       ;; switch to the target immediately.
 123       (unless riece-current-channel
 124         (riece-switch-to-channel target))
 125       (riece-redisplay-buffers)
 126       (setq entry (riece-identity-assoc-no-server
 127                    target riece-channel-buffer-alist)))
 128     (cdr entry)))
 129
 130 (defun riece-message-parent-buffers (message buffer)
 131   "Return the parents of BUFFER where MESSAGE should appear.
 132 Normally they are *Dialogue* and/or *Others*."
 133   (if (or (and buffer (riece-frozen buffer))
 134           (and riece-current-channel
 135                (not (riece-identity-equal-no-server
 136                      (riece-message-target message)
 137                      riece-current-channel))))
 138       (list riece-dialogue-buffer riece-others-buffer)
 139     riece-dialogue-buffer))
 140
 141 (defun riece-display-message (message)
 142   "Display MESSAGE object."
 143   (let* ((open-bracket
 144           (funcall riece-message-make-open-bracket-function message))
 145          (close-bracket
 146           (funcall riece-message-make-close-bracket-function message))
 147          (name
 148           (funcall riece-message-make-name-function message))
 149          (global-name
 150           (funcall riece-message-make-global-name-function message))
 151          (buffer (riece-message-buffer message))
 152          (parent-buffers (riece-message-parent-buffers message buffer)))
 153     (riece-insert buffer
 154                   (concat open-bracket name close-bracket
 155                           " " (riece-message-text message) "\n"))
 156     (riece-insert parent-buffers
 157                   (concat
 158                    (riece-concat-server-name
 159                     (concat open-bracket global-name close-bracket
 160                             " " (riece-message-text message)))
 161                    "\n"))
 162     (run-hook-with-args 'riece-after-display-message-functions message)))
 163
 164 (defun riece-make-message (speaker target text &optional type own-p)
 165   "Make an instance of message object.
 166 Arguments are appropriate to the sender, the receiver, and text
 167 content, respectively.
 168 Optional 4th argument TYPE specifies the type of the message.
 169 Currently possible values are `action' and `notice'.
 170 Optional 5th argument is the flag to indicate that this message is not
 171 from the network."
 172   (vector speaker target text type own-p))
 173
 174 (defun riece-message-speaker (message)
 175   "Return the sender of MESSAGE."
 176   (aref message 0))
 177
 178 (defun riece-message-target (message)
 179   "Return the receiver of MESSAGE."
 180   (aref message 1))
 181
 182 (defun riece-message-text (message)
 183   "Return the text part of MESSAGE."
 184   (aref message 2))
 185
 186 (defun riece-message-type (message)
 187   "Return the type of MESSAGE.
 188 Currently possible values are `action' and `notice'."
 189   (aref message 3))
 190
 191 (defun riece-message-own-p (message)
 192   "Return t if MESSAGE is not from the network."
 193   (aref message 4))
 194
 195 (defun riece-message-private-p (message)
 196   "Return t if MESSAGE is a private message."
 197   (if (riece-message-own-p message)
 198       (not (riece-channel-p (riece-message-target message)))
 199     (riece-identity-equal-no-server
 200      (riece-message-target message)
 201      (riece-current-nickname))))
 202
 203 (defun riece-message-external-p (message)
 204   "Return t if MESSAGE is from outside the channel."
 205   (not (riece-identity-member-no-server
 206         (riece-message-target message)
 207         (mapcar #'riece-make-identity
 208                 (riece-user-get-channels (riece-message-speaker message))))))
 209
 210 (defun riece-own-channel-message (message &optional channel type)
 211   "Display MESSAGE as you sent to CHNL."
 212   (riece-display-message
 213    (riece-make-message (riece-current-nickname)
 214                        (or channel riece-current-channel)
 215                        message type t)))
 216
 217 (provide 'riece-message)
 218
 219 ;;; riece-message.el ends here