44ee790f893f16aacdc589917b4b01b2fe2e651b
[gnus] / lisp / nnimap.el
1 ;;; nnimap.el --- IMAP interface for Gnus
2
3 ;; Copyright (C) 2010-2011 Free Software Foundation, Inc.
4
5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
6 ;;         Simon Josefsson <simon@josefsson.org>
7
8 ;; This file is part of GNU Emacs.
9
10 ;; GNU Emacs is free software: you can redistribute it and/or modify
11 ;; it under the terms of the GNU General Public License as published by
12 ;; the Free Software Foundation, either version 3 of the License, or
13 ;; (at your option) any later version.
14
15 ;; GNU Emacs is distributed in the hope that it will be useful,
16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
18 ;; GNU General Public License for more details.
19
20 ;; You should have received a copy of the GNU General Public License
21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
22
23 ;;; Commentary:
24
25 ;; nnimap interfaces Gnus with IMAP servers.
26
27 ;;; Code:
28
29 ;; For Emacs <22.2 and XEmacs.
30 (eval-and-compile
31   (unless (fboundp 'declare-function) (defmacro declare-function (&rest r))))
32
33 (eval-and-compile
34   (require 'nnheader))
35
36 (eval-when-compile
37   (require 'cl))
38
39 (require 'nnheader)
40 (require 'gnus-util)
41 (require 'gnus)
42 (require 'nnoo)
43 (require 'netrc)
44 (require 'utf7)
45 (require 'tls)
46 (require 'parse-time)
47 (require 'nnmail)
48 (require 'proto-stream)
49
50 (autoload 'auth-source-forget-user-or-password "auth-source")
51 (autoload 'auth-source-user-or-password "auth-source")
52
53 (nnoo-declare nnimap)
54
55 (defvoo nnimap-address nil
56   "The address of the IMAP server.")
57
58 (defvoo nnimap-server-port nil
59   "The IMAP port used.
60 If nnimap-stream is `ssl', this will default to `imaps'.  If not,
61 it will default to `imap'.")
62
63 (defvoo nnimap-stream 'undecided
64   "How nnimap will talk to the IMAP server.
65 Values are `ssl', `network', `starttls' or `shell'.
66 The default is to try `ssl' first, and then `network'.")
67
68 (defvoo nnimap-shell-program (if (boundp 'imap-shell-program)
69                                  (if (listp imap-shell-program)
70                                      (car imap-shell-program)
71                                    imap-shell-program)
72                                "ssh %s imapd"))
73
74 (defvoo nnimap-inbox nil
75   "The mail box where incoming mail arrives and should be split out of.")
76
77 (defvoo nnimap-split-methods nil
78   "How mail is split.
79 Uses the same syntax as nnmail-split-methods")
80
81 (defvoo nnimap-split-fancy nil
82   "Uses the same syntax as nnmail-split-fancy.")
83
84 (defvoo nnimap-unsplittable-articles '(%Deleted %Seen)
85   "Articles with the flags in the list will not be considered when splitting.")
86
87 (make-obsolete-variable 'nnimap-split-rule "see `nnimap-split-methods'"
88                         "Emacs 24.1")
89
90 (defvoo nnimap-authenticator nil
91   "How nnimap authenticate itself to the server.
92 Possible choices are nil (use default methods) or `anonymous'.")
93
94 (defvoo nnimap-expunge t
95   "If non-nil, expunge articles after deleting them.
96 This is always done if the server supports UID EXPUNGE, but it's
97 not done by default on servers that doesn't support that command.")
98
99 (defvoo nnimap-streaming t
100   "If non-nil, try to use streaming commands with IMAP servers.
101 Switching this off will make nnimap slower, but it helps with
102 some servers.")
103
104 (defvoo nnimap-connection-alist nil)
105
106 (defvoo nnimap-current-infos nil)
107
108 (defvoo nnimap-fetch-partial-articles nil
109   "If non-nil, Gnus will fetch partial articles.
110 If t, nnimap will fetch only the first part.  If a string, it
111 will fetch all parts that have types that match that string.  A
112 likely value would be \"text/\" to automatically fetch all
113 textual parts.")
114
115 (defvar nnimap-process nil)
116
117 (defvar nnimap-status-string "")
118
119 (defvar nnimap-split-download-body-default nil
120   "Internal variable with default value for `nnimap-split-download-body'.")
121
122 (defvar nnimap-keepalive-timer nil)
123 (defvar nnimap-process-buffers nil)
124
125 (defstruct nnimap
126   group process commands capabilities select-result newlinep server
127   last-command-time greeting examined stream-type)
128
129 (defvar nnimap-object nil)
130
131 (defvar nnimap-mark-alist
132   '((read "\\Seen" %Seen)
133     (tick "\\Flagged" %Flagged)
134     (reply "\\Answered" %Answered)
135     (expire "gnus-expire")
136     (dormant "gnus-dormant")
137     (score "gnus-score")
138     (save "gnus-save")
139     (download "gnus-download")
140     (forward "gnus-forward")))
141
142 (defvar nnimap-quirks
143   '(("QRESYNC" "Zimbra" "QRESYNC ")))
144
145 (defun nnimap-buffer ()
146   (nnimap-find-process-buffer nntp-server-buffer))
147
148 (defun nnimap-header-parameters ()
149   (format "(UID RFC822.SIZE BODYSTRUCTURE %s)"
150           (format
151            (if (nnimap-ver4-p)
152                "BODY.PEEK[HEADER.FIELDS %s]"
153              "RFC822.HEADER.LINES %s")
154            (append '(Subject From Date Message-Id
155                              References In-Reply-To Xref)
156                    nnmail-extra-headers))))
157
158 (deffoo nnimap-retrieve-headers (articles &optional group server fetch-old)
159   (with-current-buffer nntp-server-buffer
160     (erase-buffer)
161     (when (nnimap-possibly-change-group group server)
162       (with-current-buffer (nnimap-buffer)
163         (erase-buffer)
164         (nnimap-wait-for-response
165          (nnimap-send-command
166           "UID FETCH %s %s"
167           (nnimap-article-ranges (gnus-compress-sequence articles))
168           (nnimap-header-parameters))
169          t)
170         (nnimap-transform-headers)
171         (nnheader-remove-cr-followed-by-lf))
172       (insert-buffer-substring
173        (nnimap-find-process-buffer (current-buffer))))
174     'headers))
175
176 (defun nnimap-transform-headers ()
177   (goto-char (point-min))
178   (let (article bytes lines size string)
179     (block nil
180       (while (not (eobp))
181         (while (not (looking-at "^\\* [0-9]+ FETCH.*UID \\([0-9]+\\)"))
182           (delete-region (point) (progn (forward-line 1) (point)))
183           (when (eobp)
184             (return)))
185         (setq article (match-string 1))
186         ;; Unfold quoted {number} strings.
187         (while (re-search-forward "[^]][ (]{\\([0-9]+\\)}\r?\n"
188                                   (1+ (line-end-position)) t)
189           (setq size (string-to-number (match-string 1)))
190           (delete-region (+ (match-beginning 0) 2) (point))
191           (setq string (buffer-substring (point) (+ (point) size)))
192           (delete-region (point) (+ (point) size))
193           (insert (format "%S" string)))
194         (setq bytes (nnimap-get-length)
195               lines nil)
196         (beginning-of-line)
197         (setq size
198               (and (re-search-forward "RFC822.SIZE \\([0-9]+\\)"
199                                       (line-end-position)
200                                       t)
201                    (match-string 1)))
202         (beginning-of-line)
203         (when (search-forward "BODYSTRUCTURE" (line-end-position) t)
204           (let ((structure (ignore-errors
205                              (read (current-buffer)))))
206             (while (and (consp structure)
207                         (not (stringp (car structure))))
208               (setq structure (car structure)))
209             (setq lines (nth 7 structure))))
210         (delete-region (line-beginning-position) (line-end-position))
211         (insert (format "211 %s Article retrieved." article))
212         (forward-line 1)
213         (when size
214           (insert (format "Chars: %s\n" size)))
215         (when lines
216           (insert (format "Lines: %s\n" lines)))
217         (unless (re-search-forward "^\r$" nil t)
218           (goto-char (point-max)))
219         (delete-region (line-beginning-position) (line-end-position))
220         (insert ".")
221         (forward-line 1)))))
222
223 (defun nnimap-unfold-quoted-lines ()
224   ;; Unfold quoted {number} strings.
225   (let (size string)
226     (while (re-search-forward " {\\([0-9]+\\)}\r?\n" nil t)
227       (setq size (string-to-number (match-string 1)))
228       (delete-region (1+ (match-beginning 0)) (point))
229       (setq string (buffer-substring (point) (+ (point) size)))
230       (delete-region (point) (+ (point) size))
231       (insert (format "%S" string)))))
232
233 (defun nnimap-get-length ()
234   (and (re-search-forward "{\\([0-9]+\\)}" (line-end-position) t)
235        (string-to-number (match-string 1))))
236
237 (defun nnimap-article-ranges (ranges)
238   (let (result)
239     (cond
240      ((numberp ranges)
241       (number-to-string ranges))
242      ((numberp (cdr ranges))
243       (format "%d:%d" (car ranges) (cdr ranges)))
244      (t
245       (dolist (elem ranges)
246         (push
247          (if (consp elem)
248              (format "%d:%d" (car elem) (cdr elem))
249            (number-to-string elem))
250          result))
251       (mapconcat #'identity (nreverse result) ",")))))
252
253 (deffoo nnimap-open-server (server &optional defs)
254   (if (nnimap-server-opened server)
255       t
256     (unless (assq 'nnimap-address defs)
257       (setq defs (append defs (list (list 'nnimap-address server)))))
258     (nnoo-change-server 'nnimap server defs)
259     (or (nnimap-find-connection nntp-server-buffer)
260         (nnimap-open-connection nntp-server-buffer))))
261
262 (defun nnimap-make-process-buffer (buffer)
263   (with-current-buffer
264       (generate-new-buffer (format "*nnimap %s %s %s*"
265                                    nnimap-address nnimap-server-port
266                                    (gnus-buffer-exists-p buffer)))
267     (mm-disable-multibyte)
268     (buffer-disable-undo)
269     (gnus-add-buffer)
270     (set (make-local-variable 'after-change-functions) nil)
271     (set (make-local-variable 'nnimap-object)
272          (make-nnimap :server (nnoo-current-server 'nnimap)))
273     (push (list buffer (current-buffer)) nnimap-connection-alist)
274     (push (current-buffer) nnimap-process-buffers)
275     (current-buffer)))
276
277 (defun nnimap-credentials (address ports &optional inhibit-create)
278   (let (port credentials)
279     ;; Request the credentials from all ports, but only query on the
280     ;; last port if all the previous ones have failed.
281     (while (and (null credentials)
282                 (setq port (pop ports)))
283       (setq credentials
284             (auth-source-user-or-password
285              '("login" "password") address port nil
286              (if inhibit-create
287                  nil
288                (null ports)))))
289     credentials))
290
291 (defun nnimap-keepalive ()
292   (let ((now (current-time)))
293     (dolist (buffer nnimap-process-buffers)
294       (when (buffer-name buffer)
295         (with-current-buffer buffer
296           (when (and nnimap-object
297                      (nnimap-last-command-time nnimap-object)
298                      (> (gnus-float-time
299                          (time-subtract
300                           now
301                           (nnimap-last-command-time nnimap-object)))
302                         ;; More than five minutes since the last command.
303                         (* 5 60)))
304             (nnimap-send-command "NOOP")))))))
305
306 (defun nnimap-open-connection (buffer)
307   ;; Be backwards-compatible -- the earlier value of nnimap-stream was
308   ;; `ssl' when nnimap-server-port was nil.  Sort of.
309   (when (and nnimap-server-port
310              (eq nnimap-stream 'undecided))
311     (setq nnimap-stream 'ssl))
312   (let ((stream
313          (if (eq nnimap-stream 'undecided)
314              (loop for type in '(ssl network)
315                    for stream = (let ((nnimap-stream type))
316                                   (nnimap-open-connection-1 buffer))
317                    while (eq stream 'no-connect)
318                    finally (return stream))
319            (nnimap-open-connection-1 buffer))))
320     (if (eq stream 'no-connect)
321         nil
322       stream)))
323
324 (defun nnimap-open-connection-1 (buffer)
325   (unless nnimap-keepalive-timer
326     (setq nnimap-keepalive-timer (run-at-time (* 60 15) (* 60 15)
327                                               'nnimap-keepalive)))
328   (with-current-buffer (nnimap-make-process-buffer buffer)
329     (let* ((coding-system-for-read 'binary)
330            (coding-system-for-write 'binary)
331            (port nil)
332            (ports
333             (cond
334              ((or (eq nnimap-stream 'network)
335                   (eq nnimap-stream 'starttls))
336               (nnheader-message 7 "Opening connection to %s..."
337                                 nnimap-address)
338               '("143" "imap"))
339              ((eq nnimap-stream 'shell)
340               (nnheader-message 7 "Opening connection to %s via shell..."
341                                 nnimap-address)
342               '("imap"))
343              ((memq nnimap-stream '(ssl tls))
344               (nnheader-message 7 "Opening connection to %s via tls..."
345                                 nnimap-address)
346               '("143" "993" "imap" "imaps"))
347              (t
348               (error "Unknown stream type: %s" nnimap-stream))))
349            (proto-stream-always-use-starttls t)
350            login-result credentials)
351       (when nnimap-server-port
352         (setq ports (append ports (list nnimap-server-port))))
353       (destructuring-bind (stream greeting capabilities stream-type)
354           (open-protocol-stream
355            "*nnimap*" (current-buffer) nnimap-address (car (last ports))
356            :type nnimap-stream
357            :shell-command nnimap-shell-program
358            :capability-command "1 CAPABILITY\r\n"
359            :success " OK "
360            :starttls-function
361            (lambda (capabilities)
362              (when (gnus-string-match-p "STARTTLS" capabilities)
363                "1 STARTTLS\r\n")))
364         (setf (nnimap-process nnimap-object) stream)
365         (setf (nnimap-stream-type nnimap-object) stream-type)
366         (if (not stream)
367             (progn
368               (nnheader-report 'nnimap "Unable to contact %s:%s via %s"
369                                nnimap-address port nnimap-stream)
370               'no-connect)
371           (gnus-set-process-query-on-exit-flag stream nil)
372           (if (not (gnus-string-match-p "[*.] \\(OK\\|PREAUTH\\)" greeting))
373               (nnheader-report 'nnimap "%s" greeting)
374             ;; Store the greeting (for debugging purposes).
375             (setf (nnimap-greeting nnimap-object) greeting)
376             (setf (nnimap-capabilities nnimap-object)
377                   (mapcar #'upcase
378                           (split-string capabilities)))
379             (unless (gnus-string-match-p "[*.] PREAUTH" greeting)
380               (if (not (setq credentials
381                              (if (eq nnimap-authenticator 'anonymous)
382                                  (list "anonymous"
383                                        (message-make-address))
384                                (or
385                                 ;; First look for the credentials based
386                                 ;; on the virtual server name.
387                                 (nnimap-credentials
388                                  (nnoo-current-server 'nnimap) ports t)
389                                 ;; Then look them up based on the
390                                 ;; physical address.
391                                 (nnimap-credentials nnimap-address ports)))))
392                   (setq nnimap-object nil)
393                 (setq login-result
394                       (nnimap-login (car credentials) (cadr credentials)))
395                 (unless (car login-result)
396                   ;; If the login failed, then forget the credentials
397                   ;; that are now possibly cached.
398                   (dolist (host (list (nnoo-current-server 'nnimap)
399                                       nnimap-address))
400                     (dolist (port ports)
401                       (dolist (element '("login" "password"))
402                         (auth-source-forget-user-or-password
403                          element host port))))
404                   (delete-process (nnimap-process nnimap-object))
405                   (setq nnimap-object nil))))
406             (when nnimap-object
407               (when (nnimap-capability "QRESYNC")
408                 (nnimap-command "ENABLE QRESYNC"))
409               (nnimap-process nnimap-object))))))))
410
411 (autoload 'rfc2104-hash "rfc2104")
412
413 (defun nnimap-login (user password)
414   (cond
415    ;; Prefer plain LOGIN if it's enabled (since it requires fewer
416    ;; round trips than CRAM-MD5, and it's less likely to be buggy),
417    ;; and we're using an encrypted connection.
418    ((and (not (nnimap-capability "LOGINDISABLED"))
419          (eq (nnimap-stream-type nnimap-object) 'tls))
420     (nnimap-command "LOGIN %S %S" user password))
421    ((nnimap-capability "AUTH=CRAM-MD5")
422     (erase-buffer)
423     (let ((sequence (nnimap-send-command "AUTHENTICATE CRAM-MD5"))
424           (challenge (nnimap-wait-for-line "^\\+\\(.*\\)\n")))
425       (process-send-string
426        (get-buffer-process (current-buffer))
427        (concat
428         (base64-encode-string
429          (concat user " "
430                  (rfc2104-hash 'md5 64 16 password
431                                (base64-decode-string challenge))))
432         "\r\n"))
433       (nnimap-wait-for-response sequence)))
434    ((not (nnimap-capability "LOGINDISABLED"))
435     (nnimap-command "LOGIN %S %S" user password))
436    ((nnimap-capability "AUTH=PLAIN")
437     (nnimap-command
438      "AUTHENTICATE PLAIN %s"
439      (base64-encode-string
440       (format "\000%s\000%s"
441               (nnimap-quote-specials user)
442               (nnimap-quote-specials password)))))))
443
444 (defun nnimap-quote-specials (string)
445   (with-temp-buffer
446     (insert string)
447     (goto-char (point-min))
448     (while (re-search-forward "[\\\"]" nil t)
449       (forward-char -1)
450       (insert "\\")
451       (forward-char 1))
452     (buffer-string)))
453
454 (defun nnimap-find-parameter (parameter elems)
455   (let (result)
456     (dolist (elem elems)
457       (cond
458        ((equal (car elem) parameter)
459         (setq result (cdr elem)))
460        ((and (equal (car elem) "OK")
461              (consp (cadr elem))
462              (equal (caadr elem) parameter))
463         (setq result (cdr (cadr elem))))))
464     result))
465
466 (deffoo nnimap-close-server (&optional server)
467   (when (nnoo-change-server 'nnimap server nil)
468     (ignore-errors
469       (delete-process (get-buffer-process (nnimap-buffer))))
470     (nnoo-close-server 'nnimap server)
471     t))
472
473 (deffoo nnimap-request-close ()
474   t)
475
476 (deffoo nnimap-server-opened (&optional server)
477   (and (nnoo-current-server-p 'nnimap server)
478        nntp-server-buffer
479        (gnus-buffer-live-p nntp-server-buffer)
480        (nnimap-find-connection nntp-server-buffer)))
481
482 (deffoo nnimap-status-message (&optional server)
483   nnimap-status-string)
484
485 (deffoo nnimap-request-article (article &optional group server to-buffer)
486   (with-current-buffer nntp-server-buffer
487     (let ((result (nnimap-possibly-change-group group server))
488           parts structure)
489       (when (stringp article)
490         (setq article (nnimap-find-article-by-message-id group article)))
491       (when (and result
492                  article)
493         (erase-buffer)
494         (with-current-buffer (nnimap-buffer)
495           (erase-buffer)
496           (when nnimap-fetch-partial-articles
497             (nnimap-command "UID FETCH %d (BODYSTRUCTURE)" article)
498             (goto-char (point-min))
499             (when (re-search-forward "FETCH.*BODYSTRUCTURE" nil t)
500               (setq structure (ignore-errors
501                                 (let ((start (point)))
502                                   (forward-sexp 1)
503                                   (downcase-region start (point))
504                                   (goto-char start)
505                                   (read (current-buffer))))
506                     parts (nnimap-find-wanted-parts structure))))
507           (when (if parts
508                     (nnimap-get-partial-article article parts structure)
509                   (nnimap-get-whole-article article))
510             (let ((buffer (current-buffer)))
511               (with-current-buffer (or to-buffer nntp-server-buffer)
512                 (erase-buffer)
513                 (insert-buffer-substring buffer)
514                 (nnheader-ms-strip-cr)
515                 (cons group article)))))))))
516
517 (deffoo nnimap-request-head (article &optional group server to-buffer)
518   (when (nnimap-possibly-change-group group server)
519     (with-current-buffer (nnimap-buffer)
520       (when (stringp article)
521         (setq article (nnimap-find-article-by-message-id group article)))
522       (if (null article)
523           nil
524         (nnimap-get-whole-article
525          article (format "UID FETCH %%d %s"
526                          (nnimap-header-parameters)))
527         (let ((buffer (current-buffer)))
528           (with-current-buffer (or to-buffer nntp-server-buffer)
529             (erase-buffer)
530             (insert-buffer-substring buffer)
531             (nnheader-ms-strip-cr)
532             (cons group article)))))))
533
534 (defun nnimap-get-whole-article (article &optional command)
535   (let ((result
536          (nnimap-command
537           (or command
538               (if (nnimap-ver4-p)
539                   "UID FETCH %d BODY.PEEK[]"
540                 "UID FETCH %d RFC822.PEEK"))
541           article)))
542     ;; Check that we really got an article.
543     (goto-char (point-min))
544     (unless (re-search-forward "\\* [0-9]+ FETCH" nil t)
545       (setq result nil))
546     (when result
547       ;; Remove any data that may have arrived before the FETCH data.
548       (beginning-of-line)
549       (unless (bobp)
550         (delete-region (point-min) (point)))
551       (let ((bytes (nnimap-get-length)))
552         (delete-region (line-beginning-position)
553                        (progn (forward-line 1) (point)))
554         (goto-char (+ (point) bytes))
555         (delete-region (point) (point-max)))
556       t)))
557
558 (defun nnimap-capability (capability)
559   (member capability (nnimap-capabilities nnimap-object)))
560
561 (defun nnimap-ver4-p ()
562   (nnimap-capability "IMAP4REV1"))
563
564 (defun nnimap-get-partial-article (article parts structure)
565   (let ((result
566          (nnimap-command
567           "UID FETCH %d (%s %s)"
568           article
569           (if (nnimap-ver4-p)
570               "BODY.PEEK[HEADER]"
571             "RFC822.HEADER")
572           (if (nnimap-ver4-p)
573               (mapconcat (lambda (part)
574                            (format "BODY.PEEK[%s]" part))
575                          parts " ")
576             (mapconcat (lambda (part)
577                          (format "RFC822.PEEK[%s]" part))
578                        parts " ")))))
579     (when result
580       (nnimap-convert-partial-article structure))))
581
582 (defun nnimap-convert-partial-article (structure)
583   ;; First just skip past the headers.
584   (goto-char (point-min))
585   (let ((bytes (nnimap-get-length))
586         id parts)
587     ;; Delete "FETCH" line.
588     (delete-region (line-beginning-position)
589                    (progn (forward-line 1) (point)))
590     (goto-char (+ (point) bytes))
591     ;; Collect all the body parts.
592     (while (looking-at ".*BODY\\[\\([.0-9]+\\)\\]")
593       (setq id (match-string 1)
594             bytes (or (nnimap-get-length) 0))
595       (beginning-of-line)
596       (delete-region (point) (progn (forward-line 1) (point)))
597       (push (list id (buffer-substring (point) (+ (point) bytes)))
598             parts)
599       (delete-region (point) (+ (point) bytes)))
600     ;; Delete trailing junk.
601     (delete-region (point) (point-max))
602     ;; Now insert all the parts again where they fit in the structure.
603     (nnimap-insert-partial-structure structure parts)
604     t))
605
606 (defun nnimap-insert-partial-structure (structure parts &optional subp)
607   (let (type boundary)
608     (let ((bstruc structure))
609       (while (consp (car bstruc))
610         (pop bstruc))
611       (setq type (car bstruc))
612       (setq bstruc (car (cdr bstruc)))
613       (let ((has-boundary (member "boundary" bstruc)))
614         (when has-boundary
615           (setq boundary (cadr has-boundary)))))
616     (when subp
617       (insert (format "Content-type: multipart/%s; boundary=%S\n\n"
618                       (downcase type) boundary)))
619     (while (not (stringp (car structure)))
620       (insert "\n--" boundary "\n")
621       (if (consp (caar structure))
622           (nnimap-insert-partial-structure (pop structure) parts t)
623         (let ((bit (pop structure)))
624           (insert (format  "Content-type: %s/%s"
625                            (downcase (nth 0 bit))
626                            (downcase (nth 1 bit))))
627           (if (member "CHARSET" (nth 2 bit))
628               (insert (format
629                        "; charset=%S\n" (cadr (member "CHARSET" (nth 2 bit)))))
630             (insert "\n"))
631           (insert (format "Content-transfer-encoding: %s\n"
632                           (nth 5 bit)))
633           (insert "\n")
634           (when (assoc (nth 9 bit) parts)
635             (insert (cadr (assoc (nth 9 bit) parts)))))))
636     (insert "\n--" boundary "--\n")))
637
638 (defun nnimap-find-wanted-parts (structure)
639   (message-flatten-list (nnimap-find-wanted-parts-1 structure "")))
640
641 (defun nnimap-find-wanted-parts-1 (structure prefix)
642   (let ((num 1)
643         parts)
644     (while (consp (car structure))
645       (let ((sub (pop structure)))
646         (if (consp (car sub))
647             (push (nnimap-find-wanted-parts-1
648                    sub (if (string= prefix "")
649                            (number-to-string num)
650                          (format "%s.%s" prefix num)))
651                   parts)
652           (let ((type (format "%s/%s" (nth 0 sub) (nth 1 sub)))
653                 (id (if (string= prefix "")
654                         (number-to-string num)
655                       (format "%s.%s" prefix num))))
656             (setcar (nthcdr 9 sub) id)
657             (when (if (eq nnimap-fetch-partial-articles t)
658                       (equal id "1")
659                     (string-match nnimap-fetch-partial-articles type))
660               (push id parts))))
661         (incf num)))
662     (nreverse parts)))
663
664 (deffoo nnimap-request-group (group &optional server dont-check info)
665   (let ((result (nnimap-possibly-change-group
666                  ;; Don't SELECT the group if we're going to select it
667                  ;; later, anyway.
668                  (if (and (not dont-check)
669                           (assoc group nnimap-current-infos))
670                      nil
671                    group)
672                  server))
673         articles active marks high low)
674     (with-current-buffer nntp-server-buffer
675       (when result
676         (if (and dont-check
677                  (setq active (nth 2 (assoc group nnimap-current-infos))))
678             (insert (format "211 %d %d %d %S\n"
679                             (- (cdr active) (car active))
680                             (car active)
681                             (cdr active)
682                             group))
683           (with-current-buffer (nnimap-buffer)
684             (erase-buffer)
685             (let ((group-sequence
686                    (nnimap-send-command "SELECT %S" (utf7-encode group t)))
687                   (flag-sequence
688                    (nnimap-send-command "UID FETCH 1:* FLAGS")))
689               (setf (nnimap-group nnimap-object) group)
690               (nnimap-wait-for-response flag-sequence)
691               (setq marks
692                     (nnimap-flags-to-marks
693                      (nnimap-parse-flags
694                       (list (list group-sequence flag-sequence
695                                   1 group "SELECT")))))
696               (when (and info
697                          marks)
698                 (nnimap-update-infos marks (list info))
699                 (nnimap-store-info info (gnus-active (gnus-info-group info))))
700               (goto-char (point-max))
701               (let ((uidnext (nth 5 (car marks))))
702                 (setq high (or (if uidnext
703                                    (1- uidnext)
704                                  (nth 3 (car marks)))
705                                0)
706                       low (or (nth 4 (car marks)) uidnext 1)))))
707           (erase-buffer)
708           (insert
709            (format
710             "211 %d %d %d %S\n" (1+ (- high low)) low high group)))
711         t))))
712
713 (deffoo nnimap-request-create-group (group &optional server args)
714   (when (nnimap-possibly-change-group nil server)
715     (with-current-buffer (nnimap-buffer)
716       (car (nnimap-command "CREATE %S" (utf7-encode group t))))))
717
718 (deffoo nnimap-request-delete-group (group &optional force server)
719   (when (nnimap-possibly-change-group nil server)
720     (with-current-buffer (nnimap-buffer)
721       (car (nnimap-command "DELETE %S" (utf7-encode group t))))))
722
723 (deffoo nnimap-request-rename-group (group new-name &optional server)
724   (when (nnimap-possibly-change-group nil server)
725     (with-current-buffer (nnimap-buffer)
726       (nnimap-unselect-group)
727       (car (nnimap-command "RENAME %S %S"
728                            (utf7-encode group t) (utf7-encode new-name t))))))
729
730 (defun nnimap-unselect-group ()
731   ;; Make sure we don't have this group open read/write by asking
732   ;; to examine a mailbox that doesn't exist.  This seems to be
733   ;; the only way that allows us to reliably go back to unselected
734   ;; state on Courier.
735   (nnimap-command "EXAMINE DOES.NOT.EXIST"))
736
737 (deffoo nnimap-request-expunge-group (group &optional server)
738   (when (nnimap-possibly-change-group group server)
739     (with-current-buffer (nnimap-buffer)
740       (car (nnimap-command "EXPUNGE")))))
741
742 (defun nnimap-get-flags (spec)
743   (let ((articles nil)
744         elems end)
745     (with-current-buffer (nnimap-buffer)
746       (erase-buffer)
747       (nnimap-wait-for-response (nnimap-send-command
748                                  "UID FETCH %s FLAGS" spec))
749       (setq end (point))
750       (subst-char-in-region (point-min) (point-max)
751                             ?\\ ?% t)
752       (goto-char (point-min))
753       (while (search-forward " FETCH " end t)
754         (setq elems (read (current-buffer)))
755         (push (cons (cadr (memq 'UID elems))
756                     (cadr (memq 'FLAGS elems)))
757               articles)))
758     (nreverse articles)))
759
760 (deffoo nnimap-close-group (group &optional server)
761   t)
762
763 (deffoo nnimap-request-move-article (article group server accept-form
764                                              &optional last internal-move-group)
765   (with-temp-buffer
766     (mm-disable-multibyte)
767     (when (funcall (if internal-move-group
768                        'nnimap-request-head
769                      'nnimap-request-article)
770                    article group server (current-buffer))
771       ;; If the move is internal (on the same server), just do it the easy
772       ;; way.
773       (let ((message-id (message-field-value "message-id")))
774         (if internal-move-group
775             (let ((result
776                    (with-current-buffer (nnimap-buffer)
777                      (nnimap-command "UID COPY %d %S"
778                                      article
779                                      (utf7-encode internal-move-group t)))))
780               (when (car result)
781                 (nnimap-delete-article article)
782                 (cons internal-move-group
783                       (or (nnimap-find-uid-response "COPYUID" (cadr result))
784                           (nnimap-find-article-by-message-id
785                            internal-move-group message-id)))))
786           ;; Move the article to a different method.
787           (let ((result (eval accept-form)))
788             (when result
789               (nnimap-delete-article article)
790               result)))))))
791
792 (deffoo nnimap-request-expire-articles (articles group &optional server force)
793   (cond
794    ((null articles)
795     nil)
796    ((not (nnimap-possibly-change-group group server))
797     articles)
798    ((and force
799          (eq nnmail-expiry-target 'delete))
800     (unless (nnimap-delete-article (gnus-compress-sequence articles))
801       (nnheader-message 7 "Article marked for deletion, but not expunged."))
802     nil)
803    (t
804     (let ((deletable-articles
805            (if (or force
806                    (eq nnmail-expiry-wait 'immediate))
807                articles
808              (gnus-sorted-intersection
809               articles
810               (nnimap-find-expired-articles group)))))
811       (if (null deletable-articles)
812           articles
813         (if (eq nnmail-expiry-target 'delete)
814             (nnimap-delete-article (gnus-compress-sequence deletable-articles))
815           (setq deletable-articles
816                 (nnimap-process-expiry-targets
817                  deletable-articles group server)))
818         ;; Return the articles we didn't delete.
819         (gnus-sorted-complement articles deletable-articles))))))
820
821 (defun nnimap-process-expiry-targets (articles group server)
822   (let ((deleted-articles nil))
823     (cond
824      ;; shortcut further processing if we're going to delete the articles
825      ((eq nnmail-expiry-target 'delete)
826       (setq deleted-articles articles)
827       t)
828      ;; or just move them to another folder on the same IMAP server
829      ((and (not (functionp nnmail-expiry-target))
830            (gnus-server-equal (gnus-group-method nnmail-expiry-target)
831                               (gnus-server-to-method
832                                (format "nnimap:%s" server))))
833       (and (nnimap-possibly-change-group group server)
834            (with-current-buffer (nnimap-buffer)
835              (nnheader-message 7 "Expiring articles from %s: %s" group articles)
836              (nnimap-command
837               "UID COPY %s %S"
838               (nnimap-article-ranges (gnus-compress-sequence articles))
839               (utf7-encode (gnus-group-real-name nnmail-expiry-target) t))
840              (setq deleted-articles articles)))
841       t)
842      (t
843       (dolist (article articles)
844         (let ((target nnmail-expiry-target))
845           (with-temp-buffer
846             (mm-disable-multibyte)
847             (when (nnimap-request-article article group server (current-buffer))
848               (nnheader-message 7 "Expiring article %s:%d" group article)
849               (when (functionp target)
850                 (setq target (funcall target group)))
851               (when (and target
852                          (not (eq target 'delete)))
853                 (if (or (gnus-request-group target t)
854                         (gnus-request-create-group target))
855                     (nnmail-expiry-target-group target group)
856                   (setq target nil)))
857               (when target
858                 (push article deleted-articles))))))))
859     ;; Change back to the current group again.
860     (nnimap-possibly-change-group group server)
861     (setq deleted-articles (nreverse deleted-articles))
862     (nnimap-delete-article (gnus-compress-sequence deleted-articles))
863     deleted-articles))
864
865 (defun nnimap-find-expired-articles (group)
866   (let ((cutoff (nnmail-expired-article-p group nil nil)))
867     (with-current-buffer (nnimap-buffer)
868       (let ((result
869              (nnimap-command
870               "UID SEARCH SENTBEFORE %s"
871               (format-time-string
872                (format "%%d-%s-%%Y"
873                        (upcase
874                         (car (rassoc (nth 4 (decode-time cutoff))
875                                      parse-time-months))))
876                cutoff))))
877         (and (car result)
878              (delete 0 (mapcar #'string-to-number
879                                (cdr (assoc "SEARCH" (cdr result))))))))))
880
881
882 (defun nnimap-find-article-by-message-id (group message-id)
883   (with-current-buffer (nnimap-buffer)
884     (erase-buffer)
885     (unless (equal group (nnimap-group nnimap-object))
886       (setf (nnimap-group nnimap-object) nil)
887       (setf (nnimap-examined nnimap-object) group)
888       (nnimap-send-command "EXAMINE %S" (utf7-encode group t)))
889     (let ((sequence
890            (nnimap-send-command "UID SEARCH HEADER Message-Id %S" message-id))
891           article result)
892       (setq result (nnimap-wait-for-response sequence))
893       (when (and result
894                  (car (setq result (nnimap-parse-response))))
895         ;; Select the last instance of the message in the group.
896         (and (setq article
897                    (car (last (assoc "SEARCH" (cdr result)))))
898              (string-to-number article))))))
899
900 (defun nnimap-delete-article (articles)
901   (with-current-buffer (nnimap-buffer)
902     (nnimap-command "UID STORE %s +FLAGS.SILENT (\\Deleted)"
903                     (nnimap-article-ranges articles))
904     (cond
905      ((nnimap-capability "UIDPLUS")
906       (nnimap-command "UID EXPUNGE %s"
907                       (nnimap-article-ranges articles))
908       t)
909      (nnimap-expunge
910       (nnimap-command "EXPUNGE")
911       t)
912      (t (gnus-message 7 (concat "nnimap: nnimap-expunge is not set and the "
913                                 "server doesn't support UIDPLUS, so we won't "
914                                 "delete this article now"))))))
915
916 (deffoo nnimap-request-scan (&optional group server)
917   (when (and (nnimap-possibly-change-group nil server)
918              nnimap-inbox
919              nnimap-split-methods)
920     (nnheader-message 7 "nnimap %s splitting mail..." server)
921     (nnimap-split-incoming-mail)))
922
923 (defun nnimap-marks-to-flags (marks)
924   (let (flags flag)
925     (dolist (mark marks)
926       (when (setq flag (cadr (assq mark nnimap-mark-alist)))
927         (push flag flags)))
928     flags))
929
930 (deffoo nnimap-request-update-group-status (group status &optional server)
931   (when (nnimap-possibly-change-group nil server)
932     (let ((command (assoc
933                     status
934                     '((subscribe "SUBSCRIBE")
935                       (unsubscribe "UNSUBSCRIBE")))))
936       (when command
937         (with-current-buffer (nnimap-buffer)
938           (nnimap-command "%s %S" (cadr command) (utf7-encode group t)))))))
939
940 (deffoo nnimap-request-set-mark (group actions &optional server)
941   (when (nnimap-possibly-change-group group server)
942     (let (sequence)
943       (with-current-buffer (nnimap-buffer)
944         (erase-buffer)
945         ;; Just send all the STORE commands without waiting for
946         ;; response.  If they're successful, they're successful.
947         (dolist (action actions)
948           (destructuring-bind (range action marks) action
949             (let ((flags (nnimap-marks-to-flags marks)))
950               (when flags
951                 (setq sequence (nnimap-send-command
952                                 "UID STORE %s %sFLAGS.SILENT (%s)"
953                                 (nnimap-article-ranges range)
954                                 (cond
955                                  ((eq action 'del) "-")
956                                  ((eq action 'add) "+")
957                                  ((eq action 'set) ""))
958                                 (mapconcat #'identity flags " ")))))))
959         ;; Wait for the last command to complete to avoid later
960         ;; syncronisation problems with the stream.
961         (when sequence
962           (nnimap-wait-for-response sequence))))))
963
964 (deffoo nnimap-request-accept-article (group &optional server last)
965   (when (nnimap-possibly-change-group nil server)
966     (nnmail-check-syntax)
967     (let ((message-id (message-field-value "message-id"))
968           sequence message)
969       (nnimap-add-cr)
970       (setq message (buffer-substring-no-properties (point-min) (point-max)))
971       (with-current-buffer (nnimap-buffer)
972         ;; If we have this group open read-only, then unselect it
973         ;; before appending to it.
974         (when (equal (nnimap-examined nnimap-object) group)
975           (nnimap-unselect-group))
976         (erase-buffer)
977         (setq sequence (nnimap-send-command
978                         "APPEND %S {%d}" (utf7-encode group t)
979                         (length message)))
980         (unless nnimap-streaming
981           (nnimap-wait-for-connection "^[+]"))
982         (process-send-string (get-buffer-process (current-buffer)) message)
983         (process-send-string (get-buffer-process (current-buffer))
984                              (if (nnimap-newlinep nnimap-object)
985                                  "\n"
986                                "\r\n"))
987         (let ((result (nnimap-get-response sequence)))
988           (if (not (nnimap-ok-p result))
989               (progn
990                 (nnheader-report 'nnimap "%s" result)
991                 nil)
992             (cons group
993                   (or (nnimap-find-uid-response "APPENDUID" (car result))
994                       (nnimap-find-article-by-message-id
995                        group message-id)))))))))
996
997 (defun nnimap-ok-p (value)
998   (and (consp value)
999        (consp (car value))
1000        (equal (caar value) "OK")))
1001
1002 (defun nnimap-find-uid-response (name list)
1003   (let ((result (car (last (nnimap-find-response-element name list)))))
1004     (and result
1005          (string-to-number result))))
1006
1007 (defun nnimap-find-response-element (name list)
1008   (let (result)
1009     (dolist (elem list)
1010       (when (and (consp elem)
1011                  (equal name (car elem)))
1012         (setq result elem)))
1013     result))
1014
1015 (deffoo nnimap-request-replace-article (article group buffer)
1016   (let (group-art)
1017     (when (and (nnimap-possibly-change-group group nil)
1018                ;; Put the article into the group.
1019                (with-current-buffer buffer
1020                  (setq group-art
1021                        (nnimap-request-accept-article group nil t))))
1022       (nnimap-delete-article (list article))
1023       ;; Return the new article number.
1024       (cdr group-art))))
1025
1026 (defun nnimap-add-cr ()
1027   (goto-char (point-min))
1028   (while (re-search-forward "\r?\n" nil t)
1029     (replace-match "\r\n" t t)))
1030
1031 (defun nnimap-get-groups ()
1032   (erase-buffer)
1033   (let ((sequence (nnimap-send-command "LIST \"\" \"*\""))
1034         groups)
1035     (nnimap-wait-for-response sequence)
1036     (subst-char-in-region (point-min) (point-max)
1037                           ?\\ ?% t)
1038     (goto-char (point-min))
1039     (nnimap-unfold-quoted-lines)
1040     (goto-char (point-min))
1041     (while (search-forward "* LIST " nil t)
1042       (let ((flags (read (current-buffer)))
1043             (separator (read (current-buffer)))
1044             (group (read (current-buffer))))
1045         (unless (member '%NoSelect flags)
1046           (push (if (stringp group)
1047                     group
1048                   (format "%s" group))
1049                 groups))))
1050     (nreverse groups)))
1051
1052 (deffoo nnimap-request-list (&optional server)
1053   (nnimap-possibly-change-group nil server)
1054   (with-current-buffer nntp-server-buffer
1055     (erase-buffer)
1056     (let ((groups
1057            (with-current-buffer (nnimap-buffer)
1058              (nnimap-get-groups)))
1059           sequences responses)
1060       (when groups
1061         (with-current-buffer (nnimap-buffer)
1062           (setf (nnimap-group nnimap-object) nil)
1063           (dolist (group groups)
1064             (setf (nnimap-examined nnimap-object) group)
1065             (push (list (nnimap-send-command "EXAMINE %S" (utf7-encode group t))
1066                         group)
1067                   sequences))
1068           (nnimap-wait-for-response (caar sequences))
1069           (setq responses
1070                 (nnimap-get-responses (mapcar #'car sequences))))
1071         (dolist (response responses)
1072           (let* ((sequence (car response))
1073                  (response (cadr response))
1074                  (group (cadr (assoc sequence sequences))))
1075             (when (and group
1076                        (equal (caar response) "OK"))
1077               (let ((uidnext (nnimap-find-parameter "UIDNEXT" response))
1078                     highest exists)
1079                 (dolist (elem response)
1080                   (when (equal (cadr elem) "EXISTS")
1081                     (setq exists (string-to-number (car elem)))))
1082                 (when uidnext
1083                   (setq highest (1- (string-to-number (car uidnext)))))
1084                 (cond
1085                  ((null highest)
1086                   (insert (format "%S 0 1 y\n" (utf7-decode group t))))
1087                  ((zerop exists)
1088                   ;; Empty group.
1089                   (insert (format "%S %d %d y\n"
1090                                   (utf7-decode group t) highest (1+ highest))))
1091                  (t
1092                   ;; Return the widest possible range.
1093                   (insert (format "%S %d 1 y\n" (utf7-decode group t)
1094                                   (or highest exists)))))))))
1095         t))))
1096
1097 (deffoo nnimap-request-newgroups (date &optional server)
1098   (nnimap-possibly-change-group nil server)
1099   (with-current-buffer nntp-server-buffer
1100     (erase-buffer)
1101     (dolist (group (with-current-buffer (nnimap-buffer)
1102                      (nnimap-get-groups)))
1103       (unless (assoc group nnimap-current-infos)
1104         ;; Insert dummy numbers here -- they don't matter.
1105         (insert (format "%S 0 1 y\n" group))))
1106     t))
1107
1108 (deffoo nnimap-retrieve-group-data-early (server infos)
1109   (when (nnimap-possibly-change-group nil server)
1110     (with-current-buffer (nnimap-buffer)
1111       (erase-buffer)
1112       (setf (nnimap-group nnimap-object) nil)
1113       (let ((qresyncp (nnimap-capability "QRESYNC"))
1114             params groups sequences active uidvalidity modseq group)
1115         ;; Go through the infos and gather the data needed to know
1116         ;; what and how to request the data.
1117         (dolist (info infos)
1118           (setq params (gnus-info-params info)
1119                 group (gnus-group-real-name (gnus-info-group info))
1120                 active (cdr (assq 'active params))
1121                 uidvalidity (cdr (assq 'uidvalidity params))
1122                 modseq (cdr (assq 'modseq params)))
1123           (setf (nnimap-examined nnimap-object) group)
1124           (if (and qresyncp
1125                    uidvalidity
1126                    modseq)
1127               (push
1128                (list (nnimap-send-command "EXAMINE %S (%s (%s %s))"
1129                                           (utf7-encode group t)
1130                                           (nnimap-quirk "QRESYNC")
1131                                           uidvalidity modseq)
1132                      'qresync
1133                      nil group 'qresync)
1134                sequences)
1135             (let ((start
1136                    (if (and active uidvalidity)
1137                        ;; Fetch the last 100 flags.
1138                        (max 1 (- (cdr active) 100))
1139                      1))
1140                   (command
1141                    (if uidvalidity
1142                        "EXAMINE"
1143                      ;; If we don't have a UIDVALIDITY, then this is
1144                      ;; the first time we've seen the group, so we
1145                      ;; have to do a SELECT (which is slower than an
1146                      ;; examine), but will tell us whether the group
1147                      ;; is read-only or not.
1148                      "SELECT")))
1149               (push (list (nnimap-send-command "%s %S" command
1150                                                (utf7-encode group t))
1151                           (nnimap-send-command "UID FETCH %d:* FLAGS" start)
1152                           start group command)
1153                     sequences))))
1154         sequences))))
1155
1156 (defun nnimap-quirk (command)
1157   (let ((quirk (assoc command nnimap-quirks)))
1158     ;; If this server is of a type that matches a quirk, then return
1159     ;; the "quirked" command instead of the proper one.
1160     (if (or (null quirk)
1161             (not (string-match (nth 1 quirk) (nnimap-greeting nnimap-object))))
1162         command
1163       (nth 2 quirk))))
1164
1165 (deffoo nnimap-finish-retrieve-group-infos (server infos sequences)
1166   (when (and sequences
1167              (nnimap-possibly-change-group nil server))
1168     (with-current-buffer (nnimap-buffer)
1169       ;; Wait for the final data to trickle in.
1170       (when (nnimap-wait-for-response (if (eq (cadar sequences) 'qresync)
1171                                           (caar sequences)
1172                                         (cadar sequences))
1173                                       t)
1174         ;; Now we should have most of the data we need, no matter
1175         ;; whether we're QRESYNCING, fetching all the flags from
1176         ;; scratch, or just fetching the last 100 flags per group.
1177         (nnimap-update-infos (nnimap-flags-to-marks
1178                               (nnimap-parse-flags
1179                                (nreverse sequences)))
1180                              infos)
1181         ;; Finally, just return something resembling an active file in
1182         ;; the nntp buffer, so that the agent can save the info, too.
1183         (with-current-buffer nntp-server-buffer
1184           (erase-buffer)
1185           (dolist (info infos)
1186             (let* ((group (gnus-info-group info))
1187                    (active (gnus-active group)))
1188               (when active
1189                 (insert (format "%S %d %d y\n"
1190                                 (gnus-group-real-name group)
1191                                 (cdr active)
1192                                 (car active)))))))))))
1193
1194 (defun nnimap-update-infos (flags infos)
1195   (dolist (info infos)
1196     (let* ((group (gnus-group-real-name (gnus-info-group info)))
1197            (marks (cdr (assoc group flags))))
1198       (when marks
1199         (nnimap-update-info info marks)))))
1200
1201 (defun nnimap-update-info (info marks)
1202   (destructuring-bind (existing flags high low uidnext start-article
1203                                 permanent-flags uidvalidity
1204                                 vanished highestmodseq) marks
1205     (cond
1206      ;; Ignore groups with no UIDNEXT/marks.  This happens for
1207      ;; completely empty groups.
1208      ((and (not existing)
1209            (not uidnext))
1210       (let ((active (cdr (assq 'active (gnus-info-params info)))))
1211         (when active
1212           (gnus-set-active (gnus-info-group info) active))))
1213      ;; We have a mismatch between the old and new UIDVALIDITY
1214      ;; identifiers, so we have to re-request the group info (the next
1215      ;; time).  This virtually never happens.
1216      ((let ((old-uidvalidity
1217              (cdr (assq 'uidvalidity (gnus-info-params info)))))
1218         (and old-uidvalidity
1219              (not (equal old-uidvalidity uidvalidity))
1220              (> start-article 1)))
1221       (gnus-group-remove-parameter info 'uidvalidity)
1222       (gnus-group-remove-parameter info 'modseq))
1223      ;; We have the data needed to update.
1224      (t
1225       (let* ((group (gnus-info-group info))
1226              (completep (and start-article
1227                              (= start-article 1)))
1228              (active (or (gnus-active group)
1229                          (cdr (assq 'active (gnus-info-params info)))))
1230              new-active)
1231         (when uidnext
1232           (setq high (1- uidnext)))
1233         ;; First set the active ranges based on high/low.
1234         (setq new-active
1235               (if (or completep
1236                       (not (gnus-active group)))
1237                   (cond
1238                    (active
1239                     (cons (min (or low (car active))
1240                                (car active))
1241                           (max (or high (cdr active))
1242                                (cdr active))))
1243                    ((and low high)
1244                     (cons low high))
1245                    (uidnext
1246                     ;; No articles in this group.
1247                     (cons uidnext (1- uidnext)))
1248                    (start-article
1249                     (cons start-article (1- start-article)))
1250                    (t
1251                     ;; No articles and no uidnext.
1252                     nil))
1253                 (cons (car active)
1254                       (or high (1- uidnext)))))
1255         (gnus-set-active group new-active)
1256         ;; See whether this is a read-only group.
1257         (unless (eq permanent-flags 'not-scanned)
1258           (gnus-group-set-parameter
1259            info 'permanent-flags
1260            (and (or (memq '%* permanent-flags)
1261                     (memq '%Seen permanent-flags))
1262                 permanent-flags)))
1263         ;; Update marks and read articles if this isn't a
1264         ;; read-only IMAP group.
1265         (when (setq permanent-flags
1266                     (cdr (assq 'permanent-flags (gnus-info-params info))))
1267           (if (and highestmodseq
1268                    (not start-article))
1269               ;; We've gotten the data by QRESYNCing.
1270               (nnimap-update-qresync-info
1271                info existing (nnimap-imap-ranges-to-gnus-ranges vanished) flags)
1272             ;; Do normal non-QRESYNC flag updates.
1273             ;; Update the list of read articles.
1274             (let* ((unread
1275                     (gnus-compress-sequence
1276                      (gnus-set-difference
1277                       (gnus-set-difference
1278                        existing
1279                        (cdr (assoc '%Seen flags)))
1280                       (cdr (assoc '%Flagged flags)))))
1281                    (read (gnus-range-difference
1282                           (cons start-article high) unread)))
1283               (when (> start-article 1)
1284                 (setq read
1285                       (gnus-range-nconcat
1286                        (if (> start-article 1)
1287                            (gnus-sorted-range-intersection
1288                             (cons 1 (1- start-article))
1289                             (gnus-info-read info))
1290                          (gnus-info-read info))
1291                        read)))
1292               (when (or (not (listp permanent-flags))
1293                         (memq '%Seen permanent-flags))
1294                 (gnus-info-set-read info read))
1295               ;; Update the marks.
1296               (setq marks (gnus-info-marks info))
1297               (dolist (type (cdr nnimap-mark-alist))
1298                 (when (or (not (listp permanent-flags))
1299                           (memq (car (assoc (caddr type) flags))
1300                                 permanent-flags)
1301                           (memq '%* permanent-flags))
1302                   (let ((old-marks (assoc (car type) marks))
1303                         (new-marks
1304                          (gnus-compress-sequence
1305                           (cdr (or (assoc (caddr type) flags) ; %Flagged
1306                                    (assoc (intern (cadr type) obarray) flags)
1307                                    (assoc (cadr type) flags)))))) ; "\Flagged"
1308                     (setq marks (delq old-marks marks))
1309                     (pop old-marks)
1310                     (when (and old-marks
1311                                (> start-article 1))
1312                       (setq old-marks (gnus-range-difference
1313                                        old-marks
1314                                        (cons start-article high)))
1315                       (setq new-marks (gnus-range-nconcat old-marks new-marks)))
1316                     (when new-marks
1317                       (push (cons (car type) new-marks) marks)))))
1318               (gnus-info-set-marks info marks t))))
1319         ;; Tell Gnus whether there are any \Recent messages in any of
1320         ;; the groups.
1321         (let ((recent (cdr (assoc '%Recent flags))))
1322           (when (and active recent)
1323             (while recent
1324               (when (> (car recent) (cdr active))
1325                 (push (list (cons (gnus-group-real-name group) 0))
1326                       nnmail-split-history)
1327                 (setq recent nil))
1328               (pop recent))))
1329         ;; Note the active level for the next run-through.
1330         (gnus-group-set-parameter info 'active (gnus-active group))
1331         (gnus-group-set-parameter info 'uidvalidity uidvalidity)
1332         (gnus-group-set-parameter info 'modseq highestmodseq)
1333         (nnimap-store-info info (gnus-active group)))))))
1334
1335 (defun nnimap-update-qresync-info (info existing vanished flags)
1336   ;; Add all the vanished articles to the list of read articles.
1337   (gnus-info-set-read
1338    info
1339    (gnus-add-to-range
1340     (gnus-add-to-range
1341      (gnus-range-add (gnus-info-read info)
1342                      vanished)
1343      (cdr (assq '%Flagged flags)))
1344     (cdr (assq '%Seen flags))))
1345   (let ((marks (gnus-info-marks info)))
1346     (dolist (type (cdr nnimap-mark-alist))
1347       (let ((ticks (assoc (car type) marks))
1348             (new-marks
1349              (cdr (or (assoc (caddr type) flags) ; %Flagged
1350                       (assoc (intern (cadr type) obarray) flags)
1351                       (assoc (cadr type) flags))))) ; "\Flagged"
1352         (setq marks (delq ticks marks))
1353         (pop ticks)
1354         ;; Add the new marks we got.
1355         (setq ticks (gnus-add-to-range ticks new-marks))
1356         ;; Remove the marks from messages that don't have them.
1357         (setq ticks (gnus-remove-from-range
1358                      ticks
1359                      (gnus-compress-sequence
1360                       (gnus-sorted-complement existing new-marks))))
1361         (when ticks
1362           (push (cons (car type) ticks) marks)))
1363       (gnus-info-set-marks info marks t))))
1364
1365 (defun nnimap-imap-ranges-to-gnus-ranges (irange)
1366   (if (zerop (length irange))
1367       nil
1368     (let ((result nil))
1369       (dolist (elem (split-string irange ","))
1370         (push
1371          (if (string-match ":" elem)
1372              (let ((numbers (split-string elem ":")))
1373                (cons (string-to-number (car numbers))
1374                      (string-to-number (cadr numbers))))
1375            (string-to-number elem))
1376          result))
1377       (nreverse result))))
1378
1379 (defun nnimap-store-info (info active)
1380   (let* ((group (gnus-group-real-name (gnus-info-group info)))
1381          (entry (assoc group nnimap-current-infos)))
1382     (if entry
1383         (setcdr entry (list info active))
1384       (push (list group info active) nnimap-current-infos))))
1385
1386 (defun nnimap-flags-to-marks (groups)
1387   (let (data group totalp uidnext articles start-article mark permanent-flags
1388              uidvalidity vanished highestmodseq)
1389     (dolist (elem groups)
1390       (setq group (car elem)
1391             uidnext (nth 1 elem)
1392             start-article (nth 2 elem)
1393             permanent-flags (nth 3 elem)
1394             uidvalidity (nth 4 elem)
1395             vanished (nth 5 elem)
1396             highestmodseq (nth 6 elem)
1397             articles (nthcdr 7 elem))
1398       (let ((high (caar articles))
1399             marks low existing)
1400         (dolist (article articles)
1401           (setq low (car article))
1402           (push (car article) existing)
1403           (dolist (flag (cdr article))
1404             (setq mark (assoc flag marks))
1405             (if (not mark)
1406                 (push (list flag (car article)) marks)
1407               (setcdr mark (cons (car article) (cdr mark))))))
1408         (push (list group existing marks high low uidnext start-article
1409                     permanent-flags uidvalidity vanished highestmodseq)
1410               data)))
1411     data))
1412
1413 (defun nnimap-parse-flags (sequences)
1414   (goto-char (point-min))
1415   ;; Change \Delete etc to %Delete, so that the reader can read it.
1416   (subst-char-in-region (point-min) (point-max)
1417                         ?\\ ?% t)
1418   (let (start end articles groups uidnext elems permanent-flags
1419               uidvalidity vanished highestmodseq)
1420     (dolist (elem sequences)
1421       (destructuring-bind (group-sequence flag-sequence totalp group command)
1422           elem
1423         (setq start (point))
1424         (when (and
1425                ;; The EXAMINE was successful.
1426                (search-forward (format "\n%d OK " group-sequence) nil t)
1427                (progn
1428                  (forward-line 1)
1429                  (setq end (point))
1430                  (goto-char start)
1431                  (setq permanent-flags
1432                        (if (equal command "SELECT")
1433                            (and (search-forward "PERMANENTFLAGS "
1434                                                 (or end (point-min)) t)
1435                                 (read (current-buffer)))
1436                          'not-scanned))
1437                  (goto-char start)
1438                  (setq uidnext
1439                        (and (search-forward "UIDNEXT "
1440                                             (or end (point-min)) t)
1441                             (read (current-buffer))))
1442                  (goto-char start)
1443                  (setq uidvalidity
1444                        (and (re-search-forward "UIDVALIDITY \\([0-9]+\\)"
1445                                                (or end (point-min)) t)
1446                             ;; Store UIDVALIDITY as a string, as it's
1447                             ;; too big for 32-bit Emacsen, usually.
1448                             (match-string 1)))
1449                  (goto-char start)
1450                  (setq vanished
1451                        (and (eq flag-sequence 'qresync)
1452                             (re-search-forward "^\\* VANISHED .* \\([0-9:,]+\\)"
1453                                                (or end (point-min)) t)
1454                             (match-string 1)))
1455                  (goto-char start)
1456                  (setq highestmodseq
1457                        (and (search-forward "HIGHESTMODSEQ "
1458                                             (or end (point-min)) t)
1459                             (read (current-buffer))))
1460                  (goto-char end)
1461                  (forward-line -1))
1462                ;; The UID FETCH FLAGS was successful.
1463                (or (eq flag-sequence 'qresync)
1464                    (search-forward (format "\n%d OK " flag-sequence) nil t)))
1465           (if (eq flag-sequence 'qresync)
1466               (progn
1467                 (goto-char start)
1468                 (setq start end))
1469             (setq start (point))
1470             (goto-char end))
1471           (while (re-search-forward "^\\* [0-9]+ FETCH " start t)
1472             (setq elems (read (current-buffer)))
1473             (push (cons (cadr (memq 'UID elems))
1474                         (cadr (memq 'FLAGS elems)))
1475                   articles))
1476           (push (nconc (list group uidnext totalp permanent-flags uidvalidity
1477                              vanished highestmodseq)
1478                        articles)
1479                 groups)
1480           (goto-char end)
1481           (setq articles nil))))
1482     groups))
1483
1484 (defun nnimap-find-process-buffer (buffer)
1485   (cadr (assoc buffer nnimap-connection-alist)))
1486
1487 (deffoo nnimap-request-post (&optional server)
1488   (setq nnimap-status-string "Read-only server")
1489   nil)
1490
1491 (declare-function gnus-fetch-headers "gnus-sum"
1492                   (articles &optional limit force-new dependencies))
1493
1494 (deffoo nnimap-request-thread (header)
1495   (let* ((id (mail-header-id header))
1496          (refs (split-string
1497                 (or (mail-header-references header)
1498                     "")))
1499          (cmd (let ((value
1500                      (format
1501                       "(OR HEADER REFERENCES %s HEADER Message-Id %s)"
1502                       id id)))
1503                 (dolist (refid refs value)
1504                   (setq value (format
1505                                "(OR (OR HEADER Message-Id %s HEADER REFERENCES %s) %s)"
1506                                refid refid value)))))
1507          (result (with-current-buffer (nnimap-buffer)
1508                    (nnimap-command  "UID SEARCH %s" cmd))))
1509     (gnus-fetch-headers
1510      (and (car result) (delete 0 (mapcar #'string-to-number
1511                                          (cdr (assoc "SEARCH" (cdr result))))))
1512      nil t)))
1513
1514 (defun nnimap-possibly-change-group (group server)
1515   (let ((open-result t))
1516     (when (and server
1517                (not (nnimap-server-opened server)))
1518       (setq open-result (nnimap-open-server server)))
1519     (cond
1520      ((not open-result)
1521       nil)
1522      ((not group)
1523       t)
1524      (t
1525       (with-current-buffer (nnimap-buffer)
1526         (if (equal group (nnimap-group nnimap-object))
1527             t
1528           (let ((result (nnimap-command "SELECT %S" (utf7-encode group t))))
1529             (when (car result)
1530               (setf (nnimap-group nnimap-object) group
1531                     (nnimap-select-result nnimap-object) result)
1532               result))))))))
1533
1534 (defun nnimap-find-connection (buffer)
1535   "Find the connection delivering to BUFFER."
1536   (let ((entry (assoc buffer nnimap-connection-alist)))
1537     (when entry
1538       (if (and (buffer-name (cadr entry))
1539                (get-buffer-process (cadr entry))
1540                (memq (process-status (get-buffer-process (cadr entry)))
1541                      '(open run)))
1542           (get-buffer-process (cadr entry))
1543         (setq nnimap-connection-alist (delq entry nnimap-connection-alist))
1544         nil))))
1545
1546 (defvar nnimap-sequence 0)
1547
1548 (defun nnimap-send-command (&rest args)
1549   (process-send-string
1550    (get-buffer-process (current-buffer))
1551    (nnimap-log-command
1552     (format "%d %s%s\n"
1553             (incf nnimap-sequence)
1554             (apply #'format args)
1555             (if (nnimap-newlinep nnimap-object)
1556                 ""
1557               "\r"))))
1558   ;; Some servers apparently can't have many outstanding
1559   ;; commands, so throttle them.
1560   (unless nnimap-streaming
1561     (nnimap-wait-for-response nnimap-sequence))
1562   nnimap-sequence)
1563
1564 (defun nnimap-log-command (command)
1565   (with-current-buffer (get-buffer-create "*imap log*")
1566     (goto-char (point-max))
1567     (insert (format-time-string "%H:%M:%S") " " command))
1568   command)
1569
1570 (defun nnimap-command (&rest args)
1571   (erase-buffer)
1572   (setf (nnimap-last-command-time nnimap-object) (current-time))
1573   (let* ((sequence (apply #'nnimap-send-command args))
1574          (response (nnimap-get-response sequence)))
1575     (if (equal (caar response) "OK")
1576         (cons t response)
1577       (nnheader-report 'nnimap "%s"
1578                        (mapconcat (lambda (a)
1579                                     (format "%s" a))
1580                                   (car response) " "))
1581       nil)))
1582
1583 (defun nnimap-get-response (sequence)
1584   (nnimap-wait-for-response sequence)
1585   (nnimap-parse-response))
1586
1587 (defun nnimap-wait-for-connection (&optional regexp)
1588   (nnimap-wait-for-line (or regexp "^[*.] .*\n") "[*.] \\([A-Z0-9]+\\)"))
1589
1590 (defun nnimap-wait-for-line (regexp &optional response-regexp)
1591   (let ((process (get-buffer-process (current-buffer))))
1592     (goto-char (point-min))
1593     (while (and (memq (process-status process)
1594                       '(open run))
1595                 (not (re-search-forward regexp nil t)))
1596       (nnheader-accept-process-output process)
1597       (goto-char (point-min)))
1598     (forward-line -1)
1599     (and (looking-at (or response-regexp regexp))
1600          (match-string 1))))
1601
1602 (defun nnimap-wait-for-response (sequence &optional messagep)
1603   (let ((process (get-buffer-process (current-buffer)))
1604         openp)
1605     (condition-case nil
1606         (progn
1607           (goto-char (point-max))
1608           (while (and (setq openp (memq (process-status process)
1609                                         '(open run)))
1610                       (progn
1611                         ;; Skip past any "*" lines that the server has
1612                         ;; output.
1613                         (while (and (not (bobp))
1614                                     (progn
1615                                       (forward-line -1)
1616                                       (looking-at "\\*"))))
1617                         (not (looking-at (format "%d " sequence)))))
1618             (when messagep
1619               (nnheader-message 7 "nnimap read %dk" (/ (buffer-size) 1000)))
1620             (nnheader-accept-process-output process)
1621             (goto-char (point-max)))
1622           openp)
1623       (quit
1624        ;; The user hit C-g while we were waiting: kill the process, in case
1625        ;; it's a gnutls-cli process that's stuck (tends to happen a lot behind
1626        ;; NAT routers).
1627        (delete-process process)
1628        nil))))
1629
1630 (defun nnimap-parse-response ()
1631   (let ((lines (split-string (nnimap-last-response-string) "\r\n" t))
1632         result)
1633     (dolist (line lines)
1634       (push (cdr (nnimap-parse-line line)) result))
1635     ;; Return the OK/error code first, and then all the "continuation
1636     ;; lines" afterwards.
1637     (cons (pop result)
1638           (nreverse result))))
1639
1640 ;; Parse an IMAP response line lightly.  They look like
1641 ;; "* OK [UIDVALIDITY 1164213559] UIDs valid", typically, so parse
1642 ;; the lines into a list of strings and lists of string.
1643 (defun nnimap-parse-line (line)
1644   (let (char result)
1645     (with-temp-buffer
1646       (mm-disable-multibyte)
1647       (insert line)
1648       (goto-char (point-min))
1649       (while (not (eobp))
1650         (if (eql (setq char (following-char)) ? )
1651             (forward-char 1)
1652           (push
1653            (cond
1654             ((eql char ?\[)
1655              (split-string
1656               (buffer-substring
1657                (1+ (point))
1658                (if (search-forward "]" (line-end-position) 'move)
1659                    (1- (point))
1660                  (point)))))
1661             ((eql char ?\()
1662              (split-string
1663               (buffer-substring
1664                (1+ (point))
1665                (if (search-forward ")" (line-end-position) 'move)
1666                    (1- (point))
1667                  (point)))))
1668             ((eql char ?\")
1669              (forward-char 1)
1670              (buffer-substring
1671               (point)
1672               (1- (or (search-forward "\"" (line-end-position) 'move)
1673                       (point)))))
1674             (t
1675              (buffer-substring (point) (if (search-forward " " nil t)
1676                                            (1- (point))
1677                                          (goto-char (point-max))))))
1678            result)))
1679       (nreverse result))))
1680
1681 (defun nnimap-last-response-string ()
1682   (save-excursion
1683     (forward-line 1)
1684     (let ((end (point)))
1685       (forward-line -1)
1686       (when (not (bobp))
1687         (forward-line -1)
1688         (while (and (not (bobp))
1689                     (eql (following-char) ?*))
1690           (forward-line -1))
1691         (unless (eql (following-char) ?*)
1692           (forward-line 1)))
1693       (buffer-substring (point) end))))
1694
1695 (defun nnimap-get-responses (sequences)
1696   (let (responses)
1697     (dolist (sequence sequences)
1698       (goto-char (point-min))
1699       (when (re-search-forward (format "^%d " sequence) nil t)
1700         (push (list sequence (nnimap-parse-response))
1701               responses)))
1702     responses))
1703
1704 (defvar nnimap-incoming-split-list nil)
1705
1706 (defun nnimap-fetch-inbox (articles)
1707   (erase-buffer)
1708   (nnimap-wait-for-response
1709    (nnimap-send-command
1710     "UID FETCH %s %s"
1711     (nnimap-article-ranges articles)
1712     (format "(UID %s%s)"
1713             (format
1714              (if (nnimap-ver4-p)
1715                  "BODY.PEEK[HEADER] BODY.PEEK"
1716                "RFC822.PEEK"))
1717             (if nnimap-split-download-body-default
1718                 "[]"
1719               "[1]")))
1720    t))
1721
1722 (defun nnimap-split-incoming-mail ()
1723   (with-current-buffer (nnimap-buffer)
1724     (let ((nnimap-incoming-split-list nil)
1725           (nnmail-split-methods (if (eq nnimap-split-methods 'default)
1726                                     nnmail-split-methods
1727                                   nnimap-split-methods))
1728           (nnmail-split-fancy (or nnimap-split-fancy
1729                                   nnmail-split-fancy))
1730           (nnmail-inhibit-default-split-group t)
1731           (groups (nnimap-get-groups))
1732           new-articles)
1733       (erase-buffer)
1734       (nnimap-command "SELECT %S" nnimap-inbox)
1735       (setf (nnimap-group nnimap-object) nnimap-inbox)
1736       (setq new-articles (nnimap-new-articles (nnimap-get-flags "1:*")))
1737       (when new-articles
1738         (nnimap-fetch-inbox new-articles)
1739         (nnimap-transform-split-mail)
1740         (nnheader-ms-strip-cr)
1741         (nnmail-cache-open)
1742         (nnmail-split-incoming (current-buffer)
1743                                #'nnimap-save-mail-spec
1744                                nil nil
1745                                #'nnimap-dummy-active-number
1746                                #'nnimap-save-mail-spec)
1747         (when nnimap-incoming-split-list
1748           (let ((specs (nnimap-make-split-specs nnimap-incoming-split-list))
1749                 sequences junk-articles)
1750             ;; Create any groups that doesn't already exist on the
1751             ;; server first.
1752             (dolist (spec specs)
1753               (when (and (not (member (car spec) groups))
1754                          (not (eq (car spec) 'junk)))
1755                 (nnimap-command "CREATE %S" (utf7-encode (car spec) t))))
1756             ;; Then copy over all the messages.
1757             (erase-buffer)
1758             (dolist (spec specs)
1759               (let ((group (car spec))
1760                     (ranges (cdr spec)))
1761                 (if (eq group 'junk)
1762                     (setq junk-articles ranges)
1763                   (push (list (nnimap-send-command
1764                                "UID COPY %s %S"
1765                                (nnimap-article-ranges ranges)
1766                                (utf7-encode group t))
1767                               ranges)
1768                         sequences))))
1769             ;; Wait for the last COPY response...
1770             (when sequences
1771               (nnimap-wait-for-response (caar sequences))
1772               ;; And then mark the successful copy actions as deleted,
1773               ;; and possibly expunge them.
1774               (nnimap-mark-and-expunge-incoming
1775                (nnimap-parse-copied-articles sequences)))
1776             (nnimap-mark-and-expunge-incoming junk-articles)))))))
1777
1778 (defun nnimap-mark-and-expunge-incoming (range)
1779   (when range
1780     (setq range (nnimap-article-ranges range))
1781     (erase-buffer)
1782     (let ((sequence
1783            (nnimap-send-command
1784             "UID STORE %s +FLAGS.SILENT (\\Deleted)" range)))
1785       (cond
1786        ;; If the server supports it, we now delete the message we have
1787        ;; just copied over.
1788        ((nnimap-capability "UIDPLUS")
1789         (setq sequence (nnimap-send-command "UID EXPUNGE %s" range)))
1790        ;; If it doesn't support UID EXPUNGE, then we only expunge if the
1791        ;; user has configured it.
1792        (nnimap-expunge
1793         (setq sequence (nnimap-send-command "EXPUNGE"))))
1794       (nnimap-wait-for-response sequence))))
1795
1796 (defun nnimap-parse-copied-articles (sequences)
1797   (let (sequence copied range)
1798     (goto-char (point-min))
1799     (while (re-search-forward "^\\([0-9]+\\) OK " nil t)
1800       (setq sequence (string-to-number (match-string 1)))
1801       (when (setq range (cadr (assq sequence sequences)))
1802         (push (gnus-uncompress-range range) copied)))
1803     (gnus-compress-sequence (sort (apply #'nconc copied) #'<))))
1804
1805 (defun nnimap-new-articles (flags)
1806   (let (new)
1807     (dolist (elem flags)
1808       (unless (gnus-list-memq-of-list nnimap-unsplittable-articles
1809                                       (cdr elem))
1810         (push (car elem) new)))
1811     (gnus-compress-sequence (nreverse new))))
1812
1813 (defun nnimap-make-split-specs (list)
1814   (let ((specs nil)
1815         entry)
1816     (dolist (elem list)
1817       (destructuring-bind (article spec) elem
1818         (dolist (group (delete nil (mapcar #'car spec)))
1819           (unless (setq entry (assoc group specs))
1820             (push (setq entry (list group)) specs))
1821           (setcdr entry (cons article (cdr entry))))))
1822     (dolist (entry specs)
1823       (setcdr entry (gnus-compress-sequence (sort (cdr entry) #'<))))
1824     specs))
1825
1826 (defun nnimap-transform-split-mail ()
1827   (goto-char (point-min))
1828   (let (article bytes)
1829     (block nil
1830       (while (not (eobp))
1831         (while (not (looking-at "^\\* [0-9]+ FETCH.*UID \\([0-9]+\\)"))
1832           (delete-region (point) (progn (forward-line 1) (point)))
1833           (when (eobp)
1834             (return)))
1835         (setq article (match-string 1)
1836               bytes (nnimap-get-length))
1837         (delete-region (line-beginning-position) (line-end-position))
1838         ;; Insert MMDF separator, and a way to remember what this
1839         ;; article UID is.
1840         (insert (format "\^A\^A\^A\^A\n\nX-nnimap-article: %s" article))
1841         (forward-char (1+ bytes))
1842         (setq bytes (nnimap-get-length))
1843         (delete-region (line-beginning-position) (line-end-position))
1844         ;; There's a body; skip past that.
1845         (when bytes
1846           (forward-char (1+ bytes))
1847           (delete-region (line-beginning-position) (line-end-position)))))))
1848
1849 (defun nnimap-dummy-active-number (group &optional server)
1850   1)
1851
1852 (defun nnimap-save-mail-spec (group-art &optional server full-nov)
1853   (let (article)
1854     (goto-char (point-min))
1855     (if (not (re-search-forward "X-nnimap-article: \\([0-9]+\\)" nil t))
1856         (error "Invalid nnimap mail")
1857       (setq article (string-to-number (match-string 1))))
1858     (push (list article
1859                 (if (eq group-art 'junk)
1860                     (list (cons 'junk 1))
1861                   group-art))
1862           nnimap-incoming-split-list)))
1863
1864 (provide 'nnimap)
1865
1866 ;;; nnimap.el ends here