cgit.sxemacs.org Git - riece/blob - lisp/riece-debug.el

   1 ;;; riece-debug.el --- debug support
   2 ;; Copyright (C) 1998-2005 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Created: 1998-09-28
   6 ;; Keywords: IRC, riece
   7
   8 ;; This file is part of Riece.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Code:
  26
  27 (require 'riece-globals)
  28 (require 'riece-options)
  29
  30 (defun riece-debug (message &optional detail)
  31   "Print a one-line debug MESSAGE at the bottom of the frame.
  32 If the optional 2nd argument DETAIL is specified, it is stored into
  33 `riece-debug-buffer'."
  34   (message "riece-debug: %s" message)
  35   (save-excursion
  36     (set-buffer riece-debug-buffer)
  37     (goto-char (point-max))
  38     (let ((point (point)))
  39       (if detail
  40           (insert message "\n" detail "\n")
  41         (insert message "\n")))))
  42
  43 (defun riece-debug-reset-standard-output ()
  44   "Reset `riece-temp-buffer' to be used as `standard-output'."
  45   (save-excursion
  46     (set-buffer riece-temp-buffer)
  47     (buffer-disable-undo)
  48     (erase-buffer)))
  49
  50 (defmacro riece-debug-with-backtrace (&rest body)
  51   "Execute BODY and send a backtrace to `riece-temp-buffer'."
  52   `(unwind-protect
  53        (progn ,@body)
  54      (riece-debug-reset-standard-output)
  55      (let ((standard-output riece-temp-buffer))
  56        (backtrace))))
  57
  58 (put 'riece-debug-with-backtrace 'lisp-indent-function 0)
  59 (put 'riece-debug-with-backtrace 'edebug-form-spec '(form body))
  60
  61 (defmacro riece-ignore-errors (location &rest body)
  62   "Execute BODY; if an error occurs, return nil.
  63 Otherwise, return result of last FORM.
  64 If `riece-debug' is non-nil and an error occurred, it sends a
  65 backtrace to standard-output."
  66   `(condition-case error
  67        (if riece-debug
  68            (riece-debug-with-backtrace ,@body)
  69          ,@body)
  70      (error
  71       (if riece-debug
  72           (save-excursion
  73             (set-buffer riece-temp-buffer)
  74             (goto-char (point-min))
  75             (if (re-search-forward "^  signal(" nil t)
  76                 (delete-region (point-min) (match-beginning 0)))
  77             (riece-debug (format "Error in `%s': %S" ,location error)
  78                          (buffer-string))))
  79       nil)))
  80
  81 (put 'riece-ignore-errors 'lisp-indent-function 1)
  82 (put 'riece-ignore-errors 'edebug-form-spec '(form body))
  83
  84 (defun riece-funcall-ignore-errors (location function &rest args)
  85   "Call FUNCTION with ARGS; if an error occurs, return nil.
  86 Otherwise, return result of the function.
  87 If `riece-debug' is non-nil and an error occurred, it sends a
  88 backtrace to standard-output."
  89   (riece-ignore-errors location
  90     (apply function args)))
  91
  92 (provide 'riece-debug)
  93
  94 ;;; riece-debug.el ends here