cgit.sxemacs.org Git - riece/blob - lisp/riece-layout.el

   1 ;;; riece-layout.el --- layout management
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;;      TAKAHASHI "beatmaria" Kaoru <kaoru@kaisei.org>
   6 ;; Keywords: IRC, riece
   7
   8 ;; This file is part of Riece.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Code:
  26
  27 (require 'riece-globals)
  28 (require 'riece-misc)
  29
  30 (defgroup riece-layout nil
  31   "Manage window layouts"
  32   :prefix "riece-"
  33   :group 'riece)
  34
  35 (defcustom riece-layout "default"
  36   "Current layout setting."
  37   :type 'string
  38   :group 'riece-layout)
  39
  40 (defcustom riece-layout-alist
  41   '(("middle-right" riece-configure-windows right middle)
  42     ("middle-left" riece-configure-windows left middle)
  43     ("top-right" riece-configure-windows right top)
  44     ("top-left" riece-configure-windows left top)
  45     ("bottom-right" riece-configure-windows right bottom)
  46     ("bottom-left" riece-configure-windows left bottom)
  47     ("top" riece-configure-windows-top)
  48     ("default" . "middle-right"))
  49   "An alist mapping the names to layout functions.
  50 An element of this alist is either in the following forms:
  51
  52 (NAME CONFIGURE-FUNCTION [PARAMETERS])
  53 (NAME1 . NAME2)
  54
  55 In the first form, NAME is a string which specifies the layout
  56 setting, and CONFIGURE-FUNCTION is a function which does window
  57 splitting, etc.  PARAMETERS are collected and passed to CONFIGURE-FUNCTION.
  58 In the second form, NAME1 is an alias for NAME2."
  59   :type 'list
  60   :group 'riece-layout)
  61
  62 (defun riece-redraw-layout (&optional force)
  63   "Reconfigure windows with the current layout.
  64 If optional argument FORCE is non-nil, window reconfiguration will
  65 happen unconditionally."
  66   (let ((layout (cdr (assoc riece-layout riece-layout-alist))))
  67     (unless layout
  68       (error "No such layout!"))
  69     (if (stringp layout)
  70         (let ((riece-layout layout))
  71           (riece-redraw-layout force))
  72       (if (or force
  73               (riece-reconfigure-windows-predicate))
  74           (apply (car layout) (cdr layout))))))
  75
  76 (defun riece-set-window-points ()
  77   (if (get-buffer-window riece-user-list-buffer)
  78       (with-current-buffer riece-user-list-buffer
  79         (unless (riece-frozen riece-user-list-buffer)
  80           (set-window-start (get-buffer-window riece-user-list-buffer)
  81                             (point-min)))))
  82   (if (get-buffer-window riece-channel-list-buffer)
  83       (with-current-buffer riece-channel-list-buffer
  84         (unless (riece-frozen riece-channel-list-buffer)
  85           (set-window-start (get-buffer-window riece-channel-list-buffer)
  86                             (point-min)))))
  87   (if (and riece-channel-buffer
  88            (get-buffer-window riece-channel-buffer))
  89       (with-current-buffer riece-channel-buffer
  90         (unless (riece-frozen riece-channel-buffer)
  91           (set-window-point (get-buffer-window riece-channel-buffer)
  92                             (point-max)))))
  93   (if (get-buffer-window riece-others-buffer)
  94       (with-current-buffer riece-others-buffer
  95         (unless (riece-frozen riece-others-buffer)
  96           (set-window-point (get-buffer-window riece-others-buffer)
  97                             (point-max)))))
  98   (if (get-buffer-window riece-dialogue-buffer)
  99       (with-current-buffer riece-dialogue-buffer
 100         (unless (riece-frozen riece-dialogue-buffer)
 101           (set-window-point (get-buffer-window riece-dialogue-buffer)
 102                             (point-max))))))
 103
 104 (defun riece-reconfigure-windows-predicate ()
 105   "Return t, if window reconfiguration is needed.
 106 This function is used by \"default\" layout."
 107   (memq (window-buffer (selected-window))
 108         riece-buffer-list))
 109
 110 (defun riece-configure-windows (hpos vpos)
 111   (let ((buffer (window-buffer))
 112         (show-user-list
 113          (and riece-user-list-buffer-mode
 114               riece-current-channel
 115               ;; User list buffer is nuisance for private conversation.
 116               (riece-channel-p (riece-identity-prefix
 117                                 riece-current-channel)))))
 118     ;; Can't expand minibuffer to full frame.
 119     (if (eq (selected-window) (minibuffer-window))
 120         (other-window 1))
 121     (delete-other-windows)
 122     (if (and riece-current-channel
 123              (or show-user-list riece-channel-list-buffer-mode))
 124         (let ((rest-window (split-window (selected-window)
 125                                          (if (eq hpos 'left)
 126                                              (- (window-width)
 127                                                 (/ (window-width) 5))
 128                                            (/ (window-width) 5))
 129                                          t)))
 130           (when (eq hpos 'left)
 131             (setq rest-window (selected-window))
 132             (other-window 1))
 133           (if (and show-user-list riece-channel-list-buffer-mode)
 134               (progn
 135                 (set-window-buffer (split-window)
 136                                    riece-channel-list-buffer)
 137                 (set-window-buffer (selected-window)
 138                                    riece-user-list-buffer))
 139             (if show-user-list
 140                 (set-window-buffer (selected-window)
 141                                    riece-user-list-buffer)
 142               (if riece-channel-list-buffer-mode
 143                   (set-window-buffer (selected-window)
 144                                      riece-channel-list-buffer))))
 145           (select-window rest-window)))
 146     (if (and riece-current-channel
 147              riece-channel-buffer-mode)
 148         (progn
 149           (if (eq vpos 'top)
 150               (let ((rest-window (split-window nil 4)))
 151                 (set-window-buffer (selected-window)
 152                                    riece-command-buffer)
 153                 (select-window rest-window)
 154                 (set-window-buffer (split-window rest-window)
 155                                    riece-others-buffer)
 156                 (set-window-buffer (selected-window)
 157                                    riece-channel-buffer))
 158             (if (eq vpos 'middle)
 159                 (let ((rest-window (split-window)))
 160                   (set-window-buffer (selected-window)
 161                                      riece-channel-buffer)
 162                   (set-window-buffer (split-window rest-window 4)
 163                                      riece-others-buffer)
 164                   (set-window-buffer rest-window
 165                                      riece-command-buffer))
 166               (let ((rest-window (split-window nil (- (window-height) 4))))
 167                 (set-window-buffer (selected-window)
 168                                    riece-others-buffer)
 169                 (set-window-buffer (split-window)
 170                                    riece-channel-buffer)
 171                 (set-window-buffer rest-window
 172                                    riece-command-buffer))))
 173           (with-current-buffer riece-channel-buffer
 174             (setq truncate-partial-width-windows nil))
 175           (with-current-buffer riece-others-buffer
 176             (setq truncate-partial-width-windows nil)))
 177       (if (eq vpos 'bottom)
 178           (progn
 179             (set-window-buffer (selected-window)
 180                                riece-command-buffer)
 181             (set-window-buffer (split-window (selected-window) 4)
 182                                riece-dialogue-buffer))
 183         (set-window-buffer (split-window (selected-window) 4)
 184                            riece-dialogue-buffer)
 185         (set-window-buffer (selected-window)
 186                            riece-command-buffer)))
 187     (riece-set-window-points)
 188     (select-window (or (get-buffer-window buffer)
 189                        (get-buffer-window riece-command-buffer)))))
 190
 191 (defun riece-configure-windows-top (&rest plist)
 192   "Candidate of `riece-configure-windows-function'.
 193 PLIST accept :command-height, :user-list-width, and :channel-list-width."
 194   (let ((command-height (or (plist-get plist :command-height) 4))
 195         (user-list-width (or (plist-get plist :user-list-width) (+ 9 1 1)))
 196         (channel-list-width (or (plist-get plist :channel-list-width) 18))
 197         (buffer (window-buffer))
 198         (show-user-list
 199          (and riece-user-list-buffer-mode
 200               riece-current-channel
 201               ;; User list buffer is nuisance for private conversation.
 202               (riece-channel-p (riece-identity-prefix
 203                                 riece-current-channel)))))
 204     ;; Can't expand minibuffer to full frame.
 205     (when (eq (selected-window) (minibuffer-window))
 206       (other-window 1))
 207     (delete-other-windows)
 208     ;; top of frame
 209     (let ((rest-window (split-window (selected-window) command-height)))
 210       (set-window-buffer (selected-window)
 211                          riece-command-buffer)
 212       (select-window rest-window))
 213     ;; middle of frame (vertical-spilit when need)
 214     (when (or (and riece-current-channel riece-channel-buffer-mode)
 215               show-user-list)
 216       (let ((rest-window
 217              (split-window (selected-window)
 218                            (/ (* 5 (+ (window-height) command-height)) 8))))
 219         (cond
 220          ;; channel-buffer + user-list
 221          ((and show-user-list
 222                (and riece-current-channel riece-channel-buffer-mode))
 223           (let ((user-list-window (split-window (selected-window) nil t)))
 224             (set-window-buffer (selected-window) riece-channel-buffer)
 225             (set-window-buffer user-list-window riece-user-list-buffer)
 226             (select-window user-list-window)
 227             (shrink-window-horizontally (- (window-width) user-list-width))
 228             (setq truncate-partial-width-windows nil)))
 229          ;; only user-list
 230          (show-user-list
 231           (set-window-buffer (selected-window) riece-user-list-buffer))
 232          ;; only channel-buffer
 233          (riece-channel-buffer-mode
 234           (set-window-buffer (selected-window) riece-channel-buffer)))
 235         (select-window rest-window)))
 236     ;; bottom of frame
 237     (if (and riece-current-channel
 238              riece-channel-list-buffer-mode)
 239         (let ((channel-list-window (split-window (selected-window) nil t)))
 240           (set-window-buffer (selected-window) riece-others-buffer)
 241           (set-window-buffer channel-list-window riece-channel-list-buffer)
 242           (select-window channel-list-window)
 243           (shrink-window-horizontally (- (window-width) channel-list-width))
 244           (setq truncate-partial-width-windows nil))
 245       (set-window-buffer (selected-window) riece-dialogue-buffer))
 246     (riece-set-window-points)
 247     (select-window (or (get-buffer-window buffer)
 248                        (get-buffer-window riece-command-buffer)))))
 249
 250 (provide 'riece-layout)
 251
 252 ;;; riece-layout.el ends here