cgit.sxemacs.org Git - riece/blob - lisp/riece-keyword.el

   1 ;;; riece-keyword.el --- highlight keywords in channel buffers
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Created: 1998-09-28
   6 ;; Keywords: IRC, riece
   7
   8 ;; This file is part of Riece.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; To use, add the following line to your ~/.riece/init.el:
  28 ;; (add-to-list 'riece-addons 'riece-keyword)
  29
  30 ;;; Code:
  31
  32 (require 'riece-message)
  33
  34 (defgroup riece-keyword nil
  35   "Highlight keyword in IRC buffer."
  36   :group 'riece)
  37
  38 (defcustom riece-keywords nil
  39   "Keywords to be highlightened."
  40   :type '(repeat (choice (string :tag "Keyword")
  41                          (cons (string :tag "Regexp")
  42                                (integer :tag "Match"))))
  43   :group 'riece-keyword)
  44
  45 (defcustom riece-notify-keyword-functions nil
  46   "Functions used to notify keyword match."
  47   :type '(list function)
  48   :group 'riece-keyword)
  49
  50 (make-obsolete-variable 'riece-notify-keyword-functions
  51                         'riece-keyword-notify-functions)
  52
  53 (defcustom riece-keyword-notify-functions nil
  54   "Functions used to notify keyword match.
  55 Two arguments are passed to each function: the keyword used to match
  56 and the matched message object."
  57   :type '(list function)
  58   :group 'riece-keyword)
  59
  60 (defface riece-keyword-face
  61   '((((class color))
  62      (:foreground "red" :underline t))
  63     (t
  64      ()))
  65   "Face used for highlightening matching keyword."
  66   :group 'riece-highlight-faces)
  67 (defvar riece-keyword-face 'riece-keyword-face)
  68
  69 (defvar riece-keyword-enabled nil)
  70
  71 (defconst riece-keyword-description
  72   "Highlight keywords in IRC buffers")
  73
  74 ;;; The old XEmacs package doesn't have autoload setting for regexp-opt.
  75 (autoload 'regexp-opt "regexp-opt")
  76 (defun riece-keyword-message-filter (message)
  77   (if (and riece-keyword-enabled
  78            riece-keywords
  79            ;; Ignore messages which belongs to myself.
  80            (not (riece-message-own-p message)))
  81       (let* (keywords
  82              (alist
  83               (nconc
  84                (delq nil (mapcar
  85                           (lambda (matcher)
  86                             (if (stringp matcher)
  87                                 (ignore
  88                                  (setq keywords (cons matcher keywords)))
  89                               matcher))
  90                           riece-keywords))
  91                (list (cons (regexp-opt keywords) 0))))
  92              index)
  93         (while alist
  94           (setq index 0)
  95           (while (string-match (car (car alist))
  96                                (riece-message-text message) index)
  97             (put-text-property (match-beginning (cdr (car alist)))
  98                                (match-end (cdr (car alist)))
  99                                'riece-overlay-face riece-keyword-face
 100                                (riece-message-text message))
 101             (run-hook-with-args 'riece-notify-keyword-functions
 102                                 (match-string (cdr (car alist))
 103                                               (riece-message-text message)))
 104             (run-hook-with-args 'riece-keyword-notify-functions
 105                                 (cdr (car alist))
 106                                 message)
 107             (setq index (match-end (cdr (car alist)))))
 108           (setq alist (cdr alist)))))
 109   message)
 110
 111 (defun riece-keyword-requires ()
 112   (if (memq 'riece-highlight riece-addons)
 113       '(riece-highlight)))
 114
 115 (defun riece-keyword-insinuate ()
 116   (add-hook 'riece-message-filter-functions 'riece-keyword-message-filter))
 117
 118 (defun riece-keyword-enable ()
 119   (setq riece-keyword-enabled t))
 120
 121 (defun riece-keyword-disable ()
 122   (setq riece-keyword-enabled nil))
 123
 124 (provide 'riece-keyword)
 125
 126 ;;; riece-keyword.el ends here