cgit.sxemacs.org Git - riece/blob - lisp/riece-addon.el

   1 ;;; riece-addon.el --- add-on management
   2 ;; Copyright (C) 1998-2004 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Created: 1998-09-28
   6 ;; Keywords: IRC, riece
   7
   8 ;; This file is part of Riece.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Code:
  26
  27 (require 'font-lock)
  28 (require 'riece-options)
  29 (require 'riece-compat)
  30 (require 'riece-misc)
  31 (require 'riece-addon-modules)
  32
  33 (defgroup riece-addon-list nil
  34   "Add-on listing."
  35   :tag "Addon list"
  36   :prefix "riece-addon-list-"
  37   :group 'riece)
  38
  39 (defgroup riece-addon-list-faces nil
  40   "Faces for riece-addon-list-mode."
  41   :tag "Faces"
  42   :prefix "riece-addon-list-"
  43   :group 'riece-addon-list)
  44
  45 (defface riece-addon-list-enabled-face
  46   '((((class color) (background dark))
  47      (:foreground "PaleTurquoise" :bold t))
  48     (t
  49      (:bold t)))
  50   "Face used for displaying the enabled addon."
  51   :group 'riece-addon-list-faces)
  52 (defvar riece-addon-list-enabled-face 'riece-addon-list-enabled-face)
  53
  54 (defface riece-addon-list-disabled-face
  55   '((((class color) (background dark))
  56      (:foreground "PaleTurquoise" :italic t))
  57     (t
  58      ()))
  59   "Face used for displaying the disabled addon."
  60   :group 'riece-addon-list-faces)
  61 (defvar riece-addon-list-disabled-face 'riece-addon-list-disabled-face)
  62
  63 (defface riece-addon-list-unsupported-face
  64   '((((class color) (background dark))
  65      (:foreground "PaleTurquoise"))
  66     (t
  67      ()))
  68   "Face used for displaying the unsupported addon."
  69   :group 'riece-addon-list-faces)
  70 (defvar riece-addon-list-unsupported-face 'riece-addon-list-unsupported-face)
  71
  72 (defface riece-addon-list-uninstalled-face
  73   '((t
  74      (:italic t)))
  75   "Face used for displaying the uninstalled addon."
  76   :group 'riece-addon-list-faces)
  77 (defvar riece-addon-list-uninstalled-face 'riece-addon-list-uninstalled-face)
  78
  79 (defface riece-addon-list-unloaded-face
  80   '((t
  81      (:italic t :inverse-video t)))
  82   "Face used for displaying the unloaded addon."
  83   :group 'riece-addon-list-faces)
  84 (defvar riece-addon-list-unloaded-face 'riece-addon-list-unloaded-face)
  85
  86 (defface riece-addon-list-description-face
  87   '((((class color)
  88       (background dark))
  89      (:foreground "lightyellow"))
  90     (((class color)
  91       (background light))
  92      (:foreground "blue4"))
  93     (t
  94      ()))
  95   "Face used for displaying the description addon."
  96   :group 'riece-addon-list-faces)
  97 (defvar riece-addon-list-description-face 'riece-addon-list-description-face)
  98
  99 (defcustom riece-addon-list-mark-face-alist
 100   '((?+ . riece-addon-list-enabled-face)
 101     (?- . riece-addon-list-disabled-face)
 102     (?! . riece-addon-list-unsupported-face)
 103     (?? . riece-addon-list-uninstalled-face)
 104     (?  . riece-addon-list-unloaded-face))
 105   "An alist mapping marks on riece-addon-list-buffer to faces."
 106   :type 'list
 107   :group 'riece-addon-list)
 108
 109 (defcustom riece-addon-list-font-lock-keywords
 110   '(("^\\([-+! ] [^:]+\\): \\(.*\\)"
 111      (1 (cdr (assq (aref (match-string 1) 0)
 112                    riece-addon-list-mark-face-alist)))
 113      (2 riece-addon-list-description-face)))
 114   "Default expressions to addon in riece-addon-list-mode."
 115   :type '(repeat (list string))
 116   :group 'riece-addon-list)
 117
 118 (defvar riece-addon-list-mode-map
 119   (let ((keymap (make-sparse-keymap)))
 120     (define-key keymap "+" 'riece-command-enable-addon)
 121     (define-key keymap "-" 'riece-command-disable-addon)
 122     (define-key keymap "i" 'riece-command-insinuate-addon)
 123     (define-key keymap "u" 'riece-command-uninstall-addon)
 124     (define-key keymap "U" 'riece-command-unload-addon)
 125     (define-key keymap "n" 'next-line)
 126     (define-key keymap "p" 'previous-line)
 127     (define-key keymap " " 'scroll-up)
 128     (define-key keymap [delete] 'scroll-down)
 129     (define-key keymap "q" 'bury-buffer)
 130     keymap))
 131
 132 (defun riece-load-and-build-addon-dependencies (addons)
 133   (let ((load-path (cons riece-addon-directory load-path))
 134         dependencies)
 135     (while addons
 136       (require (car addons))            ;error will be reported here
 137       (let* ((requires-function
 138               (intern-soft
 139                (concat (symbol-name (car addons)) "-requires")))
 140              (requires
 141               (if (and requires-function
 142                        (fboundp requires-function))
 143                   (funcall requires-function)))
 144              (pointer requires)
 145              entry)
 146         ;; Increment succs' pred count.
 147         (if (setq entry (assq (car addons) dependencies))
 148             (setcar (cdr entry) (+ (length requires) (nth 1 entry)))
 149           (setq dependencies (cons (list (car addons) (length requires))
 150                                    dependencies)))
 151         ;; Merge pred's succs.
 152         (while pointer
 153           (if (setq entry (assq (car pointer) dependencies))
 154               (setcdr (cdr entry) (cons (car addons) (nthcdr 2 entry)))
 155             (setq dependencies (cons (list (car pointer) 0 (car addons))
 156                                      dependencies)))
 157           (setq pointer (cdr pointer))))
 158       (setq addons (cdr addons)))
 159     dependencies))
 160
 161 (defun riece-sort-addon-dependencies (dependencies)
 162   (let ((pointer dependencies)
 163         addons queue)
 164     (while pointer
 165       (if (zerop (nth 1 (car pointer)))
 166           (setq dependencies (delq (car pointer) dependencies)
 167                 queue (cons (car pointer) queue)))
 168       (setq pointer (cdr pointer)))
 169     (while queue
 170       (setq addons (cons (cons (car (car queue)) (nthcdr 2 (car queue)))
 171                          addons)
 172             pointer (nthcdr 2 (car queue)))
 173       (while pointer
 174         (let* ((entry (assq (car pointer) dependencies))
 175                (count (1- (nth 1 entry))))
 176           (if (zerop count)
 177               (setq dependencies (delq entry dependencies)
 178                     queue (nconc queue (list entry)))
 179             (setcar (cdr entry) count)))
 180         (setq pointer (cdr pointer)))
 181       (setq queue (cdr queue)))
 182     (if dependencies
 183         (error "Circular add-on dependency found: %S" dependencies))
 184     (nreverse addons)))
 185
 186 (defun riece-resolve-addons (addons)
 187   ;; Add files in riece-addon-directory to addons.
 188   (if (file-directory-p riece-addon-directory)
 189       (setq addons (nconc
 190                     addons
 191                     (mapcar
 192                      (lambda (name)
 193                        (unless (file-directory-p
 194                                 (expand-file-name name riece-addon-directory))
 195                          (intern (file-name-sans-extension name))))
 196                      (directory-files riece-addon-directory nil "\\`[^.]")))))
 197   ;; Sort & uniquify.
 198   (setq addons (sort addons (lambda (symbol1 symbol2)
 199                               (string-lessp (symbol-name symbol1)
 200                                             (symbol-name symbol2)))))
 201   (let ((pointer addons))
 202     (while pointer
 203       (if (memq (car pointer) (cdr pointer))
 204           (setcar pointer nil))
 205       (setq pointer (cdr pointer)))
 206     (delq nil addons))
 207   ;; Build & resolve dependencies.
 208   (riece-sort-addon-dependencies
 209    (riece-load-and-build-addon-dependencies addons)))
 210
 211 (defun riece-insinuate-addon-1 (addon verbose)
 212   (if (get addon 'riece-addon-insinuated)
 213       (if verbose
 214           (message "Add-on %S is already insinuated" addon))
 215     (require addon)
 216     (funcall (intern (concat (symbol-name addon) "-insinuate")))
 217     (put addon 'riece-addon-insinuated t)
 218     (if verbose
 219         (message "Add-on %S is insinuated" addon))
 220     (unless (get addon 'riece-addon-default-disabled)
 221       (riece-enable-addon addon t))))
 222
 223 (defun riece-insinuate-addon (addon &optional verbose)
 224   (unless (assq addon riece-addon-dependencies)
 225     (setq riece-addons (cons addon riece-addons)
 226           riece-addon-dependencies
 227           (riece-resolve-addons
 228            (cons addon (mapcar #'car riece-addon-dependencies)))))
 229   (let ((pointer riece-addon-dependencies))
 230     (while pointer
 231       (unless (get (car (car pointer)) 'riece-addon-insinuated)
 232         (riece-insinuate-addon-1 (car (car pointer)) verbose))
 233       (if (eq (car (car pointer)) addon)
 234           (setq pointer nil)
 235         (setq pointer (cdr pointer))))))
 236
 237 (defun riece-uninstall-addon (addon &optional verbose)
 238   (if (not (get addon 'riece-addon-insinuated))
 239       (if verbose
 240           (message "Add-on %S is not insinuated" addon))
 241     (let ((entry (assq addon riece-addon-dependencies))
 242           (enabled (intern-soft (concat (symbol-name addon) "-enabled")))
 243           (uninstall (intern-soft (concat (symbol-name addon) "-uninstall"))))
 244       (if entry
 245           (if (cdr entry)
 246               (if (= (length (cdr entry)) 1)
 247                   (error "%S depends on %S" (car (cdr entry)) addon)
 248                 (error "%s depend on %S"
 249                        (mapconcat #'symbol-name (cdr entry) ", ")
 250                        addon))
 251             (if (and enabled
 252                      (boundp enabled)
 253                      (symbol-value enabled))
 254                 (riece-disable-addon addon verbose))
 255             (if (and uninstall
 256                      (fboundp uninstall))
 257                 (funcall uninstall))
 258             (setq riece-addon-dependencies
 259                   (delq entry riece-addon-dependencies))
 260             (remprop addon 'riece-addon-insinuated)
 261             (setq riece-addons (delq addon riece-addons)
 262                   riece-addon-dependencies
 263                   (riece-resolve-addons
 264                    (delq addon (mapcar #'car riece-addon-dependencies))))))
 265       (if verbose
 266           (message "Add-on %S is uninstalled" addon)))))
 267
 268 (defun riece-enable-addon (addon &optional verbose)
 269   (unless (get addon 'riece-addon-insinuated)
 270     (error "Add-on %S is not insinuated" addon))
 271   (let ((enabled (intern-soft (concat (symbol-name addon) "-enabled"))))
 272     (if (or (null enabled)
 273             (not (boundp enabled)))
 274         (if verbose
 275             (message "Add-on %S doesn't support enable/disable" addon))
 276       (if (symbol-value enabled)
 277           (if verbose
 278               (message "Add-on %S is already enabled" addon))
 279         (funcall (intern (concat (symbol-name addon) "-enable")))
 280         (if verbose
 281             (message "Add-on %S enabled" addon))))))
 282
 283 (defun riece-disable-addon (addon &optional verbose)
 284   (unless (get addon 'riece-addon-insinuated)
 285     (error "Add-on %S is not insinuated" addon))
 286   (let ((enabled (intern-soft (concat (symbol-name addon) "-enabled"))))
 287     (if (or (null enabled)
 288             (not (boundp enabled)))
 289         (if verbose
 290             (message "Add-on %S doesn't support enable/disable" addon))
 291       (if (symbol-value enabled)
 292           (progn
 293             (funcall (intern (concat (symbol-name addon) "-disable")))
 294             (if verbose
 295                 (message "Add-on %S disabled" addon)))
 296         (if verbose
 297             (message "Add-on %S is already enabled" addon))))))
 298
 299 (put 'riece-addon-list-mode 'font-lock-defaults
 300      '(riece-addon-list-font-lock-keywords t))
 301
 302 (defun riece-addon-list-mode ()
 303   "Major mode for displaying addon list.
 304 All normal editing commands are turned off."
 305   (kill-all-local-variables)
 306   (buffer-disable-undo)
 307   (setq major-mode 'riece-addon-list-mode
 308         mode-name "AddOns"
 309         mode-line-buffer-identification
 310         (riece-mode-line-buffer-identification '("Riece: %12b"))
 311         truncate-lines t
 312         buffer-read-only t)
 313   (use-local-map riece-addon-list-mode-map)
 314   (make-local-variable 'font-lock-defaults)
 315   (setq font-lock-defaults '(riece-addon-list-font-lock-keywords t))
 316   ;; In XEmacs, auto-initialization of font-lock is not effective
 317   ;; if buffer-file-name is not set.
 318   (font-lock-set-defaults)
 319   (run-hooks 'riece-addon-list-mode-hook))
 320
 321 (defun riece-command-list-addons ()
 322   (interactive)
 323   (set-buffer (riece-get-buffer-create "*AddOn*" 'riece-addon-list-mode))
 324   (riece-addon-list-mode)
 325   (let ((inhibit-read-only t)
 326         buffer-read-only
 327         (pointer riece-addon-dependencies)
 328         module-description-alist
 329         description enabled point)
 330     (while pointer
 331       (setq description (intern-soft (concat (symbol-name (car (car pointer)))
 332                                              "-description"))
 333             module-description-alist
 334             (cons (cons (car (car pointer))
 335                         (if (and description
 336                                  (boundp description))
 337                             (symbol-value description)
 338                           "(no description)"))
 339                   module-description-alist)
 340             pointer (cdr pointer)))
 341     (setq pointer riece-addon-modules)
 342     (while pointer
 343       (unless (assq (car (car pointer))
 344                     module-description-alist)
 345         (setq module-description-alist
 346               (cons (car pointer) module-description-alist)))
 347       (setq pointer (cdr pointer)))
 348     (erase-buffer)
 349     (riece-kill-all-overlays)
 350     (setq pointer (sort module-description-alist
 351                         (lambda (entry1 entry2)
 352                           (string-lessp (symbol-name (car entry1))
 353                                         (symbol-name (car entry2))))))
 354     (while pointer
 355       (setq enabled (intern-soft (concat (symbol-name (car (car pointer)))
 356                                          "-enabled")))
 357       (setq point (point))
 358       (insert (format "%c %S: %s\n"
 359                       (if (not (featurep (car (car pointer))))
 360                           ?
 361                         (if (not (get (car (car pointer))
 362                                       'riece-addon-insinuated))
 363                             ??
 364                           (if (null enabled)
 365                               ?!
 366                             (if (symbol-value enabled)
 367                                 ?+
 368                               ?-))))
 369                       (car (car pointer))
 370                       (cdr (car pointer))))
 371       (put-text-property point (point) 'riece-addon (car (car pointer)))
 372       (setq pointer (cdr pointer)))
 373     (insert "
 374 Symbols in the leftmost column:
 375
 376   +     The add-on is enabled.
 377   -     The add-on is disabled.
 378   !     The add-on doesn't support enable/disable operation.
 379   ?     The add-on is not insinuated.
 380         The add-on is not loaded.
 381 ")
 382     (insert (substitute-command-keys "
 383 Useful keys:
 384
 385   `\\[riece-command-enable-addon]' to enable the current add-on.
 386   `\\[riece-command-disable-addon]' to disable the current add-on.
 387 "))
 388     (goto-char (point-min))
 389     (pop-to-buffer (current-buffer))
 390     (delete-other-windows)))
 391
 392 (defun riece-addon-list-set-point (addon)
 393   (let ((point (point-min)))
 394     (while (and (not (eq (get-text-property point 'riece-addon) addon))
 395                 (setq point (next-single-property-change point
 396                                                          'riece-addon))))
 397     (if point
 398         (goto-char point))))
 399
 400 (defun riece-command-enable-addon (addon)
 401   (interactive
 402    (list
 403     (or (if (eq major-mode 'riece-addon-list-mode)
 404             (get-text-property (point) 'riece-addon))
 405         (intern-soft
 406          (completing-read "Add-on: "
 407                           (mapcar (lambda (dependency)
 408                                     (list (symbol-name (car dependency))))
 409                                   riece-addon-dependencies)
 410                           (lambda (pointer)
 411                             (let ((enabled
 412                                    (intern-soft (concat (car pointer)
 413                                                         "-enabled"))))
 414                               (and enabled
 415                                    (null (symbol-value enabled)))))
 416                           t)))))
 417   (riece-enable-addon addon t)
 418   (when (eq major-mode 'riece-addon-list-mode)
 419     (riece-command-list-addons)
 420     (riece-addon-list-set-point addon)))
 421
 422 (defun riece-command-disable-addon (addon)
 423   (interactive
 424    (list
 425     (or (if (eq major-mode 'riece-addon-list-mode)
 426             (get-text-property (point) 'riece-addon))
 427         (intern-soft
 428          (completing-read "Add-on: "
 429                           (mapcar (lambda (dependency)
 430                                     (list (symbol-name (car dependency))))
 431                                   riece-addon-dependencies)
 432                           (lambda (pointer)
 433                             (let ((enabled
 434                                    (intern-soft (concat (car pointer)
 435                                                         "-enabled"))))
 436                               (and enabled
 437                                    (symbol-value enabled))))
 438                           t)))))
 439   (riece-disable-addon addon t)
 440   (when (eq major-mode 'riece-addon-list-mode)
 441     (riece-command-list-addons)
 442     (riece-addon-list-set-point addon)))
 443
 444 (defun riece-command-insinuate-addon (addon)
 445   (interactive
 446    (list
 447     (or (if (eq major-mode 'riece-addon-list-mode)
 448             (get-text-property (point) 'riece-addon))
 449         (intern-soft
 450          (completing-read "Add-on: "
 451                           (mapcar (lambda (dependency)
 452                                     (list (symbol-name (car dependency))))
 453                                   riece-addon-modules)
 454                           (lambda (pointer)
 455                             (not (get (car pointer) 'riece-addon-insinuated)))
 456                           t)))))
 457   (riece-insinuate-addon addon t)
 458   (when (eq major-mode 'riece-addon-list-mode)
 459     (riece-command-list-addons)
 460     (riece-addon-list-set-point addon)))
 461
 462 (defun riece-command-uninstall-addon (addon)
 463   (interactive
 464    (list
 465     (or (if (eq major-mode 'riece-addon-list-mode)
 466             (get-text-property (point) 'riece-addon))
 467         (intern-soft
 468          (completing-read "Add-on: "
 469                           (mapcar (lambda (dependency)
 470                                     (list (symbol-name (car dependency))))
 471                                   riece-addon-dependencies)
 472                           (lambda (pointer)
 473                             (get (car pointer) 'riece-addon-insinuated))
 474                           t)))))
 475   (riece-uninstall-addon addon t)
 476   (when (eq major-mode 'riece-addon-list-mode)
 477     (riece-command-list-addons)
 478     (riece-addon-list-set-point addon)))
 479
 480 (defun riece-command-unload-addon (addon)
 481   (interactive
 482    (list
 483     (or (if (eq major-mode 'riece-addon-list-mode)
 484             (get-text-property (point) 'riece-addon))
 485         (intern-soft
 486          (completing-read "Add-on: "
 487                           (mapcar (lambda (dependency)
 488                                     (list (symbol-name (car dependency))))
 489                                   riece-addon-dependencies)
 490                           (lambda (pointer)
 491                             (get (car pointer) 'riece-addon-insinuated))
 492                           t)))))
 493   (riece-uninstall-addon addon t)
 494   (if (get addon 'riece-addon-not-unloadable)
 495       (message "Add-on %S is not allowed to unload" addon)
 496     (unload-feature addon)
 497     (message "Add-on %S is unloaded" addon))
 498   (when (eq major-mode 'riece-addon-list-mode)
 499     (riece-command-list-addons)
 500     (riece-addon-list-set-point addon)))
 501
 502 (provide 'riece-addon)
 503
 504 ;;; riece-addon.el ends here