cgit.sxemacs.org Git - gnus/blob - lisp/qp.el

   1 ;;; qp.el --- Quoted-Printable functions
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2001 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: mail, extensions
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Functions for encoding and decoding quoted-printable text as
  28 ;; defined in RFC 2045.
  29
  30 ;;; Code:
  31
  32 (require 'mm-util)
  33 (eval-when-compile (defvar mm-use-ultra-safe-encoding))
  34
  35 (defun quoted-printable-decode-region (from to &optional coding-system)
  36   "Decode quoted-printable in the region between FROM and TO, per RFC 2045.
  37 If CODING-SYSTEM is non-nil, decode bytes into characters with that
  38 coding-system.
  39
  40 Interactively, you can supply the CODING-SYSTEM argument
  41 with \\[universal-coding-system-argument]."
  42   (interactive
  43    ;; Let the user determine the coding system with "C-x RET c".
  44    (list (region-beginning) (region-end) coding-system-for-read))
  45   (unless (mm-coding-system-p coding-system) ; e.g. `ascii' from Gnus
  46     (setq coding-system nil))
  47   (save-excursion
  48     (save-restriction
  49       ;; RFC 2045:  ``An "=" followed by two hexadecimal digits, one
  50       ;; or both of which are lowercase letters in "abcdef", is
  51       ;; formally illegal. A robust implementation might choose to
  52       ;; recognize them as the corresponding uppercase letters.''
  53       (let ((case-fold-search t))
  54         (narrow-to-region from to)
  55         ;; Do this in case we're called from Gnus, say, in a buffer
  56         ;; which already contains non-ASCII characters which would
  57         ;; then get doubly-decoded below.
  58         (if coding-system
  59             (mm-encode-coding-region (point-min) (point-max) coding-system))
  60         (goto-char (point-min))
  61         (while (and (skip-chars-forward "^=")
  62                     (not (eobp)))
  63           (cond ((eq (char-after (1+ (point))) ?\n)
  64                  (delete-char 2))
  65                 ((looking-at "=[0-9A-F][0-9A-F]")
  66                  (let ((byte (string-to-int (buffer-substring (1+ (point))
  67                                                               (+ 3 (point)))
  68                                             16)))
  69                    (insert byte)
  70                    (delete-char 3)
  71                    ;; Why backward-char???
  72                    ;;(unless (eq byte 61) ;; 61 is not ?= in XEmacs
  73                    ;;  (backward-char))
  74                    ))
  75                 (t
  76                  (message "Malformed quoted-printable text")
  77                  (forward-char)))))
  78       (if coding-system
  79           (mm-decode-coding-region (point-min) (point-max) coding-system)))))
  80
  81 (defun quoted-printable-decode-string (string &optional coding-system)
  82   "Decode the quoted-printable encoded STRING and return the result.
  83 If CODING-SYSTEM is non-nil, decode the region with coding-system."
  84   (with-temp-buffer
  85     (insert string)
  86     (quoted-printable-decode-region (point-min) (point-max) coding-system)
  87     (buffer-string)))
  88
  89 (defun quoted-printable-encode-region (from to &optional fold class)
  90   "Quoted-printable encode the region between FROM and TO per RFC 2045.
  91
  92 If FOLD, fold long lines at 76 characters (as required by the RFC).
  93 If CLASS is non-nil, translate the characters not matched by that
  94 regexp class, which is in the form expected by `skip-chars-forward'.
  95 You should probably avoid non-ASCII characters in this arg.
  96
  97 If `mm-use-ultra-safe-encoding' is set, fold lines unconditionally and
  98 encode lines starting with \"From\"."
  99   (interactive "r")
 100   (unless class
 101     ;; Avoid using 8bit characters. = is \075.
 102     ;; Equivalent to "^\000-\007\013\015-\037\200-\377="
 103     (setq class "\010-\012\014\040-\074\076-\177"))
 104   (save-excursion
 105     (save-restriction
 106       (narrow-to-region from to)
 107       ;; We can live with characters between 00-FF.
 108       (goto-char (point-min))
 109       (while (not (eobp))
 110         (if (>= (char-after) 256)
 111             (error "Multibyte character in QP encoding region"))
 112         (forward-char))
 113       ;; Encode all the non-ascii and control characters.
 114       (goto-char (point-min))
 115       (while (and (skip-chars-forward class)
 116                   (not (eobp)))
 117         (insert
 118          (prog1
 119              (format "=%02X" (char-after))
 120            (delete-char 1))))
 121       ;; Encode white space at the end of lines.
 122       (goto-char (point-min))
 123       (while (re-search-forward "[ \t]+$" nil t)
 124         (goto-char (match-beginning 0))
 125         (while (not (eolp))
 126           (insert
 127            (prog1
 128                (format "=%02X" (char-after))
 129              (delete-char 1)))))
 130       (let ((mm-use-ultra-safe-encoding
 131              (and (boundp 'mm-use-ultra-safe-encoding)
 132                   mm-use-ultra-safe-encoding)))
 133         (when (or fold mm-use-ultra-safe-encoding)
 134           (let ((tab-width 1))  ; HTAB is one character.
 135             (goto-char (point-min))
 136             (while (not (eobp))
 137               ;; In ultra-safe mode, encode "From " at the beginning
 138               ;; of a line.
 139               (when mm-use-ultra-safe-encoding
 140                 (if (looking-at "From ")
 141                     (replace-match "From=20" nil t)
 142                   (if (looking-at "-")
 143                         (replace-match "=2D" nil t))))
 144               (end-of-line)
 145               ;; Fold long lines.
 146               (while (> (current-column) 76) ; tab-width must be 1.
 147                 (beginning-of-line)
 148                 (forward-char 75)       ; 75 chars plus an "="
 149                 (search-backward "=" (- (point) 2) t)
 150                 (insert "=\n")
 151                 (end-of-line))
 152               (forward-line))))))))
 153
 154 (defun quoted-printable-encode-string (string)
 155   "Encode the STRING as quoted-printable and return the result."
 156   (let ((default-enable-multibyte-characters (mm-multibyte-string-p string)))
 157     (with-temp-buffer
 158       (insert string)
 159       (quoted-printable-encode-region (point-min) (point-max))
 160       (buffer-string))))
 161
 162 (provide 'qp)
 163
 164 ;;; qp.el ends here