cgit.sxemacs.org Git - gnus/blob - lisp/smime.el

   1 ;;; smime.el --- S/MIME support library
   2 ;; Copyright (c) 2000, 2001 Free Software Foundation, Inc.
   3
   4 ;; Author: Simon Josefsson <simon@josefsson.org>
   5 ;; Keywords: SMIME X.509 PEM OpenSSL
   6
   7 ;; This file is not a part of GNU Emacs, but the same permissions apply.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published
  11 ;; by the Free Software Foundation; either version 2, or (at your
  12 ;; option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful, but
  15 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 ;; General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; This library perform S/MIME operations from within Emacs.
  27 ;;
  28 ;; Functions for fetching certificates from public repositories are
  29 ;; provided, currently only from DNS.  LDAP support (via EUDC) is planned.
  30 ;;
  31 ;; It uses OpenSSL (tested with version 0.9.5a and 0.9.6) for signing,
  32 ;; encryption and decryption.
  33 ;;
  34 ;; Some general knowledge of S/MIME, X.509, PKCS#12, PEM etc is
  35 ;; probably required to use this library in any useful way.
  36 ;; Especially, don't expect this library to buy security for you.  If
  37 ;; you don't understand what you are doing, you're as likely to lose
  38 ;; security than gain any by using this library.
  39 ;;
  40 ;; This library is not intended to provide a "raw" API for S/MIME,
  41 ;; PKCSx or similar, it's intended to perform common operations
  42 ;; done on messages encoded in these formats.  The terminology chosen
  43 ;; reflect this.
  44
  45 ;;; Quick introduction:
  46
  47 ;; Get your S/MIME certificate from VeriSign or someplace.  I used
  48 ;; Netscape to generate the key and certificate request and stuff, and
  49 ;; Netscape can export the key into PKCS#12 format.
  50 ;;
  51 ;; Enter OpenSSL.  To be able to use this library, it need to have the
  52 ;; SMIME key readable in PEM format.  OpenSSL is used to convert the
  53 ;; key:
  54 ;;
  55 ;; $ openssl pkcs12 -in mykey.p12 -clcerts -nodes > mykey.pem
  56 ;; ...
  57 ;;
  58 ;; Now, use M-x customize-variable smime-keys and add mykey.pem as
  59 ;; a key.
  60 ;;
  61 ;; Now you should be able to sign messages!  Create a buffer and write
  62 ;; something and run M-x smime-sign-buffer RET RET and you should see
  63 ;; your message MIME armoured and a signature.  Encryption, M-x
  64 ;; smime-encrypt-buffer, should also work.
  65 ;;
  66 ;; To be able to verify messages you need to build up trust with
  67 ;; someone.  Perhaps you trust the CA that issued your certificate, at
  68 ;; least I did, so I export it's certificates from my PKCS#12
  69 ;; certificate with:
  70 ;;
  71 ;; $ openssl pkcs12 -in mykey.p12 -cacerts -nodes > cacert.pem
  72 ;; ...
  73 ;;
  74 ;; Now, use M-x customize-variable smime-CAs and add cacert.pem as a
  75 ;; CA certificate.
  76 ;;
  77 ;; You should now be able to sign messages, and even verify messages
  78 ;; sent by others that use the same CA as you.
  79
  80 ;; Bugs:
  81 ;;
  82 ;; Don't complain that this package doesn't do encrypted PEM files,
  83 ;; submit a patch instead.  I store my keys in a safe place, so I
  84 ;; didn't need the encryption.  Also, programming was made easier by
  85 ;; that decision.  One might think that this even influenced were I
  86 ;; store my keys, and one would probably be right. :-)
  87 ;;
  88 ;; Update: Mathias Herberts sent the patch.  However, it uses
  89 ;; environment variables to pass the password to OpenSSL, which is
  90 ;; slightly insecure. Hence a new todo: use a better -passin method.
  91 ;;
  92 ;; Suggestions and comments are appreciated, mail me at simon@josefsson.org.
  93
  94 ;; <rant>
  95 ;;
  96 ;; I would include pointers to introductory text on concepts used in
  97 ;; this library here, but the material I've read are so horrible I
  98 ;; don't want to recomend them.
  99 ;;
 100 ;; Why can't someone write a simple introduction to all this stuff?
 101 ;; Until then, much of this resemble security by obscurity.
 102 ;;
 103 ;; Also, I'm not going to mention anything about the wonders of
 104 ;; cryptopolitics.  Oops, I just did.
 105 ;;
 106 ;; </rant>
 107
 108 ;;; Revision history:
 109
 110 ;; version 0 not released
 111
 112 ;;; Code:
 113
 114 (require 'dig)
 115 (require 'comint)
 116 (eval-when-compile (require 'cl))
 117
 118 (defgroup smime nil
 119   "S/MIME configuration.")
 120
 121 (defcustom smime-keys nil
 122   "Map mail addresses to a file containing Certificate (and private key).
 123 The file is assumed to be in PEM format. You can also associate additional
 124 certificates to be sent with every message to each address."
 125   :type '(repeat (list (string :tag "Mail address")
 126                        (file :tag "File name")
 127                        (repeat :tag "Additional certificate files"
 128                                (file :tag "File name"))))
 129   :group 'smime)
 130
 131 (defcustom smime-CA-directory nil
 132   "Directory containing certificates for CAs you trust.
 133 Directory should contain files (in PEM format) named to the X.509
 134 hash of the certificate.  This can be done using OpenSSL such as:
 135
 136 $ ln -s ca.pem `openssl x509 -noout -hash -in ca.pem`
 137
 138 where `ca.pem' is the file containing a PEM encoded X.509 CA
 139 certificate."
 140   :type '(choice (const :tag "none" nil)
 141                  directory)
 142   :group 'smime)
 143
 144 (defcustom smime-CA-file nil
 145   "Files containing certificates for CAs you trust.
 146 File should contain certificates in PEM format."
 147   :type '(choice (const :tag "none" nil)
 148                  file)
 149   :group 'smime)
 150
 151 (defcustom smime-certificate-directory "~/Mail/certs/"
 152   "Directory containing other people's certificates.
 153 It should contain files named to the X.509 hash of the certificate,
 154 and the files themself should be in PEM format."
 155 ;The S/MIME library provide simple functionality for fetching
 156 ;certificates into this directory, so there is no need to populate it
 157 ;manually.
 158   :type 'directory
 159   :group 'smime)
 160
 161 (defcustom smime-openssl-program
 162   (and (condition-case ()
 163            (eq 0 (call-process "openssl" nil nil nil "version"))
 164          (error nil))
 165        "openssl")
 166   "Name of OpenSSL binary."
 167   :type 'string
 168   :group 'smime)
 169
 170 ;; OpenSSL option to select the encryption cipher
 171
 172 (defcustom smime-encrypt-cipher "-des3"
 173   "Cipher algorithm used for encryption."
 174   :type '(choice (const :tag "Triple DES" "-des3")
 175                  (const :tag "DES"  "-des")
 176                  (const :tag "RC2 40 bits" "-rc2-40")
 177                  (const :tag "RC2 64 bits" "-rc2-64")
 178                  (const :tag "RC2 128 bits" "-rc2-128"))
 179   :group 'smime)
 180
 181 (defcustom smime-dns-server nil
 182   "DNS server to query certificates from.
 183 If nil, use system defaults."
 184   :type '(choice (const :tag "System defaults")
 185                  string)
 186   :group 'dig)
 187
 188 (defvar smime-details-buffer "*OpenSSL output*")
 189
 190 ;; Password dialog function
 191
 192 (defun smime-ask-passphrase ()
 193   "Asks the passphrase to unlock the secret key."
 194   (let ((passphrase
 195          (comint-read-noecho
 196           "Passphrase for secret key (RET for no passphrase): " t)))
 197     (if (string= passphrase "")
 198         nil
 199       passphrase)))
 200
 201 ;; OpenSSL wrappers.
 202
 203 (defun smime-call-openssl-region (b e buf &rest args)
 204   (case (apply 'call-process-region b e smime-openssl-program nil buf nil args)
 205     (0 t)
 206     (1 (message "OpenSSL: An error occurred parsing the command options.") nil)
 207     (2 (message "OpenSSL: One of the input files could not be read.") nil)
 208     (3 (message "OpenSSL: An error occurred creating the PKCS#7 file or when reading the MIME message.") nil)
 209     (4 (message "OpenSSL: An error occurred decrypting or verifying the message.") nil)
 210     (t (error "Unknown OpenSSL exitcode") nil)))
 211
 212 (defun smime-make-certfiles (certfiles)
 213   (if certfiles
 214       (append (list "-certfile" (expand-file-name (car certfiles)))
 215               (smime-make-certfiles (cdr certfiles)))))
 216
 217 ;; Sign+encrypt region
 218
 219 (defun smime-sign-region (b e keyfiles)
 220   "Sign region with certified key in KEYFILES.
 221 If signing fails, the buffer is not modified.  Region is assumed to
 222 have proper MIME tags.  KEYFILES is expected to contain a PEM encoded
 223 private key and certificate as its car, and a list of additional certificates
 224 to include in its caar."
 225   (let ((keyfile (car keyfiles))
 226         (certfiles (and (cdr keyfiles) (cadr keyfiles)))
 227         (buffer (generate-new-buffer (generate-new-buffer-name " *smime*")))
 228         (passphrase (smime-ask-passphrase)))
 229     (if passphrase
 230         (setenv "GNUS_SMIME_PASSPHRASE" passphrase))
 231     (prog1
 232         (when (apply 'smime-call-openssl-region b e buffer "smime" "-sign"
 233                      "-signer" (expand-file-name keyfile)
 234                      (append
 235                       (smime-make-certfiles certfiles)
 236                       (if passphrase
 237                           (list "-passin" "env:GNUS_SMIME_PASSPHRASE"))))
 238           (delete-region b e)
 239           (insert-buffer buffer)
 240           (when (looking-at "^MIME-Version: 1.0$")
 241             (delete-region (point) (progn (forward-line 1) (point))))
 242           t)
 243       (if passphrase
 244           (setenv "GNUS_SMIME_PASSPHRASE" "" t))
 245       (with-current-buffer (get-buffer-create smime-details-buffer)
 246         (goto-char (point-max))
 247         (insert-buffer buffer))
 248       (kill-buffer buffer))))
 249
 250 (defun smime-encrypt-region (b e certfiles)
 251   "Encrypt region for recipients specified in CERTFILES.
 252 If encryption fails, the buffer is not modified.  Region is assumed to
 253 have proper MIME tags.  CERTFILES is a list of filenames, each file
 254 is expected to contain of a PEM encoded certificate."
 255   (let ((buffer (generate-new-buffer (generate-new-buffer-name " *smime*"))))
 256     (prog1
 257         (when (apply 'smime-call-openssl-region b e buffer "smime" "-encrypt"
 258                      smime-encrypt-cipher (mapcar 'expand-file-name certfiles))
 259           (delete-region b e)
 260           (insert-buffer buffer)
 261           (when (looking-at "^MIME-Version: 1.0$")
 262             (delete-region (point) (progn (forward-line 1) (point))))
 263           t)
 264       (with-current-buffer (get-buffer-create smime-details-buffer)
 265         (goto-char (point-max))
 266         (insert-buffer buffer))
 267       (kill-buffer buffer))))
 268
 269 (defun smime-get-certfiles (keyfile keys)
 270   (if keys
 271       (let ((curkey (car keys))
 272             (otherkeys (cdr keys)))
 273         (if (string= keyfile (cadr curkey))
 274             (caddr curkey)
 275           (smime-get-certfiles keyfile otherkeys)))))
 276
 277 ;; Sign+encrypt buffer
 278
 279 (defun smime-sign-buffer (&optional keyfile buffer)
 280   "S/MIME sign BUFFER with key in KEYFILE.
 281 KEYFILE should contain a PEM encoded key and certificate."
 282   (interactive)
 283   (with-current-buffer (or buffer (current-buffer))
 284     (smime-sign-region
 285      (point-min) (point-max)
 286      (if keyfile
 287          (list keyfile (smime-get-certfiles keyfile smime-keys))
 288        (smime-get-key-by-email
 289         (completing-read "Sign using which signature? " smime-keys nil nil
 290                          (and (listp (car-safe smime-keys))
 291                               (cdr smime-keys))))))))
 292
 293 (defun smime-encrypt-buffer (&optional certfiles buffer)
 294   "S/MIME encrypt BUFFER for recipients specified in CERTFILES.
 295 CERTFILES is a list of filenames, each file is expected to consist of
 296 a PEM encoded key and certificate.  Uses current buffer if BUFFER is
 297 nil."
 298   (interactive)
 299   (with-current-buffer (or buffer (current-buffer))
 300     (smime-encrypt-region
 301      (point-min) (point-max)
 302      (or certfiles
 303          (list (read-file-name "Recipient's S/MIME certificate: "
 304                                smime-certificate-directory nil))))))
 305
 306 ;; Verify+decrypt region
 307
 308 (defun smime-verify-region (b e)
 309   (let ((buffer (get-buffer-create smime-details-buffer))
 310         (CAs (append (if smime-CA-file
 311                          (list "-CAfile"
 312                                (expand-file-name smime-CA-file)))
 313                      (if smime-CA-directory
 314                          (list "-CApath"
 315                                (expand-file-name smime-CA-directory))))))
 316     (unless CAs (error "No CA configured"))
 317     (with-current-buffer buffer
 318       (erase-buffer))
 319     (if (apply 'smime-call-openssl-region b e buffer "smime" "-verify"
 320                "-out" "/dev/null" CAs)
 321         (message "S/MIME message verified succesfully.")
 322       (message "S/MIME message NOT verified successfully.")
 323       nil)))
 324
 325 (defun smime-noverify-region (b e)
 326   (let ((buffer (get-buffer-create smime-details-buffer)))
 327     (with-current-buffer buffer
 328       (erase-buffer))
 329     (if (apply 'smime-call-openssl-region b e buffer "smime" "-verify"
 330                "-noverify" "-out" '("/dev/null"))
 331         (message "S/MIME message verified succesfully.")
 332       (message "S/MIME message NOT verified successfully.")
 333       nil)))
 334
 335 (defun smime-decrypt-region (b e keyfile)
 336   (let ((buffer (generate-new-buffer (generate-new-buffer-name "*smime*")))
 337         CAs (passphrase (smime-ask-passphrase)))
 338     (if passphrase
 339         (setenv "GNUS_SMIME_PASSPHRASE" passphrase))
 340     (when (apply 'smime-call-openssl-region
 341                  b e buffer "smime" "-decrypt"
 342                  "-recip" keyfile
 343                  (if passphrase
 344                      (list "-passin" "env:GNUS_SMIME_PASSPHRASE" )))
 345       (delete-region b e)
 346       (insert-buffer buffer))
 347     (if passphrase
 348         (setenv "GNUS_SMIME_PASSPHRASE" "" t))
 349     (with-current-buffer (get-buffer-create smime-details-buffer)
 350       (goto-char (point-max))
 351       (insert-buffer buffer))
 352     (kill-buffer buffer)))
 353
 354 ;; Verify+Decrypt buffer
 355
 356 (defun smime-verify-buffer (&optional buffer)
 357   "Verify integrity of S/MIME message in BUFFER.
 358 Uses current buffer if BUFFER is nil."
 359   (interactive)
 360   (with-current-buffer (or buffer (current-buffer))
 361     (smime-verify-region (point-min) (point-max))))
 362
 363 (defun smime-noverify-buffer (&optional buffer)
 364   "Verify integrity of S/MIME message in BUFFER.
 365 Uses current buffer if BUFFER is nil.
 366 Does NOT verify validity of certificate."
 367   (interactive)
 368   (with-current-buffer (or buffer (current-buffer))
 369     (smime-noverify-region (point-min) (point-max))))
 370
 371 (defun smime-decrypt-buffer (&optional buffer keyfile)
 372   "Decrypt S/MIME message in BUFFER using KEYFILE.
 373 Uses current buffer if BUFFER is nil, queries user of KEYFILE is nil."
 374   (interactive)
 375   (with-current-buffer (or buffer (current-buffer))
 376     (smime-decrypt-region
 377      (point-min) (point-max)
 378      (expand-file-name
 379       (or keyfile
 380           (smime-get-key-by-email
 381            (completing-read "Decrypt with which key? " smime-keys nil nil
 382                             (and (listp (car-safe smime-keys))
 383                                  (caar smime-keys)))))))))
 384
 385 ;; Various operations
 386
 387 (defun smime-pkcs7-region (b e)
 388   "Convert S/MIME message between points B and E into a PKCS7 message."
 389   (let ((buffer (get-buffer-create smime-details-buffer)))
 390     (with-current-buffer buffer
 391       (erase-buffer))
 392     (when (smime-call-openssl-region b e buffer "smime" "-pk7out")
 393       (delete-region b e)
 394       (insert-buffer-substring buffer)
 395       t)))
 396
 397 (defun smime-pkcs7-certificates-region (b e)
 398   "Extract any certificates enclosed in PKCS7 message between points B and E."
 399   (let ((buffer (get-buffer-create smime-details-buffer)))
 400     (with-current-buffer buffer
 401       (erase-buffer))
 402     (when (smime-call-openssl-region b e buffer "pkcs7" "-print_certs" "-text")
 403       (delete-region b e)
 404       (insert-buffer-substring buffer)
 405       t)))
 406
 407 (defun smime-pkcs7-email-region (b e)
 408   "Get email addresses contained in certificate between points B and E.
 409 A string or a list of strings is returned."
 410   (let ((buffer (get-buffer-create smime-details-buffer)))
 411     (with-current-buffer buffer
 412       (erase-buffer))
 413     (when (smime-call-openssl-region b e buffer "x509" "-email" "-noout")
 414       (delete-region b e)
 415       (insert-buffer-substring buffer)
 416       t)))
 417
 418 (defalias 'smime-point-at-eol
 419   (if (fboundp 'point-at-eol)
 420       'point-at-eol
 421     'line-end-position))
 422
 423 (defun smime-buffer-as-string-region (b e)
 424   "Return each line in region between B and E as a list of strings."
 425   (save-excursion
 426     (goto-char b)
 427     (let (res)
 428       (while (< (point) e)
 429         (let ((str (buffer-substring (point) (smime-point-at-eol))))
 430           (unless (string= "" str)
 431             (push str res)))
 432         (forward-line))
 433       res)))
 434
 435 ;; Find certificates
 436
 437 (defun smime-mail-to-domain (mailaddr)
 438   (if (string-match "@" mailaddr)
 439       (replace-match "." 'fixedcase 'literal mailaddr)
 440     mailaddr))
 441
 442 (defun smime-cert-by-dns (mail)
 443   (let* ((dig-dns-server smime-dns-server)
 444          (digbuf (dig-invoke (smime-mail-to-domain mail) "cert" nil nil "+vc"))
 445          (retbuf (generate-new-buffer (format "*certificate for %s*" mail)))
 446          (certrr (with-current-buffer digbuf
 447                    (dig-extract-rr (smime-mail-to-domain mail) "cert")))
 448          (cert (and certrr (dig-rr-get-pkix-cert certrr))))
 449       (if cert
 450           (with-current-buffer retbuf
 451             (insert "-----BEGIN CERTIFICATE-----\n")
 452             (let ((i 0) (len (length cert)))
 453               (while (> (- len 64) i)
 454                 (insert (substring cert i (+ i 64)) "\n")
 455                 (setq i (+ i 64)))
 456               (insert (substring cert i len) "\n"))
 457             (insert "-----END CERTIFICATE-----\n"))
 458         (kill-buffer retbuf)
 459         (setq retbuf nil))
 460       (kill-buffer digbuf)
 461       retbuf))
 462
 463 ;; User interface.
 464
 465 (defvar smime-buffer "*SMIME*")
 466
 467 (defvar smime-mode-map nil)
 468 (put 'smime-mode 'mode-class 'special)
 469
 470 (unless smime-mode-map
 471   (setq smime-mode-map (make-sparse-keymap))
 472   (suppress-keymap smime-mode-map)
 473
 474   (define-key smime-mode-map "q" 'smime-exit)
 475   (define-key smime-mode-map "f" 'smime-certificate-info))
 476
 477 (defun smime-mode ()
 478   "Major mode for browsing, viewing and fetching certificates.
 479
 480 All normal editing commands are switched off.
 481 \\<smime-mode-map>
 482
 483 The following commands are available:
 484
 485 \\{smime-mode-map}"
 486   (interactive)
 487   (kill-all-local-variables)
 488   (setq major-mode 'smime-mode)
 489   (setq mode-name "SMIME")
 490   (setq mode-line-process nil)
 491   (use-local-map smime-mode-map)
 492   (buffer-disable-undo)
 493   (setq truncate-lines t)
 494   (setq buffer-read-only t))
 495
 496 (defun smime-certificate-info (certfile)
 497   (interactive "fCertificate file: ")
 498   (let ((buffer (get-buffer-create (format "*certificate %s*" certfile))))
 499     (switch-to-buffer buffer)
 500     (erase-buffer)
 501     (call-process smime-openssl-program nil buffer 'display
 502                   "x509" "-in" (expand-file-name certfile) "-text")
 503     (fundamental-mode)
 504     (set-buffer-modified-p nil)
 505     (toggle-read-only t)
 506     (goto-char (point-min))))
 507
 508 (defun smime-draw-buffer ()
 509   (with-current-buffer smime-buffer
 510     (let (buffer-read-only)
 511       (erase-buffer)
 512       (insert "\nYour keys:\n")
 513       (dolist (key smime-keys)
 514         (insert
 515          (format "\t\t%s: %s\n" (car key) (cadr key))))
 516       (insert "\nTrusted Certificate Authoritys:\n")
 517       (insert "\nKnown Certificates:\n"))))
 518
 519 (defun smime ()
 520   "Go to the SMIME buffer."
 521   (interactive)
 522   (unless (get-buffer smime-buffer)
 523     (save-excursion
 524       (set-buffer (get-buffer-create smime-buffer))
 525       (smime-mode)))
 526   (smime-draw-buffer)
 527   (switch-to-buffer smime-buffer))
 528
 529 (defun smime-exit ()
 530   "Quit the S/MIME buffer."
 531   (interactive)
 532   (kill-buffer (current-buffer)))
 533
 534 ;; Other functions
 535
 536 (defun smime-get-key-by-email (email)
 537   (cadr (assoc email smime-keys)))
 538
 539 (provide 'smime)
 540
 541 ;;; smime.el ends here