cgit.sxemacs.org Git - gnus/blob - lisp/nnmh.el

   1 ;;; nnmh.el --- mhspool access for Gnus
   2 ;; Copyright (C) 1995,96,97,98,99 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;; Keywords: news, mail
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Based on nnspool.el by Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>.
  28 ;; For an overview of what the interface functions do, please see the
  29 ;; Gnus sources.
  30
  31 ;;; Code:
  32
  33 (require 'nnheader)
  34 (require 'nnmail)
  35 (require 'gnus-start)
  36 (require 'nnoo)
  37 (eval-when-compile (require 'cl))
  38
  39 (nnoo-declare nnmh)
  40
  41 (defvoo nnmh-directory message-directory
  42   "*Mail spool directory.")
  43
  44 (defvoo nnmh-get-new-mail t
  45   "*If non-nil, nnmh will check the incoming mail file and split the mail.")
  46
  47 (defvoo nnmh-prepare-save-mail-hook nil
  48   "*Hook run narrowed to an article before saving.")
  49
  50 (defvoo nnmh-be-safe nil
  51   "*If non-nil, nnmh will check all articles to make sure whether they are new or not.
  52 Go through the .nnmh-articles file and compare with the actual
  53 articles in this folder.  The articles that are \"new\" will be marked
  54 as unread by Gnus.")
  55
  56 \f
  57
  58 (defconst nnmh-version "nnmh 1.0"
  59   "nnmh version.")
  60
  61 (defvoo nnmh-current-directory nil
  62   "Current news group directory.")
  63
  64 (defvoo nnmh-status-string "")
  65 (defvoo nnmh-group-alist nil)
  66 ;; Don't even think about setting this variable.  It does not exist.
  67 ;; Forget about it.  Uh-huh.  Nope.  Nobody here.  It's only bound
  68 ;; dynamically by certain functions in nndraft.
  69 (defvar nnmh-allow-delete-final nil)
  70
  71 \f
  72
  73 ;;; Interface functions.
  74
  75 (nnoo-define-basics nnmh)
  76
  77 (deffoo nnmh-retrieve-headers (articles &optional newsgroup server fetch-old)
  78   (save-excursion
  79     (set-buffer nntp-server-buffer)
  80     (erase-buffer)
  81     (let* ((file nil)
  82            (number (length articles))
  83            (large (and (numberp nnmail-large-newsgroup)
  84                        (> number nnmail-large-newsgroup)))
  85            (count 0)
  86            (file-name-coding-system nnmail-pathname-coding-system)
  87            beg article)
  88       (nnmh-possibly-change-directory newsgroup server)
  89       ;; We don't support fetching by Message-ID.
  90       (if (stringp (car articles))
  91           'headers
  92         (while articles
  93           (when (and (file-exists-p
  94                       (setq file (concat (file-name-as-directory
  95                                           nnmh-current-directory)
  96                                          (int-to-string
  97                                           (setq article (pop articles))))))
  98                      (not (file-directory-p file)))
  99             (insert (format "221 %d Article retrieved.\n" article))
 100             (setq beg (point))
 101             (nnheader-insert-head file)
 102             (goto-char beg)
 103             (if (search-forward "\n\n" nil t)
 104                 (forward-char -1)
 105               (goto-char (point-max))
 106               (insert "\n\n"))
 107             (insert ".\n")
 108             (delete-region (point) (point-max)))
 109           (setq count (1+ count))
 110
 111           (and large
 112                (zerop (% count 20))
 113                (nnheader-message 5 "nnmh: Receiving headers... %d%%"
 114                                  (/ (* count 100) number))))
 115
 116         (when large
 117           (nnheader-message 5 "nnmh: Receiving headers...done"))
 118
 119         (nnheader-fold-continuation-lines)
 120         'headers))))
 121
 122 (deffoo nnmh-open-server (server &optional defs)
 123   (nnoo-change-server 'nnmh server defs)
 124   (when (not (file-exists-p nnmh-directory))
 125     (condition-case ()
 126         (make-directory nnmh-directory t)
 127       (error t)))
 128   (cond
 129    ((not (file-exists-p nnmh-directory))
 130     (nnmh-close-server)
 131     (nnheader-report 'nnmh "Couldn't create directory: %s" nnmh-directory))
 132    ((not (file-directory-p (file-truename nnmh-directory)))
 133     (nnmh-close-server)
 134     (nnheader-report 'nnmh "Not a directory: %s" nnmh-directory))
 135    (t
 136     (nnheader-report 'nnmh "Opened server %s using directory %s"
 137                      server nnmh-directory)
 138     t)))
 139
 140 (deffoo nnmh-request-article (id &optional newsgroup server buffer)
 141   (nnmh-possibly-change-directory newsgroup server)
 142   (let ((file (if (stringp id)
 143                   nil
 144                 (concat nnmh-current-directory (int-to-string id))))
 145         (file-name-coding-system nnmail-pathname-coding-system)
 146         (nntp-server-buffer (or buffer nntp-server-buffer)))
 147     (and (stringp file)
 148          (file-exists-p file)
 149          (not (file-directory-p file))
 150          (save-excursion (nnmail-find-file file))
 151          (string-to-int (file-name-nondirectory file)))))
 152
 153 (deffoo nnmh-request-group (group &optional server dont-check)
 154   (nnheader-init-server-buffer)
 155   (nnmh-possibly-change-directory group server)
 156   (let ((pathname (nnmail-group-pathname group nnmh-directory))
 157         (file-name-coding-system nnmail-pathname-coding-system)
 158         dir)
 159     (cond
 160      ((not (file-directory-p pathname))
 161       (nnheader-report
 162        'nnmh "Can't select group (no such directory): %s" group))
 163      (t
 164       (setq nnmh-current-directory pathname)
 165       (and nnmh-get-new-mail
 166            nnmh-be-safe
 167            (nnmh-update-gnus-unreads group))
 168       (cond
 169        (dont-check
 170         (nnheader-report 'nnmh "Selected group %s" group)
 171         t)
 172        (t
 173         ;; Re-scan the directory if it's on a foreign system.
 174         (nnheader-re-read-dir pathname)
 175         (setq dir
 176               (sort
 177                (mapcar (lambda (name) (string-to-int name))
 178                        (directory-files pathname nil "^[0-9]+$" t))
 179                '<))
 180         (cond
 181          (dir
 182           (setq nnmh-group-alist
 183                 (delq (assoc group nnmh-group-alist) nnmh-group-alist))
 184           (push (list group (cons (car dir) (car (last dir))))
 185                 nnmh-group-alist)
 186           (nnheader-report 'nnmh "Selected group %s" group)
 187           (nnheader-insert
 188            "211 %d %d %d %s\n" (length dir) (car dir)
 189            (car (last dir)) group))
 190          (t
 191           (nnheader-report 'nnmh "Empty group %s" group)
 192           (nnheader-insert (format "211 0 1 0 %s\n" group))))))))))
 193
 194 (deffoo nnmh-request-scan (&optional group server)
 195   (nnmail-get-new-mail 'nnmh nil nnmh-directory group))
 196
 197 (deffoo nnmh-request-list (&optional server dir)
 198   (nnheader-insert "")
 199   (nnmh-possibly-change-directory nil server)
 200   (let ((file-name-coding-system nnmail-pathname-coding-system)
 201         (nnmh-toplev
 202          (file-truename (or dir (file-name-as-directory nnmh-directory)))))
 203     (nnmh-request-list-1 nnmh-toplev))
 204   (setq nnmh-group-alist (nnmail-get-active))
 205   t)
 206
 207 (defvar nnmh-toplev)
 208 (defun nnmh-request-list-1 (dir)
 209   (setq dir (expand-file-name dir))
 210   ;; Recurse down all directories.
 211   (let ((dirs (and (file-readable-p dir)
 212                    (> (nth 1 (file-attributes (file-chase-links dir))) 2)
 213                    (nnheader-directory-files dir t nil t)))
 214         rdir)
 215     ;; Recurse down directories.
 216     (while (setq rdir (pop dirs))
 217       (when (and (file-directory-p rdir)
 218                  (file-readable-p rdir)
 219                  (not (equal (file-truename rdir)
 220                              (file-truename dir))))
 221         (nnmh-request-list-1 rdir))))
 222   ;; For each directory, generate an active file line.
 223   (unless (string= (expand-file-name nnmh-toplev) dir)
 224     (let ((files (mapcar
 225                   (lambda (name) (string-to-int name))
 226                   (directory-files dir nil "^[0-9]+$" t))))
 227       (when files
 228         (save-excursion
 229           (set-buffer nntp-server-buffer)
 230           (goto-char (point-max))
 231           (insert
 232            (format
 233             "%s %d %d y\n"
 234             (progn
 235               (string-match
 236                (regexp-quote
 237                 (file-truename (file-name-as-directory
 238                                 (expand-file-name nnmh-toplev))))
 239                dir)
 240               (nnheader-replace-chars-in-string
 241                (mm-decode-coding-string (substring dir (match-end 0))
 242                                         nnmail-pathname-coding-system)
 243                ?/ ?.))
 244             (apply 'max files)
 245             (apply 'min files)))))))
 246   t)
 247
 248 (deffoo nnmh-request-newgroups (date &optional server)
 249   (nnmh-request-list server))
 250
 251 (deffoo nnmh-request-expire-articles (articles newsgroup
 252                                                &optional server force)
 253   (nnmh-possibly-change-directory newsgroup server)
 254   (let* ((is-old t)
 255          article rest mod-time)
 256     (nnheader-init-server-buffer)
 257
 258     (while (and articles is-old)
 259       (setq article (concat nnmh-current-directory
 260                             (int-to-string (car articles))))
 261       (when (setq mod-time (nth 5 (file-attributes article)))
 262         (if (and (nnmh-deletable-article-p newsgroup (car articles))
 263                  (setq is-old
 264                        (nnmail-expired-article-p newsgroup mod-time force)))
 265             (progn
 266               ;; Allow a special target group. -- jcn
 267               (unless (eq nnmail-expiry-target 'delete)
 268                 (with-temp-buffer
 269                   (nnmh-request-article (car articles)
 270                                         newsgroup server (current-buffer))
 271                   (nnmail-expiry-target-group
 272                    nnmail-expiry-target newsgroup)))
 273               (nnheader-message 5 "Deleting article %s in %s..."
 274                                 article newsgroup)
 275               (condition-case ()
 276                   (funcall nnmail-delete-file-function article)
 277                 (file-error
 278                  (nnheader-message 1 "Couldn't delete article %s in %s"
 279                                    article newsgroup)
 280                  (push (car articles) rest))))
 281           (push (car articles) rest)))
 282       (setq articles (cdr articles)))
 283     (nnheader-message 5 "")
 284     (nconc rest articles)))
 285
 286 (deffoo nnmh-close-group (group &optional server)
 287   t)
 288
 289 (deffoo nnmh-request-move-article
 290     (article group server accept-form &optional last)
 291   (let ((buf (get-buffer-create " *nnmh move*"))
 292         result)
 293     (and
 294      (nnmh-deletable-article-p group article)
 295      (nnmh-request-article article group server)
 296      (save-excursion
 297        (set-buffer buf)
 298        (erase-buffer)
 299        (insert-buffer-substring nntp-server-buffer)
 300        (setq result (eval accept-form))
 301        (kill-buffer (current-buffer))
 302        result)
 303      (progn
 304        (nnmh-possibly-change-directory group server)
 305        (condition-case ()
 306            (funcall nnmail-delete-file-function
 307                     (concat nnmh-current-directory (int-to-string article)))
 308          (file-error nil))))
 309     result))
 310
 311 (deffoo nnmh-request-accept-article (group &optional server last noinsert)
 312   (nnmh-possibly-change-directory group server)
 313   (nnmail-check-syntax)
 314   (when nnmail-cache-accepted-message-ids
 315     (nnmail-cache-insert (nnmail-fetch-field "message-id")))
 316   (nnheader-init-server-buffer)
 317   (prog1
 318       (if (stringp group)
 319           (if noinsert
 320               (nnmh-active-number group)
 321             (car (nnmh-save-mail
 322                   (list (cons group (nnmh-active-number group)))
 323                   noinsert)))
 324         (let ((res (nnmail-article-group 'nnmh-active-number)))
 325           (if (and (null res)
 326                    (yes-or-no-p "Moved to `junk' group; delete article? "))
 327               'junk
 328             (car (nnmh-save-mail res noinsert)))))
 329     (when (and last nnmail-cache-accepted-message-ids)
 330       (nnmail-cache-close))))
 331
 332 (deffoo nnmh-request-replace-article (article group buffer)
 333   (nnmh-possibly-change-directory group)
 334   (save-excursion
 335     (set-buffer buffer)
 336     (nnmh-possibly-create-directory group)
 337     (ignore-errors
 338       (nnmail-write-region
 339        (point-min) (point-max)
 340        (concat nnmh-current-directory (int-to-string article))
 341        nil (if (nnheader-be-verbose 5) nil 'nomesg))
 342       t)))
 343
 344 (deffoo nnmh-request-create-group (group &optional server args)
 345   (nnheader-init-server-buffer)
 346   (unless (assoc group nnmh-group-alist)
 347     (let (active)
 348       (push (list group (setq active (cons 1 0)))
 349             nnmh-group-alist)
 350       (nnmh-possibly-create-directory group)
 351       (nnmh-possibly-change-directory group server)
 352       (let ((articles (mapcar
 353                        (lambda (file)
 354                          (string-to-int file))
 355                        (directory-files
 356                         nnmh-current-directory nil "^[0-9]+$"))))
 357         (when articles
 358           (setcar active (apply 'min articles))
 359           (setcdr active (apply 'max articles))))))
 360   t)
 361
 362 (deffoo nnmh-request-delete-group (group &optional force server)
 363   (nnmh-possibly-change-directory group server)
 364   ;; Delete all articles in GROUP.
 365   (if (not force)
 366       ()                                ; Don't delete the articles.
 367     (let ((articles (directory-files nnmh-current-directory t "^[0-9]+$")))
 368       (while articles
 369         (when (file-writable-p (car articles))
 370           (nnheader-message 5 "Deleting article %s in %s..."
 371                             (car articles) group)
 372           (funcall nnmail-delete-file-function (car articles)))
 373         (setq articles (cdr articles))))
 374     ;; Try to delete the directory itself.
 375     (ignore-errors
 376       (delete-directory nnmh-current-directory)))
 377   ;; Remove the group from all structures.
 378   (setq nnmh-group-alist
 379         (delq (assoc group nnmh-group-alist) nnmh-group-alist)
 380         nnmh-current-directory nil)
 381   t)
 382
 383 (deffoo nnmh-request-rename-group (group new-name &optional server)
 384   (nnmh-possibly-change-directory group server)
 385   (let ((new-dir (nnmail-group-pathname new-name nnmh-directory))
 386         (old-dir (nnmail-group-pathname group nnmh-directory)))
 387     (when (ignore-errors
 388             (make-directory new-dir t)
 389             t)
 390       ;; We move the articles file by file instead of renaming
 391       ;; the directory -- there may be subgroups in this group.
 392       ;; One might be more clever, I guess.
 393       (let ((files (nnheader-article-to-file-alist old-dir)))
 394         (while files
 395           (rename-file
 396            (concat old-dir (cdar files))
 397            (concat new-dir (cdar files)))
 398           (pop files)))
 399       (when (<= (length (directory-files old-dir)) 2)
 400         (ignore-errors
 401           (delete-directory old-dir)))
 402       ;; That went ok, so we change the internal structures.
 403       (let ((entry (assoc group nnmh-group-alist)))
 404         (when entry
 405           (setcar entry new-name))
 406         (setq nnmh-current-directory nil)
 407         t))))
 408
 409 (nnoo-define-skeleton nnmh)
 410
 411 \f
 412 ;;; Internal functions.
 413
 414 (defun nnmh-possibly-change-directory (newsgroup &optional server)
 415   (when (and server
 416              (not (nnmh-server-opened server)))
 417     (nnmh-open-server server))
 418   (when newsgroup
 419     (let ((pathname (nnmail-group-pathname newsgroup nnmh-directory))
 420           (file-name-coding-system nnmail-pathname-coding-system))
 421       (if (file-directory-p pathname)
 422           (setq nnmh-current-directory pathname)
 423         (error "No such newsgroup: %s" newsgroup)))))
 424
 425 (defun nnmh-possibly-create-directory (group)
 426   (let (dir dirs)
 427     (setq dir (nnmail-group-pathname group nnmh-directory))
 428     (while (not (file-directory-p dir))
 429       (push dir dirs)
 430       (setq dir (file-name-directory (directory-file-name dir))))
 431     (while dirs
 432       (when (make-directory (directory-file-name (car dirs)))
 433         (error "Could not create directory %s" (car dirs)))
 434       (nnheader-message 5 "Creating mail directory %s" (car dirs))
 435       (setq dirs (cdr dirs)))))
 436
 437 (defun nnmh-save-mail (group-art &optional noinsert)
 438   "Called narrowed to an article."
 439   (unless noinsert
 440     (nnmail-insert-lines)
 441     (nnmail-insert-xref group-art))
 442   (run-hooks 'nnmail-prepare-save-mail-hook)
 443   (run-hooks 'nnmh-prepare-save-mail-hook)
 444   (goto-char (point-min))
 445   (while (looking-at "From ")
 446     (replace-match "X-From-Line: ")
 447     (forward-line 1))
 448   ;; We save the article in all the newsgroups it belongs in.
 449   (let ((ga group-art)
 450         first)
 451     (while ga
 452       (nnmh-possibly-create-directory (caar ga))
 453       (let ((file (concat (nnmail-group-pathname
 454                            (caar ga) nnmh-directory)
 455                           (int-to-string (cdar ga)))))
 456         (if first
 457             ;; It was already saved, so we just make a hard link.
 458             (funcall nnmail-crosspost-link-function first file t)
 459           ;; Save the article.
 460           (nnmail-write-region (point-min) (point-max) file nil nil)
 461           (setq first file)))
 462       (setq ga (cdr ga))))
 463   group-art)
 464
 465 (defun nnmh-active-number (group)
 466   "Compute the next article number in GROUP."
 467   (let ((active (cadr (assoc group nnmh-group-alist)))
 468         (dir (nnmail-group-pathname group nnmh-directory))
 469         (file-name-coding-system nnmail-pathname-coding-system)
 470         file)
 471     (unless active
 472       ;; The group wasn't known to nnmh, so we just create an active
 473       ;; entry for it.
 474       (setq active (cons 1 0))
 475       (push (list group active) nnmh-group-alist)
 476       (unless (file-exists-p dir)
 477         (gnus-make-directory dir))
 478       ;; Find the highest number in the group.
 479       (let ((files (sort
 480                     (mapcar
 481                      (lambda (f)
 482                        (string-to-int f))
 483                      (directory-files dir nil "^[0-9]+$"))
 484                     '>)))
 485         (when files
 486           (setcdr active (car files)))))
 487     (setcdr active (1+ (cdr active)))
 488     (while (or
 489             ;; See whether the file exists...
 490             (file-exists-p
 491              (setq file (concat (nnmail-group-pathname group nnmh-directory)
 492                                 (int-to-string (cdr active)))))
 493             ;; ... or there is a buffer that will make that file exist
 494             ;; in the future.
 495             (get-file-buffer file))
 496       ;; Skip past that file.
 497       (setcdr active (1+ (cdr active))))
 498     (cdr active)))
 499
 500 (defun nnmh-update-gnus-unreads (group)
 501   ;; Go through the .nnmh-articles file and compare with the actual
 502   ;; articles in this folder.  The articles that are "new" will be
 503   ;; marked as unread by Gnus.
 504   (let* ((dir nnmh-current-directory)
 505          (files (sort (mapcar (function (lambda (name) (string-to-int name)))
 506                               (directory-files nnmh-current-directory
 507                                                nil "^[0-9]+$" t))
 508                       '<))
 509          (nnmh-file (concat dir ".nnmh-articles"))
 510          new articles)
 511     ;; Load the .nnmh-articles file.
 512     (when (file-exists-p nnmh-file)
 513       (setq articles
 514             (let (nnmh-newsgroup-articles)
 515               (ignore-errors (load nnmh-file nil t t))
 516               nnmh-newsgroup-articles)))
 517     ;; Add all new articles to the `new' list.
 518     (let ((art files))
 519       (while art
 520         (unless (assq (car art) articles)
 521           (push (car art) new))
 522         (setq art (cdr art))))
 523     ;; Remove all deleted articles.
 524     (let ((art articles))
 525       (while art
 526         (unless (memq (caar art) files)
 527           (setq articles (delq (car art) articles)))
 528         (setq art (cdr art))))
 529     ;; Check whether the articles really are the ones that Gnus thinks
 530     ;; they are by looking at the time-stamps.
 531     (let ((arts articles)
 532           art)
 533       (while (setq art (pop arts))
 534         (when (not (equal
 535                     (nth 5 (file-attributes
 536                             (concat dir (int-to-string (car art)))))
 537                     (cdr art)))
 538           (setq articles (delq art articles))
 539           (push (car art) new))))
 540     ;; Go through all the new articles and add them, and their
 541     ;; time-stamps, to the list.
 542     (setq articles
 543           (nconc articles
 544                  (mapcar
 545                   (lambda (art)
 546                     (cons art
 547                           (nth 5 (file-attributes
 548                                   (concat dir (int-to-string art))))))
 549                   new)))
 550     ;; Make Gnus mark all new articles as unread.
 551     (when new
 552       (gnus-make-articles-unread
 553        (gnus-group-prefixed-name group (list 'nnmh ""))
 554        (setq new (sort new '<))))
 555     ;; Sort the article list with highest numbers first.
 556     (setq articles (sort articles (lambda (art1 art2)
 557                                     (> (car art1) (car art2)))))
 558     ;; Finally write this list back to the .nnmh-articles file.
 559     (with-temp-file nnmh-file
 560       (insert ";; Gnus article active file for " group "\n\n")
 561       (insert "(setq nnmh-newsgroup-articles '")
 562       (gnus-prin1 articles)
 563       (insert ")\n"))))
 564
 565 (defun nnmh-deletable-article-p (group article)
 566   "Say whether ARTICLE in GROUP can be deleted."
 567   (let ((path (concat nnmh-current-directory (int-to-string article))))
 568     ;; Writable.
 569     (and (file-writable-p path)
 570          (or
 571           ;; We can never delete the last article in the group.
 572           (not (eq (cdr (nth 1 (assoc group nnmh-group-alist)))
 573                    article))
 574           ;; Well, we can.
 575           nnmh-allow-delete-final))))
 576
 577 (provide 'nnmh)
 578
 579 ;;; nnmh.el ends here