cgit.sxemacs.org Git - gnus/blob - lisp/nnimap.el

   1 ;;; nnimap.el --- IMAP interface for Gnus
   2
   3 ;; Copyright (C) 2010 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;         Simon Josefsson <simon@josefsson.org>
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; nnimap interfaces Gnus with IMAP servers.
  26
  27 ;;; Code:
  28
  29 (eval-and-compile
  30   (require 'nnheader))
  31
  32 (eval-when-compile
  33   (require 'cl))
  34
  35 (require 'nnheader)
  36 (require 'gnus-util)
  37 (require 'gnus)
  38 (require 'nnoo)
  39 (require 'netrc)
  40 (require 'utf7)
  41 (require 'tls)
  42 (require 'parse-time)
  43
  44 (autoload 'auth-source-forget-user-or-password "auth-source")
  45 (autoload 'auth-source-user-or-password "auth-source")
  46
  47 (nnoo-declare nnimap)
  48
  49 (defvoo nnimap-address nil
  50   "The address of the IMAP server.")
  51
  52 (defvoo nnimap-server-port nil
  53   "The IMAP port used.
  54 If nnimap-stream is `ssl', this will default to `imaps'.  If not,
  55 it will default to `imap'.")
  56
  57 (defvoo nnimap-stream 'ssl
  58   "How nnimap will talk to the IMAP server.
  59 Values are `ssl', `network', `starttls' or `shell'.")
  60
  61 (defvoo nnimap-shell-program (if (boundp 'imap-shell-program)
  62                                  (if (listp imap-shell-program)
  63                                      (car imap-shell-program)
  64                                    imap-shell-program)
  65                                "ssh %s imapd"))
  66
  67 (defvoo nnimap-inbox nil
  68   "The mail box where incoming mail arrives and should be split out of.")
  69
  70 (defvoo nnimap-split-methods nil
  71   "How mail is split.
  72 Uses the same syntax as nnmail-split-methods")
  73
  74 (defvoo nnimap-split-fancy nil
  75   "Uses the same syntax as nnmail-split-fancy.")
  76
  77 (make-obsolete-variable 'nnimap-split-rule "see `nnimap-split-methods'"
  78                         "Emacs 24.1")
  79
  80 (defvoo nnimap-authenticator nil
  81   "How nnimap authenticate itself to the server.
  82 Possible choices are nil (use default methods) or `anonymous'.")
  83
  84 (defvoo nnimap-expunge t
  85   "If non-nil, expunge articles after deleting them.
  86 This is always done if the server supports UID EXPUNGE, but it's
  87 not done by default on servers that doesn't support that command.")
  88
  89 (defvoo nnimap-streaming t
  90   "If non-nil, try to use streaming commands with IMAP servers.
  91 Switching this off will make nnimap slower, but it helps with
  92 some servers.")
  93
  94 (defvoo nnimap-connection-alist nil)
  95
  96 (defvoo nnimap-current-infos nil)
  97
  98 (defvoo nnimap-fetch-partial-articles nil
  99   "If non-nil, Gnus will fetch partial articles.
 100 If t, nnimap will fetch only the first part.  If a string, it
 101 will fetch all parts that have types that match that string.  A
 102 likely value would be \"text/\" to automatically fetch all
 103 textual parts.")
 104
 105 (defvar nnimap-process nil)
 106
 107 (defvar nnimap-status-string "")
 108
 109 (defvar nnimap-split-download-body-default nil
 110   "Internal variable with default value for `nnimap-split-download-body'.")
 111
 112 (defvar nnimap-keepalive-timer nil)
 113 (defvar nnimap-process-buffers nil)
 114
 115 (defstruct nnimap
 116   group process commands capabilities select-result newlinep server
 117   last-command-time greeting)
 118
 119 (defvar nnimap-object nil)
 120
 121 (defvar nnimap-mark-alist
 122   '((read "\\Seen" %Seen)
 123     (tick "\\Flagged" %Flagged)
 124     (reply "\\Answered" %Answered)
 125     (expire "gnus-expire")
 126     (dormant "gnus-dormant")
 127     (score "gnus-score")
 128     (save "gnus-save")
 129     (download "gnus-download")
 130     (forward "gnus-forward")))
 131
 132 (defun nnimap-buffer ()
 133   (nnimap-find-process-buffer nntp-server-buffer))
 134
 135 (deffoo nnimap-retrieve-headers (articles &optional group server fetch-old)
 136   (with-current-buffer nntp-server-buffer
 137     (erase-buffer)
 138     (when (nnimap-possibly-change-group group server)
 139       (with-current-buffer (nnimap-buffer)
 140         (erase-buffer)
 141         (nnimap-wait-for-response
 142          (nnimap-send-command
 143           "UID FETCH %s %s"
 144           (nnimap-article-ranges (gnus-compress-sequence articles))
 145           (format "(UID RFC822.SIZE BODYSTRUCTURE %s)"
 146                   (format
 147                    (if (nnimap-ver4-p)
 148                        "BODY.PEEK[HEADER.FIELDS %s]"
 149                      "RFC822.HEADER.LINES %s")
 150                    (append '(Subject From Date Message-Id
 151                                      References In-Reply-To Xref)
 152                            nnmail-extra-headers))))
 153          t)
 154         (nnimap-transform-headers))
 155       (insert-buffer-substring
 156        (nnimap-find-process-buffer (current-buffer))))
 157     'headers))
 158
 159 (defun nnimap-transform-headers ()
 160   (goto-char (point-min))
 161   (let (article bytes lines size string)
 162     (block nil
 163       (while (not (eobp))
 164         (while (not (looking-at "^\\* [0-9]+ FETCH.*UID \\([0-9]+\\)"))
 165           (delete-region (point) (progn (forward-line 1) (point)))
 166           (when (eobp)
 167             (return)))
 168         (setq article (match-string 1))
 169         ;; Unfold quoted {number} strings.
 170         (while (re-search-forward "[^]] {\\([0-9]+\\)}\r\n"
 171                                   (1+ (line-end-position)) t)
 172           (setq size (string-to-number (match-string 1)))
 173           (delete-region (+ (match-beginning 0) 2) (point))
 174           (setq string (delete-region (point) (+ (point) size)))
 175           (insert (format "%S" string)))
 176         (setq bytes (nnimap-get-length)
 177               lines nil)
 178         (beginning-of-line)
 179         (setq size
 180               (and (re-search-forward "RFC822.SIZE \\([0-9]+\\)"
 181                                       (line-end-position)
 182                                       t)
 183                    (match-string 1)))
 184         (beginning-of-line)
 185         (when (search-forward "BODYSTRUCTURE" (line-end-position) t)
 186           (let ((structure (ignore-errors
 187                              (read (current-buffer)))))
 188             (while (and (consp structure)
 189                         (not (stringp (car structure))))
 190               (setq structure (car structure)))
 191             (setq lines (nth 7 structure))))
 192         (delete-region (line-beginning-position) (line-end-position))
 193         (insert (format "211 %s Article retrieved." article))
 194         (forward-line 1)
 195         (when size
 196           (insert (format "Chars: %s\n" size)))
 197         (when lines
 198           (insert (format "Lines: %s\n" lines)))
 199         (re-search-forward "^\r$")
 200         (delete-region (line-beginning-position) (line-end-position))
 201         (insert ".")
 202         (forward-line 1)))))
 203
 204 (defun nnimap-get-length ()
 205   (and (re-search-forward "{\\([0-9]+\\)}" (line-end-position) t)
 206        (string-to-number (match-string 1))))
 207
 208 (defun nnimap-article-ranges (ranges)
 209   (let (result)
 210     (cond
 211      ((numberp ranges)
 212       (number-to-string ranges))
 213      ((numberp (cdr ranges))
 214       (format "%d:%d" (car ranges) (cdr ranges)))
 215      (t
 216       (dolist (elem ranges)
 217         (push
 218          (if (consp elem)
 219              (format "%d:%d" (car elem) (cdr elem))
 220            (number-to-string elem))
 221          result))
 222       (mapconcat #'identity (nreverse result) ",")))))
 223
 224 (deffoo nnimap-open-server (server &optional defs)
 225   (if (nnimap-server-opened server)
 226       t
 227     (unless (assq 'nnimap-address defs)
 228       (setq defs (append defs (list (list 'nnimap-address server)))))
 229     (nnoo-change-server 'nnimap server defs)
 230     (or (nnimap-find-connection nntp-server-buffer)
 231         (nnimap-open-connection nntp-server-buffer))))
 232
 233 (defun nnimap-make-process-buffer (buffer)
 234   (with-current-buffer
 235       (generate-new-buffer (format "*nnimap %s %s %s*"
 236                                    nnimap-address nnimap-server-port
 237                                    (gnus-buffer-exists-p buffer)))
 238     (mm-disable-multibyte)
 239     (buffer-disable-undo)
 240     (gnus-add-buffer)
 241     (set (make-local-variable 'after-change-functions) nil)
 242     (set (make-local-variable 'nnimap-object)
 243          (make-nnimap :server (nnoo-current-server 'nnimap)))
 244     (push (list buffer (current-buffer)) nnimap-connection-alist)
 245     (push (current-buffer) nnimap-process-buffers)
 246     (current-buffer)))
 247
 248 (defun nnimap-open-shell-stream (name buffer host port)
 249   (let ((process-connection-type nil))
 250     (start-process name buffer shell-file-name
 251                    shell-command-switch
 252                    (format-spec
 253                     nnimap-shell-program
 254                     (format-spec-make
 255                      ?s host
 256                      ?p port)))))
 257
 258 (defun nnimap-credentials (address ports &optional inhibit-create)
 259   (let (port credentials)
 260     ;; Request the credentials from all ports, but only query on the
 261     ;; last port if all the previous ones have failed.
 262     (while (and (null credentials)
 263                 (setq port (pop ports)))
 264       (setq credentials
 265             (auth-source-user-or-password
 266              '("login" "password") address port nil
 267              (if inhibit-create
 268                  nil
 269                (null ports)))))
 270     credentials))
 271
 272 (defun nnimap-keepalive ()
 273   (let ((now (current-time)))
 274     (dolist (buffer nnimap-process-buffers)
 275       (when (buffer-name buffer)
 276         (with-current-buffer buffer
 277           (when (and nnimap-object
 278                      (nnimap-last-command-time nnimap-object)
 279                      (> (time-to-seconds
 280                          (time-subtract
 281                           now
 282                           (nnimap-last-command-time nnimap-object)))
 283                         ;; More than five minutes since the last command.
 284                         (* 5 60)))
 285             (nnimap-send-command "NOOP")))))))
 286
 287 (defun nnimap-open-connection (buffer)
 288   (unless nnimap-keepalive-timer
 289     (setq nnimap-keepalive-timer (run-at-time (* 60 15) (* 60 15)
 290                                               'nnimap-keepalive)))
 291   (block nil
 292     (with-current-buffer (nnimap-make-process-buffer buffer)
 293       (let* ((coding-system-for-read 'binary)
 294              (coding-system-for-write 'binary)
 295              (port nil)
 296              (ports
 297               (cond
 298                ((eq nnimap-stream 'network)
 299                 (open-network-stream
 300                  "*nnimap*" (current-buffer) nnimap-address
 301                  (setq port
 302                        (or nnimap-server-port
 303                            (if (netrc-find-service-number "imap")
 304                                "imap"
 305                              "143"))))
 306                 '("143" "imap"))
 307                ((eq nnimap-stream 'shell)
 308                 (nnimap-open-shell-stream
 309                  "*nnimap*" (current-buffer) nnimap-address
 310                  (setq port (or nnimap-server-port "imap")))
 311                 '("imap"))
 312                ((eq nnimap-stream 'starttls)
 313                 (let ((tls-program (nnimap-extend-tls-programs)))
 314                   (open-tls-stream
 315                    "*nnimap*" (current-buffer) nnimap-address
 316                    (setq port (or nnimap-server-port "imap"))
 317                    'starttls))
 318                 '("imap"))
 319                ((eq nnimap-stream 'ssl)
 320                 (open-tls-stream
 321                  "*nnimap*" (current-buffer) nnimap-address
 322                  (setq port
 323                        (or nnimap-server-port
 324                            (if (netrc-find-service-number "imaps")
 325                                "imaps"
 326                              "993"))))
 327                 '("143" "993" "imap" "imaps"))))
 328              connection-result login-result credentials)
 329         (setf (nnimap-process nnimap-object)
 330               (get-buffer-process (current-buffer)))
 331         (if (not (and (nnimap-process nnimap-object)
 332                       (memq (process-status (nnimap-process nnimap-object))
 333                             '(open run))))
 334             (nnheader-report 'nnimap "Unable to contact %s:%s via %s"
 335                              nnimap-address port nnimap-stream)
 336           (gnus-set-process-query-on-exit-flag (nnimap-process nnimap-object) nil)
 337           (if (not (setq connection-result (nnimap-wait-for-connection)))
 338               (nnheader-report 'nnimap
 339                                "%s" (buffer-substring
 340                                      (point) (line-end-position)))
 341             ;; Store the greeting (for debugging purposes).
 342             (setf (nnimap-greeting nnimap-object)
 343                   (buffer-substring (line-beginning-position)
 344                                     (line-end-position)))
 345             ;; Store the capabilities.
 346             (setf (nnimap-capabilities nnimap-object)
 347                   (mapcar
 348                    #'upcase
 349                    (nnimap-find-parameter
 350                     "CAPABILITY" (cdr (nnimap-command "CAPABILITY")))))
 351             (when nnimap-server-port
 352               (push (format "%s" nnimap-server-port) ports))
 353             ;; If this is a STARTTLS-capable server, then sever the
 354             ;; connection and start a STARTTLS connection instead.
 355             (when (and (eq nnimap-stream 'network)
 356                        (member "STARTTLS" (nnimap-capabilities nnimap-object)))
 357               (let ((nnimap-stream 'starttls))
 358                 (let ((tls-process
 359                        (nnimap-open-connection buffer)))
 360                   ;; If the STARTTLS connection was successful, we
 361                   ;; kill our first non-encrypted connection.  If it
 362                   ;; wasn't successful, we just use our unencrypted
 363                   ;; connection.
 364                   (when (memq (process-status tls-process) '(open run))
 365                     (delete-process (nnimap-process nnimap-object))
 366                     (kill-buffer (current-buffer))
 367                     (return tls-process)))))
 368             (unless (equal connection-result "PREAUTH")
 369               (if (not (setq credentials
 370                              (if (eq nnimap-authenticator 'anonymous)
 371                                  (list "anonymous"
 372                                        (message-make-address))
 373                                (or
 374                                 ;; First look for the credentials based
 375                                 ;; on the virtual server name.
 376                                 (nnimap-credentials
 377                                  (nnoo-current-server 'nnimap) ports t)
 378                                 ;; Then look them up based on the
 379                                 ;; physical address.
 380                                 (nnimap-credentials nnimap-address ports)))))
 381                   (setq nnimap-object nil)
 382                 (setq login-result (nnimap-command "LOGIN %S %S"
 383                                                    (car credentials)
 384                                                    (cadr credentials)))
 385                 (unless (car login-result)
 386                   ;; If the login failed, then forget the credentials
 387                   ;; that are now possibly cached.
 388                   (dolist (host (list (nnoo-current-server 'nnimap)
 389                                       nnimap-address))
 390                     (dolist (port ports)
 391                       (dolist (element '("login" "password"))
 392                         (auth-source-forget-user-or-password
 393                          element host port))))
 394                   (delete-process (nnimap-process nnimap-object))
 395                   (setq nnimap-object nil))))
 396             (when nnimap-object
 397               (when (member "QRESYNC" (nnimap-capabilities nnimap-object))
 398                 (nnimap-command "ENABLE QRESYNC"))
 399               (nnimap-process nnimap-object))))))))
 400
 401 (defun nnimap-extend-tls-programs ()
 402   (let ((programs tls-program)
 403         result)
 404     (unless (consp programs)
 405       (setq programs (list programs)))
 406     (dolist (program programs)
 407       (when (assoc (car (split-string program)) tls-starttls-switches)
 408         (push (if (not (string-match "%s" program))
 409                   (concat program " " "%s")
 410                 program)
 411               result)))
 412     (nreverse result)))
 413
 414 (defun nnimap-find-parameter (parameter elems)
 415   (let (result)
 416     (dolist (elem elems)
 417       (cond
 418        ((equal (car elem) parameter)
 419         (setq result (cdr elem)))
 420        ((and (equal (car elem) "OK")
 421              (consp (cadr elem))
 422              (equal (caadr elem) parameter))
 423         (setq result (cdr (cadr elem))))))
 424     result))
 425
 426 (deffoo nnimap-close-server (&optional server)
 427   t)
 428
 429 (deffoo nnimap-request-close ()
 430   t)
 431
 432 (deffoo nnimap-server-opened (&optional server)
 433   (and (nnoo-current-server-p 'nnimap server)
 434        nntp-server-buffer
 435        (gnus-buffer-live-p nntp-server-buffer)
 436        (nnimap-find-connection nntp-server-buffer)))
 437
 438 (deffoo nnimap-status-message (&optional server)
 439   nnimap-status-string)
 440
 441 (deffoo nnimap-request-article (article &optional group server to-buffer)
 442   (with-current-buffer nntp-server-buffer
 443     (let ((result (nnimap-possibly-change-group group server))
 444           parts structure)
 445       (when (stringp article)
 446         (setq article (nnimap-find-article-by-message-id group article)))
 447       (when (and result
 448                  article)
 449         (erase-buffer)
 450         (with-current-buffer (nnimap-buffer)
 451           (erase-buffer)
 452           (when nnimap-fetch-partial-articles
 453             (nnimap-command "UID FETCH %d (BODYSTRUCTURE)" article)
 454             (goto-char (point-min))
 455             (when (re-search-forward "FETCH.*BODYSTRUCTURE" nil t)
 456               (setq structure (ignore-errors
 457                                 (let ((start (point)))
 458                                   (forward-sexp 1)
 459                                   (downcase-region start (point))
 460                                   (goto-char (point))
 461                                   (read (current-buffer))))
 462                     parts (nnimap-find-wanted-parts structure))))
 463           (when (if parts
 464                     (nnimap-get-partial-article article parts structure)
 465                   (nnimap-get-whole-article article))
 466             (let ((buffer (current-buffer)))
 467               (with-current-buffer (or to-buffer nntp-server-buffer)
 468                 (erase-buffer)
 469                 (insert-buffer-substring buffer)
 470                 (nnheader-ms-strip-cr)
 471                 (cons group article)))))))))
 472
 473 (defun nnimap-get-whole-article (article)
 474   (let ((result
 475          (nnimap-command
 476           (if (nnimap-ver4-p)
 477               "UID FETCH %d BODY.PEEK[]"
 478             "UID FETCH %d RFC822.PEEK")
 479           article)))
 480     ;; Check that we really got an article.
 481     (goto-char (point-min))
 482     (unless (re-search-forward "\\* [0-9]+ FETCH" nil t)
 483       (setq result nil))
 484     (when result
 485       ;; Remove any data that may have arrived before the FETCH data.
 486       (beginning-of-line)
 487       (unless (bobp)
 488         (delete-region (point-min) (point)))
 489       (let ((bytes (nnimap-get-length)))
 490         (delete-region (line-beginning-position)
 491                        (progn (forward-line 1) (point)))
 492         (goto-char (+ (point) bytes))
 493         (delete-region (point) (point-max)))
 494       t)))
 495
 496 (defun nnimap-ver4-p ()
 497   (member "IMAP4REV1" (nnimap-capabilities nnimap-object)))
 498
 499 (defun nnimap-get-partial-article (article parts structure)
 500   (let ((result
 501          (nnimap-command
 502           "UID FETCH %d (%s %s)"
 503           article
 504           (if (nnimap-ver4-p)
 505               "BODY.PEEK[HEADER]"
 506             "RFC822.HEADER")
 507           (if (nnimap-ver4-p)
 508               (mapconcat (lambda (part)
 509                            (format "BODY.PEEK[%s]" part))
 510                          parts " ")
 511             (mapconcat (lambda (part)
 512                          (format "RFC822.PEEK[%s]" part))
 513                        parts " ")))))
 514     (when result
 515       (nnimap-convert-partial-article structure))))
 516
 517 (defun nnimap-convert-partial-article (structure)
 518   ;; First just skip past the headers.
 519   (goto-char (point-min))
 520   (let ((bytes (nnimap-get-length))
 521         id parts)
 522     ;; Delete "FETCH" line.
 523     (delete-region (line-beginning-position)
 524                    (progn (forward-line 1) (point)))
 525     (goto-char (+ (point) bytes))
 526     ;; Collect all the body parts.
 527     (while (looking-at ".*BODY\\[\\([.0-9]+\\)\\]")
 528       (setq id (match-string 1)
 529             bytes (nnimap-get-length))
 530       (beginning-of-line)
 531       (delete-region (point) (progn (forward-line 1) (point)))
 532       (push (list id (buffer-substring (point) (+ (point) bytes)))
 533             parts)
 534       (delete-region (point) (+ (point) bytes)))
 535     ;; Delete trailing junk.
 536     (delete-region (point) (point-max))
 537     ;; Now insert all the parts again where they fit in the structure.
 538     (nnimap-insert-partial-structure structure parts)
 539     t))
 540
 541 (defun nnimap-insert-partial-structure (structure parts &optional subp)
 542   (let (type boundary)
 543     (let ((bstruc structure))
 544       (while (consp (car bstruc))
 545         (pop bstruc))
 546       (setq type (car bstruc))
 547       (setq bstruc (car (cdr bstruc)))
 548       (when (and (stringp (car bstruc))
 549                  (string= (downcase (car bstruc)) "boundary"))
 550         (setq boundary (cadr bstruc))))
 551     (when subp
 552       (insert (format "Content-type: multipart/%s; boundary=%S\n\n"
 553                       (downcase type) boundary)))
 554     (while (not (stringp (car structure)))
 555       (insert "\n--" boundary "\n")
 556       (if (consp (caar structure))
 557           (nnimap-insert-partial-structure (pop structure) parts t)
 558         (let ((bit (pop structure)))
 559           (insert (format  "Content-type: %s/%s"
 560                            (downcase (nth 0 bit))
 561                            (downcase (nth 1 bit))))
 562           (if (member "CHARSET" (nth 2 bit))
 563               (insert (format
 564                        "; charset=%S\n" (cadr (member "CHARSET" (nth 2 bit)))))
 565             (insert "\n"))
 566           (insert (format "Content-transfer-encoding: %s\n"
 567                           (nth 5 bit)))
 568           (insert "\n")
 569           (when (assoc (nth 9 bit) parts)
 570             (insert (cadr (assoc (nth 9 bit) parts)))))))
 571     (insert "\n--" boundary "--\n")))
 572
 573 (defun nnimap-find-wanted-parts (structure)
 574   (message-flatten-list (nnimap-find-wanted-parts-1 structure "")))
 575
 576 (defun nnimap-find-wanted-parts-1 (structure prefix)
 577   (let ((num 1)
 578         parts)
 579     (while (consp (car structure))
 580       (let ((sub (pop structure)))
 581         (if (consp (car sub))
 582             (push (nnimap-find-wanted-parts-1
 583                    sub (if (string= prefix "")
 584                            (number-to-string num)
 585                          (format "%s.%s" prefix num)))
 586                   parts)
 587           (let ((type (format "%s/%s" (nth 0 sub) (nth 1 sub)))
 588                 (id (if (string= prefix "")
 589                         (number-to-string num)
 590                       (format "%s.%s" prefix num))))
 591             (setcar (nthcdr 9 sub) id)
 592             (when (if (eq nnimap-fetch-partial-articles t)
 593                       (equal id "1")
 594                     (string-match nnimap-fetch-partial-articles type))
 595               (push id parts))))
 596         (incf num)))
 597     (nreverse parts)))
 598
 599 (deffoo nnimap-request-group (group &optional server dont-check info)
 600   (let ((result (nnimap-possibly-change-group group server))
 601         articles active marks high low)
 602     (with-current-buffer nntp-server-buffer
 603       (when result
 604         (if (and dont-check
 605                  (setq active (nth 2 (assoc group nnimap-current-infos))))
 606             (insert (format "211 %d %d %d %S\n"
 607                             (- (cdr active) (car active))
 608                             (car active)
 609                             (cdr active)
 610                             group))
 611           (with-current-buffer (nnimap-buffer)
 612             (erase-buffer)
 613             (let ((group-sequence
 614                    (nnimap-send-command "SELECT %S" (utf7-encode group t)))
 615                   (flag-sequence
 616                    (nnimap-send-command "UID FETCH 1:* FLAGS")))
 617               (nnimap-wait-for-response flag-sequence)
 618               (setq marks
 619                     (nnimap-flags-to-marks
 620                      (nnimap-parse-flags
 621                       (list (list group-sequence flag-sequence 1 group)))))
 622               (when info
 623                 (nnimap-update-infos marks (list info)))
 624               (goto-char (point-max))
 625               (let ((uidnext (nth 5 (car marks))))
 626                 (setq high (or (if uidnext
 627                                    (1- uidnext)
 628                                  (nth 3 (car marks)))
 629                                0)
 630                       low (or (nth 4 (car marks)) uidnext 1)))))
 631           (erase-buffer)
 632           (insert
 633            (format
 634             "211 %d %d %d %S\n" (1+ (- high low)) low high group)))
 635         t))))
 636
 637 (deffoo nnimap-request-create-group (group &optional server args)
 638   (when (nnimap-possibly-change-group nil server)
 639     (with-current-buffer (nnimap-buffer)
 640       (car (nnimap-command "CREATE %S" (utf7-encode group t))))))
 641
 642 (deffoo nnimap-request-delete-group (group &optional force server)
 643   (when (nnimap-possibly-change-group nil server)
 644     (with-current-buffer (nnimap-buffer)
 645       (car (nnimap-command "DELETE %S" (utf7-encode group t))))))
 646
 647 (deffoo nnimap-request-expunge-group (group &optional server)
 648   (when (nnimap-possibly-change-group group server)
 649     (with-current-buffer (nnimap-buffer)
 650       (car (nnimap-command "EXPUNGE")))))
 651
 652 (defun nnimap-get-flags (spec)
 653   (let ((articles nil)
 654         elems)
 655     (with-current-buffer (nnimap-buffer)
 656       (erase-buffer)
 657       (nnimap-wait-for-response (nnimap-send-command
 658                                  "UID FETCH %s FLAGS" spec))
 659       (goto-char (point-min))
 660       (while (re-search-forward "^\\* [0-9]+ FETCH (\\(.*\\))" nil t)
 661         (setq elems (nnimap-parse-line (match-string 1)))
 662         (push (cons (string-to-number (cadr (member "UID" elems)))
 663                     (cadr (member "FLAGS" elems)))
 664               articles)))
 665     (nreverse articles)))
 666
 667 (deffoo nnimap-close-group (group &optional server)
 668   t)
 669
 670 (deffoo nnimap-request-move-article (article group server accept-form
 671                                              &optional last internal-move-group)
 672   (with-temp-buffer
 673     (when (nnimap-request-article article group server (current-buffer))
 674       ;; If the move is internal (on the same server), just do it the easy
 675       ;; way.
 676       (let ((message-id (message-field-value "message-id")))
 677         (if internal-move-group
 678             (let ((result
 679                    (with-current-buffer (nnimap-buffer)
 680                      (nnimap-command "UID COPY %d %S"
 681                                      article
 682                                      (utf7-encode internal-move-group t)))))
 683               (when (car result)
 684                 (nnimap-delete-article article)
 685                 (cons internal-move-group
 686                       (nnimap-find-article-by-message-id
 687                        internal-move-group message-id))))
 688           ;; Move the article to a different method.
 689           (let ((result (eval accept-form)))
 690             (when result
 691               (nnimap-delete-article article)
 692               result)))))))
 693
 694 (deffoo nnimap-request-expire-articles (articles group &optional server force)
 695   (cond
 696    ((null articles)
 697     nil)
 698    ((not (nnimap-possibly-change-group group server))
 699     articles)
 700    ((and force
 701          (eq nnmail-expiry-target 'delete))
 702     (unless (nnimap-delete-article (gnus-compress-sequence articles))
 703       (message "Article marked for deletion, but not expunged."))
 704     nil)
 705    (t
 706     (let ((deletable-articles
 707            (if (or force
 708                    (eq nnmail-expiry-wait 'immediate))
 709                articles
 710              (gnus-sorted-intersection
 711               articles
 712               (nnimap-find-expired-articles group)))))
 713       (if (null deletable-articles)
 714           articles
 715         (if (eq nnmail-expiry-target 'delete)
 716             (nnimap-delete-article (gnus-compress-sequence deletable-articles))
 717           (setq deletable-articles
 718                 (nnimap-process-expiry-targets
 719                  deletable-articles group server)))
 720         ;; Return the articles we didn't delete.
 721         (gnus-sorted-complement articles deletable-articles))))))
 722
 723 (defun nnimap-process-expiry-targets (articles group server)
 724   (let ((deleted-articles nil))
 725     (dolist (article articles)
 726       (let ((target nnmail-expiry-target))
 727         (with-temp-buffer
 728           (when (nnimap-request-article article group server (current-buffer))
 729             (message "Expiring article %s:%d" group article)
 730             (when (functionp target)
 731               (setq target (funcall target group)))
 732             (when (and target
 733                        (not (eq target 'delete)))
 734               (if (or (gnus-request-group target t)
 735                       (gnus-request-create-group target))
 736                   (nnmail-expiry-target-group target group)
 737                 (setq target nil)))
 738             (when target
 739               (push article deleted-articles))))))
 740     ;; Change back to the current group again.
 741     (nnimap-possibly-change-group group server)
 742     (setq deleted-articles (nreverse deleted-articles))
 743     (nnimap-delete-article (gnus-compress-sequence deleted-articles))
 744     deleted-articles))
 745
 746 (defun nnimap-find-expired-articles (group)
 747   (let ((cutoff (nnmail-expired-article-p group nil nil)))
 748     (with-current-buffer (nnimap-buffer)
 749       (let ((result
 750              (nnimap-command
 751               "UID SEARCH SENTBEFORE %s"
 752               (format-time-string
 753                (format "%%d-%s-%%Y"
 754                        (upcase
 755                         (car (rassoc (nth 4 (decode-time cutoff))
 756                                      parse-time-months))))
 757                cutoff))))
 758         (and (car result)
 759              (delete 0 (mapcar #'string-to-number
 760                                (cdr (assoc "SEARCH" (cdr result))))))))))
 761
 762
 763 (defun nnimap-find-article-by-message-id (group message-id)
 764   (with-current-buffer (nnimap-buffer)
 765     (erase-buffer)
 766     (setf (nnimap-group nnimap-object) nil)
 767     (nnimap-send-command "EXAMINE %S" (utf7-encode group t))
 768     (let ((sequence
 769            (nnimap-send-command "UID SEARCH HEADER Message-Id %S" message-id))
 770           article result)
 771       (setq result (nnimap-wait-for-response sequence))
 772       (when (and result
 773                  (car (setq result (nnimap-parse-response))))
 774         ;; Select the last instance of the message in the group.
 775         (and (setq article
 776                    (car (last (assoc "SEARCH" (cdr result)))))
 777              (string-to-number article))))))
 778
 779 (defun nnimap-delete-article (articles)
 780   (with-current-buffer (nnimap-buffer)
 781     (nnimap-command "UID STORE %s +FLAGS.SILENT (\\Deleted)"
 782                     (nnimap-article-ranges articles))
 783     (cond
 784      ((member "UIDPLUS" (nnimap-capabilities nnimap-object))
 785       (nnimap-command "UID EXPUNGE %s"
 786                       (nnimap-article-ranges articles))
 787       t)
 788      (nnimap-expunge
 789       (nnimap-command "EXPUNGE")
 790       t)
 791      (t (gnus-message 7 (concat "nnimap: nnimap-expunge is not set and the "
 792                                 "server doesn't support UIDPLUS, so we won't "
 793                                 "delete this article now"))))))
 794
 795 (deffoo nnimap-request-scan (&optional group server)
 796   (when (and (nnimap-possibly-change-group nil server)
 797              nnimap-inbox
 798              nnimap-split-methods)
 799     (message "nnimap %s splitting mail..." server)
 800     (nnimap-split-incoming-mail)))
 801
 802 (defun nnimap-marks-to-flags (marks)
 803   (let (flags flag)
 804     (dolist (mark marks)
 805       (when (setq flag (cadr (assq mark nnimap-mark-alist)))
 806         (push flag flags)))
 807     flags))
 808
 809 (deffoo nnimap-request-set-mark (group actions &optional server)
 810   (when (nnimap-possibly-change-group group server)
 811     (let (sequence)
 812       (with-current-buffer (nnimap-buffer)
 813         (erase-buffer)
 814         ;; Just send all the STORE commands without waiting for
 815         ;; response.  If they're successful, they're successful.
 816         (dolist (action actions)
 817           (destructuring-bind (range action marks) action
 818             (let ((flags (nnimap-marks-to-flags marks)))
 819               (when flags
 820                 (setq sequence (nnimap-send-command
 821                                 "UID STORE %s %sFLAGS.SILENT (%s)"
 822                                 (nnimap-article-ranges range)
 823                                 (if (eq action 'del)
 824                                     "-"
 825                                   "+")
 826                                 (mapconcat #'identity flags " ")))))))
 827         ;; Wait for the last command to complete to avoid later
 828         ;; syncronisation problems with the stream.
 829         (when sequence
 830           (nnimap-wait-for-response sequence))))))
 831
 832 (deffoo nnimap-request-accept-article (group &optional server last)
 833   (when (nnimap-possibly-change-group nil server)
 834     (nnmail-check-syntax)
 835     (let ((message-id (message-field-value "message-id"))
 836           sequence message)
 837       (nnimap-add-cr)
 838       (setq message (buffer-string))
 839       (with-current-buffer (nnimap-buffer)
 840         (setq sequence (nnimap-send-command
 841                         "APPEND %S {%d}" (utf7-encode group t)
 842                         (length message)))
 843         (process-send-string (get-buffer-process (current-buffer)) message)
 844         (process-send-string (get-buffer-process (current-buffer))
 845                              (if (nnimap-newlinep nnimap-object)
 846                                  "\n"
 847                                "\r\n"))
 848         (let ((result (nnimap-get-response sequence)))
 849           (if (not (car result))
 850               (progn
 851                 (message "%s" (nnheader-get-report-string 'nnimap))
 852                 nil)
 853             (cons group
 854                   (nnimap-find-article-by-message-id group message-id))))))))
 855
 856 (defun nnimap-add-cr ()
 857   (goto-char (point-min))
 858   (while (re-search-forward "\r?\n" nil t)
 859     (replace-match "\r\n" t t)))
 860
 861 (defun nnimap-get-groups ()
 862   (let ((result (nnimap-command "LIST \"\" \"*\""))
 863         groups)
 864     (when (car result)
 865       (dolist (line (cdr result))
 866         (when (and (equal (car line) "LIST")
 867                    (not (and (caadr line)
 868                              (string-match "noselect" (caadr line)))))
 869           (push (car (last line)) groups)))
 870       (nreverse groups))))
 871
 872 (deffoo nnimap-request-list (&optional server)
 873   (nnimap-possibly-change-group nil server)
 874   (with-current-buffer nntp-server-buffer
 875     (erase-buffer)
 876     (let ((groups
 877            (with-current-buffer (nnimap-buffer)
 878              (nnimap-get-groups)))
 879           sequences responses)
 880       (when groups
 881         (with-current-buffer (nnimap-buffer)
 882           (setf (nnimap-group nnimap-object) nil)
 883           (dolist (group groups)
 884             (push (list (nnimap-send-command "EXAMINE %S" (utf7-encode group t))
 885                         group)
 886                   sequences))
 887           (nnimap-wait-for-response (caar sequences))
 888           (setq responses
 889                 (nnimap-get-responses (mapcar #'car sequences))))
 890         (dolist (response responses)
 891           (let* ((sequence (car response))
 892                  (response (cadr response))
 893                  (group (cadr (assoc sequence sequences))))
 894             (when (and group
 895                        (equal (caar response) "OK"))
 896               (let ((uidnext (nnimap-find-parameter "UIDNEXT" response))
 897                     highest exists)
 898                 (dolist (elem response)
 899                   (when (equal (cadr elem) "EXISTS")
 900                     (setq exists (string-to-number (car elem)))))
 901                 (when uidnext
 902                   (setq highest (1- (string-to-number (car uidnext)))))
 903                 (cond
 904                  ((null highest)
 905                   (insert (format "%S 0 1 y\n" (utf7-decode group t))))
 906                  ((zerop exists)
 907                   ;; Empty group.
 908                   (insert (format "%S %d %d y\n"
 909                                   (utf7-decode group t) highest (1+ highest))))
 910                  (t
 911                   ;; Return the widest possible range.
 912                   (insert (format "%S %d 1 y\n" (utf7-decode group t)
 913                                   (or highest exists)))))))))
 914         t))))
 915
 916 (deffoo nnimap-request-newgroups (date &optional server)
 917   (nnimap-possibly-change-group nil server)
 918   (with-current-buffer nntp-server-buffer
 919     (erase-buffer)
 920     (dolist (group (with-current-buffer (nnimap-buffer)
 921                      (nnimap-get-groups)))
 922       (unless (assoc group nnimap-current-infos)
 923         ;; Insert dummy numbers here -- they don't matter.
 924         (insert (format "%S 0 1 y\n" group))))))
 925
 926 (deffoo nnimap-retrieve-group-data-early (server infos)
 927   (when (nnimap-possibly-change-group nil server)
 928     (with-current-buffer (nnimap-buffer)
 929       ;; QRESYNC handling isn't implemented.
 930       (let ((qresyncp (member "notQRESYNC" (nnimap-capabilities nnimap-object)))
 931             marks groups sequences)
 932         ;; Go through the infos and gather the data needed to know
 933         ;; what and how to request the data.
 934         (dolist (info infos)
 935           (setq marks (gnus-info-marks info))
 936           (push (list (gnus-group-real-name (gnus-info-group info))
 937                       (cdr (assq 'active marks))
 938                       (cdr (assq 'uid marks)))
 939                 groups))
 940         ;; Then request the data.
 941         (erase-buffer)
 942         (setf (nnimap-group nnimap-object) nil)
 943         (dolist (elem groups)
 944           (if (and qresyncp
 945                    (nth 2 elem))
 946               (push
 947                (list 'qresync
 948                      (nnimap-send-command "EXAMINE %S (QRESYNC (%s %s))"
 949                                           (car elem)
 950                                           (car (nth 2 elem))
 951                                           (cdr (nth 2 elem)))
 952                      nil
 953                      (car elem))
 954                sequences)
 955             (let ((start
 956                    (if (nth 1 elem)
 957                        ;; Fetch the last 100 flags.
 958                        (max 1 (- (cdr (nth 1 elem)) 100))
 959                      1)))
 960               (push (list (nnimap-send-command "EXAMINE %S" (car elem))
 961                           (nnimap-send-command "UID FETCH %d:* FLAGS" start)
 962                           start
 963                           (car elem))
 964                     sequences)))
 965           ;; Some servers apparently can't have many outstanding
 966           ;; commands, so throttle them.
 967           (when (and (not nnimap-streaming)
 968                      (car sequences))
 969             (nnimap-wait-for-response (caar sequences))))
 970         sequences))))
 971
 972 (deffoo nnimap-finish-retrieve-group-infos (server infos sequences)
 973   (when (and sequences
 974              (nnimap-possibly-change-group nil server))
 975     (with-current-buffer (nnimap-buffer)
 976       ;; Wait for the final data to trickle in.
 977       (when (nnimap-wait-for-response (cadar sequences))
 978         ;; Now we should have all the data we need, no matter whether
 979         ;; we're QRESYNCING, fetching all the flags from scratch, or
 980         ;; just fetching the last 100 flags per group.
 981         (nnimap-update-infos (nnimap-flags-to-marks
 982                               (nnimap-parse-flags
 983                                (nreverse sequences)))
 984                              infos)
 985         ;; Finally, just return something resembling an active file in
 986         ;; the nntp buffer, so that the agent can save the info, too.
 987         (with-current-buffer nntp-server-buffer
 988           (erase-buffer)
 989           (dolist (info infos)
 990             (let* ((group (gnus-info-group info))
 991                    (active (gnus-active group)))
 992               (when active
 993                 (insert (format "%S %d %d y\n"
 994                                 (gnus-group-real-name group)
 995                                 (cdr active)
 996                                 (car active)))))))))))
 997
 998 (defun nnimap-update-infos (flags infos)
 999   (dolist (info infos)
1000     (let ((group (gnus-group-real-name (gnus-info-group info))))
1001       (nnimap-update-info info (cdr (assoc group flags))))))
1002
1003 (defun nnimap-update-info (info marks)
1004   (when (and marks
1005              ;; Ignore groups with no UIDNEXT values.
1006              (nth 4 marks))
1007     (destructuring-bind (existing flags high low uidnext start-article
1008                                   permanent-flags) marks
1009       (let ((group (gnus-info-group info))
1010             (completep (and start-article
1011                             (= start-article 1))))
1012         (when uidnext
1013           (setq high (1- uidnext)))
1014         ;; First set the active ranges based on high/low.
1015         (if (or completep
1016                 (not (gnus-active group)))
1017             (gnus-set-active group
1018                              (cond
1019                               ((and low high)
1020                                (cons low high))
1021                               (uidnext
1022                                ;; No articles in this group.
1023                                (cons uidnext (1- uidnext)))
1024                               (start-article
1025                                (cons start-article (1- start-article)))
1026                               (t
1027                                ;; No articles and no uidnext.
1028                                nil)))
1029           (gnus-set-active
1030            group
1031            (cons (car (gnus-active group))
1032                  (or high (1- uidnext)))))
1033         (when (and (not high)
1034                    uidnext)
1035           (setq high (1- uidnext)))
1036         ;; Then update the list of read articles.
1037         (let* ((unread
1038                 (gnus-compress-sequence
1039                  (gnus-set-difference
1040                   (gnus-set-difference
1041                    existing
1042                    (cdr (assoc '%Seen flags)))
1043                   (cdr (assoc '%Flagged flags)))))
1044                (read (gnus-range-difference
1045                       (cons start-article high) unread)))
1046           (when (> start-article 1)
1047             (setq read
1048                   (gnus-range-nconcat
1049                    (if (> start-article 1)
1050                        (gnus-sorted-range-intersection
1051                         (cons 1 (1- start-article))
1052                         (gnus-info-read info))
1053                      (gnus-info-read info))
1054                    read)))
1055           (gnus-info-set-read info read)
1056           ;; Update the marks.
1057           (setq marks (gnus-info-marks info))
1058           ;; Note the active level for the next run-through.
1059           (let ((active (assq 'active marks)))
1060             (if active
1061                 (setcdr active (gnus-active group))
1062               (push (cons 'active (gnus-active group)) marks)))
1063           (dolist (type (cdr nnimap-mark-alist))
1064             (let ((old-marks (assoc (car type) marks))
1065                   (new-marks
1066                    (gnus-compress-sequence
1067                     (cdr (or (assoc (caddr type) flags)     ; %Flagged
1068                              (assoc (intern (cadr type) obarray) flags)
1069                              (assoc (cadr type) flags)))))) ; "\Flagged"
1070               (setq marks (delq old-marks marks))
1071               (pop old-marks)
1072               (when (and old-marks
1073                          (> start-article 1))
1074                 (setq old-marks (gnus-range-difference
1075                                  old-marks
1076                                  (cons start-article high)))
1077                 (setq new-marks (gnus-range-nconcat old-marks new-marks)))
1078               (when new-marks
1079                 (push (cons (car type) new-marks) marks)))
1080             (gnus-info-set-marks info marks t)
1081             (nnimap-store-info info (gnus-active group))))))))
1082
1083 (defun nnimap-store-info (info active)
1084   (let* ((group (gnus-group-real-name (gnus-info-group info)))
1085          (entry (assoc group nnimap-current-infos)))
1086     (if entry
1087         (setcdr entry (list info active))
1088       (push (list group info active) nnimap-current-infos))))
1089
1090 (defun nnimap-flags-to-marks (groups)
1091   (let (data group totalp uidnext articles start-article mark permanent-flags)
1092     (dolist (elem groups)
1093       (setq group (car elem)
1094             uidnext (nth 1 elem)
1095             start-article (nth 2 elem)
1096             permanent-flags (nth 3 elem)
1097             articles (nthcdr 4 elem))
1098       (let ((high (caar articles))
1099             marks low existing)
1100         (dolist (article articles)
1101           (setq low (car article))
1102           (push (car article) existing)
1103           (dolist (flag (cdr article))
1104             (setq mark (assoc flag marks))
1105             (if (not mark)
1106                 (push (list flag (car article)) marks)
1107               (setcdr mark (cons (car article) (cdr mark))))))
1108         (push (list group existing marks high low uidnext start-article
1109                     permanent-flags)
1110               data)))
1111     data))
1112
1113 (defun nnimap-parse-flags (sequences)
1114   (goto-char (point-min))
1115   ;; Change \Delete etc to %Delete, so that the reader can read it.
1116   (subst-char-in-region (point-min) (point-max)
1117                         ?\\ ?% t)
1118   (let (start end articles groups uidnext elems permanent-flags)
1119     (dolist (elem sequences)
1120       (destructuring-bind (group-sequence flag-sequence totalp group) elem
1121         (setq start (point))
1122         ;; The EXAMINE was successful.
1123         (when (and (search-forward (format "\n%d OK " group-sequence) nil t)
1124                    (progn
1125                      (forward-line 1)
1126                      (setq end (point))
1127                      (goto-char start)
1128                      (setq permanent-flags
1129                            (and (search-forward "PERMANENTFLAGS "
1130                                                  (or end (point-min)) t)
1131                                 (read (current-buffer))))
1132                      (goto-char start)
1133                      (setq uidnext
1134                            (and (search-forward "UIDNEXT "
1135                                                  (or end (point-min)) t)
1136                                 (read (current-buffer))))
1137                      (goto-char end)
1138                      (forward-line -1))
1139                    ;; The UID FETCH FLAGS was successful.
1140                    (search-forward (format "\n%d OK " flag-sequence) nil t))
1141           (setq start (point))
1142           (goto-char end)
1143           (while (search-forward " FETCH " start t)
1144             (setq elems (read (current-buffer)))
1145             (push (cons (cadr (memq 'UID elems))
1146                         (cadr (memq 'FLAGS elems)))
1147                   articles))
1148           (push (nconc (list group uidnext totalp permanent-flags) articles)
1149                 groups)
1150           (setq articles nil))))
1151     groups))
1152
1153 (defun nnimap-find-process-buffer (buffer)
1154   (cadr (assoc buffer nnimap-connection-alist)))
1155
1156 (deffoo nnimap-request-post (&optional server)
1157   (setq nnimap-status-string "Read-only server")
1158   nil)
1159
1160 (defun nnimap-possibly-change-group (group server)
1161   (let ((open-result t))
1162     (when (and server
1163                (not (nnimap-server-opened server)))
1164       (setq open-result (nnimap-open-server server)))
1165     (cond
1166      ((not open-result)
1167       nil)
1168      ((not group)
1169       t)
1170      (t
1171       (with-current-buffer (nnimap-buffer)
1172         (if (equal group (nnimap-group nnimap-object))
1173             t
1174           (let ((result (nnimap-command "SELECT %S" (utf7-encode group t))))
1175             (when (car result)
1176               (setf (nnimap-group nnimap-object) group
1177                     (nnimap-select-result nnimap-object) result)
1178               result))))))))
1179
1180 (defun nnimap-find-connection (buffer)
1181   "Find the connection delivering to BUFFER."
1182   (let ((entry (assoc buffer nnimap-connection-alist)))
1183     (when entry
1184       (if (and (buffer-name (cadr entry))
1185                (get-buffer-process (cadr entry))
1186                (memq (process-status (get-buffer-process (cadr entry)))
1187                      '(open run)))
1188           (get-buffer-process (cadr entry))
1189         (setq nnimap-connection-alist (delq entry nnimap-connection-alist))
1190         nil))))
1191
1192 (defvar nnimap-sequence 0)
1193
1194 (defun nnimap-send-command (&rest args)
1195   (process-send-string
1196    (get-buffer-process (current-buffer))
1197    (nnimap-log-command
1198     (format "%d %s%s\n"
1199             (incf nnimap-sequence)
1200             (apply #'format args)
1201             (if (nnimap-newlinep nnimap-object)
1202                 ""
1203               "\r"))))
1204   nnimap-sequence)
1205
1206 (defun nnimap-log-command (command)
1207   (with-current-buffer (get-buffer-create "*imap log*")
1208     (goto-char (point-max))
1209     (insert (format-time-string "%H:%M:%S") " " command))
1210   command)
1211
1212 (defun nnimap-command (&rest args)
1213   (erase-buffer)
1214   (setf (nnimap-last-command-time nnimap-object) (current-time))
1215   (let* ((sequence (apply #'nnimap-send-command args))
1216          (response (nnimap-get-response sequence)))
1217     (if (equal (caar response) "OK")
1218         (cons t response)
1219       (nnheader-report 'nnimap "%s"
1220                        (mapconcat (lambda (a)
1221                                     (format "%s" a))
1222                                   (car response) " "))
1223       nil)))
1224
1225 (defun nnimap-get-response (sequence)
1226   (nnimap-wait-for-response sequence)
1227   (nnimap-parse-response))
1228
1229 (defun nnimap-wait-for-connection ()
1230   (let ((process (get-buffer-process (current-buffer))))
1231     (goto-char (point-min))
1232     (while (and (memq (process-status process)
1233                       '(open run))
1234                 (not (re-search-forward "^[*.] .*\n" nil t)))
1235       (nnheader-accept-process-output process)
1236       (goto-char (point-min)))
1237     (forward-line -1)
1238     (and (looking-at "[*.] \\([A-Z0-9]+\\)")
1239          (match-string 1))))
1240
1241 (defun nnimap-wait-for-response (sequence &optional messagep)
1242   (let ((process (get-buffer-process (current-buffer)))
1243         openp)
1244     (goto-char (point-max))
1245     (while (and (setq openp (memq (process-status process)
1246                                   '(open run)))
1247                 (not (re-search-backward
1248                       (format "^%d .*\n" sequence)
1249                       (if nnimap-streaming
1250                           (max (point-min) (- (point) 500))
1251                         (point-min))
1252                       t)))
1253       (when messagep
1254         (message "Read %dKB" (/ (buffer-size) 1000)))
1255       (nnheader-accept-process-output process)
1256       (goto-char (point-max)))
1257     openp))
1258
1259 (defun nnimap-parse-response ()
1260   (let ((lines (split-string (nnimap-last-response-string) "\r\n" t))
1261         result)
1262     (dolist (line lines)
1263       (push (cdr (nnimap-parse-line line)) result))
1264     ;; Return the OK/error code first, and then all the "continuation
1265     ;; lines" afterwards.
1266     (cons (pop result)
1267           (nreverse result))))
1268
1269 ;; Parse an IMAP response line lightly.  They look like
1270 ;; "* OK [UIDVALIDITY 1164213559] UIDs valid", typically, so parse
1271 ;; the lines into a list of strings and lists of string.
1272 (defun nnimap-parse-line (line)
1273   (let (char result)
1274     (with-temp-buffer
1275       (insert line)
1276       (goto-char (point-min))
1277       (while (not (eobp))
1278         (if (eql (setq char (following-char)) ? )
1279             (forward-char 1)
1280           (push
1281            (cond
1282             ((eql char ?\[)
1283              (split-string (buffer-substring
1284                             (1+ (point))
1285                             (1- (search-forward "]" (line-end-position) 'move)))))
1286             ((eql char ?\()
1287              (split-string (buffer-substring
1288                             (1+ (point))
1289                             (1- (search-forward ")" (line-end-position) 'move)))))
1290             ((eql char ?\")
1291              (forward-char 1)
1292              (buffer-substring
1293               (point)
1294               (1- (or (search-forward "\"" (line-end-position) 'move)
1295                       (point)))))
1296             (t
1297              (buffer-substring (point) (if (search-forward " " nil t)
1298                                            (1- (point))
1299                                          (goto-char (point-max))))))
1300            result)))
1301       (nreverse result))))
1302
1303 (defun nnimap-last-response-string ()
1304   (save-excursion
1305     (forward-line 1)
1306     (let ((end (point)))
1307       (forward-line -1)
1308       (when (not (bobp))
1309         (forward-line -1)
1310         (while (and (not (bobp))
1311                     (eql (following-char) ?*))
1312           (forward-line -1))
1313         (unless (eql (following-char) ?*)
1314           (forward-line 1)))
1315       (buffer-substring (point) end))))
1316
1317 (defun nnimap-get-responses (sequences)
1318   (let (responses)
1319     (dolist (sequence sequences)
1320       (goto-char (point-min))
1321       (when (re-search-forward (format "^%d " sequence) nil t)
1322         (push (list sequence (nnimap-parse-response))
1323               responses)))
1324     responses))
1325
1326 (defvar nnimap-incoming-split-list nil)
1327
1328 (defun nnimap-fetch-inbox (articles)
1329   (erase-buffer)
1330   (nnimap-wait-for-response
1331    (nnimap-send-command
1332     "UID FETCH %s %s"
1333     (nnimap-article-ranges articles)
1334     (format "(UID %s%s)"
1335             (format
1336              (if (nnimap-ver4-p)
1337                  "BODY.PEEK[HEADER] BODY.PEEK"
1338                "RFC822.PEEK"))
1339             (if nnimap-split-download-body-default
1340                 "[]"
1341               "[1]")))
1342    t))
1343
1344 (defun nnimap-split-incoming-mail ()
1345   (with-current-buffer (nnimap-buffer)
1346     (let ((nnimap-incoming-split-list nil)
1347           (nnmail-split-methods (if (eq nnimap-split-methods 'default)
1348                                     nnmail-split-methods
1349                                   nnimap-split-methods))
1350           (nnmail-split-fancy (or nnimap-split-fancy
1351                                   nnmail-split-fancy))
1352           (nnmail-inhibit-default-split-group t)
1353           (groups (nnimap-get-groups))
1354           new-articles)
1355       (erase-buffer)
1356       (nnimap-command "SELECT %S" nnimap-inbox)
1357       (setq new-articles (nnimap-new-articles (nnimap-get-flags "1:*")))
1358       (when new-articles
1359         (nnimap-fetch-inbox new-articles)
1360         (nnimap-transform-split-mail)
1361         (nnheader-ms-strip-cr)
1362         (nnmail-cache-open)
1363         (nnmail-split-incoming (current-buffer)
1364                                #'nnimap-save-mail-spec
1365                                nil nil
1366                                #'nnimap-dummy-active-number
1367                                #'nnimap-save-mail-spec)
1368         (when nnimap-incoming-split-list
1369           (let ((specs (nnimap-make-split-specs nnimap-incoming-split-list))
1370                 sequences junk-articles)
1371             ;; Create any groups that doesn't already exist on the
1372             ;; server first.
1373             (dolist (spec specs)
1374               (when (and (not (member (car spec) groups))
1375                          (not (eq (car spec) 'junk)))
1376                 (nnimap-command "CREATE %S" (utf7-encode (car spec) t))))
1377             ;; Then copy over all the messages.
1378             (erase-buffer)
1379             (dolist (spec specs)
1380               (let ((group (car spec))
1381                     (ranges (cdr spec)))
1382                 (if (eq group 'junk)
1383                     (setq junk-articles ranges)
1384                   (push (list (nnimap-send-command
1385                                "UID COPY %s %S"
1386                                (nnimap-article-ranges ranges)
1387                                (utf7-encode group t))
1388                               ranges)
1389                         sequences))))
1390             ;; Wait for the last COPY response...
1391             (when sequences
1392               (nnimap-wait-for-response (caar sequences))
1393               ;; And then mark the successful copy actions as deleted,
1394               ;; and possibly expunge them.
1395               (nnimap-mark-and-expunge-incoming
1396                (nnimap-parse-copied-articles sequences)))
1397             (nnimap-mark-and-expunge-incoming junk-articles)))))))
1398
1399 (defun nnimap-mark-and-expunge-incoming (range)
1400   (when range
1401     (setq range (nnimap-article-ranges range))
1402     (erase-buffer)
1403     (let ((sequence
1404            (nnimap-send-command
1405             "UID STORE %s +FLAGS.SILENT (\\Deleted)" range)))
1406       (cond
1407        ;; If the server supports it, we now delete the message we have
1408        ;; just copied over.
1409        ((member "UIDPLUS" (nnimap-capabilities nnimap-object))
1410         (setq sequence (nnimap-send-command "UID EXPUNGE %s" range)))
1411        ;; If it doesn't support UID EXPUNGE, then we only expunge if the
1412        ;; user has configured it.
1413        (nnimap-expunge
1414         (setq sequence (nnimap-send-command "EXPUNGE"))))
1415       (nnimap-wait-for-response sequence))))
1416
1417 (defun nnimap-parse-copied-articles (sequences)
1418   (let (sequence copied range)
1419     (goto-char (point-min))
1420     (while (re-search-forward "^\\([0-9]+\\) OK " nil t)
1421       (setq sequence (string-to-number (match-string 1)))
1422       (when (setq range (cadr (assq sequence sequences)))
1423         (push (gnus-uncompress-range range) copied)))
1424     (gnus-compress-sequence (sort (apply #'nconc copied) #'<))))
1425
1426 (defun nnimap-new-articles (flags)
1427   (let (new)
1428     (dolist (elem flags)
1429       (when (or (null (cdr elem))
1430                 (and (not (memq '%Deleted (cdr elem)))
1431                      (not (memq '%Seen (cdr elem)))))
1432         (push (car elem) new)))
1433     (gnus-compress-sequence (nreverse new))))
1434
1435 (defun nnimap-make-split-specs (list)
1436   (let ((specs nil)
1437         entry)
1438     (dolist (elem list)
1439       (destructuring-bind (article spec) elem
1440         (dolist (group (delete nil (mapcar #'car spec)))
1441           (unless (setq entry (assoc group specs))
1442             (push (setq entry (list group)) specs))
1443           (setcdr entry (cons article (cdr entry))))))
1444     (dolist (entry specs)
1445       (setcdr entry (gnus-compress-sequence (sort (cdr entry) #'<))))
1446     specs))
1447
1448 (defun nnimap-transform-split-mail ()
1449   (goto-char (point-min))
1450   (let (article bytes)
1451     (block nil
1452       (while (not (eobp))
1453         (while (not (looking-at "^\\* [0-9]+ FETCH.*UID \\([0-9]+\\)"))
1454           (delete-region (point) (progn (forward-line 1) (point)))
1455           (when (eobp)
1456             (return)))
1457         (setq article (match-string 1)
1458               bytes (nnimap-get-length))
1459         (delete-region (line-beginning-position) (line-end-position))
1460         ;; Insert MMDF separator, and a way to remember what this
1461         ;; article UID is.
1462         (insert (format "\^A\^A\^A\^A\n\nX-nnimap-article: %s" article))
1463         (forward-char (1+ bytes))
1464         (setq bytes (nnimap-get-length))
1465         (delete-region (line-beginning-position) (line-end-position))
1466         (forward-char (1+ bytes))
1467         (delete-region (line-beginning-position) (line-end-position))))))
1468
1469 (defun nnimap-dummy-active-number (group &optional server)
1470   1)
1471
1472 (defun nnimap-save-mail-spec (group-art &optional server full-nov)
1473   (let (article)
1474     (goto-char (point-min))
1475     (if (not (re-search-forward "X-nnimap-article: \\([0-9]+\\)" nil t))
1476         (error "Invalid nnimap mail")
1477       (setq article (string-to-number (match-string 1))))
1478     (push (list article
1479                 (if (eq group-art 'junk)
1480                     (list (cons 'junk 1))
1481                   group-art))
1482           nnimap-incoming-split-list)))
1483
1484 (provide 'nnimap)
1485
1486 ;;; nnimap.el ends here