cgit.sxemacs.org Git - riece/blob - lisp/riece-highlight.el

   1 ;;; riece-highlight.el --- highlight IRC buffers
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Created: 1998-09-28
   6 ;; Keywords: IRC, riece
   7
   8 ;; This file is part of Riece.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; NOTE: This is an add-on module for Riece.
  28
  29 ;;; Code:
  30
  31 (require 'riece-globals)
  32 (require 'riece-options)                ;riece-channel-list-buffer-mode
  33 (require 'riece-identity)               ;riece-format-identity
  34 (require 'riece-misc)
  35 (require 'font-lock)
  36 (require 'derived)
  37
  38 (defgroup riece-highlight nil
  39   "Decorate IRC buffers with faces and fonts."
  40   :tag "Highlight"
  41   :prefix "riece-"
  42   :group 'riece)
  43
  44 (defgroup riece-highlight-faces nil
  45   "Faces for highlight IRC buffers."
  46   :tag "Faces"
  47   :prefix "riece-highlight-"
  48   :group 'riece-highlight)
  49
  50 (defface riece-dialogue-change-face
  51   '((((class color)
  52       (background dark))
  53      (:foreground "cyan" :bold t))
  54     (((class color)
  55       (background light))
  56      (:foreground "RoyalBlue" :bold t))
  57     (t
  58      (:bold t)))
  59   "Face used for displaying \"*** Change:\" line"
  60   :group 'riece-highlight-faces)
  61 (defvar riece-dialogue-change-face 'riece-dialogue-change-face)
  62
  63 (defface riece-dialogue-notice-face
  64   '((((class color)
  65       (background dark))
  66      (:foreground "green2" :bold t))
  67     (((class color)
  68       (background light))
  69      (:foreground "MidnightBlue" :bold t))
  70     (t
  71      (:bold t)))
  72   "Face used for displaying \"*** Notice:\" line"
  73   :group 'riece-highlight-faces)
  74 (defvar riece-dialogue-notice-face 'riece-dialogue-notice-face)
  75
  76 (defface riece-dialogue-wallops-face
  77   '((((class color)
  78       (background dark))
  79      (:foreground "yellow" :bold t))
  80     (((class color)
  81       (background light))
  82      (:foreground "blue4" :bold t))
  83     (t
  84      (:bold t)))
  85   "Face used for displaying \"*** Wallops:\" line"
  86   :group 'riece-highlight-faces)
  87 (defvar riece-dialogue-wallops-face 'riece-dialogue-wallops-face)
  88
  89 (defface riece-dialogue-error-face
  90   '((((class color)
  91       (background dark))
  92      (:foreground "cornflower blue" :bold t))
  93     (((class color)
  94       (background light))
  95      (:foreground "DarkGreen"))
  96     (t
  97      (:bold t)))
  98   "Face used for displaying \"*** Error:\" line"
  99   :group 'riece-highlight-faces)
 100 (defvar riece-dialogue-error-face 'riece-dialogue-error-face)
 101
 102 (defface riece-dialogue-info-face
 103   '((((class color)
 104       (background dark))
 105      (:foreground "PaleTurquoise" :bold t))
 106     (((class color)
 107       (background light))
 108      (:foreground "RoyalBlue"))
 109     (t
 110      (:bold t)))
 111   "Face used for displaying \"*** Info:\" line"
 112   :group 'riece-highlight-faces)
 113 (defvar riece-dialogue-info-face 'riece-dialogue-info-face)
 114
 115 (defface riece-dialogue-server-face
 116   '((((class color)
 117       (background dark))
 118      (:foreground "Gray70"))
 119     (((class color)
 120       (background light))
 121      (:foreground "DimGray"))
 122     (t
 123      (:bold t)))
 124   "Face used for displaying \"(from server)\" extent."
 125   :group 'riece-highlight-faces)
 126 (defvar riece-dialogue-server-face 'riece-dialogue-server-face)
 127
 128 (defface riece-dialogue-prefix-face
 129   '((((class color)
 130       (background dark))
 131      (:foreground "moccasin"))
 132     (((class color)
 133       (background light))
 134      (:foreground "firebrick"))
 135     (t
 136      (:bold nil)))
 137   "Face used for displaying \"<nick>\" extent"
 138   :group 'riece-highlight-faces)
 139 (defvar riece-dialogue-prefix-face 'riece-dialogue-prefix-face)
 140
 141 (defcustom riece-dialogue-font-lock-keywords
 142   (append
 143    (list (list (concat "^" riece-time-prefix-regexp
 144                        "\\(<[^>]+>\\|>[^<]+<\\|([^)]+)\\|{[^}]+}\\|=[^=]+=\\)")
 145                '(1 riece-dialogue-prefix-face append t)))
 146    ;; set property to the whole line
 147    (mapcar
 148     (lambda (line)
 149       (cons
 150        (concat
 151         "^" riece-time-prefix-regexp "\\("
 152         (regexp-quote
 153          (symbol-value (intern (format "riece-%s-prefix" line))))
 154         ".*\\)$")
 155        (list 1 (intern (format "riece-dialogue-%s-face" line)) t t)))
 156     '(change notice wallops error info))
 157    '((riece-highlight-server-match 0 riece-dialogue-server-face t)))
 158   "Default expressions to highlight in riece-dialogue-mode."
 159   :type '(repeat (list string))
 160   :group 'riece-highlight)
 161
 162 (defface riece-channel-list-default-face
 163   '((t ()))
 164   "Face used for displaying channels."
 165   :group 'riece-highlight-faces)
 166 (defvar riece-channel-list-default-face 'riece-channel-list-default-face)
 167
 168 (defface riece-channel-list-current-face
 169   '((((class color)
 170       (background dark))
 171      (:foreground "turquoise" :underline t))
 172     (((class color)
 173       (background light))
 174      (:foreground "SeaGreen" :underline t))
 175     (t
 176      ()))
 177   "Face used for displaying the current channel."
 178   :group 'riece-highlight-faces)
 179 (defvar riece-channel-list-current-face 'riece-channel-list-current-face)
 180
 181 (defcustom riece-channel-list-mark-face-alist
 182   '((?* . riece-channel-list-current-face))
 183   "An alist mapping marks on riece-channel-list-buffer to faces."
 184   :type 'list
 185   :group 'riece-highlight)
 186
 187 (defcustom riece-channel-list-font-lock-keywords
 188   '(("^[ 0-9][0-9]:\\(.\\)\\(.*\\)"
 189      (2 (or (cdr (assq (aref (match-string 1) 0)
 190                        riece-channel-list-mark-face-alist))
 191             riece-channel-list-default-face))))
 192   "Default expressions to highlight in riece-channel-list-mode."
 193   :type '(repeat (list string))
 194   :group 'riece-highlight)
 195
 196 (unless (riece-facep 'riece-modeline-current-face)
 197   (make-face 'riece-modeline-current-face
 198              "Face used for displaying the current channel in modeline.")
 199   (if (featurep 'xemacs)
 200       (set-face-parent 'riece-modeline-current-face 'modeline))
 201   (set-face-foreground 'riece-modeline-current-face
 202                        (face-foreground 'riece-channel-list-current-face)))
 203
 204 (defvar riece-highlight-enabled nil)
 205
 206 (defconst riece-highlight-description
 207   "Highlight IRC buffers.")
 208
 209 (defun riece-highlight-server-match (limit)
 210   (and (re-search-forward "(from [^)]+)$" limit t)
 211        (get-text-property (match-beginning 0) 'riece-server-name)))
 212
 213 (defun riece-highlight-setup-dialogue ()
 214   (make-local-variable 'font-lock-defaults)
 215   (setq font-lock-defaults '(riece-dialogue-font-lock-keywords t))
 216   ;; In XEmacs, auto-initialization of font-lock is not affective
 217   ;; when buffer-file-name is not set.
 218   (font-lock-set-defaults)
 219   (make-local-hook 'after-change-functions)
 220   (add-hook 'after-change-functions
 221             'riece-highlight-hide-prefix nil 'local)
 222   (if riece-highlight-enabled
 223       (font-lock-mode 1)))
 224
 225 (defun riece-highlight-setup-channel-list ()
 226   (make-local-variable 'font-lock-defaults)
 227   (setq font-lock-defaults '(riece-channel-list-font-lock-keywords t))
 228   ;; In XEmacs, auto-initialization of font-lock is not affective
 229   ;; when buffer-file-name is not set.
 230   (font-lock-set-defaults)
 231   (if riece-highlight-enabled
 232       (font-lock-mode 1)))
 233
 234 (defun riece-highlight-hide-prefix (start end length)
 235   (save-excursion
 236     (goto-char start)
 237     (if (looking-at riece-prefix-regexp)
 238         (put-text-property (match-beginning 1) (match-end 1) 'invisible t))))
 239
 240 (defun riece-highlight-put-overlay-faces (start end)
 241   (if riece-highlight-enabled
 242       (riece-scan-property-region
 243        'riece-overlay-face
 244        start end
 245        (lambda (start end)
 246          (riece-overlay-put (riece-make-overlay start end)
 247                             'face
 248                             (get-text-property start 'riece-overlay-face))))))
 249
 250 (defun riece-highlight-format-identity-for-channel-list-indicator (index
 251                                                                    identity)
 252   (if (and riece-highlight-enabled
 253            (riece-identity-equal identity riece-current-channel))
 254       (let ((string (riece-format-identity identity))
 255             (start 0))
 256         ;; Escape % -> %%.
 257         (while (string-match "%" string start)
 258           (setq start (1+ (match-end 0))
 259                 string (replace-match "%%" nil nil string)))
 260         (list (format "%d:" index)
 261               (riece-propertize-modeline-string
 262                string 'face 'riece-modeline-current-face)))))
 263
 264 (defun riece-highlight-insinuate ()
 265   (put 'riece-channel-mode 'font-lock-defaults
 266        '(riece-dialogue-font-lock-keywords t))
 267   (add-hook 'riece-channel-mode-hook
 268             'riece-highlight-setup-dialogue)
 269   (put 'riece-others-mode 'font-lock-defaults
 270        '(riece-dialogue-font-lock-keywords t))
 271   (add-hook 'riece-others-mode-hook
 272             'riece-highlight-setup-dialogue)
 273   (put 'riece-dialogue-mode 'font-lock-defaults
 274        '(riece-dialogue-font-lock-keywords t))
 275   (add-hook 'riece-dialogue-mode-hook
 276             'riece-highlight-setup-dialogue)
 277   (put 'riece-channel-list-mode 'font-lock-defaults
 278        '(riece-channel-list-font-lock-keywords t))
 279   (add-hook 'riece-channel-list-mode-hook
 280             'riece-highlight-setup-channel-list)
 281   (add-hook 'riece-format-identity-for-channel-list-indicator-functions
 282             'riece-highlight-format-identity-for-channel-list-indicator)
 283   (add-hook 'riece-after-insert-functions
 284             'riece-highlight-put-overlay-faces))
 285
 286 (defun riece-highlight-uninstall ()
 287   (remprop 'riece-channel-mode 'font-lock-defaults)
 288   (remove-hook 'riece-channel-mode-hook
 289                'riece-highlight-setup-dialogue)
 290   (remprop 'riece-others-mode 'font-lock-defaults)
 291   (remove-hook 'riece-others-mode-hook
 292                'riece-highlight-setup-dialogue)
 293   (remprop 'riece-dialogue-mode 'font-lock-defaults)
 294   (remove-hook 'riece-dialogue-mode-hook
 295                'riece-highlight-setup-dialogue)
 296   (remprop 'riece-channel-list-mode 'font-lock-defaults)
 297   (remove-hook 'riece-channel-list-mode-hook
 298                'riece-highlight-setup-channel-list)
 299   (remove-hook 'riece-format-identity-for-channel-list-indicator-functions
 300                'riece-highlight-format-identity-for-channel-list-indicator)
 301   (remove-hook 'riece-after-insert-functions
 302                'riece-highlight-put-overlay-faces))
 303
 304 (defun riece-highlight-enable ()
 305   (let ((buffers riece-buffer-list))
 306     (while buffers
 307       (if (memq (derived-mode-class
 308                (with-current-buffer (car buffers)
 309                  major-mode))
 310                 '(riece-dialogue-mode riece-channel-list-mode))
 311           (with-current-buffer (car buffers)
 312             (font-lock-mode 1)))
 313       (setq buffers (cdr buffers))))
 314   (setq riece-highlight-enabled t))
 315
 316 (defun riece-highlight-disable ()
 317   (let ((buffers riece-buffer-list))
 318     (while buffers
 319       (if (memq (derived-mode-class
 320                (with-current-buffer (car buffers)
 321                  major-mode))
 322                 '(riece-dialogue-mode riece-channel-list-mode))
 323           (with-current-buffer (car buffers)
 324             (font-lock-mode 0)))
 325       (setq buffers (cdr buffers))))
 326   (setq riece-highlight-enabled nil))
 327
 328 (provide 'riece-highlight)
 329
 330 ;;; riece-highlight.el ends here