cgit.sxemacs.org Git - riece/blob - lisp/riece-message.el

   1 ;;; riece-message.el --- generate and display message line
   2 ;; Copyright (C) 1999-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Keywords: message
   6
   7 ;; This file is part of Riece.
   8
   9 ;; This program is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; This program is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Code:
  25
  26 (require 'riece-identity)
  27 (require 'riece-channel)
  28 (require 'riece-user)
  29 (require 'riece-display)
  30 (require 'riece-misc)
  31
  32 (defgroup riece-message nil
  33   "Messages"
  34   :tag "Message"
  35   :prefix "riece-"
  36   :group 'riece)
  37
  38 (defcustom riece-message-filter-functions nil
  39   "Functions to filter incoming messages."
  40   :type 'function
  41   :group 'riece-message)
  42
  43 (defcustom riece-message-make-open-bracket-function
  44   #'riece-message-make-open-bracket
  45   "Function which makes `open-bracket' string for each message."
  46   :type 'function
  47   :group 'riece-message)
  48
  49 (defcustom riece-message-make-close-bracket-function
  50   #'riece-message-make-close-bracket
  51   "Function which makes `close-bracket' string for each message."
  52   :type 'function
  53   :group 'riece-message)
  54
  55 (defcustom riece-message-make-name-function
  56   #'riece-message-make-name
  57   "Function which makes local identity for each message."
  58   :type 'function
  59   :group 'riece-message)
  60
  61 (defcustom riece-message-make-global-name-function
  62   #'riece-message-make-global-name
  63   "Function which makes global identity for each message."
  64   :type 'function
  65   :group 'riece-message)
  66
  67 (defun riece-message-make-open-bracket (message)
  68   "Make `open-bracket' string for MESSAGE."
  69   (if (riece-message-own-p message)
  70       ">"
  71     (if (eq (riece-message-type message) 'notice)
  72         "{"
  73       (if (riece-message-private-p message)
  74           "="
  75         (if (riece-message-external-p message)
  76             "("
  77           "<")))))
  78
  79 (defun riece-message-make-close-bracket (message)
  80   "Make `close-bracket' string for MESSAGE."
  81   (if (riece-message-own-p message)
  82       "<"
  83     (if (eq (riece-message-type message) 'notice)
  84         "}"
  85       (if (riece-message-private-p message)
  86           "="
  87         (if (riece-message-external-p message)
  88             ")"
  89           ">")))))
  90
  91 (defun riece-message-make-name (message)
  92   "Make local identity for MESSAGE."
  93   (if (riece-message-private-p message)
  94       (if (riece-message-own-p message)
  95           (riece-format-identity (riece-message-target message) t)
  96         (riece-format-identity (riece-message-speaker message) t))
  97     (riece-format-identity (riece-message-speaker message) t)))
  98
  99 (defun riece-message-make-global-name (message)
 100   "Make global identity for MESSAGE."
 101   (if (riece-message-private-p message)
 102       (if (riece-message-own-p message)
 103           (riece-format-identity (riece-message-target message) t)
 104         (riece-format-identity (riece-message-speaker message) t))
 105     (concat (riece-format-identity (riece-message-target message) t) ":"
 106             (riece-format-identity (riece-message-speaker message) t))))
 107
 108 (defun riece-message-buffer (message)
 109   "Return the buffer where MESSAGE should appear."
 110   (let ((target (if (riece-message-private-p message)
 111                     (if (riece-message-own-p message)
 112                         (riece-message-target message)
 113                       (riece-message-speaker message))
 114                   (riece-message-target message))))
 115     (unless (riece-identity-member target riece-current-channels)
 116       (riece-join-channel target)
 117       ;; If you are not joined any channel,
 118       ;; switch to the target immediately.
 119       (unless riece-current-channel
 120         (riece-switch-to-channel target)))
 121     (riece-channel-buffer target)))
 122
 123 (defun riece-message-parent-buffers (message buffer)
 124   "Return the parents of BUFFER where MESSAGE should appear.
 125 Normally they are *Dialogue* and/or *Others*."
 126   (if (and buffer (riece-frozen buffer)) ;the message might not be
 127                                          ;visible in buffer's window
 128       (list riece-dialogue-buffer riece-others-buffer)
 129     (if (and riece-current-channel      ;the message is not sent to
 130                                         ;the current channel
 131              (if (riece-message-private-p message)
 132                  (if (riece-message-own-p message)
 133                      (not (riece-identity-equal
 134                            (riece-message-target message)
 135                            riece-current-channel))
 136                    (not (riece-identity-equal
 137                          (riece-message-speaker message)
 138                          riece-current-channel)))
 139                (not (riece-identity-equal
 140                      (riece-message-target message)
 141                      riece-current-channel))))
 142         (list riece-dialogue-buffer riece-others-buffer)
 143       riece-dialogue-buffer)))
 144
 145 (defun riece-format-message (message &optional global)
 146   (let ((open-bracket
 147          (funcall riece-message-make-open-bracket-function message))
 148         (close-bracket
 149          (funcall riece-message-make-close-bracket-function message))
 150         (name
 151          (if global
 152              (funcall riece-message-make-global-name-function message)
 153            (funcall riece-message-make-name-function message)))
 154         (server-name (riece-identity-server (riece-message-speaker message))))
 155     (riece-with-server-buffer (riece-current-server-name)
 156       (riece-concat-server-name
 157        (concat open-bracket name close-bracket
 158                " " (riece-message-text message) "\n")))))
 159
 160 (defun riece-display-message-1 (message)
 161   (let ((buffer (riece-message-buffer message))
 162         parent-buffers)
 163     (when (and buffer
 164                (riece-message-own-p message)
 165                (riece-own-frozen buffer))
 166       (with-current-buffer buffer
 167         (setq riece-freeze nil))
 168       (riece-emit-signal 'buffer-freeze-changed buffer nil))
 169     (setq parent-buffers (riece-message-parent-buffers message buffer))
 170     (riece-insert buffer (riece-format-message message))
 171     (riece-insert parent-buffers (riece-format-message message t))
 172     (run-hook-with-args 'riece-after-display-message-functions message)))
 173
 174 (defun riece-display-message (message)
 175   "Display MESSAGE object."
 176   (let ((functions riece-message-filter-functions))
 177     (setq message (copy-sequence message))
 178     (while functions
 179       (setq message (funcall (car functions) message)
 180             functions (cdr functions)))
 181     (if message
 182         (riece-display-message-1 message))))
 183
 184 (defun riece-make-message (speaker target text &optional type own-p)
 185   "Make an instance of message object.
 186 Arguments are appropriate to the sender, the receiver, and text
 187 content, respectively.
 188 Optional 4th argument TYPE specifies the type of the message.
 189 Currently possible values are `action' and `notice'.
 190 Optional 5th argument is the flag to indicate that this message is not
 191 from the network."
 192   (vector speaker target text type own-p))
 193
 194 (defun riece-message-speaker (message)
 195   "Return the sender of MESSAGE."
 196   (aref message 0))
 197
 198 (defun riece-message-target (message)
 199   "Return the receiver of MESSAGE."
 200   (aref message 1))
 201
 202 (defun riece-message-text (message)
 203   "Return the text part of MESSAGE."
 204   (aref message 2))
 205
 206 (defun riece-message-type (message)
 207   "Return the type of MESSAGE.
 208 Currently possible values are `action' and `notice'."
 209   (aref message 3))
 210
 211 (defun riece-message-own-p (message)
 212   "Return t if MESSAGE is not from the network."
 213   (aref message 4))
 214
 215 (defun riece-message-private-p (message)
 216   "Return t if MESSAGE is a private message."
 217   (not (or (riece-channel-p (riece-identity-prefix
 218                              (riece-message-speaker message)))
 219            (riece-channel-p (riece-identity-prefix
 220                              (riece-message-target message))))))
 221
 222 (defun riece-message-external-p (message)
 223   "Return t if MESSAGE is from outside the channel."
 224   (not (riece-identity-member
 225         (riece-message-speaker message)
 226         (let ((target (riece-message-target message)))
 227           (riece-with-server-buffer (riece-identity-server target)
 228             (mapcar
 229              (lambda (user)
 230                (riece-make-identity (car user) riece-server-name))
 231              (riece-channel-get-users (riece-identity-prefix target))))))))
 232
 233 (provide 'riece-message)
 234
 235 ;;; riece-message.el ends here