cgit.sxemacs.org Git - gnus/blob - lisp/nnimap.el

   1 ;;; nnimap.el --- IMAP interface for Gnus
   2
   3 ;; Copyright (C) 2010 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;         Simon Josefsson <simon@josefsson.org>
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; nnimap interfaces Gnus with IMAP servers.
  26
  27 ;;; Code:
  28
  29 (eval-and-compile
  30   (require 'nnheader))
  31
  32 (eval-when-compile
  33   (require 'cl))
  34
  35 (require 'nnheader)
  36 (require 'gnus-util)
  37 (require 'gnus)
  38 (require 'nnoo)
  39 (require 'netrc)
  40
  41 (nnoo-declare nnimap)
  42
  43 (defvoo nnimap-address nil
  44   "The address of the IMAP server.")
  45
  46 (defvoo nnimap-server-port nil
  47   "The IMAP port used.
  48 If nnimap-stream is `ssl', this will default to `imaps'.  If not,
  49 it will default to `imap'.")
  50
  51 (defvoo nnimap-stream 'ssl
  52   "How nnimap will talk to the IMAP server.
  53 Values are `ssl' and `network'.")
  54
  55 (defvoo nnimap-shell-program (if (boundp 'imap-shell-program)
  56                                  (if (listp imap-shell-program)
  57                                      (car imap-shell-program)
  58                                    imap-shell-program)
  59                                "ssh %s imapd"))
  60
  61 (defvoo nnimap-inbox nil
  62   "The mail box where incoming mail arrives and should be split out of.")
  63
  64 (defvoo nnimap-expunge-inbox nil
  65   "If non-nil, expunge the inbox after fetching mail.
  66 This is always done if the server supports UID EXPUNGE, but it's
  67 not done by default on servers that doesn't support that command.")
  68
  69 (defvoo nnimap-authenticator nil
  70   "How nnimap authenticate itself to the server.
  71 Possible choices are nil (use default methods) or `anonymous'.")
  72
  73 (defvoo nnimap-fetch-partial-articles nil
  74   "If non-nil, nnimap will fetch partial articles.
  75 If t, nnimap will fetch only the first part.  If a string, it
  76 will fetch all parts that have types that match that string.  A
  77 likely value would be \"text/\" to automatically fetch all
  78 textual parts.")
  79
  80 (defvoo nnimap-connection-alist nil)
  81
  82 (defvoo nnimap-current-infos nil)
  83
  84 (defvar nnimap-process nil)
  85
  86 (defvar nnimap-status-string "")
  87
  88 (defvar nnimap-split-download-body-default nil
  89   "Internal variable with default value for `nnimap-split-download-body'.")
  90
  91 (defstruct nnimap
  92   group process commands capabilities select-result newlinep)
  93
  94 (defvar nnimap-object nil)
  95
  96 (defvar nnimap-mark-alist
  97   '((read "\\Seen")
  98     (tick "\\Flagged")
  99     (reply "\\Answered")
 100     (expire "gnus-expire")
 101     (dormant "gnus-dormant")
 102     (score "gnus-score")
 103     (save "gnus-save")
 104     (download "gnus-download")
 105     (forward "gnus-forward")))
 106
 107 (defvar nnimap-split-methods nil)
 108
 109 (defun nnimap-buffer ()
 110   (nnimap-find-process-buffer nntp-server-buffer))
 111
 112 (deffoo nnimap-retrieve-headers (articles &optional group server fetch-old)
 113   (with-current-buffer nntp-server-buffer
 114     (erase-buffer)
 115     (when (nnimap-possibly-change-group group server)
 116       (with-current-buffer (nnimap-buffer)
 117         (nnimap-send-command "SELECT %S" (utf7-encode group t))
 118         (erase-buffer)
 119         (nnimap-wait-for-response
 120          (nnimap-send-command
 121           "UID FETCH %s %s"
 122           (nnimap-article-ranges (gnus-compress-sequence articles))
 123           (format "(UID RFC822.SIZE BODYSTRUCTURE %s)"
 124                   (format
 125                    (if (member "IMAP4REV1"
 126                                (nnimap-capabilities nnimap-object))
 127                        "BODY.PEEK[HEADER.FIELDS %s]"
 128                      "RFC822.HEADER.LINES %s")
 129                    (append '(Subject From Date Message-Id
 130                                      References In-Reply-To Xref)
 131                            nnmail-extra-headers))))
 132          t)
 133         (nnimap-transform-headers))
 134       (insert-buffer-substring
 135        (nnimap-find-process-buffer (current-buffer))))
 136     t))
 137
 138 (defun nnimap-transform-headers ()
 139   (goto-char (point-min))
 140   (let (article bytes lines size)
 141     (block nil
 142       (while (not (eobp))
 143         (while (not (looking-at "^\\* [0-9]+ FETCH.*UID \\([0-9]+\\)"))
 144           (delete-region (point) (progn (forward-line 1) (point)))
 145           (when (eobp)
 146             (return)))
 147         (setq article (match-string 1)
 148               bytes (nnimap-get-length)
 149               lines nil)
 150         (beginning-of-line)
 151         (setq size
 152               (and (re-search-forward "RFC822.SIZE \\([0-9]+\\)"
 153                                       (line-end-position)
 154                                       t)
 155                    (match-string 1)))
 156         (beginning-of-line)
 157         (when (search-forward "BODYSTRUCTURE" (line-end-position) t)
 158           (let ((structure (ignore-errors (read (current-buffer)))))
 159             (while (and (consp structure)
 160                         (not (stringp (car structure))))
 161               (setq structure (car structure)))
 162             (setq lines (nth 7 structure))))
 163         (delete-region (line-beginning-position) (line-end-position))
 164         (insert (format "211 %s Article retrieved." article))
 165         (forward-line 1)
 166         (when size
 167           (insert (format "Chars: %s\n" size)))
 168         (when lines
 169           (insert (format "Lines: %s\n" lines)))
 170         (re-search-forward "^\r$")
 171         (delete-region (line-beginning-position) (line-end-position))
 172         (insert ".")
 173         (forward-line 1)))))
 174
 175 (defun nnimap-get-length ()
 176   (and (re-search-forward "{\\([0-9]+\\)}" (line-end-position) t)
 177        (string-to-number (match-string 1))))
 178
 179 (defun nnimap-article-ranges (ranges)
 180   (let (result)
 181     (cond
 182      ((numberp ranges)
 183       (number-to-string ranges))
 184      ((numberp (cdr ranges))
 185       (format "%d:%d" (car ranges) (cdr ranges)))
 186      (t
 187       (dolist (elem ranges)
 188         (push
 189          (if (consp elem)
 190              (format "%d:%d" (car elem) (cdr elem))
 191            (number-to-string elem))
 192          result))
 193       (mapconcat #'identity (nreverse result) ",")))))
 194
 195 (deffoo nnimap-open-server (server &optional defs)
 196   (if (nnimap-server-opened server)
 197       t
 198     (unless (assq 'nnimap-address defs)
 199       (setq defs (append defs (list (list 'nnimap-address server)))))
 200     (nnoo-change-server 'nnimap server defs)
 201     (or (nnimap-find-connection nntp-server-buffer)
 202         (nnimap-open-connection nntp-server-buffer))))
 203
 204 (defun nnimap-make-process-buffer (buffer)
 205   (with-current-buffer
 206       (generate-new-buffer (format "*nnimap %s %s %s*"
 207                                    nnimap-address nnimap-server-port
 208                                    (gnus-buffer-exists-p buffer)))
 209     (mm-disable-multibyte)
 210     (buffer-disable-undo)
 211     (gnus-add-buffer)
 212     (set (make-local-variable 'after-change-functions) nil)
 213     (set (make-local-variable 'nnimap-object) (make-nnimap))
 214     (push (list buffer (current-buffer)) nnimap-connection-alist)
 215     (current-buffer)))
 216
 217 (defun nnimap-open-shell-stream (name buffer host port)
 218   (let ((process-connection-type nil))
 219     (start-process name buffer shell-file-name
 220                    shell-command-switch
 221                    (format-spec
 222                     nnimap-shell-program
 223                     (format-spec-make
 224                      ?s host
 225                      ?p port)))))
 226
 227 (defun nnimap-credentials (address ports)
 228   (let (port credentials)
 229     ;; Request the credentials from all ports, but only query on the
 230     ;; last port if all the previous ones have failed.
 231     (while (and (null credentials)
 232                 (setq port (pop ports)))
 233       (setq credentials
 234             (auth-source-user-or-password
 235              '("login" "password") address port nil (null ports))))
 236     credentials))
 237
 238 (defun nnimap-open-connection (buffer)
 239   (with-current-buffer (nnimap-make-process-buffer buffer)
 240     (let* ((coding-system-for-read 'binary)
 241            (coding-system-for-write 'binary)
 242            (ports
 243             (cond
 244              ((eq nnimap-stream 'network)
 245               (open-network-stream
 246                "*nnimap*" (current-buffer) nnimap-address
 247                (or nnimap-server-port
 248                    (if (netrc-find-service-number "imap")
 249                        "imap"
 250                      "143")))
 251               '("143" "imap"))
 252              ((eq nnimap-stream 'shell)
 253               (nnimap-open-shell-stream
 254                "*nnimap*" (current-buffer) nnimap-address
 255                (or nnimap-server-port "imap"))
 256               '("imap"))
 257              ((eq nnimap-stream 'ssl)
 258               (open-tls-stream
 259                "*nnimap*" (current-buffer) nnimap-address
 260                (or nnimap-server-port
 261                    (if (netrc-find-service-number "imaps")
 262                        "imaps"
 263                      "993")))
 264               '("143" "993" "imap" "imaps"))))
 265            connection-result login-result credentials)
 266       (setf (nnimap-process nnimap-object)
 267             (get-buffer-process (current-buffer)))
 268       (when (and (nnimap-process nnimap-object)
 269                  (memq (process-status (nnimap-process nnimap-object))
 270                        '(open run)))
 271         (gnus-set-process-query-on-exit-flag (nnimap-process nnimap-object) nil)
 272         (when (setq connection-result (nnimap-wait-for-connection))
 273           (unless (equal connection-result "PREAUTH")
 274             (if (not (setq credentials
 275                            (if (eq nnimap-authenticator 'anonymous)
 276                                (list "anonymous"
 277                                      (message-make-address))
 278                              (nnimap-credentials
 279                               nnimap-address
 280                               (if nnimap-server-port
 281                                   (cons (format "%s" nnimap-server-port) ports)
 282                                 ports)))))
 283                 (setq nnimap-object nil)
 284               (setq login-result (nnimap-command "LOGIN %S %S"
 285                                                  (car credentials)
 286                                                  (cadr credentials)))
 287               (unless (car login-result)
 288                 (delete-process (nnimap-process nnimap-object))
 289                 (setq nnimap-object nil))))
 290           (when nnimap-object
 291             (setf (nnimap-capabilities nnimap-object)
 292                   (mapcar
 293                    #'upcase
 294                    (or (nnimap-find-parameter "CAPABILITY" (cdr login-result))
 295                        (nnimap-find-parameter
 296                         "CAPABILITY" (cdr (nnimap-command "CAPABILITY"))))))
 297             (when (member "QRESYNC" (nnimap-capabilities nnimap-object))
 298               (nnimap-command "ENABLE QRESYNC"))
 299             t))))))
 300
 301 (defun nnimap-find-parameter (parameter elems)
 302   (let (result)
 303     (dolist (elem elems)
 304       (cond
 305        ((equal (car elem) parameter)
 306         (setq result (cdr elem)))
 307        ((and (equal (car elem) "OK")
 308              (consp (cadr elem))
 309              (equal (caadr elem) parameter))
 310         (setq result (cdr (cadr elem))))))
 311     result))
 312
 313 (deffoo nnimap-close-server (&optional server)
 314   t)
 315
 316 (deffoo nnimap-request-close ()
 317   t)
 318
 319 (deffoo nnimap-server-opened (&optional server)
 320   (and (nnoo-current-server-p 'nnimap server)
 321        nntp-server-buffer
 322        (gnus-buffer-live-p nntp-server-buffer)
 323        (nnimap-find-connection nntp-server-buffer)))
 324
 325 (deffoo nnimap-status-message (&optional server)
 326   nnimap-status-string)
 327
 328 (deffoo nnimap-request-article (article &optional group server to-buffer)
 329   (with-current-buffer nntp-server-buffer
 330     (let ((result (nnimap-possibly-change-group group server))
 331           parts)
 332       (when (stringp article)
 333         (setq article (nnimap-find-article-by-message-id group article)))
 334       (when (and result
 335                  article)
 336         (erase-buffer)
 337         (with-current-buffer (nnimap-buffer)
 338           (erase-buffer)
 339           (when nnimap-fetch-partial-articles
 340             (if (eq nnimap-fetch-partial-articles t)
 341                 (setq parts '(1))
 342               (nnimap-command "UID FETCH %d (BODYSTRUCTURE)" article)
 343               (goto-char (point-min))
 344               (when (re-search-forward "FETCH.*BODYSTRUCTURE" nil t)
 345                 (let ((structure (ignore-errors (read (current-buffer)))))
 346                   (setq parts (nnimap-find-wanted-parts structure))))))
 347           (setq result
 348                 (nnimap-command
 349                  (if (member "IMAP4REV1" (nnimap-capabilities nnimap-object))
 350                      "UID FETCH %d BODY.PEEK[]"
 351                    "UID FETCH %d RFC822.PEEK")
 352                  article))
 353           ;; Check that we really got an article.
 354           (goto-char (point-min))
 355           (unless (looking-at "\\* [0-9]+ FETCH")
 356             (setq result nil)))
 357         (let ((buffer (nnimap-find-process-buffer (current-buffer))))
 358           (when (car result)
 359             (with-current-buffer (or to-buffer nntp-server-buffer)
 360               (insert-buffer-substring buffer)
 361               (goto-char (point-min))
 362               (let ((bytes (nnimap-get-length)))
 363                 (delete-region (line-beginning-position)
 364                                (progn (forward-line 1) (point)))
 365                 (goto-char (+ (point) bytes))
 366                 (delete-region (point) (point-max))
 367                 (nnheader-ms-strip-cr))
 368               (cons group article))))))))
 369
 370 (defun nnimap-find-wanted-parts (structure)
 371   (message-flatten-list (nnimap-find-wanted-parts-1 structure "")))
 372
 373 (defun nnimap-find-wanted-parts-1 (structure prefix)
 374   (let ((num 1)
 375         parts)
 376     (while (consp (car structure))
 377       (let ((sub (pop structure)))
 378         (if (consp (car sub))
 379             (push (nnimap-find-wanted-parts-1
 380                    sub (if (string= prefix "")
 381                            (number-to-string num)
 382                          (format "%s.%s" prefix num)))
 383                   parts)
 384           (let ((type (format "%s/%s" (nth 0 sub) (nth 1 sub))))
 385             (when (string-match nnimap-fetch-partial-articles type)
 386               (push (if (string= prefix "")
 387                         (number-to-string num)
 388                       (format "%s.%s" prefix num))
 389                     parts)))
 390           (incf num))))
 391     (nreverse parts)))
 392
 393 (deffoo nnimap-request-group (group &optional server dont-check info)
 394   (let ((result (nnimap-possibly-change-group group server))
 395         articles active marks high low)
 396     (with-current-buffer nntp-server-buffer
 397       (when result
 398         (if (and dont-check
 399                  (setq active (nth 2 (assoc group nnimap-current-infos))))
 400             (insert (format "211 %d %d %d %S\n"
 401                             (- (cdr active) (car active))
 402                             (car active)
 403                             (cdr active)
 404                             group))
 405           (with-current-buffer (nnimap-buffer)
 406             (erase-buffer)
 407             (let ((group-sequence
 408                    (nnimap-send-command "SELECT %S" (utf7-encode group)))
 409                   (flag-sequence
 410                    (nnimap-send-command "UID FETCH 1:* FLAGS")))
 411               (nnimap-wait-for-response flag-sequence)
 412               (setq marks
 413                     (nnimap-flags-to-marks
 414                      (nnimap-parse-flags
 415                       (list (list group-sequence flag-sequence 1 group)))))
 416               (when info
 417                 (nnimap-update-infos marks (list info)))
 418               (goto-char (point-max))
 419               (cond
 420                (marks
 421                 (setq high (nth 3 (car marks))
 422                       low (nth 4 (car marks))))
 423                ((re-search-backward "UIDNEXT \\([0-9]+\\)" nil t)
 424                 (setq high (string-to-number (match-string 1))
 425                       low 1)))))
 426           (erase-buffer)
 427           (insert
 428            (format
 429             "211 %d %d %d %S\n"
 430             (1+ (- high low))
 431             low high group))))
 432       t)))
 433
 434 (deffoo nnimap-request-delete-group (group &optional force server)
 435   (when (nnimap-possibly-change-group nil server)
 436     (with-current-buffer (nnimap-buffer)
 437       (car (nnimap-command "DELETE %S" (utf7-encode group))))))
 438
 439 (defun nnimap-get-flags (spec)
 440   (let ((articles nil)
 441         elems)
 442     (with-current-buffer (nnimap-buffer)
 443       (erase-buffer)
 444       (nnimap-wait-for-response (nnimap-send-command
 445                                  "UID FETCH %s FLAGS" spec))
 446       (goto-char (point-min))
 447       (while (re-search-forward "^\\* [0-9]+ FETCH (\\(.*\\))" nil t)
 448         (setq elems (nnimap-parse-line (match-string 1)))
 449         (push (cons (string-to-number (cadr (member "UID" elems)))
 450                     (cadr (member "FLAGS" elems)))
 451               articles)))
 452     (nreverse articles)))
 453
 454 (deffoo nnimap-close-group (group &optional server)
 455   t)
 456
 457 (deffoo nnimap-request-move-article (article group server accept-form
 458                                              &optional last internal-move-group)
 459   (when (nnimap-possibly-change-group group server)
 460     ;; If the move is internal (on the same server), just do it the easy
 461     ;; way.
 462     (let ((message-id (message-field-value "message-id")))
 463       (if internal-move-group
 464           (let ((result
 465                  (with-current-buffer (nnimap-buffer)
 466                    (nnimap-command "UID COPY %d %S"
 467                                    article
 468                                    (utf7-encode internal-move-group t)))))
 469             (when (car result)
 470               (nnimap-delete-article article)
 471               (cons internal-move-group
 472                     (nnimap-find-article-by-message-id
 473                      internal-move-group message-id))))
 474         (with-temp-buffer
 475           (let ((result (eval accept-form)))
 476             (when result
 477               (nnimap-delete-article article)
 478               result)))))))
 479
 480 (deffoo nnimap-request-expire-articles (articles group &optional server force)
 481   (cond
 482    ((not (nnimap-possibly-change-group group server))
 483     articles)
 484    (force
 485     (unless (nnimap-delete-article articles)
 486       (message "Article marked for deletion, but not expunged."))
 487     nil)
 488    (t
 489     articles)))
 490
 491 (defun nnimap-find-article-by-message-id (group message-id)
 492   (when (nnimap-possibly-change-group group nil)
 493     (with-current-buffer (nnimap-buffer)
 494       (let ((result
 495              (nnimap-command "UID SEARCH HEADER Message-Id %S" message-id))
 496             article)
 497         (when (car result)
 498           ;; Select the last instance of the message in the group.
 499           (and (setq article
 500                      (car (last (assoc "SEARCH" (cdr result)))))
 501                (string-to-number article)))))))
 502
 503 (defun nnimap-delete-article (articles)
 504   (with-current-buffer (nnimap-buffer)
 505     (nnimap-command "UID STORE %s +FLAGS.SILENT (\\Deleted)"
 506                     (nnimap-article-ranges articles))
 507     (when (member "UIDPLUS" (nnimap-capabilities nnimap-object))
 508       (nnimap-send-command "UID EXPUNGE %s"
 509                            (nnimap-article-ranges articles))
 510       t)))
 511
 512 (deffoo nnimap-request-scan (&optional group server)
 513   (when (and (nnimap-possibly-change-group nil server)
 514              (equal group nnimap-inbox)
 515              nnimap-inbox
 516              nnimap-split-methods)
 517     (nnimap-split-incoming-mail)))
 518
 519 (defun nnimap-marks-to-flags (marks)
 520   (let (flags flag)
 521     (dolist (mark marks)
 522       (when (setq flag (cadr (assq mark nnimap-mark-alist)))
 523         (push flag flags)))
 524     flags))
 525
 526 (deffoo nnimap-request-set-mark (group actions &optional server)
 527   (when (nnimap-possibly-change-group group server)
 528     (let (sequence)
 529       (with-current-buffer (nnimap-buffer)
 530         ;; Just send all the STORE commands without waiting for
 531         ;; response.  If they're successful, they're successful.
 532         (dolist (action actions)
 533           (destructuring-bind (range action marks) action
 534             (let ((flags (nnimap-marks-to-flags marks)))
 535               (when flags
 536                 (setq sequence (nnimap-send-command
 537                                 "UID STORE %s %sFLAGS.SILENT (%s)"
 538                                 (nnimap-article-ranges range)
 539                                 (if (eq action 'del)
 540                                     "-"
 541                                   "+")
 542                                 (mapconcat #'identity flags " ")))))))
 543         ;; Wait for the last command to complete to avoid later
 544         ;; syncronisation problems with the stream.
 545         (when sequence
 546           (nnimap-wait-for-response sequence))))))
 547
 548 (deffoo nnimap-request-accept-article (group &optional server last)
 549   (when (nnimap-possibly-change-group nil server)
 550     (nnmail-check-syntax)
 551     (let ((message (buffer-string))
 552           (message-id (message-field-value "message-id"))
 553           sequence)
 554       (with-current-buffer (nnimap-buffer)
 555         (setq sequence (nnimap-send-command
 556                         "APPEND %S {%d}" (utf7-encode group t)
 557                         (length message)))
 558         (process-send-string (get-buffer-process (current-buffer)) message)
 559         (process-send-string (get-buffer-process (current-buffer))
 560                              (if (nnimap-newlinep nnimap-object)
 561                                  "\n"
 562                                "\r\n"))
 563         (let ((result (nnimap-get-response sequence)))
 564           (when result
 565             (cons group
 566                   (nnimap-find-article-by-message-id group message-id))))))))
 567
 568 (defun nnimap-add-cr ()
 569   (goto-char (point-min))
 570   (while (re-search-forward "\r?\n" nil t)
 571     (replace-match "\r\n" t t)))
 572
 573 (defun nnimap-get-groups ()
 574   (let ((result (nnimap-command "LIST \"\" \"*\""))
 575         groups)
 576     (when (car result)
 577       (dolist (line (cdr result))
 578         (when (and (equal (car line) "LIST")
 579                    (not (and (caadr line)
 580                              (string-match "noselect" (caadr line)))))
 581           (push (car (last line)) groups)))
 582       (nreverse groups))))
 583
 584 (deffoo nnimap-request-list (&optional server)
 585   (nnimap-possibly-change-group nil server)
 586   (with-current-buffer nntp-server-buffer
 587     (erase-buffer)
 588     (let ((groups
 589            (with-current-buffer (nnimap-buffer)
 590              (nnimap-get-groups)))
 591           sequences responses)
 592       (when groups
 593         (with-current-buffer (nnimap-buffer)
 594           (dolist (group groups)
 595             (push (list (nnimap-send-command "EXAMINE %S" (utf7-encode group t))
 596                         group)
 597                   sequences))
 598           (nnimap-wait-for-response (caar sequences))
 599           (setq responses
 600                 (nnimap-get-responses (mapcar #'car sequences))))
 601         (dolist (response responses)
 602           (let* ((sequence (car response))
 603                  (response (cadr response))
 604                  (group (cadr (assoc sequence sequences))))
 605             (when (and group
 606                        (equal (caar response) "OK"))
 607               (let ((uidnext (nnimap-find-parameter "UIDNEXT" response))
 608                     highest exists)
 609                 (dolist (elem response)
 610                   (when (equal (cadr elem) "EXISTS")
 611                     (setq exists (string-to-number (car elem)))))
 612                 (when uidnext
 613                   (setq highest (1- (string-to-number (car uidnext)))))
 614                 (cond
 615                  ((null highest)
 616                   (insert (format "%S 0 1 y\n" (utf7-decode group t))))
 617                  ((zerop exists)
 618                   ;; Empty group.
 619                   (insert (format "%S %d %d y\n"
 620                                   (utf7-decode group t) highest (1+ highest))))
 621                  (t
 622                   ;; Return the widest possible range.
 623                   (insert (format "%S %d 1 y\n" (utf7-decode group t)
 624                                   (or highest exists)))))))))
 625         t))))
 626
 627 (deffoo nnimap-retrieve-group-data-early (server infos)
 628   (when (nnimap-possibly-change-group nil server)
 629     (with-current-buffer (nnimap-buffer)
 630       ;; QRESYNC handling isn't implemented.
 631       (let ((qresyncp (member "notQRESYNC" (nnimap-capabilities nnimap-object)))
 632             marks groups sequences)
 633         ;; Go through the infos and gather the data needed to know
 634         ;; what and how to request the data.
 635         (dolist (info infos)
 636           (setq marks (gnus-info-marks info))
 637           (push (list (gnus-group-real-name (gnus-info-group info))
 638                       (cdr (assq 'active marks))
 639                       (cdr (assq 'uid marks)))
 640                 groups))
 641         ;; Then request the data.
 642         (erase-buffer)
 643         (dolist (elem groups)
 644           (if (and qresyncp
 645                    (nth 2 elem))
 646               (push
 647                (list 'qresync
 648                      (nnimap-send-command "EXAMINE %S (QRESYNC (%s %s))"
 649                                           (car elem)
 650                                           (car (nth 2 elem))
 651                                           (cdr (nth 2 elem)))
 652                      nil
 653                      (car elem))
 654                sequences)
 655             (let ((start
 656                    (if (nth 1 elem)
 657                        ;; Fetch the last 100 flags.
 658                        (max 1 (- (cdr (nth 1 elem)) 100))
 659                      1)))
 660               (push (list (nnimap-send-command "EXAMINE %S" (car elem))
 661                           (nnimap-send-command "UID FETCH %d:* FLAGS" start)
 662                           start
 663                           (car elem))
 664                     sequences))))
 665         sequences))))
 666
 667 (deffoo nnimap-finish-retrieve-group-infos (server infos sequences)
 668   (when (and sequences
 669              (nnimap-possibly-change-group nil server))
 670     (with-current-buffer (nnimap-buffer)
 671       ;; Wait for the final data to trickle in.
 672       (nnimap-wait-for-response (cadar sequences))
 673       ;; Now we should have all the data we need, no matter whether
 674       ;; we're QRESYNCING, fetching all the flags from scratch, or
 675       ;; just fetching the last 100 flags per group.
 676       (nnimap-update-infos (nnimap-flags-to-marks
 677                             (nnimap-parse-flags
 678                              (nreverse sequences)))
 679                            infos)
 680       ;; Finally, just return something resembling an active file in
 681       ;; the nntp buffer, so that the agent can save the info, too.
 682       (with-current-buffer nntp-server-buffer
 683         (erase-buffer)
 684         (dolist (info infos)
 685           (let* ((group (gnus-info-group info))
 686                  (active (gnus-active group)))
 687             (when active
 688               (insert (format "%S %d %d y\n"
 689                               (gnus-group-real-name group)
 690                               (cdr active)
 691                               (car active))))))))))
 692
 693 (defun nnimap-update-infos (flags infos)
 694   (dolist (info infos)
 695     (let ((group (gnus-group-real-name (gnus-info-group info))))
 696       (nnimap-update-info info (cdr (assoc group flags))))))
 697
 698 (defun nnimap-update-info (info marks)
 699   (when marks
 700     (destructuring-bind (existing flags high low uidnext start-article) marks
 701       (let ((group (gnus-info-group info))
 702             (completep (and start-article
 703                             (= start-article 1))))
 704         ;; First set the active ranges based on high/low.
 705         (if (or completep
 706                 (not (gnus-active group)))
 707             (gnus-set-active group
 708                              (if high
 709                                  (cons low high)
 710                                ;; No articles in this group.
 711                                (cons (1- uidnext) uidnext)))
 712           (setcdr (gnus-active group) high))
 713         ;; Then update the list of read articles.
 714         (let* ((unread
 715                 (gnus-compress-sequence
 716                  (gnus-set-difference
 717                   (gnus-set-difference
 718                    existing
 719                    (cdr (assoc "\\Seen" flags)))
 720                   (cdr (assoc "\\Flagged" flags)))))
 721                (read (gnus-range-difference
 722                       (cons start-article high) unread)))
 723           (when (> start-article 1)
 724             (setq read
 725                   (gnus-range-nconcat
 726                    (if (> start-article 1)
 727                        (gnus-sorted-range-intersection
 728                         (cons 1 (1- start-article))
 729                         (gnus-info-read info))
 730                      (gnus-info-read info))
 731                    read)))
 732           (gnus-info-set-read info read)
 733           ;; Update the marks.
 734           (setq marks (gnus-info-marks info))
 735           ;; Note the active level for the next run-through.
 736           (let ((active (assq 'active marks)))
 737             (if active
 738                 (setcdr active (gnus-active group))
 739               (push (cons 'active (gnus-active group)) marks)))
 740           (dolist (type (cdr nnimap-mark-alist))
 741             (let ((old-marks (assoc (car type) marks))
 742                   (new-marks (gnus-compress-sequence
 743                               (cdr (assoc (cadr type) flags)))))
 744               (setq marks (delq old-marks marks))
 745               (pop old-marks)
 746               (when (and old-marks
 747                          (> start-article 1))
 748                 (setq old-marks (gnus-range-difference
 749                                  old-marks
 750                                  (cons start-article high)))
 751                 (setq new-marks (gnus-range-nconcat old-marks new-marks)))
 752               (when new-marks
 753                 (push (cons (car type) new-marks) marks)))
 754             (gnus-info-set-marks info marks t)
 755             (nnimap-store-info info (gnus-active group))))))))
 756
 757 (defun nnimap-store-info (info active)
 758   (let* ((group (gnus-group-real-name (gnus-info-group info)))
 759          (entry (assoc group nnimap-current-infos)))
 760     (if entry
 761         (setcdr entry (list info active))
 762       (push (list group info active) nnimap-current-infos))))
 763
 764 (defun nnimap-flags-to-marks (groups)
 765   (let (data group totalp uidnext articles start-article mark)
 766     (dolist (elem groups)
 767       (setq group (car elem)
 768             uidnext (cadr elem)
 769             start-article (caddr elem)
 770             articles (cdddr elem))
 771       (let ((high (caar articles))
 772             marks low existing)
 773         (dolist (article articles)
 774           (setq low (car article))
 775           (push (car article) existing)
 776           (dolist (flag (cdr article))
 777             (setq mark (assoc flag marks))
 778             (if (not mark)
 779                 (push (list flag (car article)) marks)
 780               (setcdr mark (cons (car article) (cdr mark)))))
 781           (push (list group existing marks high low uidnext start-article)
 782                 data))))
 783     data))
 784
 785 (defun nnimap-parse-flags (sequences)
 786   (goto-char (point-min))
 787   (let (start end articles groups uidnext elems)
 788     (dolist (elem sequences)
 789       (destructuring-bind (group-sequence flag-sequence totalp group) elem
 790         ;; The EXAMINE was successful.
 791         (when (and (search-forward (format "\n%d OK " group-sequence) nil t)
 792                    (progn
 793                      (forward-line 1)
 794                      (setq start (point))
 795                      (if (re-search-backward "UIDNEXT \\([0-9]+\\)"
 796                                                (or end (point-min)) t)
 797                          (setq uidnext (string-to-number (match-string 1)))
 798                        (setq uidnext nil))
 799                      (goto-char start))
 800                    ;; The UID FETCH FLAGS was successful.
 801                    (search-forward (format "\n%d OK " flag-sequence) nil t))
 802           (setq end (point))
 803           (goto-char start)
 804           (while (re-search-forward "^\\* [0-9]+ FETCH (\\(.*\\))" end t)
 805             (setq elems (nnimap-parse-line (match-string 1)))
 806             (push (cons (string-to-number (cadr (member "UID" elems)))
 807                         (cadr (member "FLAGS" elems)))
 808                   articles))
 809           (push (nconc (list group uidnext totalp) articles) groups)
 810           (setq articles nil))))
 811     groups))
 812
 813 (defun nnimap-find-process-buffer (buffer)
 814   (cadr (assoc buffer nnimap-connection-alist)))
 815
 816 (deffoo nnimap-request-post (&optional server)
 817   (setq nnimap-status-string "Read-only server")
 818   nil)
 819
 820 (defun nnimap-possibly-change-group (group server)
 821   (let ((open-result t))
 822     (when (and server
 823                (not (nnimap-server-opened server)))
 824       (setq open-result (nnimap-open-server server)))
 825     (cond
 826      ((not open-result)
 827       nil)
 828      ((not group)
 829       t)
 830      (t
 831       (with-current-buffer (nnimap-buffer)
 832         (if (equal group (nnimap-group nnimap-object))
 833             t
 834           (let ((result (nnimap-command "SELECT %S" (utf7-encode group t))))
 835             (when (car result)
 836               (setf (nnimap-group nnimap-object) group
 837                     (nnimap-select-result nnimap-object) result)
 838               result))))))))
 839
 840 (defun nnimap-find-connection (buffer)
 841   "Find the connection delivering to BUFFER."
 842   (let ((entry (assoc buffer nnimap-connection-alist)))
 843     (when entry
 844       (if (and (buffer-name (cadr entry))
 845                (get-buffer-process (cadr entry))
 846                (memq (process-status (get-buffer-process (cadr entry)))
 847                      '(open run)))
 848           (get-buffer-process (cadr entry))
 849         (setq nnimap-connection-alist (delq entry nnimap-connection-alist))
 850         nil))))
 851
 852 (defvar nnimap-sequence 0)
 853
 854 (defun nnimap-send-command (&rest args)
 855   (process-send-string
 856    (get-buffer-process (current-buffer))
 857    (nnimap-log-command
 858     (format "%d %s%s\n"
 859             (incf nnimap-sequence)
 860             (apply #'format args)
 861             (if (nnimap-newlinep nnimap-object)
 862                 ""
 863               "\r"))))
 864   nnimap-sequence)
 865
 866 (defun nnimap-log-command (command)
 867   (with-current-buffer (get-buffer-create "*imap log*")
 868     (goto-char (point-max))
 869     (insert (format-time-string "%H:%M:%S") " " command))
 870   command)
 871
 872 (defun nnimap-command (&rest args)
 873   (erase-buffer)
 874   (let* ((sequence (apply #'nnimap-send-command args))
 875          (response (nnimap-get-response sequence)))
 876     (if (equal (caar response) "OK")
 877         (cons t response)
 878       (nnheader-report 'nnimap "%s"
 879                        (mapconcat #'identity (car response) " "))
 880       nil)))
 881
 882 (defun nnimap-get-response (sequence)
 883   (nnimap-wait-for-response sequence)
 884   (nnimap-parse-response))
 885
 886 (defun nnimap-wait-for-connection ()
 887   (let ((process (get-buffer-process (current-buffer))))
 888     (goto-char (point-min))
 889     (while (and (memq (process-status process)
 890                       '(open run))
 891                 (not (re-search-forward "^\\* .*\n" nil t)))
 892       (nnheader-accept-process-output process)
 893       (goto-char (point-min)))
 894     (forward-line -1)
 895     (and (looking-at "\\* \\([A-Z0-9]+\\)")
 896          (match-string 1))))
 897
 898 (defun nnimap-wait-for-response (sequence &optional messagep)
 899   (let ((process (get-buffer-process (current-buffer))))
 900     (goto-char (point-max))
 901     (while (and (memq (process-status process)
 902                       '(open run))
 903                 (not (re-search-backward (format "^%d .*\n" sequence)
 904                                          (max (point-min) (- (point) 500))
 905                                          t)))
 906       (when messagep
 907         (message "Read %dKB" (/ (buffer-size) 1000)))
 908       (nnheader-accept-process-output process)
 909       (goto-char (point-max)))))
 910
 911 (defun nnimap-parse-response ()
 912   (let ((lines (split-string (nnimap-last-response-string) "\r\n" t))
 913         result)
 914     (dolist (line lines)
 915       (push (cdr (nnimap-parse-line line)) result))
 916     ;; Return the OK/error code first, and then all the "continuation
 917     ;; lines" afterwards.
 918     (cons (pop result)
 919           (nreverse result))))
 920
 921 ;; Parse an IMAP response line lightly.  They look like
 922 ;; "* OK [UIDVALIDITY 1164213559] UIDs valid", typically, so parse
 923 ;; the lines into a list of strings and lists of string.
 924 (defun nnimap-parse-line (line)
 925   (let (char result)
 926     (with-temp-buffer
 927       (insert line)
 928       (goto-char (point-min))
 929       (while (not (eobp))
 930         (if (eql (setq char (following-char)) ? )
 931             (forward-char 1)
 932           (push
 933            (cond
 934             ((eql char ?\[)
 935              (split-string (buffer-substring
 936                             (1+ (point)) (1- (search-forward "]")))))
 937             ((eql char ?\()
 938              (split-string (buffer-substring
 939                             (1+ (point)) (1- (search-forward ")")))))
 940             ((eql char ?\")
 941              (forward-char 1)
 942              (buffer-substring (point) (1- (search-forward "\""))))
 943             (t
 944              (buffer-substring (point) (if (search-forward " " nil t)
 945                                            (1- (point))
 946                                          (goto-char (point-max))))))
 947            result)))
 948       (nreverse result))))
 949
 950 (defun nnimap-last-response-string ()
 951   (save-excursion
 952     (forward-line 1)
 953     (let ((end (point)))
 954       (forward-line -1)
 955       (when (not (bobp))
 956         (forward-line -1)
 957         (while (and (not (bobp))
 958                     (eql (following-char) ?*))
 959           (forward-line -1))
 960         (unless (eql (following-char) ?*)
 961           (forward-line 1)))
 962       (buffer-substring (point) end))))
 963
 964 (defun nnimap-get-responses (sequences)
 965   (let (responses)
 966     (dolist (sequence sequences)
 967       (goto-char (point-min))
 968       (when (re-search-forward (format "^%d " sequence) nil t)
 969         (push (list sequence (nnimap-parse-response))
 970               responses)))
 971     responses))
 972
 973 (defvar nnimap-incoming-split-list nil)
 974
 975 (defun nnimap-fetch-inbox (articles)
 976   (erase-buffer)
 977   (nnimap-wait-for-response
 978    (nnimap-send-command
 979     "UID FETCH %s %s"
 980     (nnimap-article-ranges articles)
 981     (format "(UID %s%s)"
 982             (format
 983              (if (member "IMAP4REV1"
 984                          (nnimap-capabilities nnimap-object))
 985                  "BODY.PEEK[HEADER] BODY.PEEK"
 986                "RFC822.PEEK"))
 987             (if nnimap-split-download-body-default
 988                 "[]"
 989               "[1]")))
 990    t))
 991
 992 (defun nnimap-split-incoming-mail ()
 993   (with-current-buffer (nnimap-buffer)
 994     (let ((nnimap-incoming-split-list nil)
 995           (nnmail-split-methods nnimap-split-methods)
 996           (nnmail-inhibit-default-split-group t)
 997           (groups (nnimap-get-groups))
 998           new-articles)
 999       (erase-buffer)
1000       (nnimap-command "SELECT %S" nnimap-inbox)
1001       (setq new-articles (nnimap-new-articles (nnimap-get-flags "1:*")))
1002       (when new-articles
1003         (nnimap-fetch-inbox new-articles)
1004         (nnimap-transform-split-mail)
1005         (nnheader-ms-strip-cr)
1006         (nnmail-cache-open)
1007         (nnmail-split-incoming (current-buffer)
1008                                #'nnimap-save-mail-spec
1009                                nil nil
1010                                #'nnimap-dummy-active-number)
1011         (when nnimap-incoming-split-list
1012           (let ((specs (nnimap-make-split-specs nnimap-incoming-split-list))
1013                 sequences)
1014             ;; Create any groups that doesn't already exist on the
1015             ;; server first.
1016             (dolist (spec specs)
1017               (unless (member (car spec) groups)
1018                 (nnimap-command "CREATE %S" (utf7-encode (car spec) t))))
1019             ;; Then copy over all the messages.
1020             (erase-buffer)
1021             (dolist (spec specs)
1022               (let ((group (car spec))
1023                     (ranges (cdr spec)))
1024                 (push (list (nnimap-send-command "UID COPY %s %S"
1025                                                  (nnimap-article-ranges ranges)
1026                                                  (utf7-encode group t))
1027                             ranges)
1028                       sequences)))
1029             ;; Wait for the last COPY response...
1030             (when sequences
1031               (nnimap-wait-for-response (caar sequences))
1032               ;; And then mark the successful copy actions as deleted,
1033               ;; and possibly expunge them.
1034               (nnimap-mark-and-expunge-incoming
1035                (nnimap-parse-copied-articles sequences)))))))))
1036
1037 (defun nnimap-mark-and-expunge-incoming (range)
1038   (when range
1039     (setq range (nnimap-article-ranges range))
1040     (nnimap-send-command
1041      "UID STORE %s +FLAGS.SILENT (\\Deleted)" range)
1042     (cond
1043      ;; If the server supports it, we now delete the message we have
1044      ;; just copied over.
1045      ((member "UIDPLUS" (nnimap-capabilities nnimap-object))
1046       (nnimap-send-command "UID EXPUNGE %s" range))
1047      ;; If it doesn't support UID EXPUNGE, then we only expunge if the
1048      ;; user has configured it.
1049      (nnimap-expunge-inbox
1050       (nnimap-send-command "EXPUNGE")))))
1051
1052 (defun nnimap-parse-copied-articles (sequences)
1053   (let (sequence copied range)
1054     (goto-char (point-min))
1055     (while (re-search-forward "^\\([0-9]+\\) OK " nil t)
1056       (setq sequence (string-to-number (match-string 1)))
1057       (when (setq range (cadr (assq sequence sequences)))
1058         (push (gnus-uncompress-range range) copied)))
1059     (gnus-compress-sequence (sort (apply #'nconc copied) #'<))))
1060
1061 (defun nnimap-new-articles (flags)
1062   (let (new)
1063     (dolist (elem flags)
1064       (when (or (null (cdr elem))
1065                 (and (not (member "\\Deleted" (cdr elem)))
1066                      (not (member "\\Seen" (cdr elem)))))
1067         (push (car elem) new)))
1068     (gnus-compress-sequence (nreverse new))))
1069
1070 (defun nnimap-make-split-specs (list)
1071   (let ((specs nil)
1072         entry)
1073     (dolist (elem list)
1074       (destructuring-bind (article spec) elem
1075         (dolist (group (delete nil (mapcar #'car spec)))
1076           (unless (setq entry (assoc group specs))
1077             (push (setq entry (list group)) specs))
1078           (setcdr entry (cons article (cdr entry))))))
1079     (dolist (entry specs)
1080       (setcdr entry (gnus-compress-sequence (sort (cdr entry) #'<))))
1081     specs))
1082
1083 (defun nnimap-transform-split-mail ()
1084   (goto-char (point-min))
1085   (let (article bytes)
1086     (block nil
1087       (while (not (eobp))
1088         (while (not (looking-at "^\\* [0-9]+ FETCH.*UID \\([0-9]+\\)"))
1089           (delete-region (point) (progn (forward-line 1) (point)))
1090           (when (eobp)
1091             (return)))
1092         (setq article (match-string 1)
1093               bytes (nnimap-get-length))
1094         (delete-region (line-beginning-position) (line-end-position))
1095         ;; Insert MMDF separator, and a way to remember what this
1096         ;; article UID is.
1097         (insert (format "\^A\^A\^A\^A\n\nX-nnimap-article: %s" article))
1098         (forward-char (1+ bytes))
1099         (setq bytes (nnimap-get-length))
1100         (delete-region (line-beginning-position) (line-end-position))
1101         (forward-char (1+ bytes))
1102         (delete-region (line-beginning-position) (line-end-position))))))
1103
1104 (defun nnimap-dummy-active-number (group &optional server)
1105   1)
1106
1107 (defun nnimap-save-mail-spec (group-art &optional server full-nov)
1108   (let (article)
1109     (goto-char (point-min))
1110     (if (not (re-search-forward "X-nnimap-article: \\([0-9]+\\)" nil t))
1111         (error "Invalid nnimap mail")
1112       (setq article (string-to-number (match-string 1))))
1113     (push (list article group-art)
1114           nnimap-incoming-split-list)))
1115
1116 (provide 'nnimap)
1117
1118 ;;; nnimap.el ends here