cgit.sxemacs.org Git - riece/blob - lisp/riece-ignore.el

   1 ;;; riece-ignore.el --- ignore user
   2 ;; Copyright (C) 1998-2004 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Created: 1998-09-28
   6 ;; Keywords: IRC, riece
   7
   8 ;; This file is part of Riece.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; To use, add the following line to your ~/.riece/init.el:
  28 ;; (add-to-list 'riece-addons 'riece-ignore)
  29
  30 ;;; Code:
  31
  32 (require 'riece-signal)
  33 (require 'riece-identity)
  34 (require 'riece-message)
  35
  36 (defgroup riece-ignore nil
  37   "Ignore messages in IRC buffers."
  38   :group 'riece)
  39
  40 (defcustom riece-ignore-discard-message 'log
  41   "If t, messages from ignored user are completely discarded.
  42 If 'log, messages are removed from IRC buffers, but they are saved in
  43 `riece-ignore-buffer'.
  44 Otherwise, they are not removed from IRC buffers, but are hidden with
  45 'invisible text-property."
  46   :group 'riece-ignore
  47   :type '(choice (const :tag "Discard completely" t)
  48                  (const :tag "Discard but save logs" log)
  49                  (const :tag "Make messages invisible" nil)))
  50
  51 (defcustom riece-ignore-buffer-name "*Ignore*"
  52   "The name of buffer where ignored messages are stored."
  53   :group 'riece-ignore
  54   :type 'string)
  55
  56 (defvar riece-ignore-buffer nil)
  57 (defvar riece-ignored-user-list nil)
  58
  59 (defun riece-ignore-user-rename-signal-function (signal handback)
  60   (let ((pointer (riece-identity-member (car (riece-signal-args signal))
  61                                         riece-ignored-user-list)))
  62     (if pointer
  63         (setcar pointer (nth 1 (riece-signal-args signal))))))
  64
  65 (defun riece-ignore-user (user toggle)
  66   (interactive
  67    (let ((completion-ignore-case t))
  68      (list (if current-prefix-arg
  69                (riece-completing-read-identity
  70                 "Unignore user: "
  71                 riece-ignored-user-list)
  72              (riece-completing-read-identity
  73               "Ignore user: "
  74               (riece-get-users-on-server (riece-current-server-name))
  75               (lambda (user)
  76                 (not (riece-identity-member
  77                       (riece-parse-identity (car user))
  78                       riece-ignored-user-list)))))
  79            (not current-prefix-arg))))
  80   (if toggle
  81       (progn
  82         (setq riece-ignored-user-list (cons user riece-ignored-user-list))
  83         (riece-connect-signal
  84          'user-renamed
  85          #'riece-ignore-user-rename-signal-function))
  86     (let ((pointer (riece-identity-member user riece-ignored-user-list)))
  87       (setq riece-ignored-user-list (delq (car pointer)
  88                                           riece-ignored-user-list))
  89       (riece-disconnect-signal
  90        'user-renamed
  91        #'riece-ignore-user-rename-signal-function))))
  92
  93 (defun riece-ignore-message-filter (message)
  94   (if (riece-identity-member (riece-message-speaker message)
  95                              riece-ignored-user-list)
  96       (if riece-ignore-discard-message
  97           (when (eq riece-ignore-discard-message 'log)
  98             (unless riece-ignore-buffer
  99               (with-current-buffer (setq riece-ignore-buffer
 100                                          (riece-get-buffer-create
 101                                           riece-ignore-buffer-name
 102                                           'riece-dialogue-mode))
 103                 (riece-dialogue-mode)))
 104             (save-excursion
 105               (set-buffer riece-ignore-buffer)
 106               (goto-char (point-max))
 107               (let ((inhibit-read-only t)
 108                     buffer-read-only)
 109                 (insert (concat (format-time-string "%H:%M") " "
 110                                 (riece-format-message message t))))))
 111         (put-text-property 0 (length (riece-message-text message))
 112                            'invisible 'riece-ignore
 113                            (riece-message-text message))
 114         message)
 115     message))
 116
 117 (defvar riece-command-mode-map)
 118 (defun riece-ignore-insinuate ()
 119   (add-hook 'riece-message-filter-functions 'riece-ignore-message-filter)
 120   (define-key riece-command-mode-map
 121     "\C-ck" 'riece-ignore-user))
 122
 123 (provide 'riece-ignore)
 124
 125 ;;; riece-ignore.el ends here