cgit.sxemacs.org Git - gnus/blob - lisp/nnmh.el

   1 ;;; nnmh.el --- mhspool access for Gnus
   2
   3 ;; Copyright (C) 1995-2011 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   7 ;; Keywords: news, mail
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Based on nnspool.el by Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>.
  27 ;; For an overview of what the interface functions do, please see the
  28 ;; Gnus sources.
  29
  30 ;;; Code:
  31
  32 (require 'nnheader)
  33 (require 'nnmail)
  34 (require 'gnus-start)
  35 (require 'nnoo)
  36 (eval-when-compile (require 'cl))
  37
  38 (nnoo-declare nnmh)
  39
  40 (defvoo nnmh-directory message-directory
  41   "Mail spool directory.")
  42
  43 (defvoo nnmh-get-new-mail t
  44   "If non-nil, nnmh will check the incoming mail file and split the mail.")
  45
  46 (defvoo nnmh-prepare-save-mail-hook nil
  47   "Hook run narrowed to an article before saving.")
  48
  49 (defvoo nnmh-be-safe nil
  50   "If non-nil, nnmh will check all articles to make sure whether they are new or not.
  51 Go through the .nnmh-articles file and compare with the actual
  52 articles in this folder.  The articles that are \"new\" will be marked
  53 as unread by Gnus.")
  54
  55 \f
  56
  57 (defconst nnmh-version "nnmh 1.0"
  58   "nnmh version.")
  59
  60 (defvoo nnmh-current-directory nil
  61   "Current news group directory.")
  62
  63 (defvoo nnmh-status-string "")
  64 (defvoo nnmh-group-alist nil)
  65 ;; Don't even think about setting this variable.  It does not exist.
  66 ;; Forget about it.  Uh-huh.  Nope.  Nobody here.  It's only bound
  67 ;; dynamically by certain functions in nndraft.
  68 (defvar nnmh-allow-delete-final nil)
  69
  70 \f
  71
  72 ;;; Interface functions.
  73
  74 (nnoo-define-basics nnmh)
  75
  76 (deffoo nnmh-retrieve-headers (articles &optional newsgroup server fetch-old)
  77   (with-current-buffer nntp-server-buffer
  78     (erase-buffer)
  79     (let* ((file nil)
  80            (number (length articles))
  81            (large (and (numberp nnmail-large-newsgroup)
  82                        (> number nnmail-large-newsgroup)))
  83            (count 0)
  84            (file-name-coding-system nnmail-pathname-coding-system)
  85            beg article)
  86       (nnmh-possibly-change-directory newsgroup server)
  87       ;; We don't support fetching by Message-ID.
  88       (if (stringp (car articles))
  89           'headers
  90         (while articles
  91           (when (and (file-exists-p
  92                       (setq file (concat (file-name-as-directory
  93                                           nnmh-current-directory)
  94                                          (int-to-string
  95                                           (setq article (pop articles))))))
  96                      (not (file-directory-p file)))
  97             (insert (format "221 %d Article retrieved.\n" article))
  98             (setq beg (point))
  99             (nnheader-insert-head file)
 100             (goto-char beg)
 101             (if (search-forward "\n\n" nil t)
 102                 (forward-char -1)
 103               (goto-char (point-max))
 104               (insert "\n\n"))
 105             (insert ".\n")
 106             (delete-region (point) (point-max)))
 107           (setq count (1+ count))
 108
 109           (and large
 110                (zerop (% count 20))
 111                (nnheader-message 5 "nnmh: Receiving headers... %d%%"
 112                                  (/ (* count 100) number))))
 113
 114         (when large
 115           (nnheader-message 5 "nnmh: Receiving headers...done"))
 116
 117         (nnheader-fold-continuation-lines)
 118         'headers))))
 119
 120 (deffoo nnmh-open-server (server &optional defs)
 121   (nnoo-change-server 'nnmh server defs)
 122   (when (not (file-exists-p nnmh-directory))
 123     (condition-case ()
 124         (make-directory nnmh-directory t)
 125       (error t)))
 126   (cond
 127    ((not (file-exists-p nnmh-directory))
 128     (nnmh-close-server)
 129     (nnheader-report 'nnmh "Couldn't create directory: %s" nnmh-directory))
 130    ((not (file-directory-p (file-truename nnmh-directory)))
 131     (nnmh-close-server)
 132     (nnheader-report 'nnmh "Not a directory: %s" nnmh-directory))
 133    (t
 134     (nnheader-report 'nnmh "Opened server %s using directory %s"
 135                      server nnmh-directory)
 136     t)))
 137
 138 (deffoo nnmh-request-article (id &optional newsgroup server buffer)
 139   (nnmh-possibly-change-directory newsgroup server)
 140   (let ((file (if (stringp id)
 141                   nil
 142                 (concat nnmh-current-directory (int-to-string id))))
 143         (file-name-coding-system nnmail-pathname-coding-system)
 144         (nntp-server-buffer (or buffer nntp-server-buffer)))
 145     (and (stringp file)
 146          (file-exists-p file)
 147          (not (file-directory-p file))
 148          (save-excursion (nnmail-find-file file))
 149          (string-to-number (file-name-nondirectory file)))))
 150
 151 (deffoo nnmh-request-group (group &optional server dont-check info)
 152   (nnheader-init-server-buffer)
 153   (nnmh-possibly-change-directory group server)
 154   (let ((pathname (nnmail-group-pathname group nnmh-directory))
 155         (file-name-coding-system nnmail-pathname-coding-system)
 156         dir)
 157     (cond
 158      ((not (file-directory-p pathname))
 159       (nnheader-report
 160        'nnmh "Can't select group (no such directory): %s" group))
 161      (t
 162       (setq nnmh-current-directory pathname)
 163       (and nnmh-get-new-mail
 164            nnmh-be-safe
 165            (nnmh-update-gnus-unreads group))
 166       (cond
 167        (dont-check
 168         (nnheader-report 'nnmh "Selected group %s" group)
 169         t)
 170        (t
 171         ;; Re-scan the directory if it's on a foreign system.
 172         (nnheader-re-read-dir pathname)
 173         (setq dir
 174               (sort
 175                (mapcar 'string-to-number
 176                        (directory-files pathname nil "^[0-9]+$" t))
 177                '<))
 178         (cond
 179          (dir
 180           (setq nnmh-group-alist
 181                 (delq (assoc group nnmh-group-alist) nnmh-group-alist))
 182           (push (list group (cons (car dir) (car (last dir))))
 183                 nnmh-group-alist)
 184           (nnheader-report 'nnmh "Selected group %s" group)
 185           (nnheader-insert
 186            "211 %d %d %d %s\n" (length dir) (car dir)
 187            (car (last dir)) group))
 188          (t
 189           (nnheader-report 'nnmh "Empty group %s" group)
 190           (nnheader-insert (format "211 0 1 0 %s\n" group))))))))))
 191
 192 (deffoo nnmh-request-scan (&optional group server)
 193   (nnmail-get-new-mail 'nnmh nil nnmh-directory group))
 194
 195 (deffoo nnmh-request-list (&optional server dir)
 196   (nnheader-insert "")
 197   (nnmh-possibly-change-directory nil server)
 198   (let ((file-name-coding-system nnmail-pathname-coding-system)
 199         (nnmh-toplev
 200          (file-truename (or dir (file-name-as-directory nnmh-directory)))))
 201     (nnmh-request-list-1 nnmh-toplev))
 202   (setq nnmh-group-alist (nnmail-get-active))
 203   t)
 204
 205 (defvar nnmh-toplev)
 206 (defun nnmh-request-list-1 (dir)
 207   (setq dir (expand-file-name dir))
 208   ;; Recurse down all directories.
 209   (let ((files (nnheader-directory-files dir t nil t))
 210         (max 0)
 211         min rdir num subdirectoriesp file)
 212     ;; Recurse down directories.
 213     (setq subdirectoriesp (> (nth 1 (file-attributes dir)) 2))
 214     (dolist (rdir files)
 215       (if (or (not subdirectoriesp)
 216               (file-regular-p rdir))
 217           (progn
 218             (setq file (file-name-nondirectory rdir))
 219             (when (string-match "^[0-9]+$" file)
 220               (setq num (string-to-number file))
 221               (setq max (max max num))
 222               (when (or (null min)
 223                         (< num min))
 224                 (setq min num))))
 225         ;; This is a directory.
 226         (when (and (file-readable-p rdir)
 227                    (not (equal (file-truename rdir)
 228                                (file-truename dir))))
 229           (nnmh-request-list-1 rdir))))
 230     ;; For each directory, generate an active file line.
 231     (unless (string= (expand-file-name nnmh-toplev) dir)
 232       (with-current-buffer nntp-server-buffer
 233         (goto-char (point-max))
 234         (insert
 235          (format
 236           "%s %.0f %.0f y\n"
 237           (progn
 238             (string-match
 239              (regexp-quote
 240               (file-truename (file-name-as-directory
 241                               (expand-file-name nnmh-toplev))))
 242              dir)
 243             (mm-string-to-multibyte ;Why?  Isn't it multibyte already?
 244              (mm-encode-coding-string
 245               (nnheader-replace-chars-in-string
 246                (substring dir (match-end 0))
 247                ?/ ?.)
 248               nnmail-pathname-coding-system)))
 249           (or max 0)
 250           (or min 1))))))
 251   t)
 252
 253 (deffoo nnmh-request-newgroups (date &optional server)
 254   (nnmh-request-list server))
 255
 256 (deffoo nnmh-request-expire-articles (articles newsgroup
 257                                                &optional server force)
 258   (nnmh-possibly-change-directory newsgroup server)
 259   (let ((is-old t)
 260         article rest mod-time)
 261     (nnheader-init-server-buffer)
 262
 263     (while (and articles is-old)
 264       (setq article (concat nnmh-current-directory
 265                             (int-to-string (car articles))))
 266       (when (setq mod-time (nth 5 (file-attributes article)))
 267         (if (and (nnmh-deletable-article-p newsgroup (car articles))
 268                  (setq is-old
 269                        (nnmail-expired-article-p newsgroup mod-time force)))
 270             (progn
 271               ;; Allow a special target group. -- jcn
 272               (unless (eq nnmail-expiry-target 'delete)
 273                 (with-temp-buffer
 274                   (nnmh-request-article (car articles)
 275                                         newsgroup server (current-buffer))
 276                   (nnmail-expiry-target-group
 277                    nnmail-expiry-target newsgroup)))
 278               (nnheader-message 5 "Deleting article %s in %s..."
 279                                 article newsgroup)
 280               (condition-case ()
 281                   (funcall nnmail-delete-file-function article)
 282                 (file-error
 283                  (nnheader-message 1 "Couldn't delete article %s in %s"
 284                                    article newsgroup)
 285                  (push (car articles) rest))))
 286           (push (car articles) rest)))
 287       (setq articles (cdr articles)))
 288     (nnheader-message 5 "")
 289     (nconc rest articles)))
 290
 291 (deffoo nnmh-close-group (group &optional server)
 292   t)
 293
 294 (deffoo nnmh-request-move-article (article group server accept-form
 295                                            &optional last move-is-internal)
 296   (let ((buf (get-buffer-create " *nnmh move*"))
 297         result)
 298     (and
 299      (nnmh-deletable-article-p group article)
 300      (nnmh-request-article article group server)
 301      (with-current-buffer buf
 302        (erase-buffer)
 303        (insert-buffer-substring nntp-server-buffer)
 304        (setq result (eval accept-form))
 305        (kill-buffer (current-buffer))
 306        result)
 307      (progn
 308        (nnmh-possibly-change-directory group server)
 309        (condition-case ()
 310            (funcall nnmail-delete-file-function
 311                     (concat nnmh-current-directory (int-to-string article)))
 312          (file-error nil))))
 313     result))
 314
 315 (deffoo nnmh-request-accept-article (group &optional server last noinsert)
 316   (nnmh-possibly-change-directory group server)
 317   (nnmail-check-syntax)
 318   (when nnmail-cache-accepted-message-ids
 319     (nnmail-cache-insert (nnmail-fetch-field "message-id")
 320                          group
 321                          (nnmail-fetch-field "subject")
 322                          (nnmail-fetch-field "from")))
 323   (nnheader-init-server-buffer)
 324   (prog1
 325       (if (stringp group)
 326           (if noinsert
 327               (nnmh-active-number group)
 328             (car (nnmh-save-mail
 329                   (list (cons group (nnmh-active-number group)))
 330                   noinsert)))
 331         (let ((res (nnmail-article-group 'nnmh-active-number)))
 332           (if (and (null res)
 333                    (yes-or-no-p "Moved to `junk' group; delete article? "))
 334               'junk
 335             (car (nnmh-save-mail res noinsert)))))
 336     (when (and last nnmail-cache-accepted-message-ids)
 337       (nnmail-cache-close))))
 338
 339 (deffoo nnmh-request-replace-article (article group buffer)
 340   (nnmh-possibly-change-directory group)
 341   (with-current-buffer buffer
 342     (nnmh-possibly-create-directory group)
 343     (ignore-errors
 344       (nnmail-write-region
 345        (point-min) (point-max)
 346        (concat nnmh-current-directory (int-to-string article))
 347        nil (if (nnheader-be-verbose 5) nil 'nomesg))
 348       t)))
 349
 350 (deffoo nnmh-request-create-group (group &optional server args)
 351   (nnheader-init-server-buffer)
 352   (unless (assoc group nnmh-group-alist)
 353     (let (active)
 354       (push (list group (setq active (cons 1 0)))
 355             nnmh-group-alist)
 356       (nnmh-possibly-create-directory group)
 357       (nnmh-possibly-change-directory group server)
 358       (let ((articles (mapcar 'string-to-number
 359                               (directory-files
 360                                nnmh-current-directory nil "^[0-9]+$"))))
 361         (when articles
 362           (setcar active (apply 'min articles))
 363           (setcdr active (apply 'max articles))))))
 364   t)
 365
 366 (deffoo nnmh-request-delete-group (group &optional force server)
 367   (nnmh-possibly-change-directory group server)
 368   ;; Delete all articles in GROUP.
 369   (if (not force)
 370       ()                                ; Don't delete the articles.
 371     (let ((articles (directory-files nnmh-current-directory t "^[0-9]+$")))
 372       (while articles
 373         (when (file-writable-p (car articles))
 374           (nnheader-message 5 "Deleting article %s in %s..."
 375                             (car articles) group)
 376           (funcall nnmail-delete-file-function (car articles)))
 377         (setq articles (cdr articles))))
 378     ;; Try to delete the directory itself.
 379     (ignore-errors
 380       (delete-directory nnmh-current-directory)))
 381   ;; Remove the group from all structures.
 382   (setq nnmh-group-alist
 383         (delq (assoc group nnmh-group-alist) nnmh-group-alist)
 384         nnmh-current-directory nil)
 385   t)
 386
 387 (deffoo nnmh-request-rename-group (group new-name &optional server)
 388   (nnmh-possibly-change-directory group server)
 389   (let ((new-dir (nnmail-group-pathname new-name nnmh-directory))
 390         (old-dir (nnmail-group-pathname group nnmh-directory)))
 391     (when (ignore-errors
 392             (make-directory new-dir t)
 393             t)
 394       ;; We move the articles file by file instead of renaming
 395       ;; the directory -- there may be subgroups in this group.
 396       ;; One might be more clever, I guess.
 397       (let ((files (nnheader-article-to-file-alist old-dir)))
 398         (while files
 399           (rename-file
 400            (concat old-dir (cdar files))
 401            (concat new-dir (cdar files)))
 402           (pop files)))
 403       (when (<= (length (directory-files old-dir)) 2)
 404         (ignore-errors
 405           (delete-directory old-dir)))
 406       ;; That went ok, so we change the internal structures.
 407       (let ((entry (assoc group nnmh-group-alist)))
 408         (when entry
 409           (setcar entry new-name))
 410         (setq nnmh-current-directory nil)
 411         t))))
 412
 413 (nnoo-define-skeleton nnmh)
 414
 415 \f
 416 ;;; Internal functions.
 417
 418 (defun nnmh-possibly-change-directory (newsgroup &optional server)
 419   (when (and server
 420              (not (nnmh-server-opened server)))
 421     (nnmh-open-server server))
 422   (when newsgroup
 423     (let ((pathname (nnmail-group-pathname newsgroup nnmh-directory))
 424           (file-name-coding-system nnmail-pathname-coding-system))
 425       (if (file-directory-p pathname)
 426           (setq nnmh-current-directory pathname)
 427         (nnheader-report 'nnmh "Not a directory: %s" nnmh-directory)))))
 428
 429 (defun nnmh-possibly-create-directory (group)
 430   (let (dir dirs)
 431     (setq dir (nnmail-group-pathname group nnmh-directory))
 432     (while (not (file-directory-p dir))
 433       (push dir dirs)
 434       (setq dir (file-name-directory (directory-file-name dir))))
 435     (while dirs
 436       (when (make-directory (directory-file-name (car dirs)))
 437         (error "Could not create directory %s" (car dirs)))
 438       (nnheader-message 5 "Creating mail directory %s" (car dirs))
 439       (setq dirs (cdr dirs)))))
 440
 441 (defun nnmh-save-mail (group-art &optional noinsert)
 442   "Called narrowed to an article."
 443   (unless noinsert
 444     (nnmail-insert-lines)
 445     (nnmail-insert-xref group-art))
 446   (run-hooks 'nnmail-prepare-save-mail-hook)
 447   (run-hooks 'nnmh-prepare-save-mail-hook)
 448   (goto-char (point-min))
 449   (while (looking-at "From ")
 450     (replace-match "X-From-Line: ")
 451     (forward-line 1))
 452   ;; We save the article in all the newsgroups it belongs in.
 453   (let ((ga group-art)
 454         first)
 455     (while ga
 456       (nnmh-possibly-create-directory (caar ga))
 457       (let ((file (concat (nnmail-group-pathname
 458                            (caar ga) nnmh-directory)
 459                           (int-to-string (cdar ga)))))
 460         (if first
 461             ;; It was already saved, so we just make a hard link.
 462             (funcall nnmail-crosspost-link-function first file t)
 463           ;; Save the article.
 464           (nnmail-write-region (point-min) (point-max) file nil nil)
 465           (setq first file)))
 466       (setq ga (cdr ga))))
 467   group-art)
 468
 469 (defun nnmh-active-number (group)
 470   "Compute the next article number in GROUP."
 471   (let ((active (cadr (assoc group nnmh-group-alist)))
 472         (dir (nnmail-group-pathname group nnmh-directory))
 473         (file-name-coding-system nnmail-pathname-coding-system)
 474         file)
 475     (unless active
 476       ;; The group wasn't known to nnmh, so we just create an active
 477       ;; entry for it.
 478       (setq active (cons 1 0))
 479       (push (list group active) nnmh-group-alist)
 480       (unless (file-exists-p dir)
 481         (gnus-make-directory dir))
 482       ;; Find the highest number in the group.
 483       (let ((files (sort
 484                     (mapcar 'string-to-number
 485                             (directory-files dir nil "^[0-9]+$"))
 486                     '>)))
 487         (when files
 488           (setcdr active (car files)))))
 489     (setcdr active (1+ (cdr active)))
 490     (while (or
 491             ;; See whether the file exists...
 492             (file-exists-p
 493              (setq file (concat (nnmail-group-pathname group nnmh-directory)
 494                                 (int-to-string (cdr active)))))
 495             ;; ... or there is a buffer that will make that file exist
 496             ;; in the future.
 497             (get-file-buffer file))
 498       ;; Skip past that file.
 499       (setcdr active (1+ (cdr active))))
 500     (cdr active)))
 501
 502 (defun nnmh-update-gnus-unreads (group)
 503   ;; Go through the .nnmh-articles file and compare with the actual
 504   ;; articles in this folder.  The articles that are "new" will be
 505   ;; marked as unread by Gnus.
 506   (let* ((dir nnmh-current-directory)
 507          (files (sort (mapcar 'string-to-number
 508                               (directory-files nnmh-current-directory
 509                                                nil "^[0-9]+$" t))
 510                       '<))
 511          (nnmh-file (concat dir ".nnmh-articles"))
 512          new articles)
 513     ;; Load the .nnmh-articles file.
 514     (when (file-exists-p nnmh-file)
 515       (setq articles
 516             (let (nnmh-newsgroup-articles)
 517               (ignore-errors (load nnmh-file nil t t))
 518               nnmh-newsgroup-articles)))
 519     ;; Add all new articles to the `new' list.
 520     (let ((art files))
 521       (while art
 522         (unless (assq (car art) articles)
 523           (push (car art) new))
 524         (setq art (cdr art))))
 525     ;; Remove all deleted articles.
 526     (let ((art articles))
 527       (while art
 528         (unless (memq (caar art) files)
 529           (setq articles (delq (car art) articles)))
 530         (setq art (cdr art))))
 531     ;; Check whether the articles really are the ones that Gnus thinks
 532     ;; they are by looking at the time-stamps.
 533     (let ((arts articles)
 534           art)
 535       (while (setq art (pop arts))
 536         (when (not (equal
 537                     (nth 5 (file-attributes
 538                             (concat dir (int-to-string (car art)))))
 539                     (cdr art)))
 540           (setq articles (delq art articles))
 541           (push (car art) new))))
 542     ;; Go through all the new articles and add them, and their
 543     ;; time-stamps, to the list.
 544     (setq articles
 545           (nconc articles
 546                  (mapcar
 547                   (lambda (art)
 548                     (cons art
 549                           (nth 5 (file-attributes
 550                                   (concat dir (int-to-string art))))))
 551                   new)))
 552     ;; Make Gnus mark all new articles as unread.
 553     (when new
 554       (gnus-make-articles-unread
 555        (gnus-group-prefixed-name group (list 'nnmh ""))
 556        (setq new (sort new '<))))
 557     ;; Sort the article list with highest numbers first.
 558     (setq articles (sort articles (lambda (art1 art2)
 559                                     (> (car art1) (car art2)))))
 560     ;; Finally write this list back to the .nnmh-articles file.
 561     (with-temp-file nnmh-file
 562       (insert ";; Gnus article active file for " group "\n\n")
 563       (insert "(setq nnmh-newsgroup-articles '")
 564       (gnus-prin1 articles)
 565       (insert ")\n"))))
 566
 567 (defun nnmh-deletable-article-p (group article)
 568   "Say whether ARTICLE in GROUP can be deleted."
 569   (let ((path (concat nnmh-current-directory (int-to-string article))))
 570     ;; Writable.
 571     (and (file-writable-p path)
 572          (or
 573           ;; We can never delete the last article in the group.
 574           (not (eq (cdr (nth 1 (assoc group nnmh-group-alist)))
 575                    article))
 576           ;; Well, we can.
 577           nnmh-allow-delete-final))))
 578
 579 (provide 'nnmh)
 580
 581 ;;; nnmh.el ends here