cgit.sxemacs.org Git - riece/blob - lisp/riece-filter.el

   1 ;;; riece-filter.el --- process filter and sentinel
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Created: 1998-09-28
   6 ;; Keywords: IRC, riece
   7
   8 ;; This file is part of Riece.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Code:
  26
  27 (eval-when-compile (require 'riece-inlines))
  28
  29 (require 'riece-handle)
  30 (require 'riece-misc)
  31 (require 'riece-server)                 ;riece-close-server
  32
  33 (defun riece-handle-numeric-reply (prefix number name string)
  34   (let ((base-number (* (/ number 100) 100))
  35         function)
  36     (condition-case nil
  37         (require (intern (format "riece-%03d" base-number)))
  38       (error))
  39     (setq function (intern-soft (format "riece-handle-%03d-message" number)))
  40     (unless (and function
  41                  (symbol-function function))
  42       (setq function
  43             (intern-soft
  44              (format "riece-handle-default-%03d-message" base-number))))
  45     (if (and function
  46              (symbol-function function))
  47         (condition-case error
  48             (funcall function prefix number name
  49                      (riece-decode-coding-string string))
  50           (error
  51            (if riece-debug
  52                (message "Error occurred in `%S': %S" function error)))))))
  53
  54 (defun riece-default-handle-numeric-reply
  55   (client-prefix prefix number name string)
  56   (riece-insert
  57    (list riece-dialogue-buffer riece-others-buffer)
  58    (concat client-prefix
  59            (riece-concat-server-name
  60             (mapconcat #'identity (riece-split-parameters string) " "))
  61            "\n")))
  62
  63 (defun riece-handle-message (prefix message string)
  64   (if (and prefix
  65            (string-match "![^\x00\x0d\x0a @]+@" prefix))
  66       (riece-user-set-user-at-host
  67        (riece-get-user (substring prefix 0 (match-beginning 0)))
  68        (riece-parse-user-at-host (substring prefix (1+ (match-beginning 0))))))
  69   (setq message (downcase message)
  70         string (riece-decode-coding-string string))
  71   (unless (run-hook-with-args-until-success
  72            (intern (concat "riece-" message "-hook"))
  73            prefix string)
  74     (let ((function (intern-soft (concat "riece-handle-" message "-message"))))
  75       (if function
  76           (condition-case error
  77               (funcall function prefix string)
  78             (error
  79              (if riece-debug
  80                  (message "Error occurred in `%S': %S" function error))))))
  81     (run-hook-with-args-until-success
  82      (intern (concat "riece-after-" message "-hook"))
  83      prefix string)))
  84
  85 (defun riece-filter (process input)
  86   (save-excursion
  87     (set-buffer (process-buffer process))
  88     (goto-char riece-read-point)
  89     (unless riece-debug
  90       (delete-region (riece-line-beginning-position) (point-min))
  91       (setq riece-read-point (point)))
  92     (insert input)
  93     (goto-char (prog1 riece-read-point
  94                  (setq riece-read-point (point))))
  95     (beginning-of-line)
  96     (catch 'contiguous
  97       (while (not (eobp))
  98         (save-excursion
  99           (if (looking-at
 100                ":\\([^ ]+\\) +\\([0-5][0-9][0-9]\\) +\\([^ ]+\\) +\\(.*\\)\r\n")
 101               (riece-handle-numeric-reply
 102                (match-string 1)         ;prefix
 103                (string-to-number (match-string 2)) ;number
 104                (match-string 3)         ;name
 105                (match-string 4))                ;reply string
 106             (if (looking-at "\\(:\\([^ ]+\\) +\\)?\\([^ ]+\\) +\\(.*\\)\r\n")
 107                 (riece-handle-message
 108                  (match-string 2)       ;optional prefix
 109                  (match-string 3)       ;command
 110                  (match-string 4))      ;params & trailing
 111               (if (looking-at ".*\r\n")
 112                   (if riece-debug
 113                       (message "Weird message from server: %s"
 114                                (buffer-substring (point) (progn
 115                                                            (end-of-line)
 116                                                            (point)))))
 117                 (throw 'contiguous nil)))))
 118         (forward-line)))))
 119
 120 (eval-when-compile
 121   (autoload 'riece "riece"))
 122 (defun riece-sentinel (process status)
 123   (if riece-reconnect-with-password
 124       (unwind-protect
 125           (riece)
 126         (setq riece-reconnect-with-password nil))
 127     (let ((server-name (with-current-buffer (process-buffer process)
 128                          riece-server-name)))
 129       (if (and (process-id process)             ;not a network connection
 130                (string-match "^exited abnormally with code \\([0-9]+\\)"
 131                              status))
 132           (if server-name
 133               (message "Connection to \"%s\" closed: %s"
 134                        server-name (match-string 1 status))
 135             (message "Connection closed: %s" (match-string 1 status)))
 136         (if server-name
 137             (message "Connection to \"%s\" closed: %s"
 138                      server-name (substring status 0 (1- (length status))))
 139           (message "Connection closed: %s"
 140                    (substring status 0 (1- (length status))))))
 141       (riece-close-server server-name))))
 142
 143 (provide 'riece-filter)
 144
 145 ;;; riece-filter.el ends here