cgit.sxemacs.org Git - riece/blob - lisp/riece-menu.el

   1 ;;; riece-menu.el --- define command menu on menubar
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Created: 1998-09-28
   6 ;; Keywords: IRC, riece
   7
   8 ;; This file is part of Riece.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; To use, add the following line to your ~/.riece/init.el:
  28 ;; (add-to-list 'riece-addons 'riece-menu)
  29
  30 ;;; Code:
  31
  32 (defvar riece-menu-items
  33   `("Riece"
  34     ["Version" riece-version t]
  35     "----"
  36     ("Change Window Layout..." :filter riece-menu-create-layouts-menu)
  37     ["Toggle Freeze Channel Buffer"
  38      riece-command-toggle-freeze t]
  39     ["Toggle Freeze Channel Buffer Until Next Message"
  40      riece-command-toggle-own-freeze t]
  41     ["Toggle Display Channel Buffer"
  42      riece-command-toggle-channel-buffer-mode t]
  43     ["Toggle Display Channel List Buffer"
  44      riece-command-toggle-channel-list-buffer-mode t]
  45     ["Toggle Display User List Buffer"
  46      riece-command-toggle-user-list-buffer-mode t]
  47     "----"
  48     ["Join Channel" riece-command-join t]
  49     ["Change Nickname" riece-command-change-nickname t]
  50     ["Mark As Away" riece-command-toggle-away t]
  51     ["Quit IRC" riece-command-quit t]
  52     "----"
  53     ["Part Channel" riece-command-part riece-current-channel]
  54     ["Set Channel Topic" riece-command-topic riece-current-channel]
  55     ["Kick User" riece-command-kick riece-current-channel]
  56     ["Invite User" riece-command-invite riece-current-channel]
  57     "----"
  58     ("Channels" :filter riece-menu-create-channels-menu)
  59     ("Servers" :filter riece-menu-create-servers-menu))
  60   "Menu used in command mode.")
  61
  62 (defun riece-menu-create-layouts-menu (menu)
  63   (mapcar (lambda (entry)
  64             (vector (car entry) (list 'riece-command-change-layout (car entry))
  65                     t))
  66           riece-layout-alist))
  67
  68 (defun riece-menu-create-channels-menu (menu)
  69   (mapcar (lambda (channel)
  70             (list (riece-format-identity channel)
  71                   (vector "Switch To Channel"
  72                           (list 'riece-command-switch-to-channel channel) t)
  73                   (vector "Part Channel"
  74                           (list 'riece-command-part channel) t)
  75                   (vector "List Channel"
  76                           (list 'riece-command-list
  77                                 (riece-identity-prefix channel)) t)))
  78           riece-current-channels))
  79
  80 (defun riece-menu-create-servers-menu (menu)
  81   (mapcar (lambda (entry)
  82             (list (car entry)
  83                   (vector "Open Server"
  84                           (list 'riece-command-open-server (car entry))
  85                           (not (riece-server-opened (car entry))))
  86                   (vector "Close Server"
  87                           (list 'riece-command-close-server (car entry))
  88                           (riece-server-opened (car entry)))))
  89           riece-server-alist))
  90
  91 (defun riece-menu-insinuate ()
  92   (add-hook 'riece-command-mode-hook
  93             (lambda ()
  94               (easy-menu-define riece-menu
  95                                 riece-command-mode-map
  96                                 "Riece Menu"
  97                                 riece-menu-items)
  98               (easy-menu-add riece-menu))))
  99
 100 (provide 'riece-menu)
 101
 102 ;;; riece-menu.el ends here