cgit.sxemacs.org Git - riece/blob - lisp/riece-ignore.el

   1 ;;; riece-ignore.el --- ignore user
   2 ;; Copyright (C) 1998-2004 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Created: 1998-09-28
   6 ;; Keywords: IRC, riece
   7
   8 ;; This file is part of Riece.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; To use, add the following line to your ~/.riece/init.el:
  28 ;; (add-to-list 'riece-addons 'riece-ignore)
  29
  30 ;;; Code:
  31
  32 (require 'riece-signal)
  33 (require 'riece-identity)
  34 (require 'riece-message)
  35
  36 (defgroup riece-ignore nil
  37   "Ignore messages in IRC buffers."
  38   :group 'riece)
  39
  40 (defcustom riece-ignore-discard-message 'log
  41   "If t, messages from ignored user are completely discarded.
  42 If 'log, messages are removed from IRC buffers, but they are saved in
  43 `riece-ignore-buffer'.
  44 Otherwise, they are not removed from IRC buffers, but are hidden with
  45 'invisible text-property."
  46   :group 'riece-ignore
  47   :type '(choice (const :tag "Discard completely" t)
  48                  (const :tag "Discard but save logs" log)
  49                  (const :tag "Make messages invisible" nil)))
  50
  51 (defcustom riece-ignore-buffer-name "*Ignore*"
  52   "The name of buffer where ignored messages are stored."
  53   :group 'riece-ignore
  54   :type 'string)
  55
  56 (defvar riece-ignore-buffer nil)
  57 (defvar riece-ignored-user-list nil)
  58
  59 (defvar riece-ignore-enabled nil)
  60
  61 (defconst riece-ignore-description
  62   "Ignore users")
  63
  64 (defun riece-ignore-user-rename-signal-function (signal handback)
  65   (let ((pointer (riece-identity-member (car (riece-signal-args signal))
  66                                         riece-ignored-user-list)))
  67     (if pointer
  68         (setcar pointer (nth 1 (riece-signal-args signal))))))
  69
  70 (defun riece-ignore-user (user toggle)
  71   (interactive
  72    (let ((completion-ignore-case t))
  73      (list (if current-prefix-arg
  74                (riece-completing-read-identity
  75                 "Unignore user: "
  76                 riece-ignored-user-list)
  77              (riece-completing-read-identity
  78               "Ignore user: "
  79               (riece-get-users-on-server (riece-current-server-name))
  80               (lambda (user)
  81                 (not (riece-identity-member
  82                       (riece-parse-identity (car user))
  83                       riece-ignored-user-list)))))
  84            (not current-prefix-arg))))
  85   (if toggle
  86       (progn
  87         (setq riece-ignored-user-list (cons user riece-ignored-user-list))
  88         (riece-connect-signal
  89          'user-renamed
  90          #'riece-ignore-user-rename-signal-function))
  91     (let ((pointer (riece-identity-member user riece-ignored-user-list)))
  92       (setq riece-ignored-user-list (delq (car pointer)
  93                                           riece-ignored-user-list))
  94       (riece-disconnect-signal
  95        'user-renamed
  96        #'riece-ignore-user-rename-signal-function))))
  97
  98 (defun riece-ignore-message-filter (message)
  99   (if (and riece-ignore-enabled
 100            (riece-identity-member (riece-message-speaker message)
 101                                   riece-ignored-user-list))
 102       (if riece-ignore-discard-message
 103           (when (eq riece-ignore-discard-message 'log)
 104             (unless riece-ignore-buffer
 105               (with-current-buffer (setq riece-ignore-buffer
 106                                          (riece-get-buffer-create
 107                                           riece-ignore-buffer-name
 108                                           'riece-dialogue-mode))
 109                 (riece-dialogue-mode)))
 110             (save-excursion
 111               (set-buffer riece-ignore-buffer)
 112               (goto-char (point-max))
 113               (let ((inhibit-read-only t)
 114                     buffer-read-only)
 115                 (insert (concat (format-time-string "%H:%M") " "
 116                                 (riece-format-message message t))))))
 117         (put-text-property 0 (length (riece-message-text message))
 118                            'invisible 'riece-ignore
 119                            (riece-message-text message))
 120         message)
 121     message))
 122
 123 (defvar riece-command-mode-map)
 124 (defun riece-ignore-insinuate ()
 125   (add-hook 'riece-message-filter-functions 'riece-ignore-message-filter))
 126
 127 (defun riece-ignore-enable ()
 128   (define-key riece-command-mode-map
 129     "\C-ck" 'riece-ignore-user)
 130   (setq riece-ignore-enabled t))
 131
 132 (defun riece-ignore-disable ()
 133   (define-key riece-command-mode-map
 134     "\C-ck" nil)
 135   (setq riece-ignore-enabled nil))
 136
 137 (provide 'riece-ignore)
 138
 139 ;;; riece-ignore.el ends here