cgit.sxemacs.org Git - gnus/blob - lisp/nnimap.el

   1 ;;; nnimap.el --- imap backend for Gnus
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 ;; Author: Simon Josefsson <jas@pdc.kth.se>
   7 ;;         Jim Radford <radford@robby.caltech.edu>
   8 ;; Keywords: mail
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 3, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Todo, major things:
  30 ;;
  31 ;;   o Fix Gnus to view correct number of unread/total articles in group buffer
  32 ;;   o Fix Gnus to handle leading '.' in group names (fixed?)
  33 ;;   o Finish disconnected mode (moving articles between mailboxes unplugged)
  34 ;;   o Sieve
  35 ;;   o MIME (partial article fetches)
  36 ;;   o Split to other backends, different split rules for different
  37 ;;     servers/inboxes
  38 ;;
  39 ;; Todo, minor things:
  40 ;;
  41 ;;   o Don't require half of Gnus -- backends should be standalone
  42 ;;   o Verify that we don't use IMAP4rev1 specific things (RFC2060 App B)
  43 ;;   o Dont uid fetch 1,* in nnimap-retrive-groups (slow)
  44 ;;   o Split up big fetches (1,* header especially) in smaller chunks
  45 ;;   o What do I do with gnus-newsgroup-*?
  46 ;;   o Tell Gnus about new groups (how can we tell?)
  47 ;;   o Respooling (fix Gnus?) (unnecessary?)
  48 ;;   o Add support for the following: (if applicable)
  49 ;;       request-list-newsgroups, request-regenerate
  50 ;;       list-active-group,
  51 ;;       request-associate-buffer, request-restore-buffer,
  52 ;;   o Do The Right Thing when UIDVALIDITY changes (what's the right thing?)
  53 ;;   o Support RFC2221 (Login referrals)
  54 ;;   o IMAP2BIS compatibility? (RFC2061)
  55 ;;   o ACAP stuff (perhaps a different project, would be nice to ACAPify
  56 ;;     .newsrc.eld)
  57 ;;   o What about Gnus's article editing, can we support it?  NO!
  58 ;;   o Use \Draft to support the draft group??
  59 ;;   o Duplicate suppression
  60 ;;   o Rewrite UID SEARCH UID X as UID FETCH X (UID) for those with slow servers
  61
  62 ;;; Code:
  63
  64 (require 'imap)
  65 (require 'nnoo)
  66 (require 'nnmail)
  67 (require 'nnheader)
  68 (require 'mm-util)
  69 (require 'gnus)
  70 (require 'gnus-range)
  71 (require 'gnus-start)
  72 (require 'gnus-int)
  73
  74 (eval-when-compile (require 'cl))
  75
  76 (nnoo-declare nnimap)
  77
  78 (defconst nnimap-version "nnimap 1.0")
  79
  80 (defgroup nnimap nil
  81   "Reading IMAP mail with Gnus."
  82   :group 'gnus)
  83
  84 (defvoo nnimap-address nil
  85   "Address of physical IMAP server.  If nil, use the virtual server's name.")
  86
  87 (defvoo nnimap-server-port nil
  88   "Port number on physical IMAP server.
  89 If nil, defaults to 993 for TLS/SSL connections and 143 otherwise.")
  90
  91 ;; Splitting variables
  92
  93 (defcustom nnimap-split-crosspost t
  94   "If non-nil, do crossposting if several split methods match the mail.
  95 If nil, the first match found will be used."
  96   :group 'nnimap
  97   :type 'boolean)
  98
  99 (defcustom nnimap-split-inbox nil
 100   "Name of mailbox to split mail from.
 101
 102 Mail is read from this mailbox and split according to rules in
 103 `nnimap-split-rule'.
 104
 105 This can be a string or a list of strings."
 106   :group 'nnimap
 107   :type '(choice (string)
 108                  (repeat string)))
 109
 110 (define-widget 'nnimap-strict-function 'function
 111   "This widget only matches values that are functionp.
 112
 113 Warning: This means that a value that is the symbol of a not yet
 114 loaded function will not match.  Use with care."
 115   :match 'nnimap-strict-function-match)
 116
 117 (defun nnimap-strict-function-match (widget value)
 118   "Ignoring WIDGET, match if VALUE is a function."
 119   (functionp value))
 120
 121 (defcustom nnimap-split-rule nil
 122   "Mail will be split according to these rules.
 123
 124 Mail is read from mailbox(es) specified in `nnimap-split-inbox'.
 125
 126 If you'd like, for instance, one mail group for mail from the
 127 \"gnus-imap\" mailing list, one group for junk mail and leave
 128 everything else in the incoming mailbox, you could do something like
 129 this:
 130
 131 \(setq nnimap-split-rule '((\"INBOX.gnus-imap\"   \"From:.*gnus-imap\")
 132                           (\"INBOX.junk\"        \"Subject:.*buy\")))
 133
 134 As you can see, `nnimap-split-rule' is a list of lists, where the
 135 first element in each \"rule\" is the name of the IMAP mailbox (or the
 136 symbol `junk' if you want to remove the mail), and the second is a
 137 regexp that nnimap will try to match on the header to find a fit.
 138
 139 The second element can also be a function.  In that case, it will be
 140 called narrowed to the headers with the first element of the rule as
 141 the argument.  It should return a non-nil value if it thinks that the
 142 mail belongs in that group.
 143
 144 This variable can also have a function as its value, the function will
 145 be called with the headers narrowed and should return a group where it
 146 thinks the article should be splitted to.  See `nnimap-split-fancy'.
 147
 148 To allow for different split rules on different virtual servers, and
 149 even different split rules in different inboxes on the same server,
 150 the syntax of this variable have been extended along the lines of:
 151
 152 \(setq nnimap-split-rule
 153       '((\"my1server\"    (\".*\"    ((\"ding\"    \"ding@gnus.org\")
 154                                   (\"junk\"    \"From:.*Simon\")))
 155         (\"my2server\"    (\"INBOX\" nnimap-split-fancy))
 156         (\"my[34]server\" (\".*\"    ((\"private\" \"To:.*Simon\")
 157                                   (\"junk\"    my-junk-func)))))
 158
 159 The virtual server name is in fact a regexp, so that the same rules
 160 may apply to several servers.  In the example, the servers
 161 \"my3server\" and \"my4server\" both use the same rules.  Similarly,
 162 the inbox string is also a regexp.  The actual splitting rules are as
 163 before, either a function, or a list with group/regexp or
 164 group/function elements."
 165   :group 'nnimap
 166   :type '(choice :tag "Rule type"
 167                  (repeat :menu-tag "Single-server"
 168                          :tag "Single-server list"
 169                          (list (string :tag "Mailbox")
 170                                (choice :tag "Predicate"
 171                                        (regexp :tag "A regexp")
 172                                        (nnimap-strict-function :tag "A function"))))
 173                  (choice :menu-tag "A function"
 174                          :tag "A function"
 175                          (function-item nnimap-split-fancy)
 176                          (function-item nnmail-split-fancy)
 177                          (nnimap-strict-function :tag "User-defined function"))
 178                  (repeat :menu-tag "Multi-server (extended)"
 179                          :tag "Multi-server list"
 180                          (list (regexp :tag "Server regexp")
 181                                (list (regexp :tag "Incoming Mailbox regexp")
 182                                      (repeat :tag "Rules for matching server(s) and mailbox(es)"
 183                                              (list (string :tag "Destination mailbox")
 184                                                    (choice :tag "Predicate"
 185                                                            (regexp :tag "A Regexp")
 186                                                            (nnimap-strict-function :tag "A Function")))))))))
 187
 188 (defcustom nnimap-split-predicate "UNSEEN UNDELETED"
 189   "The predicate used to find articles to split.
 190 If you use another IMAP client to peek on articles but always would
 191 like nnimap to split them once it's started, you could change this to
 192 \"UNDELETED\". Other available predicates are available in
 193 RFC2060 section 6.4.4."
 194   :group 'nnimap
 195   :type 'string)
 196
 197 (defcustom nnimap-split-fancy nil
 198   "Like the variable `nnmail-split-fancy'."
 199   :group 'nnimap
 200   :type 'sexp)
 201
 202 (defvar nnimap-split-download-body-default nil
 203   "Internal variable with default value for `nnimap-split-download-body'.")
 204
 205 (defcustom nnimap-split-download-body 'default
 206   "Whether to download entire articles during splitting.
 207 This is generally not required, and will slow things down considerably.
 208 You may need it if you want to use an advanced splitting function that
 209 analyzes the body before splitting the article.
 210 If this variable is nil, bodies will not be downloaded; if this
 211 variable is the symbol `default' the default behaviour is
 212 used (which currently is nil, unless you use a statistical
 213 spam.el test); if this variable is another non-nil value bodies
 214 will be downloaded."
 215   :version "22.1"
 216   :group 'nnimap
 217   :type '(choice (const :tag "Let system decide" deault)
 218                  boolean))
 219
 220 ;; Performance / bug workaround variables
 221
 222 (defcustom nnimap-close-asynchronous t
 223   "Close mailboxes asynchronously in `nnimap-close-group'.
 224 This means that errors caught by nnimap when closing the mailbox will
 225 not prevent Gnus from updating the group status, which may be harmful.
 226 However, it increases speed."
 227   :version "22.1"
 228   :type 'boolean
 229   :group 'nnimap)
 230
 231 (defcustom nnimap-dont-close t
 232   "Never close mailboxes.
 233 This increases the speed of closing mailboxes (quiting group) but may
 234 decrease the speed of selecting another mailbox later.  Re-selecting
 235 the same mailbox will be faster though."
 236   :version "22.1"
 237   :type 'boolean
 238   :group 'nnimap)
 239
 240 (defcustom nnimap-retrieve-groups-asynchronous t
 241   "Send asynchronous STATUS commands for each mailbox before checking mail.
 242 If you have mailboxes that rarely receives mail, this speeds up new
 243 mail checking.  It works by first sending STATUS commands for each
 244 mailbox, and then only checking groups which has a modified UIDNEXT
 245 more carefully for new mail.
 246
 247 In summary, the default is O((1-p)*k+p*n) and changing it to nil makes
 248 it O(n).  If p is small, then the default is probably faster."
 249   :version "22.1"
 250   :type 'boolean
 251   :group 'nnimap)
 252
 253 (defvoo nnimap-need-unselect-to-notice-new-mail t
 254   "Unselect mailboxes before looking for new mail in them.
 255 Some servers seem to need this under some circumstances.")
 256
 257 (defvoo nnimap-logout-timeout nil
 258   "Close server immediately if it can't logout in this number of seconds.
 259 If it is nil, never close server until logout completes.  This variable
 260 overrides `imap-logout-timeout' on a per-server basis.")
 261
 262 ;; Authorization / Privacy variables
 263
 264 (defvoo nnimap-auth-method nil
 265   "Obsolete.")
 266
 267 (defvoo nnimap-stream nil
 268   "How nnimap will connect to the server.
 269
 270 The default, nil, will try to use the \"best\" method the server can
 271 handle.
 272
 273 Change this if
 274
 275 1) you want to connect with TLS/SSL.  The TLS/SSL integration
 276    with IMAP is suboptimal so you'll have to tell it
 277    specifically.
 278
 279 2) your server is more capable than your environment -- i.e. your
 280    server accept Kerberos login's but you haven't installed the
 281    `imtest' program or your machine isn't configured for Kerberos.
 282
 283 Possible choices: gssapi, kerberos4, starttls, tls, ssl, network, shell.
 284 See also `imap-streams' and `imap-stream-alist'.")
 285
 286 (defvoo nnimap-authenticator nil
 287   "How nnimap authenticate itself to the server.
 288
 289 The default, nil, will try to use the \"best\" method the server can
 290 handle.
 291
 292 There is only one reason for fiddling with this variable, and that is
 293 if your server is more capable than your environment -- i.e. you
 294 connect to a server that accept Kerberos login's but you haven't
 295 installed the `imtest' program or your machine isn't configured for
 296 Kerberos.
 297
 298 Possible choices: gssapi, kerberos4, digest-md5, cram-md5, login, anonymous.
 299 See also `imap-authenticators' and `imap-authenticator-alist'")
 300
 301 (defvoo nnimap-directory (nnheader-concat gnus-directory "overview/")
 302   "Directory to keep NOV cache files for nnimap groups.
 303 See also `nnimap-nov-file-name'.")
 304
 305 (defvoo nnimap-nov-file-name "nnimap."
 306   "NOV cache base filename.
 307 The group name and `nnimap-nov-file-name-suffix' will be appended.  A
 308 typical complete file name would be
 309 ~/News/overview/nnimap.pdc.INBOX.ding.nov, or
 310 ~/News/overview/nnimap/pdc/INBOX/ding/nov if
 311 `nnmail-use-long-file-names' is nil")
 312
 313 (defvoo nnimap-nov-file-name-suffix ".novcache"
 314   "Suffix for NOV cache base filename.")
 315
 316 (defvoo nnimap-nov-is-evil gnus-agent
 317   "If non-nil, never generate or use a local nov database for this backend.
 318 Using nov databases should speed up header fetching considerably.
 319 However, it will invoke a UID SEARCH UID command on the server, and
 320 some servers implement this command inefficiently by opening each and
 321 every message in the group, thus making it quite slow.
 322 Unlike other backends, you do not need to take special care if you
 323 flip this variable.")
 324
 325 (defvoo nnimap-search-uids-not-since-is-evil nil
 326   "If non-nil, avoid \"UID SEARCH UID ... NOT SINCE\" queries when expiring.
 327 Instead, use \"UID SEARCH SINCE\" to prune the list of expirable
 328 articles within Gnus.  This seems to be faster on Courier in some cases.")
 329
 330 (defvoo nnimap-expunge-on-close 'always ; 'ask, 'never
 331   "Whether to expunge a group when it is closed.
 332 When a IMAP group with articles marked for deletion is closed, this
 333 variable determine if nnimap should actually remove the articles or
 334 not.
 335
 336 If always, nnimap always perform a expunge when closing the group.
 337 If never, nnimap never expunges articles marked for deletion.
 338 If ask, nnimap will ask you if you wish to expunge marked articles.
 339
 340 When setting this variable to `never', you can only expunge articles
 341 by using `G x' (gnus-group-nnimap-expunge) from the Group buffer.")
 342
 343 (defvoo nnimap-list-pattern "*"
 344   "A string LIMIT or list of strings with mailbox wildcards used to limit available groups.
 345 See below for available wildcards.
 346
 347 The LIMIT string can be a cons cell (REFERENCE . LIMIT), where
 348 REFERENCE will be passed as the first parameter to LIST/LSUB.  The
 349 semantics of this are server specific, on the University of Washington
 350 server you can specify a directory.
 351
 352 Example:
 353  '(\"INBOX\" \"mail/*\" (\"~friend/mail/\" . \"list/*\"))
 354
 355 There are two wildcards * and %. * matches everything, % matches
 356 everything in the current hierarchy.")
 357
 358 (defvoo nnimap-news-groups nil
 359   "IMAP support a news-like mode, also known as bulletin board mode,
 360 where replies is sent via IMAP instead of SMTP.
 361
 362 This variable should contain a regexp matching groups where you wish
 363 replies to be stored to the mailbox directly.
 364
 365 Example:
 366   '(\"^[^I][^N][^B][^O][^X].*$\")
 367
 368 This will match all groups not beginning with \"INBOX\".
 369
 370 Note that there is nothing technically different between mail-like and
 371 news-like mailboxes.  If you wish to have a group with todo items or
 372 similar which you wouldn't want to set up a mailing list for, you can
 373 use this to make replies go directly to the group.")
 374
 375 (defvoo nnimap-expunge-search-string "UID %s NOT SINCE %s"
 376   "IMAP search command to use for articles that are to be expired.
 377 The first %s is replaced by a UID set of articles to search on,
 378 and the second %s is replaced by a date criterium.
 379
 380 One useful (and perhaps the only useful) value to change this to would
 381 be `UID %s NOT SENTSINCE %s' to make nnimap use the Date: header
 382 instead of the internal date of messages.  See section 6.4.4 of RFC
 383 2060 for more information on valid strings.
 384
 385 However, if `nnimap-search-uids-not-since-is-evil' is true, this
 386 variable has no effect since the search logic is reversed.")
 387
 388 (defvoo nnimap-importantize-dormant t
 389   "If non-nil, mark \"dormant\" articles as \"ticked\" for other IMAP clients.
 390 Note that within Gnus, dormant articles will still (only) be
 391 marked as ticked.  This is to make \"dormant\" articles stand out,
 392 just like \"ticked\" articles, in other IMAP clients.")
 393
 394 (defvoo nnimap-server-address nil
 395   "Obsolete.  Use `nnimap-address'.")
 396
 397 (defcustom nnimap-authinfo-file "~/.authinfo"
 398   "Authorization information for IMAP servers.  In .netrc format."
 399   :type
 400   '(choice file
 401            (repeat :tag "Entries"
 402                    :menu-tag "Inline"
 403                    (list :format "%v"
 404                          :value ("" ("login" . "") ("password" . ""))
 405                          (string :tag "Host")
 406                          (checklist :inline t
 407                                     (cons :format "%v"
 408                                           (const :format "" "login")
 409                                           (string :format "Login: %v"))
 410                                     (cons :format "%v"
 411                                           (const :format "" "password")
 412                                           (string :format "Password: %v"))))))
 413   :group 'nnimap)
 414
 415 (defcustom nnimap-prune-cache t
 416   "If non-nil, nnimap check whether articles still exist on server before using data stored in NOV cache."
 417   :type 'boolean
 418   :group 'nnimap)
 419
 420 (defvar nnimap-request-list-method 'imap-mailbox-list
 421   "Method to use to request a list of all folders from the server.
 422 If this is 'imap-mailbox-lsub, then use a server-side subscription list to
 423 restrict visible folders.")
 424
 425 (defcustom nnimap-id nil
 426   "Plist with client identity to send to server upon login.
 427 Nil means no information is sent, symbol `no' to disable ID query
 428 alltogheter, or plist with identifier-value pairs to send to
 429 server.  RFC 2971 describes the list as follows:
 430
 431    Any string may be sent as a field, but the following are defined to
 432    describe certain values that might be sent.  Implementations are free
 433    to send none, any, or all of these.  Strings are not case-sensitive.
 434    Field strings MUST NOT be longer than 30 octets.  Value strings MUST
 435    NOT be longer than 1024 octets.  Implementations MUST NOT send more
 436    than 30 field-value pairs.
 437
 438      name            Name of the program
 439      version         Version number of the program
 440      os              Name of the operating system
 441      os-version      Version of the operating system
 442      vendor          Vendor of the client/server
 443      support-url     URL to contact for support
 444      address         Postal address of contact/vendor
 445      date            Date program was released, specified as a date-time
 446                        in IMAP4rev1
 447      command         Command used to start the program
 448      arguments       Arguments supplied on the command line, if any
 449                        if any
 450      environment     Description of environment, i.e., UNIX environment
 451                        variables or Windows registry settings
 452
 453    Implementations MUST NOT send the same field name more than once.
 454
 455 An example plist would be '(\"name\" \"Gnus\" \"version\" gnus-version-number
 456 \"os\" system-configuration \"vendor\" \"GNU\")."
 457   :group 'nnimap
 458   :type '(choice (const :tag "No information" nil)
 459                  (const :tag "Disable ID query" no)
 460                  (plist :key-type string :value-type string)))
 461
 462 (defcustom nnimap-debug nil
 463   "If non-nil, random debug spews are placed in *nnimap-debug* buffer.
 464 Note that username, passwords and other privacy sensitive
 465 information (such as e-mail) may be stored in the *nnimap-debug*
 466 buffer.  It is not written to disk, however.  Do not enable this
 467 variable unless you are comfortable with that."
 468   :group 'nnimap
 469   :type 'boolean)
 470
 471 ;; Internal variables:
 472
 473 (defvar nnimap-debug-buffer "*nnimap-debug*")
 474 (defvar nnimap-mailbox-info (gnus-make-hashtable 997))
 475 (defvar nnimap-current-move-server nil)
 476 (defvar nnimap-current-move-group nil)
 477 (defvar nnimap-current-move-article nil)
 478 (defvar nnimap-length)
 479 (defvar nnimap-progress-chars '(?| ?/ ?- ?\\))
 480 (defvar nnimap-progress-how-often 20)
 481 (defvar nnimap-counter)
 482 (defvar nnimap-server-buffer-alist nil) ;; Map server name to buffers.
 483 (defvar nnimap-current-server nil) ;; Current server
 484 (defvar nnimap-server-buffer nil) ;; Current servers' buffer
 485
 486 \f
 487
 488 (nnoo-define-basics nnimap)
 489
 490 ;; Utility functions:
 491
 492 (defsubst nnimap-get-server-buffer (server)
 493   "Return buffer for SERVER, if nil use current server."
 494   (cadr (assoc (or server nnimap-current-server) nnimap-server-buffer-alist)))
 495
 496 (defun nnimap-remove-server-from-buffer-alist (server list)
 497   "Remove SERVER from LIST."
 498   (let (l)
 499     (dolist (e list)
 500       (unless (equal server (car-safe e))
 501         (push e l)))
 502     l))
 503
 504 (defun nnimap-possibly-change-server (server)
 505   "Return buffer for SERVER, changing the current server as a side-effect.
 506 If SERVER is nil, uses the current server."
 507   (setq nnimap-current-server (or server nnimap-current-server)
 508         nnimap-server-buffer (nnimap-get-server-buffer nnimap-current-server)))
 509
 510 (defun nnimap-verify-uidvalidity (group server)
 511   "Verify stored uidvalidity match current one in GROUP on SERVER."
 512   (let* ((gnusgroup (gnus-group-prefixed-name
 513                      group (gnus-server-to-method
 514                             (format "nnimap:%s" server))))
 515          (new-uidvalidity (imap-mailbox-get 'uidvalidity))
 516          (old-uidvalidity (gnus-group-get-parameter gnusgroup 'uidvalidity))
 517          (dir (file-name-as-directory (expand-file-name nnimap-directory)))
 518          (nameuid (nnheader-translate-file-chars
 519                    (concat nnimap-nov-file-name
 520                            (if (equal server "")
 521                                "unnamed"
 522                              server) "." group "." old-uidvalidity
 523                            nnimap-nov-file-name-suffix) t))
 524          (file (if (or nnmail-use-long-file-names
 525                        (file-exists-p (expand-file-name nameuid dir)))
 526                    (expand-file-name nameuid dir)
 527                  (expand-file-name
 528                   (mm-encode-coding-string
 529                    (nnheader-replace-chars-in-string nameuid ?. ?/)
 530                    nnmail-pathname-coding-system)
 531                   dir))))
 532     (if old-uidvalidity
 533         (if (not (equal old-uidvalidity new-uidvalidity))
 534             ;; uidvalidity clash
 535             (gnus-delete-file file)
 536           (gnus-group-set-parameter gnusgroup 'uidvalidity new-uidvalidity)
 537           t)
 538       (gnus-group-add-parameter gnusgroup (cons 'uidvalidity new-uidvalidity))
 539       t)))
 540
 541 (defun nnimap-before-find-minmax-bugworkaround ()
 542   "Function called before iterating through mailboxes with
 543 `nnimap-find-minmax-uid'."
 544   (when nnimap-need-unselect-to-notice-new-mail
 545     ;; XXX this is for UoW imapd problem, it doesn't notice new mail in
 546     ;; currently selected mailbox without a re-select/examine.
 547     (or (null (imap-current-mailbox nnimap-server-buffer))
 548         (imap-mailbox-unselect nnimap-server-buffer))))
 549
 550 (defun nnimap-find-minmax-uid (group &optional examine)
 551   "Find lowest and highest active article number in GROUP.
 552 If EXAMINE is non-nil the group is selected read-only."
 553   (with-current-buffer nnimap-server-buffer
 554     (when (or (string= group (imap-current-mailbox))
 555               (imap-mailbox-select group examine))
 556       (let (minuid maxuid)
 557         (when (> (imap-mailbox-get 'exists) 0)
 558           (imap-fetch "1,*" "UID" nil 'nouidfetch)
 559           (imap-message-map (lambda (uid Uid)
 560                               (setq minuid (if minuid (min minuid uid) uid)
 561                                     maxuid (if maxuid (max maxuid uid) uid)))
 562                             'UID))
 563         (list (imap-mailbox-get 'exists) minuid maxuid)))))
 564
 565 (defun nnimap-possibly-change-group (group &optional server)
 566   "Make GROUP the current group, and SERVER the current server."
 567   (when (nnimap-possibly-change-server server)
 568     (with-current-buffer nnimap-server-buffer
 569       (if (or (null group) (imap-current-mailbox-p group))
 570           imap-current-mailbox
 571         (if (imap-mailbox-select group)
 572             (if (or (nnimap-verify-uidvalidity
 573                      group (or server nnimap-current-server))
 574                     (zerop (imap-mailbox-get 'exists group))
 575                     t ;; for OGnus to see if ignoring uidvalidity
 576                     ;; changes has any bad effects.
 577                     (yes-or-no-p
 578                      (format
 579                       "nnimap: Group %s is not uidvalid.  Continue? " group)))
 580                 imap-current-mailbox
 581               (imap-mailbox-unselect)
 582               (error "nnimap: Group %s is not uid-valid" group))
 583           (nnheader-report 'nnimap (imap-error-text)))))))
 584
 585 (defun nnimap-replace-whitespace (string)
 586   "Return STRING with all whitespace replaced with space."
 587   (when string
 588     (while (string-match "[\r\n\t]+" string)
 589       (setq string (replace-match " " t t string)))
 590     string))
 591
 592 ;; Required backend functions
 593
 594 (defun nnimap-retrieve-headers-progress ()
 595   "Hook to insert NOV line for current article into `nntp-server-buffer'."
 596   (and (numberp nnmail-large-newsgroup)
 597        (zerop (% (incf nnimap-counter) nnimap-progress-how-often))
 598        (> nnimap-length nnmail-large-newsgroup)
 599        (nnheader-message 6 "nnimap: Retrieving headers... %c"
 600                          (nth (/ (% nnimap-counter
 601                                     (* (length nnimap-progress-chars)
 602                                        nnimap-progress-how-often))
 603                                  nnimap-progress-how-often)
 604                               nnimap-progress-chars)))
 605   (with-current-buffer nntp-server-buffer
 606     (let (headers lines chars uid mbx)
 607       (with-current-buffer nnimap-server-buffer
 608         (setq uid imap-current-message
 609               mbx imap-current-mailbox
 610               headers (nnimap-demule
 611                        (if (imap-capability 'IMAP4rev1)
 612                            ;; xxx don't just use car? alist doesn't contain
 613                            ;; anything else now, but it might...
 614                            (nth 2 (car (imap-message-get uid 'BODYDETAIL)))
 615                          (imap-message-get uid 'RFC822.HEADER)))
 616               lines (imap-body-lines (imap-message-body imap-current-message))
 617               chars (imap-message-get imap-current-message 'RFC822.SIZE)))
 618       (nnheader-insert-nov
 619        (with-temp-buffer
 620          (buffer-disable-undo)
 621          (insert headers)
 622          (let ((head (nnheader-parse-naked-head uid)))
 623            (mail-header-set-number head uid)
 624            (mail-header-set-chars head chars)
 625            (mail-header-set-lines head lines)
 626            (mail-header-set-xref
 627             head (format "%s %s:%d" (system-name) mbx uid))
 628            head))))))
 629
 630 (defun nnimap-retrieve-which-headers (articles fetch-old)
 631   "Get a range of articles to fetch based on ARTICLES and FETCH-OLD."
 632   (with-current-buffer nnimap-server-buffer
 633     (if (numberp (car-safe articles))
 634         (imap-search
 635          (concat "UID "
 636                  (imap-range-to-message-set
 637                   (gnus-compress-sequence
 638                    (append (gnus-uncompress-sequence
 639                             (and fetch-old
 640                                  (cons (if (numberp fetch-old)
 641                                            (max 1 (- (car articles) fetch-old))
 642                                          1)
 643                                        (1- (car articles)))))
 644                            articles)))))
 645       (mapcar (lambda (msgid)
 646                 (imap-search
 647                  (format "HEADER Message-Id \"%s\"" msgid)))
 648               articles))))
 649
 650 (defun nnimap-group-overview-filename (group server)
 651   "Make file name for GROUP on SERVER."
 652   (let* ((dir (file-name-as-directory (expand-file-name nnimap-directory)))
 653          (uidvalidity (gnus-group-get-parameter
 654                        (gnus-group-prefixed-name
 655                         group (gnus-server-to-method
 656                                (format "nnimap:%s" server)))
 657                        'uidvalidity))
 658          (name (nnheader-translate-file-chars
 659                 (concat nnimap-nov-file-name
 660                         (if (equal server "")
 661                             "unnamed"
 662                           server) "." group nnimap-nov-file-name-suffix) t))
 663          (nameuid (nnheader-translate-file-chars
 664                    (concat nnimap-nov-file-name
 665                            (if (equal server "")
 666                                "unnamed"
 667                              server) "." group "." uidvalidity
 668                            nnimap-nov-file-name-suffix) t))
 669          (oldfile (if (or nnmail-use-long-file-names
 670                           (file-exists-p (expand-file-name name dir)))
 671                       (expand-file-name name dir)
 672                     (expand-file-name
 673                      (mm-encode-coding-string
 674                       (nnheader-replace-chars-in-string name ?. ?/)
 675                       nnmail-pathname-coding-system)
 676                      dir)))
 677          (newfile (if (or nnmail-use-long-file-names
 678                           (file-exists-p (expand-file-name nameuid dir)))
 679                       (expand-file-name nameuid dir)
 680                     (expand-file-name
 681                      (mm-encode-coding-string
 682                       (nnheader-replace-chars-in-string nameuid ?. ?/)
 683                       nnmail-pathname-coding-system)
 684                      dir))))
 685     (when (and (file-exists-p oldfile) (not (file-exists-p newfile)))
 686       (message "nnimap: Upgrading novcache filename...")
 687       (sit-for 1)
 688       (gnus-make-directory (file-name-directory newfile))
 689       (unless (ignore-errors (rename-file oldfile newfile) t)
 690         (if (ignore-errors (copy-file oldfile newfile) t)
 691             (delete-file oldfile)
 692           (error "Can't rename `%s' to `%s'" oldfile newfile))))
 693     newfile))
 694
 695 (defun nnimap-retrieve-headers-from-file (group server)
 696   (with-current-buffer nntp-server-buffer
 697     (let ((nov (nnimap-group-overview-filename group server)))
 698       (when (file-exists-p nov)
 699         (mm-insert-file-contents nov)
 700         (set-buffer-modified-p nil)
 701         (let ((min (ignore-errors (goto-char (point-min))
 702                                   (read (current-buffer))))
 703               (max (ignore-errors (goto-char (point-max))
 704                                   (forward-line -1)
 705                                   (read (current-buffer)))))
 706           (if (and (numberp min) (numberp max))
 707               (cons min max)
 708             ;; junk, remove it, it's saved later
 709             (erase-buffer)
 710             nil))))))
 711
 712 (defun nnimap-retrieve-headers-from-server (articles group server)
 713   (with-current-buffer nnimap-server-buffer
 714     (let ((imap-fetch-data-hook '(nnimap-retrieve-headers-progress))
 715           (nnimap-length (gnus-range-length articles))
 716           (nnimap-counter 0))
 717       (imap-fetch (imap-range-to-message-set articles)
 718                   (concat "(UID RFC822.SIZE BODY "
 719                           (let ((headers
 720                                  (append '(Subject From Date Message-Id
 721                                                    References In-Reply-To Xref)
 722                                          (copy-sequence
 723                                           nnmail-extra-headers))))
 724                             (if (imap-capability 'IMAP4rev1)
 725                                 (format "BODY.PEEK[HEADER.FIELDS %s])" headers)
 726                               (format "RFC822.HEADER.LINES %s)" headers)))))
 727       (with-current-buffer nntp-server-buffer
 728         (sort-numeric-fields 1 (point-min) (point-max)))
 729       (and (numberp nnmail-large-newsgroup)
 730            (> nnimap-length nnmail-large-newsgroup)
 731            (nnheader-message 6 "nnimap: Retrieving headers...done")))))
 732
 733 (defun nnimap-dont-use-nov-p (group server)
 734   (or gnus-nov-is-evil nnimap-nov-is-evil
 735       (unless (and (gnus-make-directory
 736                     (file-name-directory
 737                      (nnimap-group-overview-filename group server)))
 738                    (file-writable-p
 739                     (nnimap-group-overview-filename group server)))
 740         (message "nnimap: Nov cache not writable, %s"
 741                  (nnimap-group-overview-filename group server)))))
 742
 743 (deffoo nnimap-retrieve-headers (articles &optional group server fetch-old)
 744   (when (nnimap-possibly-change-group group server)
 745     (with-current-buffer nntp-server-buffer
 746       (erase-buffer)
 747       (if (nnimap-dont-use-nov-p group server)
 748           (nnimap-retrieve-headers-from-server
 749            (gnus-compress-sequence articles) group server)
 750         (let (uids cached low high)
 751           (when (setq uids (nnimap-retrieve-which-headers articles fetch-old)
 752                       low (car uids)
 753                       high (car (last uids)))
 754             (if (setq cached (nnimap-retrieve-headers-from-file group server))
 755                 (progn
 756                   ;; fetch articles with uids before cache block
 757                   (when (< low (car cached))
 758                     (goto-char (point-min))
 759                     (nnimap-retrieve-headers-from-server
 760                      (cons low (1- (car cached))) group server))
 761                   ;; fetch articles with uids after cache block
 762                   (when (> high (cdr cached))
 763                     (goto-char (point-max))
 764                     (nnimap-retrieve-headers-from-server
 765                      (cons (1+ (cdr cached)) high) group server))
 766                   (when nnimap-prune-cache
 767                     ;; remove nov's for articles which has expired on server
 768                     (goto-char (point-min))
 769                     (dolist (uid (gnus-set-difference articles uids))
 770                       (when (re-search-forward (format "^%d\t" uid) nil t)
 771                         (gnus-delete-line)))))
 772               ;; nothing cached, fetch whole range from server
 773               (nnimap-retrieve-headers-from-server
 774                (cons low high) group server))
 775             (when (buffer-modified-p)
 776               (nnmail-write-region
 777                (point-min) (point-max)
 778                (nnimap-group-overview-filename group server) nil 'nomesg))
 779             (nnheader-nov-delete-outside-range low high))))
 780       'nov)))
 781
 782 (defun nnimap-open-connection (server)
 783   ;; Note: `nnimap-open-server' that calls this function binds
 784   ;; `imap-logout-timeout' to `nnimap-logout-timeout'.
 785   (if (not (imap-open nnimap-address nnimap-server-port nnimap-stream
 786                       nnimap-authenticator nnimap-server-buffer))
 787       (nnheader-report 'nnimap "Can't open connection to server %s" server)
 788     (unless (or (imap-capability 'IMAP4 nnimap-server-buffer)
 789                 (imap-capability 'IMAP4rev1 nnimap-server-buffer))
 790       (imap-close nnimap-server-buffer)
 791       (nnheader-report 'nnimap "Server %s is not IMAP4 compliant" server))
 792     (let* ((list (progn (gnus-message 7 "Parsing authinfo file `%s'."
 793                                       nnimap-authinfo-file)
 794                         (netrc-parse nnimap-authinfo-file)))
 795            (port (if nnimap-server-port
 796                      (int-to-string nnimap-server-port)
 797                    "imap"))
 798            (user (netrc-machine-user-or-password
 799                   "login"
 800                   list
 801                   (list server
 802                         (or nnimap-server-address
 803                             nnimap-address))
 804                   (list port)
 805                   (list "imap" "imaps")))
 806            (passwd (netrc-machine-user-or-password
 807                     "password"
 808                     list
 809                     (list server
 810                           (or nnimap-server-address
 811                               nnimap-address))
 812                     (list port)
 813                     (list "imap" "imaps"))))
 814       (if (imap-authenticate user passwd nnimap-server-buffer)
 815           (prog2
 816               (setq nnimap-server-buffer-alist
 817                     (nnimap-remove-server-from-buffer-alist
 818                      server
 819                      nnimap-server-buffer-alist))
 820               (push (list server nnimap-server-buffer)
 821                     nnimap-server-buffer-alist)
 822             (imap-id nnimap-id nnimap-server-buffer)
 823             (nnimap-possibly-change-server server))
 824         (imap-close nnimap-server-buffer)
 825         (kill-buffer nnimap-server-buffer)
 826         (nnheader-report 'nnimap "Could not authenticate to %s" server)))))
 827
 828 (deffoo nnimap-open-server (server &optional defs)
 829   (nnheader-init-server-buffer)
 830   (if (nnimap-server-opened server)
 831       t
 832     (unless (assq 'nnimap-server-buffer defs)
 833       (push (list 'nnimap-server-buffer (concat " *nnimap* " server)) defs))
 834     ;; translate `nnimap-server-address' to `nnimap-address' in defs
 835     ;; for people that configured nnimap with a very old version
 836     (unless (assq 'nnimap-address defs)
 837       (if (assq 'nnimap-server-address defs)
 838           (push (list 'nnimap-address
 839                       (cadr (assq 'nnimap-server-address defs))) defs)
 840         (push (list 'nnimap-address server) defs)))
 841     (nnoo-change-server 'nnimap server defs)
 842     (or nnimap-server-buffer
 843         (setq nnimap-server-buffer (cadr (assq 'nnimap-server-buffer defs))))
 844     (with-current-buffer (get-buffer-create nnimap-server-buffer)
 845       (nnoo-change-server 'nnimap server defs))
 846     (let ((imap-logout-timeout nnimap-logout-timeout))
 847       (or (and nnimap-server-buffer
 848                (imap-opened nnimap-server-buffer)
 849                (if (with-current-buffer nnimap-server-buffer
 850                      (memq imap-state '(auth selected examine)))
 851                    t
 852                  (imap-close nnimap-server-buffer)
 853                  (nnimap-open-connection server)))
 854           (nnimap-open-connection server)))))
 855
 856 (deffoo nnimap-server-opened (&optional server)
 857   "Whether SERVER is opened.
 858 If SERVER is the current virtual server, and the connection to the
 859 physical server is alive, this function return a non-nil value.  If
 860 SERVER is nil, it is treated as the current server."
 861   ;; clean up autologouts??
 862   (and (or server nnimap-current-server)
 863        (nnoo-server-opened 'nnimap (or server nnimap-current-server))
 864        (imap-opened (nnimap-get-server-buffer server))))
 865
 866 (deffoo nnimap-close-server (&optional server)
 867   "Close connection to server and free all resources connected to it.
 868 Return nil if the server couldn't be closed for some reason."
 869   (let ((server (or server nnimap-current-server))
 870         (imap-logout-timeout nnimap-logout-timeout))
 871     (when (or (nnimap-server-opened server)
 872               (imap-opened (nnimap-get-server-buffer server)))
 873       (imap-close (nnimap-get-server-buffer server))
 874       (kill-buffer (nnimap-get-server-buffer server))
 875       (setq nnimap-server-buffer nil
 876             nnimap-current-server nil
 877             nnimap-server-buffer-alist
 878             (nnimap-remove-server-from-buffer-alist
 879              server
 880              nnimap-server-buffer-alist)))
 881     (nnoo-close-server 'nnimap server)))
 882
 883 (deffoo nnimap-request-close ()
 884   "Close connection to all servers and free all resources that the backend have reserved.
 885 All buffers that have been created by that
 886 backend should be killed.  (Not the nntp-server-buffer, though.) This
 887 function is generally only called when Gnus is shutting down."
 888   (mapc (lambda (server) (nnimap-close-server (car server)))
 889         nnimap-server-buffer-alist)
 890   (setq nnimap-server-buffer-alist nil))
 891
 892 (deffoo nnimap-status-message (&optional server)
 893   "This function returns the last error message from server."
 894   (when (nnimap-possibly-change-server server)
 895     (nnoo-status-message 'nnimap server)))
 896
 897 (defun nnimap-demule (string)
 898   ;; BEWARE: we used to use string-as-multibyte here which is braindead
 899   ;; because it will turn accidental emacs-mule-valid byte sequences
 900   ;; into multibyte chars.  --Stef
 901   ;; Reverted, braindead got 7.5 out of 10 on imdb, so it can't be
 902   ;; that bad. --Simon
 903   (funcall (if (and (fboundp 'string-as-multibyte)
 904                     (subrp (symbol-function 'string-as-multibyte)))
 905                'string-as-multibyte
 906              'identity)
 907            (or string "")))
 908
 909 (defun nnimap-make-callback (article gnus-callback buffer)
 910   "Return a callback function."
 911   `(lambda ()
 912      (nnimap-callback ,article ,gnus-callback ,buffer)))
 913
 914 (defun nnimap-callback (article gnus-callback buffer)
 915   (when (eq article (imap-current-message))
 916     (remove-hook 'imap-fetch-data-hook
 917                  (nnimap-make-callback article gnus-callback buffer))
 918     (with-current-buffer buffer
 919       (insert
 920        (with-current-buffer nnimap-server-buffer
 921          (nnimap-demule
 922           (if (imap-capability 'IMAP4rev1)
 923               ;; xxx don't just use car? alist doesn't contain
 924               ;; anything else now, but it might...
 925               (nth 2 (car (imap-message-get article 'BODYDETAIL)))
 926             (imap-message-get article 'RFC822)))))
 927       (nnheader-ms-strip-cr)
 928       (funcall gnus-callback t))))
 929
 930 (defun nnimap-request-article-part (article part prop &optional
 931                                             group server to-buffer detail)
 932   (when (nnimap-possibly-change-group group server)
 933     (let ((article (if (stringp article)
 934                        (car-safe (imap-search
 935                                   (format "HEADER Message-Id \"%s\"" article)
 936                                   nnimap-server-buffer))
 937                      article)))
 938       (when article
 939         (gnus-message 10 "nnimap: Fetching (part of) article %d from %s..."
 940                       article (or group imap-current-mailbox
 941                                   gnus-newsgroup-name))
 942         (if (not nnheader-callback-function)
 943             (with-current-buffer (or to-buffer nntp-server-buffer)
 944               (erase-buffer)
 945               (let ((data (imap-fetch article part prop nil
 946                                       nnimap-server-buffer)))
 947                 (insert (nnimap-demule (if detail
 948                                            (nth 2 (car data))
 949                                          data))))
 950               (nnheader-ms-strip-cr)
 951               (gnus-message
 952                10 "nnimap: Fetching (part of) article %d from %s...done"
 953                article (or group imap-current-mailbox gnus-newsgroup-name))
 954               (if (bobp)
 955                   (nnheader-report 'nnimap "No such article %d in %s: %s"
 956                                    article (or group imap-current-mailbox
 957                                                gnus-newsgroup-name)
 958                                    (imap-error-text nnimap-server-buffer))
 959                 (cons group article)))
 960           (add-hook 'imap-fetch-data-hook
 961                     (nnimap-make-callback article
 962                                           nnheader-callback-function
 963                                           nntp-server-buffer))
 964           (imap-fetch-asynch article part nil nnimap-server-buffer)
 965           (cons group article))))))
 966
 967 (deffoo nnimap-asynchronous-p ()
 968   t)
 969
 970 (deffoo nnimap-request-article (article &optional group server to-buffer)
 971   (if (imap-capability 'IMAP4rev1 nnimap-server-buffer)
 972       (nnimap-request-article-part
 973        article "BODY.PEEK[]" 'BODYDETAIL group server to-buffer 'detail)
 974     (nnimap-request-article-part
 975      article "RFC822.PEEK" 'RFC822 group server to-buffer)))
 976
 977 (deffoo nnimap-request-head (article &optional group server to-buffer)
 978   (if (imap-capability 'IMAP4rev1 nnimap-server-buffer)
 979       (nnimap-request-article-part
 980        article "BODY.PEEK[HEADER]" 'BODYDETAIL group server to-buffer 'detail)
 981     (nnimap-request-article-part
 982      article "RFC822.HEADER" 'RFC822.HEADER group server to-buffer)))
 983
 984 (deffoo nnimap-request-body (article &optional group server to-buffer)
 985   (if (imap-capability 'IMAP4rev1 nnimap-server-buffer)
 986       (nnimap-request-article-part
 987        article "BODY.PEEK[TEXT]" 'BODYDETAIL group server to-buffer 'detail)
 988     (nnimap-request-article-part
 989      article "RFC822.TEXT.PEEK" 'RFC822.TEXT group server to-buffer)))
 990
 991 (deffoo nnimap-request-group (group &optional server fast)
 992   (nnimap-request-update-info-internal
 993    group
 994    (gnus-get-info (gnus-group-prefixed-name
 995                    group (gnus-server-to-method (format "nnimap:%s" server))))
 996    server)
 997   (when (nnimap-possibly-change-group group server)
 998     (nnimap-before-find-minmax-bugworkaround)
 999     (let (info)
1000       (cond (fast group)
1001             ((null (setq info (nnimap-find-minmax-uid group t)))
1002              (nnheader-report 'nnimap "Could not get active info for %s"
1003                               group))
1004             (t
1005              (nnheader-insert "211 %d %d %d %s\n" (or (nth 0 info) 0)
1006                               (max 1 (or (nth 1 info) 1))
1007                               (or (nth 2 info) 0) group)
1008              (nnheader-report 'nnimap "Group %s selected" group)
1009              t)))))
1010
1011 (defun nnimap-update-unseen (group &optional server)
1012   "Update the unseen count in `nnimap-mailbox-info'."
1013   (gnus-sethash
1014    (gnus-group-prefixed-name group server)
1015    (let ((old (gnus-gethash-safe (gnus-group-prefixed-name group server)
1016                                  nnimap-mailbox-info)))
1017      (list (nth 0 old) (nth 1 old)
1018            (imap-mailbox-status group 'unseen nnimap-server-buffer)
1019            (nth 3 old)))
1020    nnimap-mailbox-info))
1021
1022 (defun nnimap-close-group (group &optional server)
1023   (with-current-buffer nnimap-server-buffer
1024     (when (and (imap-opened)
1025                (nnimap-possibly-change-group group server))
1026       (nnimap-update-unseen group server)
1027       (case nnimap-expunge-on-close
1028         (always (progn
1029                   (imap-mailbox-expunge nnimap-close-asynchronous)
1030                   (unless nnimap-dont-close
1031                     (imap-mailbox-close nnimap-close-asynchronous))))
1032         (ask (if (and (imap-search "DELETED")
1033                       (gnus-y-or-n-p (format "Expunge articles in group `%s'? "
1034                                              imap-current-mailbox)))
1035                  (progn
1036                    (imap-mailbox-expunge nnimap-close-asynchronous)
1037                    (unless nnimap-dont-close
1038                      (imap-mailbox-close nnimap-close-asynchronous)))
1039                (imap-mailbox-unselect)))
1040         (t (imap-mailbox-unselect)))
1041       (not imap-current-mailbox))))
1042
1043 (defun nnimap-pattern-to-list-arguments (pattern)
1044   (mapcar (lambda (p)
1045             (cons (car-safe p) (or (cdr-safe p) p)))
1046           (if (and (listp pattern)
1047                    (listp (cdr pattern)))
1048               pattern
1049             (list pattern))))
1050
1051 (deffoo nnimap-request-list (&optional server)
1052   (when (nnimap-possibly-change-server server)
1053     (with-current-buffer nntp-server-buffer
1054       (erase-buffer))
1055     (gnus-message 5 "nnimap: Generating active list%s..."
1056                   (if (> (length server) 0) (concat " for " server) ""))
1057     (nnimap-before-find-minmax-bugworkaround)
1058     (with-current-buffer nnimap-server-buffer
1059       (dolist (pattern (nnimap-pattern-to-list-arguments nnimap-list-pattern))
1060         (dolist (mbx (funcall nnimap-request-list-method
1061                               (cdr pattern) (car pattern)))
1062           (or (member "\\NoSelect" (imap-mailbox-get 'list-flags mbx))
1063               (let ((info (nnimap-find-minmax-uid mbx 'examine)))
1064                 (when info
1065                   (with-current-buffer nntp-server-buffer
1066                     (insert (format "\"%s\" %d %d y\n"
1067                                     mbx (or (nth 2 info) 0)
1068                                     (max 1 (or (nth 1 info) 1)))))))))))
1069     (gnus-message 5 "nnimap: Generating active list%s...done"
1070                   (if (> (length server) 0) (concat " for " server) ""))
1071     t))
1072
1073 (deffoo nnimap-request-post (&optional server)
1074   (let ((success t))
1075     (dolist (mbx (message-unquote-tokens
1076                   (message-tokenize-header
1077                    (message-fetch-field "Newsgroups") ", ")) success)
1078       (let ((to-newsgroup (gnus-group-prefixed-name mbx gnus-command-method)))
1079         (or (gnus-active to-newsgroup)
1080             (gnus-activate-group to-newsgroup)
1081             (if (gnus-y-or-n-p (format "No such group: %s.  Create it? "
1082                                        to-newsgroup))
1083                 (or (and (gnus-request-create-group
1084                           to-newsgroup gnus-command-method)
1085                          (gnus-activate-group to-newsgroup nil nil
1086                                               gnus-command-method))
1087                     (error "Couldn't create group %s" to-newsgroup)))
1088             (error "No such group: %s" to-newsgroup))
1089         (unless (nnimap-request-accept-article mbx (nth 1 gnus-command-method))
1090           (setq success nil))))))
1091
1092 ;; Optional backend functions
1093
1094 (defun nnimap-string-lessp-numerical (s1 s2)
1095   "Return t if first arg string is less than second in numerical order."
1096   (cond ((string= s1 s2)
1097          nil)
1098         ((> (length s1) (length s2))
1099          nil)
1100         ((< (length s1) (length s2))
1101          t)
1102         ((< (string-to-number (substring s1 0 1))
1103             (string-to-number (substring s2 0 1)))
1104          t)
1105         ((> (string-to-number (substring s1 0 1))
1106             (string-to-number (substring s2 0 1)))
1107          nil)
1108         (t
1109          (nnimap-string-lessp-numerical (substring s1 1) (substring s2 1)))))
1110
1111 (deffoo nnimap-retrieve-groups (groups &optional server)
1112   (when (nnimap-possibly-change-server server)
1113     (gnus-message 5 "nnimap: Checking mailboxes...")
1114     (with-current-buffer nntp-server-buffer
1115       (erase-buffer)
1116       (nnimap-before-find-minmax-bugworkaround)
1117       (let (asyncgroups slowgroups)
1118         (if (null nnimap-retrieve-groups-asynchronous)
1119             (setq slowgroups groups)
1120           (dolist (group groups)
1121             (gnus-message 9 "nnimap: Quickly checking mailbox %s" group)
1122             (add-to-list (if (gnus-gethash-safe
1123                               (gnus-group-prefixed-name group server)
1124                               nnimap-mailbox-info)
1125                              'asyncgroups
1126                            'slowgroups)
1127                          (list group (imap-mailbox-status-asynch
1128                                       group '(uidvalidity uidnext unseen)
1129                                       nnimap-server-buffer))))
1130           (dolist (asyncgroup asyncgroups)
1131             (let ((group (nth 0 asyncgroup))
1132                   (tag   (nth 1 asyncgroup))
1133                   new old)
1134               (when (imap-ok-p (imap-wait-for-tag tag nnimap-server-buffer))
1135                 (if (or (not (string=
1136                               (nth 0 (gnus-gethash (gnus-group-prefixed-name
1137                                                     group server)
1138                                                    nnimap-mailbox-info))
1139                               (imap-mailbox-get 'uidvalidity group
1140                                                 nnimap-server-buffer)))
1141                         (not (string=
1142                               (nth 1 (gnus-gethash (gnus-group-prefixed-name
1143                                                     group server)
1144                                                    nnimap-mailbox-info))
1145                               (imap-mailbox-get 'uidnext group
1146                                                 nnimap-server-buffer))))
1147                     (push (list group) slowgroups)
1148                   (insert (nth 3 (gnus-gethash (gnus-group-prefixed-name
1149                                                 group server)
1150                                                nnimap-mailbox-info))))))))
1151         (dolist (group slowgroups)
1152           (if nnimap-retrieve-groups-asynchronous
1153               (setq group (car group)))
1154           (gnus-message 7 "nnimap: Mailbox %s modified" group)
1155           (imap-mailbox-put 'uidnext nil group nnimap-server-buffer)
1156           (or (member "\\NoSelect" (imap-mailbox-get 'list-flags group
1157                                                      nnimap-server-buffer))
1158               (let* ((info (nnimap-find-minmax-uid group 'examine))
1159                      (str (format "\"%s\" %d %d y\n" group
1160                                   (or (nth 2 info) 0)
1161                                   (max 1 (or (nth 1 info) 1)))))
1162                 (when (> (or (imap-mailbox-get 'recent group
1163                                                nnimap-server-buffer) 0)
1164                          0)
1165                   (push (list (cons group 0)) nnmail-split-history))
1166                 (insert str)
1167                 (when nnimap-retrieve-groups-asynchronous
1168                   (gnus-sethash
1169                    (gnus-group-prefixed-name group server)
1170                    (list (or (imap-mailbox-get
1171                               'uidvalidity group nnimap-server-buffer)
1172                              (imap-mailbox-status
1173                               group 'uidvalidity nnimap-server-buffer))
1174                          (or (imap-mailbox-get
1175                               'uidnext group nnimap-server-buffer)
1176                              (imap-mailbox-status
1177                               group 'uidnext nnimap-server-buffer))
1178                          (or (imap-mailbox-get
1179                               'unseen group nnimap-server-buffer)
1180                              (imap-mailbox-status
1181                               group 'unseen nnimap-server-buffer))
1182                          str)
1183                    nnimap-mailbox-info)))))))
1184     (gnus-message 5 "nnimap: Checking mailboxes...done")
1185     'active))
1186
1187 (deffoo nnimap-request-update-info-internal (group info &optional server)
1188   (when (nnimap-possibly-change-group group server)
1189     (when info ;; xxx what does this mean? should we create a info?
1190       (with-current-buffer nnimap-server-buffer
1191         (gnus-message 5 "nnimap: Updating info for %s..."
1192                       (gnus-info-group info))
1193
1194         (when (nnimap-mark-permanent-p 'read)
1195           (let (seen unseen)
1196             ;; read info could contain articles marked unread by other
1197             ;; imap clients!  we correct this
1198             (setq unseen (gnus-compress-sequence
1199                           (imap-search "UNSEEN UNDELETED"))
1200                   seen (gnus-range-difference (gnus-info-read info) unseen)
1201                   seen (gnus-range-add seen
1202                                        (gnus-compress-sequence
1203                                         (imap-search "SEEN")))
1204                   seen (if (and (integerp (car seen))
1205                                 (null (cdr seen)))
1206                            (list (cons (car seen) (car seen)))
1207                          seen))
1208             (gnus-info-set-read info seen)))
1209
1210         (dolist (pred gnus-article-mark-lists)
1211           (when (or (eq (cdr pred) 'recent)
1212                     (and (nnimap-mark-permanent-p (cdr pred))
1213                          (member (nnimap-mark-to-flag (cdr pred))
1214                                  (imap-mailbox-get 'flags))))
1215             (gnus-info-set-marks
1216              info
1217              (gnus-update-alist-soft
1218               (cdr pred)
1219               (gnus-compress-sequence
1220                (imap-search (nnimap-mark-to-predicate (cdr pred))))
1221               (gnus-info-marks info))
1222              t)))
1223
1224         (when nnimap-importantize-dormant
1225           ;; nnimap mark dormant article as ticked too (for other clients)
1226           ;; so we remove that mark for gnus since we support dormant
1227           (gnus-info-set-marks
1228            info
1229            (gnus-update-alist-soft
1230             'tick
1231             (gnus-remove-from-range
1232              (cdr-safe (assoc 'tick (gnus-info-marks info)))
1233              (cdr-safe (assoc 'dormant (gnus-info-marks info))))
1234             (gnus-info-marks info))
1235            t))
1236
1237         (gnus-message 5 "nnimap: Updating info for %s...done"
1238                       (gnus-info-group info))
1239
1240         info))))
1241
1242 (deffoo nnimap-request-type (group &optional article)
1243   (if (and nnimap-news-groups (string-match nnimap-news-groups group))
1244       'news
1245     'mail))
1246
1247 (deffoo nnimap-request-set-mark (group actions &optional server)
1248   (when (nnimap-possibly-change-group group server)
1249     (with-current-buffer nnimap-server-buffer
1250       (let (action)
1251         (gnus-message 7 "nnimap: Setting marks in %s..." group)
1252         (while (setq action (pop actions))
1253           (let ((range (nth 0 action))
1254                 (what  (nth 1 action))
1255                 (cmdmarks (nth 2 action))
1256                 marks)
1257             ;; bookmark can't be stored (not list/range
1258             (setq cmdmarks (delq 'bookmark cmdmarks))
1259             ;; killed can't be stored (not list/range
1260             (setq cmdmarks (delq 'killed cmdmarks))
1261             ;; unsent are for nndraft groups only
1262             (setq cmdmarks (delq 'unsent cmdmarks))
1263             ;; cache flags are pointless on the server
1264             (setq cmdmarks (delq 'cache cmdmarks))
1265             ;; seen flags are local to each gnus
1266             (setq cmdmarks (delq 'seen cmdmarks))
1267             ;; recent marks can't be set
1268             (setq cmdmarks (delq 'recent cmdmarks))
1269             (when nnimap-importantize-dormant
1270               ;; flag dormant articles as ticked
1271               (if (memq 'dormant cmdmarks)
1272                   (setq cmdmarks (cons 'tick cmdmarks))))
1273             ;; remove stuff we are forbidden to store
1274             (mapc (lambda (mark)
1275                     (if (imap-message-flag-permanent-p
1276                          (nnimap-mark-to-flag mark))
1277                         (setq marks (cons mark marks))))
1278                   cmdmarks)
1279             (when (and range marks)
1280               (cond ((eq what 'del)
1281                      (imap-message-flags-del
1282                       (imap-range-to-message-set range)
1283                       (nnimap-mark-to-flag marks nil t)))
1284                     ((eq what 'add)
1285                      (imap-message-flags-add
1286                       (imap-range-to-message-set range)
1287                       (nnimap-mark-to-flag marks nil t)))
1288                     ((eq what 'set)
1289                      (imap-message-flags-set
1290                       (imap-range-to-message-set range)
1291                       (nnimap-mark-to-flag marks nil t)))))))
1292         (gnus-message 7 "nnimap: Setting marks in %s...done" group))))
1293   nil)
1294
1295 (defun nnimap-split-fancy ()
1296   "Like the function `nnmail-split-fancy', but uses `nnimap-split-fancy'."
1297   (let ((nnmail-split-fancy nnimap-split-fancy))
1298     (nnmail-split-fancy)))
1299
1300 (defun nnimap-split-to-groups (rules)
1301   ;; tries to match all rules in nnimap-split-rule against content of
1302   ;; nntp-server-buffer, returns a list of groups that matched.
1303   (with-current-buffer nntp-server-buffer
1304     ;; Fold continuation lines.
1305     (goto-char (point-min))
1306     (while (re-search-forward "\\(\r?\n[ \t]+\\)+" nil t)
1307       (replace-match " " t t))
1308     (if (functionp rules)
1309         (funcall rules)
1310       (let (to-groups regrepp)
1311         (catch 'split-done
1312           (dolist (rule rules to-groups)
1313             (let ((group (car rule))
1314                   (regexp (cadr rule)))
1315               (goto-char (point-min))
1316               (when (and (if (stringp regexp)
1317                              (progn
1318                                (if (not (stringp group))
1319                                    (setq group (eval group))
1320                                  (setq regrepp
1321                                        (string-match "\\\\[0-9&]" group)))
1322                                (re-search-forward regexp nil t))
1323                            (funcall regexp group))
1324                          ;; Don't enter the article into the same group twice.
1325                          (not (assoc group to-groups)))
1326                 (push (if regrepp
1327                           (nnmail-expand-newtext group)
1328                         group)
1329                       to-groups)
1330                 (or nnimap-split-crosspost
1331                     (throw 'split-done to-groups))))))))))
1332
1333 (defun nnimap-assoc-match (key alist)
1334   (let (element)
1335     (while (and alist (not element))
1336       (if (string-match (car (car alist)) key)
1337           (setq element (car alist)))
1338       (setq alist (cdr alist)))
1339     element))
1340
1341 (defun nnimap-split-find-rule (server inbox)
1342   (if (and (listp nnimap-split-rule) (listp (car nnimap-split-rule))
1343            (list (cdar nnimap-split-rule)) (listp (cadar nnimap-split-rule)))
1344       ;; extended format
1345       (cadr (nnimap-assoc-match inbox (cdr (nnimap-assoc-match
1346                                             server nnimap-split-rule))))
1347     nnimap-split-rule))
1348
1349 (defun nnimap-split-find-inbox (server)
1350   (if (listp nnimap-split-inbox)
1351       nnimap-split-inbox
1352     (list nnimap-split-inbox)))
1353
1354 (defun nnimap-split-articles (&optional group server)
1355   (when (nnimap-possibly-change-server server)
1356     (with-current-buffer nnimap-server-buffer
1357       (let (rule inbox removeorig (inboxes (nnimap-split-find-inbox server)))
1358         ;; iterate over inboxes
1359         (while (and (setq inbox (pop inboxes))
1360                     (nnimap-possibly-change-group inbox)) ;; SELECT
1361           ;; find split rule for this server / inbox
1362           (when (setq rule (nnimap-split-find-rule server inbox))
1363             ;; iterate over articles
1364             (dolist (article (imap-search nnimap-split-predicate))
1365               (when (if (if (eq nnimap-split-download-body 'default)
1366                             nnimap-split-download-body-default
1367                           nnimap-split-download-body)
1368                         (and (nnimap-request-article article)
1369                              (with-current-buffer nntp-server-buffer (mail-narrow-to-head)))
1370                       (nnimap-request-head article))
1371                 ;; copy article to right group(s)
1372                 (setq removeorig nil)
1373                 (dolist (to-group (nnimap-split-to-groups rule))
1374                   (cond ((eq to-group 'junk)
1375                          (message "IMAP split removed %s:%s:%d" server inbox
1376                                   article)
1377                          (setq removeorig t))
1378                         ((imap-message-copy (number-to-string article)
1379                                             to-group nil 'nocopyuid)
1380                          (message "IMAP split moved %s:%s:%d to %s" server
1381                                   inbox article to-group)
1382                          (setq removeorig t)
1383                          (when nnmail-cache-accepted-message-ids
1384                            (with-current-buffer nntp-server-buffer
1385                              (let (msgid)
1386                                (and (setq msgid
1387                                           (nnmail-fetch-field "message-id"))
1388                                     (nnmail-cache-insert msgid
1389                                                          to-group
1390                                                          (nnmail-fetch-field "subject"))))))
1391                          ;; Add the group-art list to the history list.
1392                          (push (list (cons to-group 0)) nnmail-split-history))
1393                         (t
1394                          (message "IMAP split failed to move %s:%s:%d to %s"
1395                                   server inbox article to-group))))
1396                 (if (if (eq nnimap-split-download-body 'default)
1397                         nnimap-split-download-body-default
1398                       nnimap-split-download-body)
1399                     (widen))
1400                 ;; remove article if it was successfully copied somewhere
1401                 (and removeorig
1402                      (imap-message-flags-add (format "%d" article)
1403                                              "\\Seen \\Deleted")))))
1404           (when (imap-mailbox-select inbox) ;; just in case
1405             ;; todo: UID EXPUNGE (if available) to remove splitted articles
1406             (imap-mailbox-expunge)
1407             (imap-mailbox-close)))
1408         (when nnmail-cache-accepted-message-ids
1409           (nnmail-cache-close))
1410         t))))
1411
1412 (deffoo nnimap-request-scan (&optional group server)
1413   (nnimap-split-articles group server))
1414
1415 (deffoo nnimap-request-newgroups (date &optional server)
1416   (when (nnimap-possibly-change-server server)
1417     (with-current-buffer nntp-server-buffer
1418       (gnus-message 5 "nnimap: Listing subscribed mailboxes%s%s..."
1419                     (if (> (length server) 0) " on " "") server)
1420       (erase-buffer)
1421       (nnimap-before-find-minmax-bugworkaround)
1422       (dolist (pattern (nnimap-pattern-to-list-arguments
1423                         nnimap-list-pattern))
1424         (dolist (mbx (imap-mailbox-lsub (cdr pattern) (car pattern) nil
1425                                         nnimap-server-buffer))
1426           (or (catch 'found
1427                 (dolist (mailbox (imap-mailbox-get 'list-flags mbx
1428                                                    nnimap-server-buffer))
1429                   (if (string= (downcase mailbox) "\\noselect")
1430                       (throw 'found t)))
1431                 nil)
1432               (let ((info (nnimap-find-minmax-uid mbx 'examine)))
1433                 (when info
1434                   (insert (format "\"%s\" %d %d y\n"
1435                                   mbx (or (nth 2 info) 0)
1436                                   (max 1 (or (nth 1 info) 1)))))))))
1437       (gnus-message 5 "nnimap: Listing subscribed mailboxes%s%s...done"
1438                     (if (> (length server) 0) " on " "") server))
1439     t))
1440
1441 (deffoo nnimap-request-create-group (group &optional server args)
1442   (when (nnimap-possibly-change-server server)
1443     (or (imap-mailbox-status group 'uidvalidity nnimap-server-buffer)
1444         (imap-mailbox-create group nnimap-server-buffer)
1445         (nnheader-report 'nnimap "%S"
1446                          (imap-error-text nnimap-server-buffer)))))
1447
1448 (defun nnimap-time-substract (time1 time2)
1449   "Return TIME for TIME1 - TIME2."
1450   (let* ((ms (- (car time1) (car time2)))
1451          (ls (- (nth 1 time1) (nth 1 time2))))
1452     (if (< ls 0)
1453         (list (- ms 1) (+ (expt 2 16) ls))
1454       (list ms ls))))
1455
1456 (eval-when-compile (require 'parse-time))
1457 (defun nnimap-date-days-ago (daysago)
1458   "Return date, in format \"3-Aug-1998\", for DAYSAGO days ago."
1459   (require 'parse-time)
1460   (let* ((time (nnimap-time-substract (current-time) (days-to-time daysago)))
1461          (date (format-time-string
1462                 (format "%%d-%s-%%Y"
1463                         (capitalize (car (rassoc (nth 4 (decode-time time))
1464                                                  parse-time-months))))
1465                 time)))
1466     (if (eq ?0 (string-to-char date))
1467         (substring date 1)
1468       date)))
1469
1470 (defun nnimap-request-expire-articles-progress ()
1471   (gnus-message 5 "nnimap: Marking article %d for deletion..."
1472                 imap-current-message))
1473
1474 (defun nnimap-expiry-target (arts group server)
1475   (unless (eq nnmail-expiry-target 'delete)
1476     (with-temp-buffer
1477       (dolist (art arts)
1478         (nnimap-request-article art group server (current-buffer))
1479         ;; hints for optimization in `nnimap-request-accept-article'
1480         (let ((nnimap-current-move-article art)
1481               (nnimap-current-move-group group)
1482               (nnimap-current-move-server server))
1483           (nnmail-expiry-target-group nnmail-expiry-target group))))
1484     ;; It is not clear if `nnmail-expiry-target' somehow cause the
1485     ;; current group to be changed or not, so we make sure here.
1486     (nnimap-possibly-change-group group server)))
1487
1488 ;; Notice that we don't actually delete anything, we just mark them deleted.
1489 (deffoo nnimap-request-expire-articles (articles group &optional server force)
1490   (let ((artseq (gnus-compress-sequence articles)))
1491     (when (and artseq (nnimap-possibly-change-group group server))
1492       (with-current-buffer nnimap-server-buffer
1493         (let ((days (or (and nnmail-expiry-wait-function
1494                              (funcall nnmail-expiry-wait-function group))
1495                         nnmail-expiry-wait)))
1496           (cond ((or force (eq days 'immediate))
1497                  (let ((oldarts (imap-search
1498                                  (concat "UID "
1499                                          (imap-range-to-message-set artseq)))))
1500                    (when oldarts
1501                      (nnimap-expiry-target oldarts group server)
1502                      (when (imap-message-flags-add
1503                             (imap-range-to-message-set
1504                              (gnus-compress-sequence oldarts)) "\\Deleted")
1505                        (setq articles (gnus-set-difference
1506                                        articles oldarts))))))
1507                 ((and nnimap-search-uids-not-since-is-evil (numberp days))
1508                  (let* ((all-new-articles
1509                          (gnus-compress-sequence
1510                           (imap-search (format "SINCE %s"
1511                                                (nnimap-date-days-ago days)))))
1512                         (oldartseq
1513                          (gnus-range-difference artseq all-new-articles))
1514                         (oldarts (gnus-uncompress-range oldartseq)))
1515                    (when oldarts
1516                      (nnimap-expiry-target oldarts group server)
1517                      (when (imap-message-flags-add
1518                             (imap-range-to-message-set oldartseq)
1519                             "\\Deleted")
1520                        (setq articles (gnus-set-difference
1521                                        articles oldarts))))))
1522                 ((numberp days)
1523                  (let ((oldarts (imap-search
1524                                  (format nnimap-expunge-search-string
1525                                          (imap-range-to-message-set artseq)
1526                                          (nnimap-date-days-ago days))))
1527                        (imap-fetch-data-hook
1528                         '(nnimap-request-expire-articles-progress)))
1529                    (when oldarts
1530                      (nnimap-expiry-target oldarts group server)
1531                      (when (imap-message-flags-add
1532                             (imap-range-to-message-set
1533                              (gnus-compress-sequence oldarts)) "\\Deleted")
1534                        (setq articles (gnus-set-difference
1535                                        articles oldarts)))))))))))
1536   ;; return articles not deleted
1537   articles)
1538
1539 (deffoo nnimap-request-move-article (article group server accept-form
1540                                              &optional last move-is-internal)
1541   (when (nnimap-possibly-change-server server)
1542     (save-excursion
1543       (let ((buf (get-buffer-create " *nnimap move*"))
1544             (nnimap-current-move-article article)
1545             (nnimap-current-move-group group)
1546             (nnimap-current-move-server nnimap-current-server)
1547             result)
1548         (gnus-message 10 "nnimap-request-move-article: this is an %s move"
1549                       (if move-is-internal
1550                           "internal"
1551                         "external"))
1552         ;; request the article only when the move is NOT internal
1553         (and (or move-is-internal
1554                  (nnimap-request-article article group server))
1555              (save-excursion
1556                (set-buffer buf)
1557                (buffer-disable-undo (current-buffer))
1558                (insert-buffer-substring nntp-server-buffer)
1559                (setq result (eval accept-form))
1560                (kill-buffer buf)
1561                result)
1562              (nnimap-possibly-change-group group server)
1563              (imap-message-flags-add
1564               (imap-range-to-message-set (list article))
1565               "\\Deleted" 'silent nnimap-server-buffer))
1566         result))))
1567
1568 (deffoo nnimap-request-accept-article (group &optional server last)
1569   (when (nnimap-possibly-change-server server)
1570     (let (uid)
1571       (if (setq uid
1572                 (if (string= nnimap-current-server nnimap-current-move-server)
1573                     ;; moving article within same server, speed it up...
1574                     (and (nnimap-possibly-change-group
1575                           nnimap-current-move-group)
1576                          (imap-message-copy (number-to-string
1577                                              nnimap-current-move-article)
1578                                             group 'dontcreate nil
1579                                             nnimap-server-buffer))
1580                   (with-current-buffer (current-buffer)
1581                     (goto-char (point-min))
1582                     ;; remove any 'From blabla' lines, some IMAP servers
1583                     ;; reject the entire message otherwise.
1584                     (when (looking-at "^From[^:]")
1585                       (delete-region (point) (progn (forward-line) (point))))
1586                     ;; turn into rfc822 format (\r\n eol's)
1587                     (while (search-forward "\n" nil t)
1588                       (replace-match "\r\n"))
1589                     (when nnmail-cache-accepted-message-ids
1590                       (nnmail-cache-insert (nnmail-fetch-field "message-id")
1591                                            group
1592                                            (nnmail-fetch-field "subject"))))
1593                   (when (and last nnmail-cache-accepted-message-ids)
1594                     (nnmail-cache-close))
1595                   ;; this 'or' is for Cyrus server bug
1596                   (or (null (imap-current-mailbox nnimap-server-buffer))
1597                       (imap-mailbox-unselect nnimap-server-buffer))
1598                   (imap-message-append group (current-buffer) nil nil
1599                                        nnimap-server-buffer)))
1600           (cons group (nth 1 uid))
1601         (nnheader-report 'nnimap (imap-error-text nnimap-server-buffer))))))
1602
1603 (deffoo nnimap-request-delete-group (group force &optional server)
1604   (when (nnimap-possibly-change-server server)
1605     (with-current-buffer nnimap-server-buffer
1606       (if force
1607           (or (null (imap-mailbox-status group 'uidvalidity))
1608               (imap-mailbox-delete group))
1609         ;; UNSUBSCRIBE?
1610         t))))
1611
1612 (deffoo nnimap-request-rename-group (group new-name &optional server)
1613   (when (nnimap-possibly-change-server server)
1614     (imap-mailbox-rename group new-name nnimap-server-buffer)))
1615
1616 (defun nnimap-expunge (mailbox server)
1617   (when (nnimap-possibly-change-group mailbox server)
1618     (imap-mailbox-expunge nil nnimap-server-buffer)))
1619
1620 (defun nnimap-acl-get (mailbox server)
1621   (when (nnimap-possibly-change-server server)
1622     (and (imap-capability 'ACL nnimap-server-buffer)
1623          (imap-mailbox-acl-get mailbox nnimap-server-buffer))))
1624
1625 (defun nnimap-acl-edit (mailbox method old-acls new-acls)
1626   (when (nnimap-possibly-change-server (cadr method))
1627     (unless (imap-capability 'ACL nnimap-server-buffer)
1628       (error "Your server does not support ACL editing"))
1629     (with-current-buffer nnimap-server-buffer
1630       ;; delete all removed identifiers
1631       (mapc (lambda (old-acl)
1632               (unless (assoc (car old-acl) new-acls)
1633                 (or (imap-mailbox-acl-delete (car old-acl) mailbox)
1634                     (error "Can't delete ACL for %s" (car old-acl)))))
1635             old-acls)
1636       ;; set all changed acl's
1637       (mapc (lambda (new-acl)
1638               (let ((new-rights (cdr new-acl))
1639                     (old-rights (cdr (assoc (car new-acl) old-acls))))
1640                 (unless (and old-rights new-rights
1641                              (string= old-rights new-rights))
1642                   (or (imap-mailbox-acl-set (car new-acl) new-rights mailbox)
1643                       (error "Can't set ACL for %s to %s" (car new-acl)
1644                              new-rights)))))
1645             new-acls)
1646       t)))
1647
1648 \f
1649 ;;; Internal functions
1650
1651 ;;
1652 ;; This is confusing.
1653 ;;
1654 ;; mark      => read, tick, draft, reply etc
1655 ;; flag      => "\\Seen", "\\Flagged", "\\Draft", "gnus-expire" etc
1656 ;; predicate => "SEEN", "FLAGGED", "DRAFT", "KEYWORD gnus-expire" etc
1657 ;;
1658 ;; Mark should not really contain 'read since it's not a "mark" in the Gnus
1659 ;; world, but we cheat.  Mark == gnus-article-mark-lists + '(read . read).
1660 ;;
1661
1662 (defconst nnimap-mark-to-predicate-alist
1663   (mapcar
1664    (lambda (pair)                       ; cdr is the mark
1665      (or (assoc (cdr pair)
1666                 '((read . "SEEN")
1667                   (tick . "FLAGGED")
1668                   (draft . "DRAFT")
1669                   (recent . "RECENT")
1670                   (reply . "ANSWERED")))
1671          (cons (cdr pair)
1672                (format "KEYWORD gnus-%s" (symbol-name (cdr pair))))))
1673    (cons '(read . read) gnus-article-mark-lists)))
1674
1675 (defun nnimap-mark-to-predicate (pred)
1676   "Convert a Gnus mark (a symbol such as read, tick, expire) to a IMAP predicate.
1677 This is a string such as \"SEEN\", \"FLAGGED\", \"KEYWORD gnus-expire\",
1678 to be used within a IMAP SEARCH query."
1679   (cdr (assq pred nnimap-mark-to-predicate-alist)))
1680
1681 (defconst nnimap-mark-to-flag-alist
1682   (mapcar
1683    (lambda (pair)
1684      (or (assoc (cdr pair)
1685                 '((read . "\\Seen")
1686                   (tick . "\\Flagged")
1687                   (draft . "\\Draft")
1688                   (recent . "\\Recent")
1689                   (reply . "\\Answered")))
1690          (cons (cdr pair)
1691                (format "gnus-%s" (symbol-name (cdr pair))))))
1692    (cons '(read . read) gnus-article-mark-lists)))
1693
1694 (defun nnimap-mark-to-flag-1 (preds)
1695   (if (and (not (null preds)) (listp preds))
1696       (cons (nnimap-mark-to-flag (car preds))
1697             (nnimap-mark-to-flag (cdr preds)))
1698     (cdr (assoc preds nnimap-mark-to-flag-alist))))
1699
1700 (defun nnimap-mark-to-flag (preds &optional always-list make-string)
1701   "Convert a Gnus mark (a symbol such as read, tick, expire) to a IMAP flag.
1702 This is a string such as \"\\Seen\", \"\\Flagged\", \"gnus-expire\", to
1703 be used in a STORE FLAGS command."
1704   (let ((result (nnimap-mark-to-flag-1 preds)))
1705     (setq result (if (and (or make-string always-list)
1706                           (not (listp result)))
1707                      (list result)
1708                    result))
1709     (if make-string
1710         (mapconcat (lambda (flag)
1711                      (if (listp flag)
1712                          (mapconcat 'identity flag " ")
1713                        flag))
1714                    result " ")
1715       result)))
1716
1717 (defun nnimap-mark-permanent-p (mark &optional group)
1718   "Return t if MARK can be permanently (between IMAP sessions) saved on articles, in GROUP."
1719   (imap-message-flag-permanent-p (nnimap-mark-to-flag mark)))
1720
1721 (when nnimap-debug
1722   (require 'trace)
1723   (buffer-disable-undo (get-buffer-create nnimap-debug-buffer))
1724   (mapc (lambda (f) (trace-function-background f nnimap-debug-buffer))
1725         '(
1726           nnimap-possibly-change-server
1727           nnimap-verify-uidvalidity
1728           nnimap-find-minmax-uid
1729           nnimap-before-find-minmax-bugworkaround
1730           nnimap-possibly-change-group
1731           ;;nnimap-replace-whitespace
1732           nnimap-retrieve-headers-progress
1733           nnimap-retrieve-which-headers
1734           nnimap-group-overview-filename
1735           nnimap-retrieve-headers-from-file
1736           nnimap-retrieve-headers-from-server
1737           nnimap-retrieve-headers
1738           nnimap-open-connection
1739           nnimap-open-server
1740           nnimap-server-opened
1741           nnimap-close-server
1742           nnimap-request-close
1743           nnimap-status-message
1744           ;;nnimap-demule
1745           nnimap-request-article-part
1746           nnimap-request-article
1747           nnimap-request-head
1748           nnimap-request-body
1749           nnimap-request-group
1750           nnimap-close-group
1751           nnimap-pattern-to-list-arguments
1752           nnimap-request-list
1753           nnimap-request-post
1754           nnimap-retrieve-groups
1755           nnimap-request-update-info-internal
1756           nnimap-request-type
1757           nnimap-request-set-mark
1758           nnimap-split-to-groups
1759           nnimap-split-find-rule
1760           nnimap-split-find-inbox
1761           nnimap-split-articles
1762           nnimap-request-scan
1763           nnimap-request-newgroups
1764           nnimap-request-create-group
1765           nnimap-time-substract
1766           nnimap-date-days-ago
1767           nnimap-request-expire-articles-progress
1768           nnimap-request-expire-articles
1769           nnimap-request-move-article
1770           nnimap-request-accept-article
1771           nnimap-request-delete-group
1772           nnimap-request-rename-group
1773           gnus-group-nnimap-expunge
1774           gnus-group-nnimap-edit-acl
1775           gnus-group-nnimap-edit-acl-done
1776           nnimap-group-mode-hook
1777           nnimap-mark-to-predicate
1778           nnimap-mark-to-flag-1
1779           nnimap-mark-to-flag
1780           nnimap-mark-permanent-p
1781           )))
1782
1783 (provide 'nnimap)
1784
1785 ;; arch-tag: 2b001f20-3ff9-4094-a0ad-46807c1ba70b
1786 ;;; nnimap.el ends here