cgit.sxemacs.org Git - riece/blob - lisp/riece-addon.el

   1 ;;; riece-addon.el --- add-on management
   2 ;; Copyright (C) 1998-2004 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Created: 1998-09-28
   6 ;; Keywords: IRC, riece
   7
   8 ;; This file is part of Riece.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Code:
  26
  27 (require 'font-lock)
  28 (require 'riece-options)
  29 (require 'riece-compat)
  30 (require 'riece-misc)
  31
  32 (defgroup riece-addon-list nil
  33   "Add-on management"
  34   :tag "Addon"
  35   :prefix "riece-"
  36   :group 'riece)
  37
  38 (defgroup riece-addon-list-faces nil
  39   "Faces for riece-addon-list-mode"
  40   :tag "Faces"
  41   :prefix "riece-addon-list"
  42   :group 'riece-addon)
  43
  44 (defface riece-addon-list-enabled-face
  45   '((((class color) (background dark))
  46      (:foreground "PaleTurquoise" :bold t))
  47     (t
  48      (:bold t)))
  49   "Face used for displaying the enabled addon."
  50   :group 'riece-addon-list-faces)
  51 (defvar riece-addon-list-enabled-face 'riece-addon-list-enabled-face)
  52
  53 (defface riece-addon-list-disabled-face
  54   '((((class color) (background dark))
  55      (:foreground "PaleTurquoise" :italic t))
  56     (t
  57      (:italic t)))
  58   "Face used for displaying the disabled addon."
  59   :group 'riece-addon-list-faces)
  60 (defvar riece-addon-list-disabled-face 'riece-addon-list-disabled-face)
  61
  62 (defface riece-addon-list-unsupported-face
  63   '((((class color) (background dark))
  64      (:foreground "PaleTurquoise"))
  65     (t
  66      ()))
  67   "Face used for displaying the unsupported addon."
  68   :group 'riece-addon-list-faces)
  69 (defvar riece-addon-list-unsupported-face 'riece-addon-list-unsupported-face)
  70
  71 (defface riece-addon-list-unknown-face
  72   '((t
  73      (:foreground "red")))
  74   "Face used for displaying the unknown addon."
  75   :group 'riece-addon-list-faces)
  76 (defvar riece-addon-list-unknown-face 'riece-addon-list-unknown-face)
  77
  78 (defface riece-addon-list-description-face
  79   '((((class color)
  80       (background dark))
  81      (:foreground "lightyellow"))
  82     (((class color)
  83       (background light))
  84      (:foreground "blue4"))
  85     (t
  86      ()))
  87   "Face used for displaying the description addon."
  88   :group 'riece-addon-list-faces)
  89 (defvar riece-addon-list-description-face 'riece-addon-list-description-face)
  90
  91 (defcustom riece-addon-list-mark-face-alist
  92   '((?+ . riece-addon-list-enabled-face)
  93     (?- . riece-addon-list-disabled-face)
  94     (?! . riece-addon-list-unsupported-face)
  95     (?? . riece-addon-list-unknown-face))
  96   "An alist mapping marks on riece-addon-list-buffer to faces."
  97   :type 'list
  98   :group 'riece-addon-list)
  99
 100 (defcustom riece-addon-list-font-lock-keywords
 101   '(("^\\([-+!?] [^:]+\\): \\(.*\\)"
 102      (1 (cdr (assq (aref (match-string 1) 0)
 103                    riece-addon-list-mark-face-alist)))
 104      (2 riece-addon-list-description-face)))
 105   "Default expressions to addon in riece-addon-list-mode."
 106   :type '(repeat (list string))
 107   :group 'riece-addon-list)
 108
 109 (defvar riece-addon-list-mode-map
 110   (let ((keymap (make-sparse-keymap)))
 111     (define-key keymap "+" 'riece-command-enable-addon)
 112     (define-key keymap "-" 'riece-command-disable-addon)
 113     (define-key keymap "n" 'next-line)
 114     (define-key keymap "p" 'previous-line)
 115     (define-key keymap " " 'scroll-up)
 116     (define-key keymap [delete] 'scroll-down)
 117     (define-key keymap "q" 'bury-buffer)
 118     keymap))
 119
 120 (defun riece-load-and-build-addon-dependencies (addons)
 121   (let ((load-path (cons riece-addon-directory load-path))
 122         dependencies)
 123     (while addons
 124       (require (car addons))            ;error will be reported here
 125       (let* ((requires
 126               (funcall (or (intern-soft
 127                             (concat (symbol-name (car addons)) "-requires"))
 128                            #'ignore)))
 129              (pointer requires)
 130              entry)
 131         ;; Increment succs' pred count.
 132         (if (setq entry (assq (car addons) dependencies))
 133             (setcar (cdr entry) (+ (length requires) (nth 1 entry)))
 134           (setq dependencies (cons (list (car addons) (length requires))
 135                                    dependencies)))
 136         ;; Merge pred's succs.
 137         (while pointer
 138           (if (setq entry (assq (car pointer) dependencies))
 139               (setcdr (cdr entry)
 140                       (cons (car addons) (nthcdr 2 entry)))
 141             (setq dependencies (cons (list (car pointer) 0 (car addons))
 142                                      dependencies)))
 143           (setq pointer (cdr pointer))))
 144       (setq addons (cdr addons)))
 145     dependencies))
 146
 147 (defun riece-resolve-addon-dependencies (addons)
 148   (let ((pointer addons)
 149         dependencies queue)
 150     ;; Uniquify, first.
 151     (while pointer
 152       (if (memq (car pointer) (cdr pointer))
 153           (setcar pointer nil))
 154       (setq pointer (cdr pointer)))
 155     (setq dependencies (riece-load-and-build-addon-dependencies
 156                         (delq nil addons))
 157           pointer dependencies)
 158     ;; Sort them.
 159     (while pointer
 160       (if (zerop (nth 1 (car pointer)))
 161           (setq dependencies (delq (car pointer) dependencies)
 162                 queue (cons (car pointer) queue)))
 163       (setq pointer (cdr pointer)))
 164     (setq addons nil)
 165     (while queue
 166       (setq addons (cons (car (car queue)) addons)
 167             pointer (nthcdr 2 (car queue)))
 168       (while pointer
 169         (let* ((entry (assq (car pointer) dependencies))
 170                (count (1- (nth 1 entry))))
 171           (if (zerop count)
 172               (progn
 173                 (setq dependencies (delq entry dependencies)
 174                       queue (nconc queue (list entry))))
 175             (setcar (cdr entry) count)))
 176         (setq pointer (cdr pointer)))
 177       (setq queue (cdr queue)))
 178     (if dependencies
 179         (error "Circular add-on dependency found"))
 180     (nreverse addons)))
 181
 182 (defun riece-resolve-addons (addons)
 183   (riece-resolve-addon-dependencies
 184    (if (file-directory-p riece-addon-directory)
 185        (append addons
 186                (mapcar
 187                 (lambda (name)
 188                   (unless (file-directory-p name)
 189                     (intern (file-name-sans-extension name))))
 190                 (directory-files riece-addon-directory nil "\\`[^.]" t)))
 191      addons)))
 192
 193 (defun riece-insinuate-addon (addon &optional verbose)
 194   (require addon)               ;implicit dependency
 195   (funcall (intern (concat (symbol-name addon) "-insinuate")))
 196   (if verbose
 197       (message "Add-on %S is insinuated" addon)))
 198
 199 (defun riece-enable-addon (addon &optional verbose)
 200   (let ((enabled (intern-soft (concat (symbol-name addon) "-enabled"))))
 201     (if (null enabled)
 202         (if verbose
 203             (message "Add-on %S doesn't support enable/disable" addon))
 204       (if (symbol-value enabled)
 205           (if verbose
 206               (message "Can't enable add-on %S" addon))
 207         (funcall (intern (concat (symbol-name addon) "-enable")))
 208         (if verbose
 209             (message "Add-on %S enabled" addon))))))
 210
 211 (defun riece-disable-addon (addon &optional verbose)
 212   (let ((enabled (intern-soft (concat (symbol-name addon) "-enabled"))))
 213     (if (null enabled)
 214         (if verbose
 215             (message "Add-on %S doesn't support enable/disable" addon))
 216       (if (symbol-value enabled)
 217           (progn
 218             (funcall (intern (concat (symbol-name addon) "-disable")))
 219             (if verbose
 220                 (message "Add-on %S disabled" addon)))
 221         (if verbose
 222             (message "Can't disable add-on %S" addon))))))
 223
 224 (put 'riece-addon-list-mode 'font-lock-defaults
 225      '(riece-addon-list-font-lock-keywords t))
 226
 227 (defun riece-addon-list-mode ()
 228   "Major mode for displaying addon list.
 229 All normal editing commands are turned off."
 230   (kill-all-local-variables)
 231   (buffer-disable-undo)
 232   (setq major-mode 'riece-addon-list-mode
 233         mode-name "AddOns"
 234         mode-line-buffer-identification
 235         (riece-mode-line-buffer-identification '("Riece: %12b"))
 236         truncate-lines t
 237         buffer-read-only t)
 238   (use-local-map riece-addon-list-mode-map)
 239   (make-local-variable 'font-lock-defaults)
 240   (setq font-lock-defaults '(riece-addon-list-font-lock-keywords t))
 241   ;; In XEmacs, auto-initialization of font-lock is not affective
 242   ;; when buffer-file-name is not set.
 243   (font-lock-set-defaults)
 244   (run-hooks 'riece-addon-list-mode-hook))
 245
 246 (defun riece-command-list-addons ()
 247   (interactive)
 248   (set-buffer (riece-get-buffer-create "*AddOns*" 'riece-addon-list-mode))
 249   (riece-addon-list-mode)
 250   (let ((inhibit-read-only t)
 251         buffer-read-only
 252         (pointer (sort (copy-sequence riece-addons)
 253                        (lambda (symbol1 symbol2)
 254                                   (string-lessp (symbol-name symbol1)
 255                                                 (symbol-name symbol2)))))
 256         enabled description point)
 257     (erase-buffer)
 258     (riece-kill-all-overlays)
 259     (while pointer
 260       (setq enabled (intern-soft (concat (symbol-name (car pointer))
 261                                          "-enabled"))
 262             description (intern-soft (concat (symbol-name (car pointer))
 263                                              "-description")))
 264       (setq point (point))
 265       (insert (format "%c %S: %s\n"
 266                       (if (not (featurep (car pointer)))
 267                           ??
 268                         (if (null enabled)
 269                             ?!
 270                           (if (symbol-value enabled)
 271                               ?+
 272                             ?-)))
 273                       (car pointer)
 274                       (if description
 275                           (symbol-value description)
 276                         "(no description)")))
 277       (put-text-property point (point) 'riece-addon (car pointer))
 278       (setq pointer (cdr pointer)))
 279     (insert "
 280 Symbols in the leftmost column:
 281
 282   +     The add-on is enabled.
 283   -     The add-on is disabled.
 284   !     The add-on doesn't support enable/disable operation.
 285   ?     The add-on status is unknown.
 286 ")
 287     (insert (substitute-command-keys "
 288 Useful keys:
 289
 290   `\\[riece-command-enable-addon]' to enable the current add-on.
 291   `\\[riece-command-disable-addon]' to disable the current add-on.
 292 "))
 293     (goto-char (point-min))
 294     (pop-to-buffer (current-buffer))
 295     (delete-other-windows)))
 296
 297 (defun riece-command-enable-addon (addon)
 298   (interactive
 299    (list
 300     (or (if (eq major-mode 'riece-addon-list-mode)
 301             (get-text-property (point) 'riece-addon))
 302         (intern-soft
 303          (completing-read "Add-on: "
 304                           (mapcar (lambda (addon)
 305                                     (list (symbol-name addon)))
 306                                   riece-addons)
 307                           (lambda (pointer)
 308                             (let ((enabled
 309                                    (intern-soft (concat (car pointer)
 310                                                         "-enabled"))))
 311                               (and enabled
 312                                    (null (symbol-value enabled)))))
 313                           t)))))
 314   (riece-enable-addon addon t)
 315   (let ((enabled (intern-soft (concat (symbol-name addon) "-enabled"))))
 316     (if (and (eq major-mode 'riece-addon-list-mode)
 317              (get-text-property (point) 'riece-addon)
 318              enabled (symbol-value enabled))
 319         (save-excursion
 320           (beginning-of-line)
 321           (let ((point (point))
 322                 (inhibit-read-only t)
 323                 buffer-read-only)
 324             (delete-char 1)
 325             (insert "+")
 326             (put-text-property point (point) 'riece-addon addon))))))
 327
 328 (defun riece-command-disable-addon (addon)
 329   (interactive
 330    (list
 331     (or (if (eq major-mode 'riece-addon-list-mode)
 332             (get-text-property (point) 'riece-addon))
 333         (intern-soft
 334          (completing-read "Add-on: "
 335                           (mapcar (lambda (addon)
 336                                     (list (symbol-name addon)))
 337                                   riece-addons)
 338                           (lambda (pointer)
 339                             (let ((enabled
 340                                    (intern-soft (concat (car pointer)
 341                                                         "-enabled"))))
 342                               (and enabled
 343                                    (symbol-value enabled))))
 344                           t)))))
 345   (riece-disable-addon addon t)
 346   (let ((enabled (intern-soft (concat (symbol-name addon) "-enabled"))))
 347     (if (and (eq major-mode 'riece-addon-list-mode)
 348              (get-text-property (point) 'riece-addon)
 349              enabled (null (symbol-value enabled)))
 350         (save-excursion
 351           (beginning-of-line)
 352           (let ((point (point))
 353                 (inhibit-read-only t)
 354                 buffer-read-only)
 355             (delete-char 1)
 356             (insert "-")
 357             (put-text-property point (point) 'riece-addon addon))))))
 358
 359 (provide 'riece-addon)
 360
 361 ;;; riece-addon.el ends here