cgit.sxemacs.org Git - riece/blob - lisp/riece-log.el

   1 ;;; riece-log.el --- saving irc logs add-on
   2 ;; Copyright (C) 2003 OHASHI Akira
   3
   4 ;; Author: OHASHI Akira <bg66@koka-in.org>
   5 ;; Keywords: IRC, riece
   6
   7 ;; This file is part of Riece.
   8
   9 ;; This program is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; This program is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; This add-on saves irc logs for every channel.
  27
  28 ;; To use, add the following line to your ~/.riece/init.el:
  29 ;; (add-to-list 'riece-addons 'riece-log)
  30
  31 ;;; Code:
  32
  33 (eval-when-compile (require 'riece-message))
  34
  35 (defgroup riece-log nil
  36   "Save irc log"
  37   :group 'riece)
  38
  39 (defcustom riece-log-directory
  40   (expand-file-name "log" riece-directory)
  41   "*Where to look for log files."
  42   :type 'directory
  43   :group 'riece-log)
  44
  45 (defcustom riece-log-directory-map nil
  46   "*The map of channel name and directory name."
  47   :type '(repeat (cons (string :tag "Channel name")
  48                        (string :tag "Directory name")))
  49   :group 'riece-log)
  50
  51 (defcustom riece-log-flashback 10
  52   "*If non-nil, irc messages flash back from log files.
  53 If integer, flash back only this line numbers. t means all lines."
  54   :type '(choice (integer :tag "line numbers")
  55                  (boolean :tag "flash back or not"))
  56   :group 'riece-log)
  57
  58 (defun riece-log-display-message-function (message)
  59   (let ((open-bracket
  60          (funcall riece-message-make-open-bracket-function message))
  61         (close-bracket
  62          (funcall riece-message-make-close-bracket-function message))
  63         (name
  64          (funcall riece-message-make-name-function message))
  65         (file (riece-log-get-file (riece-message-target message))))
  66     (unless (file-directory-p (file-name-directory file))
  67       (make-directory (file-name-directory file) t))
  68     (with-temp-buffer
  69       (insert (concat (format-time-string "%H:%M") " "
  70                       open-bracket name close-bracket
  71                       " " (riece-message-text message) "\n"))
  72       (write-region (point-min) (point-max) file t 0))))
  73
  74 (defun riece-log-get-file (identity)
  75   (expand-file-name
  76    (concat (format-time-string "%Y%m%d") ".log")
  77    (riece-log-get-directory identity)))
  78
  79 (defun riece-log-get-directory (identity)
  80   (let ((channel (riece-identity-prefix identity))
  81         (server (riece-identity-server identity)))
  82     (let ((map (assoc channel riece-log-directory-map)))
  83       (if map
  84           (expand-file-name (cdr map) riece-log-directory)
  85         (if (string-match riece-channel-regexp channel)
  86             (let ((name (substring channel
  87                                    (match-end 1) (match-beginning 2)))
  88                   (suffix (match-string 2 channel)))
  89               (when (and (stringp suffix)
  90                          (string-match "^:\\*\\.\\(.*\\)" suffix))
  91                 (setq name (concat name "-" (match-string 1 suffix))))
  92               (if server
  93                   (expand-file-name
  94                    name
  95                    (expand-file-name server riece-log-directory))
  96                 (expand-file-name name riece-log-directory)))
  97           riece-log-directory)))))
  98
  99 (defun riece-log-flashback (identity)
 100   (when riece-log-flashback
 101     (let ((file (riece-log-get-file identity)))
 102       (when (file-exists-p file)
 103         (let (string)
 104           (with-temp-buffer
 105             (insert-file-contents file)
 106             (if (not (integerp riece-log-flashback))
 107                 (goto-char (point-min))
 108               (goto-char (point-max))
 109               (forward-line (- riece-log-flashback)))
 110             (setq string (buffer-substring (point) (point-max))))
 111           (let (buffer-read-only)
 112             (goto-char (point-max))
 113             (insert string)
 114             (goto-char (point-max))
 115             (set-window-point (get-buffer-window (current-buffer))
 116                               (point))))))))
 117
 118 (defun riece-log-open-directory (&optional channel)
 119   (interactive)
 120   (if channel
 121       (find-file (riece-log-get-directory channel))
 122     (find-file riece-log-directory)))
 123
 124 (defun riece-log-insinuate ()
 125   ;; FIXME: Use `riece-after-insert-functions' for trapping change,
 126   ;; notice, wallops and so on. But must add argument.
 127   (add-hook 'riece-after-display-message-functions
 128             'riece-log-display-message-function)
 129   (add-hook 'riece-channel-buffer-create-functions
 130             'riece-log-flashback))
 131
 132 (provide 'riece-log)
 133
 134 ;;; riece-log.el ends here