cgit.sxemacs.org Git - riece/blob - lisp/riece-highlight.el

   1 ;;; riece-highlight.el --- highlight IRC buffers
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Created: 1998-09-28
   6 ;; Keywords: IRC, riece
   7
   8 ;; This file is part of Riece.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Code:
  26
  27 (require 'riece-globals)
  28 (require 'riece-options)                ;riece-channel-list-buffer-mode
  29 (require 'riece-identity)               ;riece-format-identity
  30 (require 'font-lock)
  31
  32 (defgroup riece-highlight nil
  33   "Highlight IRC buffers"
  34   :tag "Highlight"
  35   :prefix "riece-"
  36   :group 'riece)
  37
  38 (defgroup riece-highlight-faces nil
  39   "Faces for highlight IRC buffers"
  40   :tag "Faces"
  41   :prefix "riece-highlight-"
  42   :group 'riece-highlight)
  43
  44 (defface riece-dialogue-change-face
  45   '((((class color)
  46       (background dark))
  47      (:foreground "cyan" :bold t))
  48     (((class color)
  49       (background light))
  50      (:foreground "RoyalBlue" :bold t))
  51     (t
  52      (:bold t)))
  53   "Face used for displaying \"*** Change:\" line"
  54   :group 'riece-highlight-faces)
  55 (defvar riece-dialogue-change-face 'riece-dialogue-change-face)
  56
  57 (defface riece-dialogue-notice-face
  58   '((((class color)
  59       (background dark))
  60      (:foreground "green2" :bold t))
  61     (((class color)
  62       (background light))
  63      (:foreground "MidnightBlue" :bold t))
  64     (t
  65      (:bold t)))
  66   "Face used for displaying \"*** Notice:\" line"
  67   :group 'riece-highlight-faces)
  68 (defvar riece-dialogue-notice-face 'riece-dialogue-notice-face)
  69
  70 (defface riece-dialogue-wallops-face
  71   '((((class color)
  72       (background dark))
  73      (:foreground "yellow" :bold t))
  74     (((class color)
  75       (background light))
  76      (:foreground "blue4" :bold t))
  77     (t
  78      (:bold t)))
  79   "Face used for displaying \"*** Wallops:\" line"
  80   :group 'riece-highlight-faces)
  81 (defvar riece-dialogue-wallops-face 'riece-dialogue-wallops-face)
  82
  83 (defface riece-dialogue-error-face
  84   '((((class color)
  85       (background dark))
  86      (:foreground "cornflower blue" :bold t))
  87     (((class color)
  88       (background light))
  89      (:foreground "DarkGreen"))
  90     (t
  91      (:bold t)))
  92   "Face used for displaying \"*** Error:\" line"
  93   :group 'riece-highlight-faces)
  94 (defvar riece-dialogue-error-face 'riece-dialogue-error-face)
  95
  96 (defface riece-dialogue-info-face
  97   '((((class color)
  98       (background dark))
  99      (:foreground "PaleTurquoise" :bold t))
 100     (((class color)
 101       (background light))
 102      (:foreground "RoyalBlue"))
 103     (t
 104      (:bold t)))
 105   "Face used for displaying \"*** Info:\" line"
 106   :group 'riece-highlight-faces)
 107 (defvar riece-dialogue-info-face 'riece-dialogue-info-face)
 108
 109 (defface riece-dialogue-server-face
 110   '((((class color)
 111       (background dark))
 112      (:foreground "Gray70"))
 113     (((class color)
 114       (background light))
 115      (:foreground "DimGray"))
 116     (t
 117      (:bold t)))
 118   "Face used for displaying \"(from server)\" extent."
 119   :group 'riece-highlight-faces)
 120 (defvar riece-dialogue-server-face 'riece-dialogue-server-face)
 121
 122 (defface riece-dialogue-prefix-face
 123   '((((class color)
 124       (background dark))
 125      (:foreground "moccasin"))
 126     (((class color)
 127       (background light))
 128      (:foreground "firebrick"))
 129     (t
 130      (:bold nil)))
 131   "Face used for displaying \"<nick>\" extent"
 132   :group 'riece-highlight-faces)
 133 (defvar riece-dialogue-prefix-face 'riece-dialogue-prefix-face)
 134
 135 (defcustom riece-dialogue-font-lock-keywords
 136   (append
 137    (list (list (concat "^" riece-time-prefix-regexp
 138                        "\\(<[^>]+>\\|>[^<]+<\\|([^)]+)\\|{[^}]+}\\|=[^=]+=\\)")
 139                '(1 riece-dialogue-prefix-face append t)))
 140    ;; set property to the whole line
 141    (mapcar
 142     (lambda (line)
 143       (cons
 144        (concat
 145         "^" riece-time-prefix-regexp "\\("
 146         (regexp-quote
 147          (symbol-value (intern (format "riece-%s-prefix" line))))
 148         ".*\\)$")
 149        (list 1 (intern (format "riece-dialogue-%s-face" line)) t t)))
 150     '(change notice wallops error info))
 151    (list (list "(from [^)]+)$" 0 riece-dialogue-server-face t)))
 152   "Default expressions to highlight in riece-dialogue-mode."
 153   :type '(repeat (list string))
 154   :group 'riece-highlight)
 155
 156 (defface riece-channel-list-default-face
 157   '((t ()))
 158   "Face used for displaying channels."
 159   :group 'riece-highlight-faces)
 160 (defvar riece-channel-list-default-face 'riece-channel-list-default-face)
 161
 162 (defface riece-channel-list-current-face
 163   '((((class color)
 164       (background dark))
 165      (:foreground "turquoise" :underline t))
 166     (((class color)
 167       (background light))
 168      (:foreground "SeaGreen" :underline t))
 169     (t
 170      ()))
 171   "Face used for displaying the current channel."
 172   :group 'riece-highlight-faces)
 173 (defvar riece-channel-list-current-face 'riece-channel-list-current-face)
 174
 175 (defcustom riece-channel-list-mark-face-alist
 176   '((?* . riece-channel-list-current-face))
 177   "An alist mapping marks on riece-channel-list-buffer to faces."
 178   :type 'list
 179   :group 'riece-highlight)
 180
 181 (defcustom riece-channel-list-font-lock-keywords
 182   '(("^[ 0-9][0-9]:\\(.\\)\\(.*\\)"
 183      (2 (or (cdr (assq (aref (match-string 1) 0)
 184                        riece-channel-list-mark-face-alist))
 185             riece-channel-list-default-face))))
 186   "Default expressions to highlight in riece-channel-list-mode."
 187   :type '(repeat (list string))
 188   :group 'riece-highlight)
 189
 190 (defvar riece-highlight-enabled nil)
 191
 192 (defconst riece-highlight-description
 193   "Highlight IRC buffers")
 194
 195 (defun riece-highlight-setup-dialogue ()
 196   (if (featurep 'xemacs)
 197       ;; In XEmacs, auto-initialization of font-lock is not affective
 198       ;; when buffer-file-name is not set.
 199       (font-lock-set-defaults)
 200     (make-local-variable 'font-lock-defaults)
 201     (setq font-lock-defaults '(riece-dialogue-font-lock-keywords t)))
 202   (make-local-hook 'after-change-functions)
 203   (add-hook 'after-change-functions
 204             'riece-highlight-hide-prefix nil 'local))
 205
 206 (defun riece-highlight-setup-channel-list ()
 207   (if (featurep 'xemacs)
 208       ;; In XEmacs, auto-initialization of font-lock is not affective
 209       ;; when buffer-file-name is not set.
 210       (font-lock-set-defaults)
 211     (make-local-variable 'font-lock-defaults)
 212     (setq font-lock-defaults '(riece-channel-list-font-lock-keywords t))))
 213
 214 (defun riece-highlight-hide-prefix (start end length)
 215   (save-excursion
 216     (goto-char start)
 217     (if (looking-at riece-prefix-regexp)
 218         (put-text-property (match-beginning 1) (match-end 1) 'invisible t))))
 219
 220 (defun riece-highlight-put-overlay-faces (start end)
 221   (if riece-highlight-enabled
 222       (riece-scan-property-region
 223        'riece-overlay-face
 224        start end
 225        (lambda (start end)
 226          (riece-overlay-put (riece-make-overlay start end)
 227                             'face
 228                             (get-text-property start 'riece-overlay-face))))))
 229
 230 (defun riece-highlight-format-identity-for-channel-list-indicator (index
 231                                                                    identity)
 232   (if (and riece-highlight-enabled
 233            (riece-identity-equal identity riece-current-channel))
 234       (let ((string (riece-format-identity identity))
 235             (start 0))
 236         ;; Escape % -> %%.
 237         (while (string-match "%" string start)
 238           (setq start (1+ (match-end 0))
 239                 string (replace-match "%%" nil nil string)))
 240         (list (format "%d:" index)
 241               (riece-propertize-modeline-string
 242                string 'face 'riece-channel-list-current-face)))))
 243
 244 (defun riece-highlight-insinuate ()
 245   (put 'riece-channel-mode 'font-lock-defaults
 246        '(riece-dialogue-font-lock-keywords t))
 247   (add-hook 'riece-channel-mode-hook
 248             'riece-highlight-setup-dialogue)
 249   (put 'riece-others-mode 'font-lock-defaults
 250        '(riece-dialogue-font-lock-keywords t))
 251   (add-hook 'riece-others-mode-hook
 252             'riece-highlight-setup-dialogue)
 253   (put 'riece-dialogue-mode 'font-lock-defaults
 254        '(riece-dialogue-font-lock-keywords t))
 255   (add-hook 'riece-dialogue-mode-hook
 256             'riece-highlight-setup-dialogue)
 257   (put 'riece-channel-list-mode 'font-lock-defaults
 258        '(riece-channel-list-font-lock-keywords t))
 259   (add-hook 'riece-channel-list-mode-hook
 260             'riece-highlight-setup-channel-list)
 261   (add-hook 'riece-format-identity-for-channel-list-indicator-functions
 262             'riece-highlight-format-identity-for-channel-list-indicator)
 263   (add-hook 'riece-after-insert-functions
 264             'riece-highlight-put-overlay-faces))
 265
 266 (defun riece-highlight-enable ()
 267   (let ((buffers riece-buffer-list))
 268     (while buffers
 269       (if (memq (derived-mode-class
 270                (with-current-buffer (car buffers)
 271                  major-mode))
 272                 '(riece-dialogue-mode riece-channel-list-mode))
 273           (with-current-buffer (car buffers)
 274             (font-lock-mode 1)))
 275       (setq buffers (cdr buffers))))
 276   (setq riece-highlight-enabled t))
 277
 278 (defun riece-highlight-disable ()
 279   (let ((buffers riece-buffer-list))
 280     (while buffers
 281       (if (memq (derived-mode-class
 282                (with-current-buffer (car buffers)
 283                  major-mode))
 284                 '(riece-dialogue-mode riece-channel-list-mode))
 285           (with-current-buffer (car buffers)
 286             (font-lock-mode -1)))
 287       (setq buffers (cdr buffers))))
 288   (setq riece-highlight-enabled nil))
 289
 290 (provide 'riece-highlight)
 291
 292 ;;; riece-highlight.el ends here