cgit.sxemacs.org Git - riece/blob - lisp/riece-commands.el

   1 ;;; riece-commands.el --- commands available in command buffer
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Created: 1998-09-28
   6 ;; Keywords: IRC, riece
   7
   8 ;; This file is part of Riece.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Code:
  26
  27 (eval-when-compile (require 'riece-inlines))
  28
  29 (require 'riece-channel)
  30 (require 'riece-complete)
  31 (require 'riece-display)
  32 (require 'riece-version)
  33 (require 'riece-server)
  34 (require 'riece-misc)
  35 (require 'riece-identity)
  36 (require 'riece-message)
  37
  38 ;;; Channel movement:
  39 (defun riece-command-switch-to-channel (channel)
  40   (interactive
  41    (list (completing-read "Channel/user: "
  42                           (mapcar #'list riece-current-channels)
  43                           nil t)))
  44   (riece-switch-to-channel channel)
  45   (riece-command-configure-windows))
  46
  47 (defun riece-command-switch-to-channel-by-number (number)
  48   (interactive
  49    (let ((command-name (symbol-name this-command)))
  50      (if (string-match "[0-9]+$" command-name)
  51          (list (string-to-number (match-string 0 command-name)))
  52        (list (string-to-number (read-string "Number: "))))))
  53   (let ((channels riece-current-channels)
  54         (index 1))
  55     (while (and channels
  56                 (< index number))
  57       (if (car channels)
  58           (setq index (1+ index)))
  59       (setq channels (cdr channels)))
  60     (if (car channels)
  61         (riece-command-switch-to-channel (car channels))
  62       (error "No such number!"))))
  63
  64 (eval-and-compile
  65   (let ((number 1))
  66     (while (<= number 20)
  67       (defalias (intern (concat "riece-command-switch-to-channel-by-number-"
  68                                 (number-to-string number)))
  69         'riece-command-switch-to-channel-by-number)
  70       (setq number (1+ number)))))
  71
  72 (defun riece-command-next-channel ()
  73   "Select the next channel."
  74   (interactive)
  75   (let ((pointer (cdr (string-list-member-ignore-case
  76                        riece-current-channel
  77                        riece-current-channels))))
  78     (while (and pointer
  79                 (null (car pointer)))
  80       (setq pointer (cdr pointer)))
  81     (if (car pointer)
  82         (riece-command-switch-to-channel (car pointer))
  83       (error "No such channel!"))))
  84
  85 (defun riece-command-previous-channel ()
  86   "Select the previous channel."
  87   (interactive)
  88   (let ((pointer (string-list-member-ignore-case
  89                   riece-current-channel
  90                   riece-current-channels))
  91         (start riece-current-channels)
  92         channel)
  93     (while (and start (not (eq start pointer)))
  94       (if (car start)
  95           (setq channel (car start)))
  96       (setq start (cdr start)))
  97     (if channel
  98         (riece-command-switch-to-channel channel)
  99       (error "No such channel!"))))
 100
 101 (defun riece-command-select-command-buffer ()
 102   "Select the command buffer."
 103   (interactive)
 104   (let ((window (get-buffer-window riece-command-buffer)))
 105     (if window
 106         (select-window window))))
 107
 108 (defun riece-command-configure-windows ()
 109   (interactive)
 110   (riece-redisplay-buffers t))
 111
 112 (defun riece-command-toggle-channel-buffer-mode ()
 113   (interactive)
 114   (setq riece-channel-buffer-mode
 115         (not riece-channel-buffer-mode))
 116   (riece-command-configure-windows))
 117
 118 (defun riece-command-toggle-user-list-buffer-mode ()
 119   (interactive)
 120   (setq riece-user-list-buffer-mode
 121         (not riece-user-list-buffer-mode))
 122   (riece-command-configure-windows))
 123
 124 (defun riece-command-toggle-channel-list-buffer-mode ()
 125   (interactive)
 126   (setq riece-channel-list-buffer-mode
 127         (not riece-channel-list-buffer-mode))
 128   (riece-command-configure-windows))
 129
 130 (defun riece-get-users-on-server ()
 131   (riece-with-server-buffer
 132    (let (users)
 133      (mapatoms
 134       (lambda (atom)
 135         (unless (riece-channel-p (symbol-name atom))
 136           (push (symbol-name atom) users)))
 137       riece-obarray)
 138      (if (member riece-real-nickname users)
 139          users
 140        (cons riece-real-nickname users)))))
 141
 142 (defun riece-command-finger (user &optional recurse)
 143   (interactive
 144    (let* ((completion-ignore-case t)
 145           (user (completing-read
 146                  "User: "
 147                  (mapcar #'list (riece-get-users-on-server)))))
 148      (list user current-prefix-arg)))
 149   (if recurse
 150       (riece-send-string (format "WHOIS %s %s\r\n" user user))
 151     (riece-send-string (format "WHOIS %s\r\n" user))))
 152
 153 (defun riece-command-topic (topic)
 154   (interactive
 155    (list (read-from-minibuffer
 156           "Topic: " (cons (or (riece-channel-get-topic
 157                                riece-current-channel)
 158                               "")
 159                           0))))
 160   (riece-send-string (format "TOPIC %s :%s\r\n"
 161                              (riece-identity-prefix riece-current-channel)
 162                              topic)))
 163
 164 (defun riece-command-invite (user)
 165   (interactive
 166    (let ((completion-ignore-case t))
 167      (unless (and riece-current-channel
 168                   (riece-channel-p riece-current-channel))
 169        (error "Not on a channel"))
 170      (list (completing-read
 171             "User: "
 172             (mapcar #'list (riece-get-users-on-server))))))
 173   (riece-send-string (format "INVITE %s %s\r\n"
 174                              user (riece-identity-prefix
 175                                    riece-current-channel))))
 176
 177 (defun riece-command-kick (user &optional message)
 178   (interactive
 179    (let ((completion-ignore-case t))
 180      (unless (and riece-current-channel
 181                   (riece-channel-p riece-current-channel))
 182        (error "Not on a channel"))
 183      (list (completing-read
 184             "User: "
 185             (mapcar #'list (riece-channel-get-users
 186                             riece-current-channel)))
 187            (if current-prefix-arg
 188                (read-string "Message: ")))))
 189   (riece-send-string
 190    (if message
 191        (format "KICK %s %s :%s\r\n"
 192                (riece-identity-prefix riece-current-channel)
 193                user message)
 194      (format "KICK %s %s\r\n"
 195              (riece-identity-prefix riece-current-channel)
 196              user))))
 197
 198 (defun riece-command-change-mode (channel change)
 199   (interactive
 200    (let* ((completion-ignore-case t)
 201           (channel
 202            (if current-prefix-arg
 203                (completing-read
 204                 "Channel/user: "
 205                 (mapcar #'list riece-current-channels))
 206              riece-current-channel))
 207           (riece-overriding-server-name (riece-identity-server channel))
 208           (riece-temp-minibuffer-message
 209            (concat "[Available modes: "
 210                    (riece-with-server-buffer
 211                     (if (and (riece-channel-p channel)
 212                              riece-supported-channel-modes)
 213                         (apply #'string riece-supported-channel-modes)
 214                       (if (and (not (riece-channel-p channel))
 215                                riece-supported-user-modes)
 216                           (apply #'string riece-supported-user-modes))))
 217                    "]")))
 218      (list channel
 219            (read-from-minibuffer
 220             (concat (riece-concat-modes channel "Mode (? for help)") ": ")
 221             nil riece-minibuffer-map))))
 222   (riece-send-string (format "MODE %s :%s\r\n" channel change)))
 223
 224 (defun riece-command-set-operators (users &optional arg)
 225   (interactive
 226    (let ((operators (riece-channel-get-operators riece-current-channel))
 227          (completion-ignore-case t)
 228          users)
 229      (if current-prefix-arg
 230          (setq users (riece-completing-read-multiple
 231                       "Users"
 232                       (mapcar #'list operators)))
 233        (setq users (riece-completing-read-multiple
 234                     "Users"
 235                     (delq nil (mapcar (lambda (user)
 236                                         (unless (member user operators)
 237                                           (list user)))
 238                                       (riece-channel-get-users
 239                                        riece-current-channel))))))
 240      (list users current-prefix-arg)))
 241   (let (group)
 242     (while users
 243       (push (pop users) group)
 244       (if (or (= (length group) 3)
 245               (null users))
 246           (riece-send-string
 247            (format "MODE %s %c%s %s\r\n"
 248                    (riece-identity-prefix riece-current-channel)
 249                    (if current-prefix-arg
 250                        ?-
 251                      ?+)
 252                    (make-string (length group) ?o)
 253                    (mapconcat #'identity group " ")))))))
 254
 255 (defun riece-command-set-speakers (users &optional arg)
 256   (interactive
 257    (let ((speakers (riece-channel-get-speakers riece-current-channel))
 258          (completion-ignore-case t)
 259          users)
 260      (if current-prefix-arg
 261          (setq users (riece-completing-read-multiple
 262                       "Users"
 263                       (mapcar #'list speakers)))
 264        (setq users (riece-completing-read-multiple
 265                     "Users"
 266                     (delq nil (mapcar (lambda (user)
 267                                         (unless (member user speakers)
 268                                           (list user)))
 269                                       (riece-channel-get-users
 270                                        riece-current-channel))))))
 271      (list users current-prefix-arg)))
 272   (let (group)
 273     (while users
 274       (push (pop users) group)
 275       (if (or (= (length group) 3)
 276               (null users))
 277           (riece-send-string
 278            (format "MODE %s %c%s %s\r\n"
 279                    (riece-identity-prefix riece-current-channel)
 280                    (if current-prefix-arg
 281                        ?-
 282                      ?+)
 283                    (make-string (length group) ?v)
 284                    (mapconcat #'identity group " ")))))))
 285
 286 (defun riece-command-send-message (message)
 287   "Send MESSAGE to the current channel."
 288   (if (equal message "")
 289       (error "No text to send"))
 290   (unless riece-current-channel
 291     (error (substitute-command-keys
 292             "Type \\[riece-command-join] to join a channel")))
 293   (riece-send-string
 294    (format "PRIVMSG %s :%s\r\n"
 295            (riece-identity-prefix riece-current-channel)
 296            message))
 297   (riece-own-channel-message message))
 298
 299 (defun riece-command-enter-message ()
 300   "Send the current line to the current channel."
 301   (interactive)
 302   (riece-command-send-message (buffer-substring
 303                                (riece-line-beginning-position)
 304                                (riece-line-end-position)))
 305   (let ((next-line-add-newlines t))
 306     (next-line 1)))
 307
 308 (defun riece-command-join-channel (target key)
 309   (let ((server-name (riece-identity-server target))
 310         process)
 311     (if server-name
 312         (setq process (cdr (assoc server-name riece-server-process-alist)))
 313       (setq process riece-server-process))
 314     (unless process
 315       (error "%s" (substitute-command-keys
 316                    "Type \\[riece-command-open-server] to open server.")))
 317     (riece-process-send-string process
 318                                (if key
 319                                    (format "JOIN %s :%s\r\n"
 320                                            (riece-identity-prefix target)
 321                                            key)
 322                                  (format "JOIN %s\r\n"
 323                                          (riece-identity-prefix target))))))
 324
 325 (defun riece-command-join-partner (target)
 326   (let ((pointer (riece-identity-member target riece-current-channels)))
 327     (if pointer
 328         (riece-command-switch-to-channel (car pointer))
 329       (riece-join-channel target)
 330       (riece-switch-to-channel target)
 331       (riece-redisplay-buffers))))
 332
 333 (defun riece-command-join (target &optional key)
 334   (interactive
 335    (let ((completion-ignore-case t)
 336          (target
 337           (completing-read "Channel/user: "
 338                            (mapcar #'list riece-current-channels)))
 339          key)
 340      (if (and current-prefix-arg
 341               (riece-channel-p target))
 342          (setq key
 343                (riece-read-passwd (format "Key for %s: " target))))
 344      (list target key)))
 345   (let ((pointer (riece-identity-member target riece-current-channels)))
 346     (if pointer
 347         (riece-command-switch-to-channel (car pointer))
 348       (if (riece-channel-p target)
 349           (riece-command-join-channel target key)
 350         (riece-command-join-partner target)))))
 351
 352 (defun riece-command-part-channel (target message)
 353   (let ((server-name (riece-identity-server target))
 354         process)
 355     (if server-name
 356         (setq process (cdr (assoc server-name riece-server-process-alist)))
 357       (setq process riece-server-process))
 358     (unless process
 359       (error "%s" (substitute-command-keys
 360                    "Type \\[riece-command-open-server] to open server.")))
 361     (riece-process-send-string process
 362                                (if message
 363                                    (format "PART %s :%s\r\n"
 364                                            (riece-identity-prefix target)
 365                                            message)
 366                                  (format "PART %s\r\n"
 367                                          (riece-identity-prefix target))))))
 368
 369 (defun riece-command-part (target &optional message)
 370   (interactive
 371    (let ((completion-ignore-case t)
 372          (target
 373           (completing-read "Channel/user: "
 374                            (mapcar #'list riece-current-channels)
 375                            nil t (cons riece-current-channel 0)))
 376          message)
 377      (if (and current-prefix-arg
 378               (riece-channel-p target))
 379          (setq message (read-string "Message: ")))
 380      (list target message)))
 381   (if (riece-identity-member target riece-current-channels)
 382       (if (riece-channel-p target)
 383           (riece-command-part-channel target message)
 384         (riece-part-channel target)
 385         (riece-redisplay-buffers))
 386     (error "You are not talking with %s" target)))
 387
 388 (defun riece-command-change-nickname (nickname)
 389   "Change your nickname to NICK."
 390   (interactive "sEnter your nickname: ")
 391   (riece-send-string (format "NICK %s\r\n" nickname)))
 392
 393 (defun riece-command-scroll-down (lines)
 394   "Scroll LINES down dialogue buffer from command buffer."
 395   (interactive "P")
 396   (let ((other-window-scroll-buffer
 397          (if riece-channel-buffer-mode
 398              riece-channel-buffer
 399            riece-dialogue-buffer)))
 400     (when (get-buffer-window other-window-scroll-buffer)
 401       (condition-case nil
 402           (scroll-other-window-down lines)
 403         (beginning-of-buffer
 404          (message "Beginning of buffer"))))))
 405
 406 (defun riece-command-scroll-up (lines)
 407   "Scroll LINES up dialogue buffer from command buffer."
 408   (interactive "P")
 409   (let* ((other-window-scroll-buffer
 410           (if riece-channel-buffer-mode
 411               riece-channel-buffer
 412             riece-dialogue-buffer)))
 413     (when (get-buffer-window other-window-scroll-buffer)
 414       (condition-case nil
 415           (scroll-other-window lines)
 416         (end-of-buffer
 417          (message "End of buffer"))))))
 418
 419 (defun riece-command-nick-scroll-down (lines)
 420   "Scroll LINES down nick buffer from command buffer."
 421   (interactive "P")
 422   (let ((other-window-scroll-buffer riece-user-list-buffer))
 423     (when (get-buffer-window other-window-scroll-buffer)
 424       (condition-case nil
 425           (scroll-other-window-down lines)
 426         (beginning-of-buffer
 427          (message "Beginning of buffer"))))))
 428
 429 (defun riece-command-nick-scroll-up (lines)
 430   "Scroll LINES up nick buffer from command buffer."
 431   (interactive "P")
 432   (let* ((other-window-scroll-buffer riece-user-list-buffer))
 433     (when (get-buffer-window other-window-scroll-buffer)
 434       (condition-case nil
 435           (scroll-other-window lines)
 436         (end-of-buffer
 437          (message "End of buffer"))))))
 438
 439 (defun riece-command-toggle-away (&optional message)
 440   "Mark yourself as being away."
 441   (interactive
 442    (if current-prefix-arg
 443        (let ((message (read-string "Away message: ")))
 444          (list message))))
 445   (if message
 446       (riece-send-string (format "AWAY :%s\r\n" message))
 447     (riece-send-string "AWAY\r\n")))
 448
 449 (defun riece-command-toggle-freeze (&optional arg)
 450   "Prevent automatic scrolling of the dialogue window.
 451 If prefix argument ARG is non-nil, toggle frozen status."
 452   (interactive "P")
 453   (riece-freeze (if riece-channel-buffer-mode
 454                     riece-channel-buffer
 455                   riece-dialogue-buffer)
 456                 (if arg (prefix-numeric-value arg))))
 457
 458 (defun riece-command-toggle-own-freeze (&optional arg)
 459   "Prevent automatic scrolling of the dialogue window.
 460 The difference from `riece-command-freeze' is that your messages are hidden.
 461 If prefix argument ARG is non-nil, toggle frozen status."
 462   (interactive "P")
 463   (riece-own-freeze (if riece-channel-buffer-mode
 464                         riece-channel-buffer
 465                       riece-dialogue-buffer)
 466                     (if arg (prefix-numeric-value arg))))
 467
 468 (defun riece-command-quit (&optional arg)
 469   "Quit IRC."
 470   (interactive "P")
 471   (if (y-or-n-p "Really quit IRC? ")
 472       (let ((message
 473              (if arg
 474                  (read-string "Message: ")
 475                (or riece-quit-message
 476                    (riece-extended-version)))))
 477         (riece-close-all-server message))))
 478
 479 (defun riece-command-raw (command)
 480   "Enter raw IRC command, which is sent to the server."
 481   (interactive "sIRC command: ")
 482   (riece-send-string (concat command "\r\n")))
 483
 484 (defun riece-command-end-of-buffer ()
 485   "Get end of the dialogue buffer."
 486   (interactive)
 487   (let (buffer window)
 488     (setq buffer (if riece-channel-buffer-mode
 489                      riece-channel-buffer
 490                    riece-dialogue-buffer))
 491     (or (setq window (get-buffer-window buffer))
 492         (setq window (get-buffer-window riece-dialogue-buffer)
 493               buffer riece-dialogue-buffer))
 494     (when window
 495       (save-selected-window
 496         (select-window window)
 497         (goto-char (point-max))))))
 498
 499 (defun riece-command-copy-region (start end)
 500   "Move current region between START and END to `kill-ring'."
 501   (interactive "r")
 502   (kill-new (buffer-substring-no-properties start end)))
 503
 504 (defun riece-command-open-server (server-name)
 505   (interactive
 506    (list (completing-read "Server: " riece-server-alist)))
 507   (let ((process (riece-start-server
 508                   (riece-server-name-to-server server-name)
 509                   server-name)))
 510     (with-current-buffer (process-buffer process)
 511       (setq riece-server-name server-name))
 512     (push (cons server-name process) riece-server-process-alist)))
 513
 514 (defun riece-command-close-server (server-name &optional message)
 515   (interactive
 516    (list (completing-read "Server: " riece-server-process-alist)
 517          (if current-prefix-arg
 518              (read-string "Message: ")
 519            (or riece-quit-message
 520                (riece-extended-version)))))
 521   (riece-close-server server-name message))
 522
 523 (defun riece-command-universal-server-name-argument ()
 524   (interactive)
 525   (let* ((riece-overriding-server-name
 526           (completing-read "Server: "
 527                            riece-server-process-alist))
 528          (command
 529           (key-binding (read-key-sequence
 530                         (format "Command to execute on \"%s\":"
 531                                 riece-overriding-server-name)))))
 532     (message "")
 533     (call-interactively command)))
 534
 535 (provide 'riece-commands)
 536
 537 ;;; riece-commands.el ends here