cgit.sxemacs.org Git - gnus/blob - lisp/nnmh.el

   1 ;;; nnmh.el --- mhspool access for Gnus
   2
   3 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   8 ;; Keywords: news, mail
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Based on nnspool.el by Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>.
  28 ;; For an overview of what the interface functions do, please see the
  29 ;; Gnus sources.
  30
  31 ;;; Code:
  32
  33 (require 'nnheader)
  34 (require 'nnmail)
  35 (require 'gnus-start)
  36 (require 'nnoo)
  37 (eval-when-compile (require 'cl))
  38
  39 (nnoo-declare nnmh)
  40
  41 (defvoo nnmh-directory message-directory
  42   "Mail spool directory.")
  43
  44 (defvoo nnmh-get-new-mail t
  45   "If non-nil, nnmh will check the incoming mail file and split the mail.")
  46
  47 (defvoo nnmh-prepare-save-mail-hook nil
  48   "Hook run narrowed to an article before saving.")
  49
  50 (defvoo nnmh-be-safe nil
  51   "If non-nil, nnmh will check all articles to make sure whether they are new or not.
  52 Go through the .nnmh-articles file and compare with the actual
  53 articles in this folder.  The articles that are \"new\" will be marked
  54 as unread by Gnus.")
  55
  56 \f
  57
  58 (defconst nnmh-version "nnmh 1.0"
  59   "nnmh version.")
  60
  61 (defvoo nnmh-current-directory nil
  62   "Current news group directory.")
  63
  64 (defvoo nnmh-status-string "")
  65 (defvoo nnmh-group-alist nil)
  66 ;; Don't even think about setting this variable.  It does not exist.
  67 ;; Forget about it.  Uh-huh.  Nope.  Nobody here.  It's only bound
  68 ;; dynamically by certain functions in nndraft.
  69 (defvar nnmh-allow-delete-final nil)
  70
  71 \f
  72
  73 ;;; Interface functions.
  74
  75 (nnoo-define-basics nnmh)
  76
  77 (deffoo nnmh-retrieve-headers (articles &optional newsgroup server fetch-old)
  78   (with-current-buffer nntp-server-buffer
  79     (erase-buffer)
  80     (let* ((file nil)
  81            (number (length articles))
  82            (large (and (numberp nnmail-large-newsgroup)
  83                        (> number nnmail-large-newsgroup)))
  84            (count 0)
  85            (file-name-coding-system nnmail-pathname-coding-system)
  86            beg article)
  87       (nnmh-possibly-change-directory newsgroup server)
  88       ;; We don't support fetching by Message-ID.
  89       (if (stringp (car articles))
  90           'headers
  91         (while articles
  92           (when (and (file-exists-p
  93                       (setq file (concat (file-name-as-directory
  94                                           nnmh-current-directory)
  95                                          (int-to-string
  96                                           (setq article (pop articles))))))
  97                      (not (file-directory-p file)))
  98             (insert (format "221 %d Article retrieved.\n" article))
  99             (setq beg (point))
 100             (nnheader-insert-head file)
 101             (goto-char beg)
 102             (if (search-forward "\n\n" nil t)
 103                 (forward-char -1)
 104               (goto-char (point-max))
 105               (insert "\n\n"))
 106             (insert ".\n")
 107             (delete-region (point) (point-max)))
 108           (setq count (1+ count))
 109
 110           (and large
 111                (zerop (% count 20))
 112                (nnheader-message 5 "nnmh: Receiving headers... %d%%"
 113                                  (/ (* count 100) number))))
 114
 115         (when large
 116           (nnheader-message 5 "nnmh: Receiving headers...done"))
 117
 118         (nnheader-fold-continuation-lines)
 119         'headers))))
 120
 121 (deffoo nnmh-open-server (server &optional defs)
 122   (nnoo-change-server 'nnmh server defs)
 123   (when (not (file-exists-p nnmh-directory))
 124     (condition-case ()
 125         (make-directory nnmh-directory t)
 126       (error t)))
 127   (cond
 128    ((not (file-exists-p nnmh-directory))
 129     (nnmh-close-server)
 130     (nnheader-report 'nnmh "Couldn't create directory: %s" nnmh-directory))
 131    ((not (file-directory-p (file-truename nnmh-directory)))
 132     (nnmh-close-server)
 133     (nnheader-report 'nnmh "Not a directory: %s" nnmh-directory))
 134    (t
 135     (nnheader-report 'nnmh "Opened server %s using directory %s"
 136                      server nnmh-directory)
 137     t)))
 138
 139 (deffoo nnmh-request-article (id &optional newsgroup server buffer)
 140   (nnmh-possibly-change-directory newsgroup server)
 141   (let ((file (if (stringp id)
 142                   nil
 143                 (concat nnmh-current-directory (int-to-string id))))
 144         (file-name-coding-system nnmail-pathname-coding-system)
 145         (nntp-server-buffer (or buffer nntp-server-buffer)))
 146     (and (stringp file)
 147          (file-exists-p file)
 148          (not (file-directory-p file))
 149          (save-excursion (nnmail-find-file file))
 150          (string-to-number (file-name-nondirectory file)))))
 151
 152 (deffoo nnmh-request-group (group &optional server dont-check)
 153   (nnheader-init-server-buffer)
 154   (nnmh-possibly-change-directory group server)
 155   (let ((pathname (nnmail-group-pathname group nnmh-directory))
 156         (file-name-coding-system nnmail-pathname-coding-system)
 157         dir)
 158     (cond
 159      ((not (file-directory-p pathname))
 160       (nnheader-report
 161        'nnmh "Can't select group (no such directory): %s" group))
 162      (t
 163       (setq nnmh-current-directory pathname)
 164       (and nnmh-get-new-mail
 165            nnmh-be-safe
 166            (nnmh-update-gnus-unreads group))
 167       (cond
 168        (dont-check
 169         (nnheader-report 'nnmh "Selected group %s" group)
 170         t)
 171        (t
 172         ;; Re-scan the directory if it's on a foreign system.
 173         (nnheader-re-read-dir pathname)
 174         (setq dir
 175               (sort
 176                (mapcar 'string-to-number
 177                        (directory-files pathname nil "^[0-9]+$" t))
 178                '<))
 179         (cond
 180          (dir
 181           (setq nnmh-group-alist
 182                 (delq (assoc group nnmh-group-alist) nnmh-group-alist))
 183           (push (list group (cons (car dir) (car (last dir))))
 184                 nnmh-group-alist)
 185           (nnheader-report 'nnmh "Selected group %s" group)
 186           (nnheader-insert
 187            "211 %d %d %d %s\n" (length dir) (car dir)
 188            (car (last dir)) group))
 189          (t
 190           (nnheader-report 'nnmh "Empty group %s" group)
 191           (nnheader-insert (format "211 0 1 0 %s\n" group))))))))))
 192
 193 (deffoo nnmh-request-scan (&optional group server)
 194   (nnmail-get-new-mail 'nnmh nil nnmh-directory group))
 195
 196 (deffoo nnmh-request-list (&optional server dir)
 197   (nnheader-insert "")
 198   (nnmh-possibly-change-directory nil server)
 199   (let ((file-name-coding-system nnmail-pathname-coding-system)
 200         (nnmh-toplev
 201          (file-truename (or dir (file-name-as-directory nnmh-directory)))))
 202     (nnmh-request-list-1 nnmh-toplev))
 203   (setq nnmh-group-alist (nnmail-get-active))
 204   t)
 205
 206 (defvar nnmh-toplev)
 207 (defun nnmh-request-list-1 (dir)
 208   (setq dir (expand-file-name dir))
 209   ;; Recurse down all directories.
 210   (let ((files (nnheader-directory-files dir t nil t))
 211         (max 0)
 212         min rdir attributes num)
 213     ;; Recurse down directories.
 214     (dolist (rdir files)
 215       (setq attributes (file-attributes rdir))
 216       (when (null (nth 0 attributes))
 217         (setq file (file-name-nondirectory rdir))
 218         (when (string-match "^[0-9]+$" file)
 219           (setq num (string-to-number file))
 220           (setq max (max max num))
 221           (when (or (null min)
 222                     (< num min))
 223             (setq min num))))
 224       (when (and (eq (nth 0 attributes) t) ; Is a directory
 225                  (> (nth 1 attributes) 2)  ; Has sub-directories
 226                  (file-readable-p rdir)
 227                  (not (equal (file-truename rdir)
 228                              (file-truename dir))))
 229         (nnmh-request-list-1 rdir)))
 230     ;; For each directory, generate an active file line.
 231     (unless (string= (expand-file-name nnmh-toplev) dir)
 232       (when min
 233         (with-current-buffer nntp-server-buffer
 234           (goto-char (point-max))
 235           (insert
 236            (format
 237             "%s %.0f %.0f y\n"
 238             (progn
 239               (string-match
 240                (regexp-quote
 241                 (file-truename (file-name-as-directory
 242                                 (expand-file-name nnmh-toplev))))
 243                dir)
 244               (mm-string-to-multibyte ;Why?  Isn't it multibyte already?
 245                (mm-encode-coding-string
 246                 (nnheader-replace-chars-in-string
 247                  (substring dir (match-end 0))
 248                  ?/ ?.)
 249                 nnmail-pathname-coding-system)))
 250             max min))))))
 251   t)
 252
 253 (deffoo nnmh-request-newgroups (date &optional server)
 254   (nnmh-request-list server))
 255
 256 (deffoo nnmh-request-expire-articles (articles newsgroup
 257                                                &optional server force)
 258   (nnmh-possibly-change-directory newsgroup server)
 259   (let ((is-old t)
 260         (nnmail-expiry-target
 261          (or (gnus-group-find-parameter newsgroup 'expiry-target t)
 262              nnmail-expiry-target))
 263         article rest mod-time)
 264     (nnheader-init-server-buffer)
 265
 266     (while (and articles is-old)
 267       (setq article (concat nnmh-current-directory
 268                             (int-to-string (car articles))))
 269       (when (setq mod-time (nth 5 (file-attributes article)))
 270         (if (and (nnmh-deletable-article-p newsgroup (car articles))
 271                  (setq is-old
 272                        (nnmail-expired-article-p newsgroup mod-time force)))
 273             (progn
 274               ;; Allow a special target group. -- jcn
 275               (unless (eq nnmail-expiry-target 'delete)
 276                 (with-temp-buffer
 277                   (nnmh-request-article (car articles)
 278                                         newsgroup server (current-buffer))
 279                   (nnmail-expiry-target-group
 280                    nnmail-expiry-target newsgroup)))
 281               (nnheader-message 5 "Deleting article %s in %s..."
 282                                 article newsgroup)
 283               (condition-case ()
 284                   (funcall nnmail-delete-file-function article)
 285                 (file-error
 286                  (nnheader-message 1 "Couldn't delete article %s in %s"
 287                                    article newsgroup)
 288                  (push (car articles) rest))))
 289           (push (car articles) rest)))
 290       (setq articles (cdr articles)))
 291     (nnheader-message 5 "")
 292     (nconc rest articles)))
 293
 294 (deffoo nnmh-close-group (group &optional server)
 295   t)
 296
 297 (deffoo nnmh-request-move-article (article group server accept-form
 298                                            &optional last move-is-internal)
 299   (let ((buf (get-buffer-create " *nnmh move*"))
 300         result)
 301     (and
 302      (nnmh-deletable-article-p group article)
 303      (nnmh-request-article article group server)
 304      (with-current-buffer buf
 305        (erase-buffer)
 306        (insert-buffer-substring nntp-server-buffer)
 307        (setq result (eval accept-form))
 308        (kill-buffer (current-buffer))
 309        result)
 310      (progn
 311        (nnmh-possibly-change-directory group server)
 312        (condition-case ()
 313            (funcall nnmail-delete-file-function
 314                     (concat nnmh-current-directory (int-to-string article)))
 315          (file-error nil))))
 316     result))
 317
 318 (deffoo nnmh-request-accept-article (group &optional server last noinsert)
 319   (nnmh-possibly-change-directory group server)
 320   (nnmail-check-syntax)
 321   (when nnmail-cache-accepted-message-ids
 322     (nnmail-cache-insert (nnmail-fetch-field "message-id")
 323                          group
 324                          (nnmail-fetch-field "subject")
 325                          (nnmail-fetch-field "from")))
 326   (nnheader-init-server-buffer)
 327   (prog1
 328       (if (stringp group)
 329           (if noinsert
 330               (nnmh-active-number group)
 331             (car (nnmh-save-mail
 332                   (list (cons group (nnmh-active-number group)))
 333                   noinsert)))
 334         (let ((res (nnmail-article-group 'nnmh-active-number)))
 335           (if (and (null res)
 336                    (yes-or-no-p "Moved to `junk' group; delete article? "))
 337               'junk
 338             (car (nnmh-save-mail res noinsert)))))
 339     (when (and last nnmail-cache-accepted-message-ids)
 340       (nnmail-cache-close))))
 341
 342 (deffoo nnmh-request-replace-article (article group buffer)
 343   (nnmh-possibly-change-directory group)
 344   (with-current-buffer buffer
 345     (nnmh-possibly-create-directory group)
 346     (ignore-errors
 347       (nnmail-write-region
 348        (point-min) (point-max)
 349        (concat nnmh-current-directory (int-to-string article))
 350        nil (if (nnheader-be-verbose 5) nil 'nomesg))
 351       t)))
 352
 353 (deffoo nnmh-request-create-group (group &optional server args)
 354   (nnheader-init-server-buffer)
 355   (unless (assoc group nnmh-group-alist)
 356     (let (active)
 357       (push (list group (setq active (cons 1 0)))
 358             nnmh-group-alist)
 359       (nnmh-possibly-create-directory group)
 360       (nnmh-possibly-change-directory group server)
 361       (let ((articles (mapcar 'string-to-number
 362                               (directory-files
 363                                nnmh-current-directory nil "^[0-9]+$"))))
 364         (when articles
 365           (setcar active (apply 'min articles))
 366           (setcdr active (apply 'max articles))))))
 367   t)
 368
 369 (deffoo nnmh-request-delete-group (group &optional force server)
 370   (nnmh-possibly-change-directory group server)
 371   ;; Delete all articles in GROUP.
 372   (if (not force)
 373       ()                                ; Don't delete the articles.
 374     (let ((articles (directory-files nnmh-current-directory t "^[0-9]+$")))
 375       (while articles
 376         (when (file-writable-p (car articles))
 377           (nnheader-message 5 "Deleting article %s in %s..."
 378                             (car articles) group)
 379           (funcall nnmail-delete-file-function (car articles)))
 380         (setq articles (cdr articles))))
 381     ;; Try to delete the directory itself.
 382     (ignore-errors
 383       (delete-directory nnmh-current-directory)))
 384   ;; Remove the group from all structures.
 385   (setq nnmh-group-alist
 386         (delq (assoc group nnmh-group-alist) nnmh-group-alist)
 387         nnmh-current-directory nil)
 388   t)
 389
 390 (deffoo nnmh-request-rename-group (group new-name &optional server)
 391   (nnmh-possibly-change-directory group server)
 392   (let ((new-dir (nnmail-group-pathname new-name nnmh-directory))
 393         (old-dir (nnmail-group-pathname group nnmh-directory)))
 394     (when (ignore-errors
 395             (make-directory new-dir t)
 396             t)
 397       ;; We move the articles file by file instead of renaming
 398       ;; the directory -- there may be subgroups in this group.
 399       ;; One might be more clever, I guess.
 400       (let ((files (nnheader-article-to-file-alist old-dir)))
 401         (while files
 402           (rename-file
 403            (concat old-dir (cdar files))
 404            (concat new-dir (cdar files)))
 405           (pop files)))
 406       (when (<= (length (directory-files old-dir)) 2)
 407         (ignore-errors
 408           (delete-directory old-dir)))
 409       ;; That went ok, so we change the internal structures.
 410       (let ((entry (assoc group nnmh-group-alist)))
 411         (when entry
 412           (setcar entry new-name))
 413         (setq nnmh-current-directory nil)
 414         t))))
 415
 416 (nnoo-define-skeleton nnmh)
 417
 418 \f
 419 ;;; Internal functions.
 420
 421 (defun nnmh-possibly-change-directory (newsgroup &optional server)
 422   (when (and server
 423              (not (nnmh-server-opened server)))
 424     (nnmh-open-server server))
 425   (when newsgroup
 426     (let ((pathname (nnmail-group-pathname newsgroup nnmh-directory))
 427           (file-name-coding-system nnmail-pathname-coding-system))
 428       (if (file-directory-p pathname)
 429           (setq nnmh-current-directory pathname)
 430         (nnheader-report 'nnmh "Not a directory: %s" nnmh-directory)))))
 431
 432 (defun nnmh-possibly-create-directory (group)
 433   (let (dir dirs)
 434     (setq dir (nnmail-group-pathname group nnmh-directory))
 435     (while (not (file-directory-p dir))
 436       (push dir dirs)
 437       (setq dir (file-name-directory (directory-file-name dir))))
 438     (while dirs
 439       (when (make-directory (directory-file-name (car dirs)))
 440         (error "Could not create directory %s" (car dirs)))
 441       (nnheader-message 5 "Creating mail directory %s" (car dirs))
 442       (setq dirs (cdr dirs)))))
 443
 444 (defun nnmh-save-mail (group-art &optional noinsert)
 445   "Called narrowed to an article."
 446   (unless noinsert
 447     (nnmail-insert-lines)
 448     (nnmail-insert-xref group-art))
 449   (run-hooks 'nnmail-prepare-save-mail-hook)
 450   (run-hooks 'nnmh-prepare-save-mail-hook)
 451   (goto-char (point-min))
 452   (while (looking-at "From ")
 453     (replace-match "X-From-Line: ")
 454     (forward-line 1))
 455   ;; We save the article in all the newsgroups it belongs in.
 456   (let ((ga group-art)
 457         first)
 458     (while ga
 459       (nnmh-possibly-create-directory (caar ga))
 460       (let ((file (concat (nnmail-group-pathname
 461                            (caar ga) nnmh-directory)
 462                           (int-to-string (cdar ga)))))
 463         (if first
 464             ;; It was already saved, so we just make a hard link.
 465             (funcall nnmail-crosspost-link-function first file t)
 466           ;; Save the article.
 467           (nnmail-write-region (point-min) (point-max) file nil nil)
 468           (setq first file)))
 469       (setq ga (cdr ga))))
 470   group-art)
 471
 472 (defun nnmh-active-number (group)
 473   "Compute the next article number in GROUP."
 474   (let ((active (cadr (assoc group nnmh-group-alist)))
 475         (dir (nnmail-group-pathname group nnmh-directory))
 476         (file-name-coding-system nnmail-pathname-coding-system)
 477         file)
 478     (unless active
 479       ;; The group wasn't known to nnmh, so we just create an active
 480       ;; entry for it.
 481       (setq active (cons 1 0))
 482       (push (list group active) nnmh-group-alist)
 483       (unless (file-exists-p dir)
 484         (gnus-make-directory dir))
 485       ;; Find the highest number in the group.
 486       (let ((files (sort
 487                     (mapcar 'string-to-number
 488                             (directory-files dir nil "^[0-9]+$"))
 489                     '>)))
 490         (when files
 491           (setcdr active (car files)))))
 492     (setcdr active (1+ (cdr active)))
 493     (while (or
 494             ;; See whether the file exists...
 495             (file-exists-p
 496              (setq file (concat (nnmail-group-pathname group nnmh-directory)
 497                                 (int-to-string (cdr active)))))
 498             ;; ... or there is a buffer that will make that file exist
 499             ;; in the future.
 500             (get-file-buffer file))
 501       ;; Skip past that file.
 502       (setcdr active (1+ (cdr active))))
 503     (cdr active)))
 504
 505 (defun nnmh-update-gnus-unreads (group)
 506   ;; Go through the .nnmh-articles file and compare with the actual
 507   ;; articles in this folder.  The articles that are "new" will be
 508   ;; marked as unread by Gnus.
 509   (let* ((dir nnmh-current-directory)
 510          (files (sort (mapcar 'string-to-number
 511                               (directory-files nnmh-current-directory
 512                                                nil "^[0-9]+$" t))
 513                       '<))
 514          (nnmh-file (concat dir ".nnmh-articles"))
 515          new articles)
 516     ;; Load the .nnmh-articles file.
 517     (when (file-exists-p nnmh-file)
 518       (setq articles
 519             (let (nnmh-newsgroup-articles)
 520               (ignore-errors (load nnmh-file nil t t))
 521               nnmh-newsgroup-articles)))
 522     ;; Add all new articles to the `new' list.
 523     (let ((art files))
 524       (while art
 525         (unless (assq (car art) articles)
 526           (push (car art) new))
 527         (setq art (cdr art))))
 528     ;; Remove all deleted articles.
 529     (let ((art articles))
 530       (while art
 531         (unless (memq (caar art) files)
 532           (setq articles (delq (car art) articles)))
 533         (setq art (cdr art))))
 534     ;; Check whether the articles really are the ones that Gnus thinks
 535     ;; they are by looking at the time-stamps.
 536     (let ((arts articles)
 537           art)
 538       (while (setq art (pop arts))
 539         (when (not (equal
 540                     (nth 5 (file-attributes
 541                             (concat dir (int-to-string (car art)))))
 542                     (cdr art)))
 543           (setq articles (delq art articles))
 544           (push (car art) new))))
 545     ;; Go through all the new articles and add them, and their
 546     ;; time-stamps, to the list.
 547     (setq articles
 548           (nconc articles
 549                  (mapcar
 550                   (lambda (art)
 551                     (cons art
 552                           (nth 5 (file-attributes
 553                                   (concat dir (int-to-string art))))))
 554                   new)))
 555     ;; Make Gnus mark all new articles as unread.
 556     (when new
 557       (gnus-make-articles-unread
 558        (gnus-group-prefixed-name group (list 'nnmh ""))
 559        (setq new (sort new '<))))
 560     ;; Sort the article list with highest numbers first.
 561     (setq articles (sort articles (lambda (art1 art2)
 562                                     (> (car art1) (car art2)))))
 563     ;; Finally write this list back to the .nnmh-articles file.
 564     (with-temp-file nnmh-file
 565       (insert ";; Gnus article active file for " group "\n\n")
 566       (insert "(setq nnmh-newsgroup-articles '")
 567       (gnus-prin1 articles)
 568       (insert ")\n"))))
 569
 570 (defun nnmh-deletable-article-p (group article)
 571   "Say whether ARTICLE in GROUP can be deleted."
 572   (let ((path (concat nnmh-current-directory (int-to-string article))))
 573     ;; Writable.
 574     (and (file-writable-p path)
 575          (or
 576           ;; We can never delete the last article in the group.
 577           (not (eq (cdr (nth 1 (assoc group nnmh-group-alist)))
 578                    article))
 579           ;; Well, we can.
 580           nnmh-allow-delete-final))))
 581
 582 (provide 'nnmh)
 583
 584 ;;; nnmh.el ends here