cgit.sxemacs.org Git - gnus/blob - lisp/mm-uu.el

   1 ;;; mm-uu.el --- Return uu stuff as mm handles
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 ;; Author: Shenghuo Zhu <zsh@cs.rochester.edu>
   7 ;; Keywords: postscript uudecode binhex shar forward gnatsweb pgp
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 3, or (at your option)
  14 ;; any later version.
  15 ;;
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'cl))
  31 (require 'mail-parse)
  32 (require 'nnheader)
  33 (require 'mm-decode)
  34 (require 'mailcap)
  35 (require 'mml2015)
  36
  37 (autoload 'uudecode-decode-region "uudecode")
  38 (autoload 'uudecode-decode-region-external "uudecode")
  39 (autoload 'uudecode-decode-region-internal "uudecode")
  40
  41 (autoload 'binhex-decode-region "binhex")
  42 (autoload 'binhex-decode-region-external "binhex")
  43 (autoload 'binhex-decode-region-internal "binhex")
  44
  45 (autoload 'yenc-decode-region "yenc")
  46 (autoload 'yenc-extract-filename "yenc")
  47
  48 (defcustom mm-uu-decode-function 'uudecode-decode-region
  49   "*Function to uudecode.
  50 Internal function is done in Lisp by default, therefore decoding may
  51 appear to be horribly slow.  You can make Gnus use an external
  52 decoder, such as uudecode."
  53   :type '(choice
  54           (function-item :tag "Auto detect" uudecode-decode-region)
  55           (function-item :tag "Internal" uudecode-decode-region-internal)
  56           (function-item :tag "External" uudecode-decode-region-external))
  57   :group 'gnus-article-mime)
  58
  59 (defcustom mm-uu-binhex-decode-function 'binhex-decode-region
  60   "*Function to binhex decode.
  61 Internal function is done in elisp by default, therefore decoding may
  62 appear to be horribly slow . You can make Gnus use the external Unix
  63 decoder, such as hexbin."
  64   :type '(choice (function-item :tag "Auto detect" binhex-decode-region)
  65                  (function-item :tag "Internal" binhex-decode-region-internal)
  66                  (function-item :tag "External" binhex-decode-region-external))
  67   :group 'gnus-article-mime)
  68
  69 (defvar mm-uu-yenc-decode-function 'yenc-decode-region)
  70
  71 (defvar mm-uu-beginning-regexp nil)
  72
  73 (defvar mm-dissect-disposition "inline"
  74   "The default disposition of uu parts.
  75 This can be either \"inline\" or \"attachment\".")
  76
  77 (defcustom mm-uu-emacs-sources-regexp "\\.emacs\\.sources"
  78   "The regexp of Emacs sources groups."
  79   :version "22.1"
  80   :type 'regexp
  81   :group 'gnus-article-mime)
  82
  83 (defcustom mm-uu-diff-groups-regexp
  84   "\\(gmane\\|gnu\\)\\..*\\(diff\\|commit\\|cvs\\|bug\\|devel\\)"
  85   "Regexp matching diff groups."
  86   :version "22.1"
  87   :type 'regexp
  88   :group 'gnus-article-mime)
  89
  90 (defcustom mm-uu-tex-groups-regexp "\\.tex\\>"
  91   "*Regexp matching TeX groups."
  92   :version "23.0"
  93   :type 'regexp
  94   :group 'gnus-article-mime)
  95
  96 (defvar mm-uu-type-alist
  97   '((postscript
  98      "^%!PS-"
  99      "^%%EOF$"
 100      mm-uu-postscript-extract
 101      nil)
 102     (uu ;; Maybe we should have a more strict test here.
 103      "^begin[ \t]+0?[0-7][0-7][0-7][ \t]+"
 104      "^end[ \t]*$"
 105      mm-uu-uu-extract
 106      mm-uu-uu-filename)
 107     (binhex
 108      "^:.\\{63,63\\}$"
 109      ":$"
 110      mm-uu-binhex-extract
 111      nil
 112      mm-uu-binhex-filename)
 113     (yenc
 114      "^=ybegin.*size=[0-9]+.*name=.*$"
 115      "^=yend.*size=[0-9]+"
 116      mm-uu-yenc-extract
 117      mm-uu-yenc-filename)
 118     (shar
 119      "^#! */bin/sh"
 120      "^exit 0$"
 121      mm-uu-shar-extract)
 122     (forward
 123      ;; Thanks to Edward J. Sabol <sabol@alderaan.gsfc.nasa.gov> and
 124      ;; Peter von der Ah\'e <pahe@daimi.au.dk>
 125      "^-+ \\(Start of \\)?Forwarded message"
 126      "^-+ End \\(of \\)?forwarded message"
 127      mm-uu-forward-extract
 128      nil
 129      mm-uu-forward-test)
 130     (gnatsweb
 131      "^----gnatsweb-attachment----"
 132      nil
 133      mm-uu-gnatsweb-extract)
 134     (pgp-signed
 135      "^-----BEGIN PGP SIGNED MESSAGE-----"
 136      "^-----END PGP SIGNATURE-----"
 137      mm-uu-pgp-signed-extract
 138      nil
 139      nil)
 140     (pgp-encrypted
 141      "^-----BEGIN PGP MESSAGE-----"
 142      "^-----END PGP MESSAGE-----"
 143      mm-uu-pgp-encrypted-extract
 144      nil
 145      nil)
 146     (pgp-key
 147      "^-----BEGIN PGP PUBLIC KEY BLOCK-----"
 148      "^-----END PGP PUBLIC KEY BLOCK-----"
 149      mm-uu-pgp-key-extract
 150      mm-uu-gpg-key-skip-to-last
 151      nil)
 152     (emacs-sources
 153      "^;;;?[ \t]*[^ \t]+\\.el[ \t]*--"
 154      "^;;;?[ \t]*\\([^ \t]+\\.el\\)[ \t]+ends here"
 155      mm-uu-emacs-sources-extract
 156      nil
 157      mm-uu-emacs-sources-test)
 158     (diff
 159      "^Index: "
 160      nil
 161      mm-uu-diff-extract
 162      nil
 163      mm-uu-diff-test)
 164     (message-marks
 165      ;; Text enclosed with tags similar to `message-mark-insert-begin' and
 166      ;; `message-mark-insert-end'.  Don't use those variables to avoid
 167      ;; dependency on `message.el'.
 168      "^-+[8<>]*-\\{9,\\}[a-z ]+-\\{9,\\}[a-z ]+-\\{9,\\}[8<>]*-+$"
 169      "^-+[8<>]*-\\{9,\\}[a-z ]+-\\{9,\\}[a-z ]+-\\{9,\\}[8<>]*-+$"
 170      (lambda () (mm-uu-verbatim-marks-extract 0 -1 1 -1))
 171      nil)
 172     ;; Omitting [a-z8<] leads to false positives (bogus signature separators
 173     ;; and mailing list banners).
 174     (insert-marks
 175      "^ *\\(-\\|_\\)\\{30,\\}.*[a-z8<].*\\(-\\|_\\)\\{30,\\} *$"
 176      "^ *\\(-\\|_\\)\\{30,\\}.*[a-z8<].*\\(-\\|_\\)\\{30,\\} *$"
 177      (lambda () (mm-uu-verbatim-marks-extract 0 0 1 -1))
 178      nil)
 179     (verbatim-marks
 180      ;; slrn-style verbatim marks, see
 181      ;; http://www.slrn.org/manual/slrn-manual-6.html#ss6.81
 182      "^#v\\+"
 183      "^#v\\-$"
 184      (lambda () (mm-uu-verbatim-marks-extract 0 0))
 185      nil)
 186     (LaTeX
 187      "^\\([\\\\%][^\n]+\n\\)*\\\\documentclass.*[[{%]"
 188      "^\\\\end{document}"
 189      mm-uu-latex-extract
 190      nil
 191      mm-uu-latex-test))
 192   "A list of specifications for non-MIME attachments.
 193 Each element consist of the following entries: label,
 194 start-regexp, end-regexp, extract-function, test-function.
 195
 196 After modifying this list you must run \\[mm-uu-configure].
 197
 198 You can disable elements from this list by customizing
 199 `mm-uu-configure-list'.")
 200
 201 (defcustom mm-uu-configure-list '((shar . disabled))
 202   "A list of mm-uu configuration.
 203 To disable dissecting shar codes, for instance, add
 204 `(shar . disabled)' to this list."
 205   :type 'alist
 206   :options (mapcar (lambda (entry)
 207                      (list (car entry) '(const disabled)))
 208                    mm-uu-type-alist)
 209   :group 'gnus-article-mime)
 210
 211 (defvar mm-uu-text-plain-type '("text/plain" (charset . gnus-decoded))
 212   "MIME type and parameters for text/plain parts.
 213 `gnus-decoded' is a fake charset, which means no further decoding.")
 214
 215 ;; functions
 216
 217 (defsubst mm-uu-type (entry)
 218   (car entry))
 219
 220 (defsubst mm-uu-beginning-regexp (entry)
 221   (nth 1 entry))
 222
 223 (defsubst mm-uu-end-regexp (entry)
 224   (nth 2 entry))
 225
 226 (defsubst mm-uu-function-extract (entry)
 227   (nth 3 entry))
 228
 229 (defsubst mm-uu-function-1 (entry)
 230   (nth 4 entry))
 231
 232 (defsubst mm-uu-function-2 (entry)
 233   (nth 5 entry))
 234
 235 ;; In Emacs 22, we could use `min-colors' in the face definition.  But Emacs
 236 ;; 21 and XEmacs don't support it.
 237 (defcustom mm-uu-hide-markers
 238   (< 16 (or (and (fboundp 'defined-colors)
 239                  (length (defined-colors)))
 240             (and (fboundp 'device-color-cells)
 241                  (device-color-cells))
 242             0))
 243   "If non-nil, hide verbatim markers.
 244 The value should be nil on displays where the face
 245 `mm-uu-extract' isn't distinguishable to the face `default'."
 246   :type '(choice (const :tag "Hide" t)
 247                  (const :tag "Don't hide" nil))
 248   :version "23.0" ;; No Gnus
 249   :group 'gnus-article-mime)
 250
 251 (defface mm-uu-extract '(;; Colors from `gnus-cite-3' plus background:
 252                          (((class color)
 253                            (background dark))
 254                           (:foreground "light yellow"
 255                            :background "dark green"))
 256                          (((class color)
 257                            (background light))
 258                           (:foreground "dark green"
 259                            :background "light yellow"))
 260                          (t
 261                           ()))
 262   "Face for extracted buffers."
 263   ;; See `mm-uu-verbatim-marks-extract'.
 264   :version "23.0" ;; No Gnus
 265   :group 'gnus-article-mime)
 266
 267 (defun mm-uu-copy-to-buffer (&optional from to properties)
 268   "Copy the contents of the current buffer to a fresh buffer.
 269 Return that buffer.
 270
 271 If PROPERTIES is non-nil, PROPERTIES are applied to the buffer,
 272 see `set-text-properties'.  If PROPERTIES equals t, this means to
 273 apply the face `mm-uu-extract'."
 274   (let ((obuf (current-buffer))
 275         (coding-system
 276          ;; Might not exist in non-MULE XEmacs
 277          (when (boundp 'buffer-file-coding-system)
 278            buffer-file-coding-system)))
 279     (with-current-buffer (generate-new-buffer " *mm-uu*")
 280       (setq buffer-file-coding-system coding-system)
 281       (insert-buffer-substring obuf from to)
 282       (cond ((eq properties  t)
 283              (set-text-properties (point-min) (point-max)
 284                                   '(face mm-uu-extract)))
 285             (properties
 286              (set-text-properties (point-min) (point-max) properties)))
 287       (current-buffer))))
 288
 289 (defun mm-uu-configure-p  (key val)
 290   (member (cons key val) mm-uu-configure-list))
 291
 292 (defun mm-uu-configure (&optional symbol value)
 293   "Configure detection of non-MIME attachments."
 294   (interactive)
 295   (if symbol (set-default symbol value))
 296   (setq mm-uu-beginning-regexp nil)
 297   (mapcar (lambda (entry)
 298              (if (mm-uu-configure-p (mm-uu-type entry) 'disabled)
 299                  nil
 300                (setq mm-uu-beginning-regexp
 301                      (concat mm-uu-beginning-regexp
 302                              (if mm-uu-beginning-regexp "\\|")
 303                              (mm-uu-beginning-regexp entry)))))
 304           mm-uu-type-alist))
 305
 306 (mm-uu-configure)
 307
 308 (eval-when-compile
 309   (defvar file-name)
 310   (defvar start-point)
 311   (defvar end-point)
 312   (defvar entry))
 313
 314 (defun mm-uu-uu-filename ()
 315   (if (looking-at ".+")
 316       (setq file-name
 317             (let ((nnheader-file-name-translation-alist
 318                    '((?/ . ?,) (?\  . ?_) (?* . ?_) (?$ . ?_))))
 319               (nnheader-translate-file-chars (match-string 0))))))
 320
 321 (defun mm-uu-binhex-filename ()
 322   (setq file-name
 323         (ignore-errors
 324           (binhex-decode-region start-point end-point t))))
 325
 326 (defun mm-uu-yenc-filename ()
 327   (goto-char start-point)
 328   (setq file-name
 329         (ignore-errors
 330           (yenc-extract-filename))))
 331
 332 (defun mm-uu-forward-test ()
 333   (save-excursion
 334     (goto-char start-point)
 335     (forward-line)
 336     (looking-at "[\r\n]*[a-zA-Z][a-zA-Z0-9-]*:")))
 337
 338 (defun mm-uu-postscript-extract ()
 339   (mm-make-handle (mm-uu-copy-to-buffer start-point end-point)
 340                   '("application/postscript")))
 341
 342 (defun mm-uu-verbatim-marks-extract (start-offset end-offset
 343                                                   &optional
 344                                                   start-hide
 345                                                   end-hide)
 346   (let ((start (or (and mm-uu-hide-markers
 347                         start-hide)
 348                    start-offset
 349                    1))
 350         (end   (or (and mm-uu-hide-markers
 351                         end-hide)
 352                    end-offset
 353                    -1)))
 354     (mm-make-handle
 355      (mm-uu-copy-to-buffer
 356       (progn (goto-char start-point)
 357              (forward-line start)
 358              (point))
 359       (progn (goto-char end-point)
 360            (forward-line end)
 361            (point))
 362       t)
 363      '("text/x-verbatim" (charset . gnus-decoded)))))
 364
 365 (defun mm-uu-latex-extract ()
 366   (mm-make-handle
 367    (mm-uu-copy-to-buffer start-point end-point t)
 368    ;; application/x-tex?
 369    '("text/x-verbatim" (charset . gnus-decoded))))
 370
 371 (defun mm-uu-emacs-sources-extract ()
 372   (mm-make-handle (mm-uu-copy-to-buffer start-point end-point)
 373                   '("application/emacs-lisp" (charset . gnus-decoded))
 374                   nil nil
 375                   (list mm-dissect-disposition
 376                         (cons 'filename file-name))))
 377
 378 (eval-when-compile
 379   (defvar gnus-newsgroup-name))
 380
 381 (defun mm-uu-emacs-sources-test ()
 382   (setq file-name (match-string 1))
 383   (and gnus-newsgroup-name
 384        mm-uu-emacs-sources-regexp
 385        (string-match mm-uu-emacs-sources-regexp gnus-newsgroup-name)))
 386
 387 (defun mm-uu-diff-extract ()
 388   (mm-make-handle (mm-uu-copy-to-buffer start-point end-point)
 389                   '("text/x-patch" (charset . gnus-decoded))))
 390
 391 (defun mm-uu-diff-test ()
 392   (and gnus-newsgroup-name
 393        mm-uu-diff-groups-regexp
 394        (string-match mm-uu-diff-groups-regexp gnus-newsgroup-name)))
 395
 396 (defun mm-uu-latex-test ()
 397   (and gnus-newsgroup-name
 398        mm-uu-tex-groups-regexp
 399        (string-match mm-uu-tex-groups-regexp gnus-newsgroup-name)))
 400
 401 (defun mm-uu-forward-extract ()
 402   (mm-make-handle (mm-uu-copy-to-buffer
 403                    (progn (goto-char start-point) (forward-line) (point))
 404                    (progn (goto-char end-point) (forward-line -1) (point)))
 405                   '("message/rfc822" (charset . gnus-decoded))))
 406
 407 (defun mm-uu-uu-extract ()
 408   (mm-make-handle (mm-uu-copy-to-buffer start-point end-point)
 409                   (list (or (and file-name
 410                                  (string-match "\\.[^\\.]+$"
 411                                                file-name)
 412                                  (mailcap-extension-to-mime
 413                                   (match-string 0 file-name)))
 414                             "application/octet-stream"))
 415                   'x-uuencode nil
 416                   (if (and file-name (not (equal file-name "")))
 417                       (list mm-dissect-disposition
 418                             (cons 'filename file-name)))))
 419
 420 (defun mm-uu-binhex-extract ()
 421   (mm-make-handle (mm-uu-copy-to-buffer start-point end-point)
 422                   (list (or (and file-name
 423                                  (string-match "\\.[^\\.]+$" file-name)
 424                                  (mailcap-extension-to-mime
 425                                   (match-string 0 file-name)))
 426                             "application/octet-stream"))
 427                   'x-binhex nil
 428                   (if (and file-name (not (equal file-name "")))
 429                       (list mm-dissect-disposition
 430                             (cons 'filename file-name)))))
 431
 432 (defun mm-uu-yenc-extract ()
 433   (mm-make-handle (mm-uu-copy-to-buffer start-point end-point)
 434                   (list (or (and file-name
 435                                  (string-match "\\.[^\\.]+$" file-name)
 436                                  (mailcap-extension-to-mime
 437                                   (match-string 0 file-name)))
 438                             "application/octet-stream"))
 439                   'x-yenc nil
 440                   (if (and file-name (not (equal file-name "")))
 441                       (list mm-dissect-disposition
 442                             (cons 'filename file-name)))))
 443
 444
 445 (defun mm-uu-shar-extract ()
 446   (mm-make-handle (mm-uu-copy-to-buffer start-point end-point)
 447                   '("application/x-shar")))
 448
 449 (defun mm-uu-gnatsweb-extract ()
 450   (save-restriction
 451     (goto-char start-point)
 452     (forward-line)
 453     (narrow-to-region (point) end-point)
 454     (mm-dissect-buffer t)))
 455
 456 (defun mm-uu-pgp-signed-test (&rest rest)
 457   (and
 458    mml2015-use
 459    (mml2015-clear-verify-function)
 460    (cond
 461     ((eq mm-verify-option 'never) nil)
 462     ((eq mm-verify-option 'always) t)
 463     ((eq mm-verify-option 'known) t)
 464     (t (prog1
 465            (y-or-n-p "Verify pgp signed part? ")
 466          (message ""))))))
 467
 468 (eval-when-compile
 469   (defvar gnus-newsgroup-charset))
 470
 471 (defun mm-uu-pgp-signed-extract-1 (handles ctl)
 472   (let ((buf (mm-uu-copy-to-buffer (point-min) (point-max))))
 473     (with-current-buffer buf
 474       (if (mm-uu-pgp-signed-test)
 475           (progn
 476             (mml2015-clean-buffer)
 477             (let ((coding-system-for-write (or gnus-newsgroup-charset
 478                                                'iso-8859-1))
 479                   (coding-system-for-read (or gnus-newsgroup-charset
 480                                               'iso-8859-1)))
 481               (funcall (mml2015-clear-verify-function))))
 482         (when (and mml2015-use (null (mml2015-clear-verify-function)))
 483           (mm-set-handle-multipart-parameter
 484            mm-security-handle 'gnus-details
 485            (format "Clear verification not supported by `%s'.\n" mml2015-use)))
 486         (mml2015-extract-cleartext-signature))
 487       (list (mm-make-handle buf mm-uu-text-plain-type)))))
 488
 489 (defun mm-uu-pgp-signed-extract ()
 490   (let ((mm-security-handle (list (format "multipart/signed"))))
 491     (mm-set-handle-multipart-parameter
 492      mm-security-handle 'protocol "application/x-gnus-pgp-signature")
 493     (save-restriction
 494       (narrow-to-region start-point end-point)
 495       (add-text-properties 0 (length (car mm-security-handle))
 496                            (list 'buffer (mm-uu-copy-to-buffer))
 497                            (car mm-security-handle))
 498       (setcdr mm-security-handle
 499               (mm-uu-pgp-signed-extract-1 nil
 500                                           mm-security-handle)))
 501     mm-security-handle))
 502
 503 (defun mm-uu-pgp-encrypted-test (&rest rest)
 504   (and
 505    mml2015-use
 506    (mml2015-clear-decrypt-function)
 507    (cond
 508     ((eq mm-decrypt-option 'never) nil)
 509     ((eq mm-decrypt-option 'always) t)
 510     ((eq mm-decrypt-option 'known) t)
 511     (t (prog1
 512            (y-or-n-p "Decrypt pgp encrypted part? ")
 513          (message ""))))))
 514
 515 (defun mm-uu-pgp-encrypted-extract-1 (handles ctl)
 516   (let ((buf (mm-uu-copy-to-buffer (point-min) (point-max)))
 517         (first t)
 518         charset)
 519     ;; Make sure there's a blank line between header and body.
 520     (with-current-buffer buf
 521       (goto-char (point-min))
 522       (while (prog2
 523                  (forward-line 1)
 524                  (if first
 525                      (looking-at "[^\t\n ]+:")
 526                    (looking-at "[^\t\n ]+:\\|[\t ]"))
 527                (setq first nil)))
 528       (unless (memq (char-after) '(?\n nil))
 529         (insert "\n"))
 530       (save-restriction
 531         (narrow-to-region (point-min) (point))
 532         (setq charset (mail-fetch-field "charset")))
 533       (if (and (mm-uu-pgp-encrypted-test)
 534                (progn
 535                  (mml2015-clean-buffer)
 536                  (funcall (mml2015-clear-decrypt-function))
 537                  (equal (mm-handle-multipart-ctl-parameter mm-security-handle
 538                                                            'gnus-info)
 539                         "OK")))
 540           (progn
 541             ;; Decode charset.
 542             (if (and (or charset
 543                          (setq charset gnus-newsgroup-charset))
 544                      (setq charset (mm-charset-to-coding-system charset))
 545                      (not (eq charset 'ascii)))
 546                 ;; Assume that buffer's multibyteness is turned off.
 547                 ;; See `mml2015-pgg-clear-decrypt'.
 548                 (insert (mm-decode-coding-string (prog1
 549                                                      (buffer-string)
 550                                                    (erase-buffer)
 551                                                    (mm-enable-multibyte))
 552                                                  charset))
 553               (mm-enable-multibyte))
 554             (list (mm-make-handle buf mm-uu-text-plain-type)))
 555         (list (mm-make-handle buf '("application/pgp-encrypted")))))))
 556
 557 (defun mm-uu-pgp-encrypted-extract ()
 558   (let ((mm-security-handle (list (format "multipart/encrypted"))))
 559     (mm-set-handle-multipart-parameter
 560      mm-security-handle 'protocol "application/x-gnus-pgp-encrypted")
 561     (save-restriction
 562       (narrow-to-region start-point end-point)
 563       (add-text-properties 0 (length (car mm-security-handle))
 564                            (list 'buffer (mm-uu-copy-to-buffer))
 565                            (car mm-security-handle))
 566       (setcdr mm-security-handle
 567               (mm-uu-pgp-encrypted-extract-1 nil
 568                                              mm-security-handle)))
 569     mm-security-handle))
 570
 571 (defun mm-uu-gpg-key-skip-to-last ()
 572   (let ((point (point))
 573         (end-regexp (mm-uu-end-regexp entry))
 574         (beginning-regexp (mm-uu-beginning-regexp entry)))
 575     (when (and end-regexp
 576                (not (mm-uu-configure-p (mm-uu-type entry) 'disabled)))
 577       (while (re-search-forward end-regexp nil t)
 578         (skip-chars-forward " \t\n\r")
 579         (if (looking-at beginning-regexp)
 580             (setq point (match-end 0)))))
 581     (goto-char point)))
 582
 583 (defun mm-uu-pgp-key-extract ()
 584   (let ((buf (mm-uu-copy-to-buffer start-point end-point)))
 585     (mm-make-handle buf
 586                     '("application/pgp-keys"))))
 587
 588 ;;;###autoload
 589 (defun mm-uu-dissect (&optional noheader mime-type)
 590   "Dissect the current buffer and return a list of uu handles.
 591 The optional NOHEADER means there's no header in the buffer.
 592 MIME-TYPE specifies a MIME type and parameters, which defaults to the
 593 value of `mm-uu-text-plain-type'."
 594   (let ((case-fold-search t)
 595         (mm-uu-text-plain-type (or mime-type mm-uu-text-plain-type))
 596         text-start start-point end-point file-name result entry func)
 597     (save-excursion
 598       (goto-char (point-min))
 599       (cond
 600        (noheader)
 601        ((looking-at "\n")
 602         (forward-line))
 603        ((search-forward "\n\n" nil t)
 604         t)
 605        (t (goto-char (point-max))))
 606       (setq text-start (point))
 607       (while (re-search-forward mm-uu-beginning-regexp nil t)
 608         (setq start-point (match-beginning 0)
 609               entry nil)
 610         (let ((alist mm-uu-type-alist)
 611               (beginning-regexp (match-string 0)))
 612           (while (not entry)
 613             (if (string-match (mm-uu-beginning-regexp (car alist))
 614                               beginning-regexp)
 615                 (setq entry (car alist))
 616               (pop alist))))
 617         (if (setq func (mm-uu-function-1 entry))
 618             (funcall func))
 619         (forward-line);; in case of failure
 620         (when (and (not (mm-uu-configure-p (mm-uu-type entry) 'disabled))
 621                    (let ((end-regexp (mm-uu-end-regexp entry)))
 622                      (if (not end-regexp)
 623                          (or (setq end-point (point-max)) t)
 624                        (prog1
 625                            (re-search-forward end-regexp nil t)
 626                          (forward-line)
 627                          (setq end-point (point)))))
 628                    (or (not (setq func (mm-uu-function-2 entry)))
 629                        (funcall func)))
 630           (if (and (> start-point text-start)
 631                    (progn
 632                      (goto-char text-start)
 633                      (re-search-forward "." start-point t)))
 634               (push
 635                (mm-make-handle (mm-uu-copy-to-buffer text-start start-point)
 636                                mm-uu-text-plain-type)
 637                result))
 638           (push
 639            (funcall (mm-uu-function-extract entry))
 640            result)
 641           (goto-char (setq text-start end-point))))
 642       (when result
 643         (if (and (> (point-max) (1+ text-start))
 644                  (save-excursion
 645                    (goto-char text-start)
 646                    (re-search-forward "." nil t)))
 647             (push
 648              (mm-make-handle (mm-uu-copy-to-buffer text-start (point-max))
 649                              mm-uu-text-plain-type)
 650              result))
 651         (setq result (cons "multipart/mixed" (nreverse result))))
 652       result)))
 653
 654 ;;;###autoload
 655 (defun mm-uu-dissect-text-parts (handle &optional decoded)
 656   "Dissect text parts and put uu handles into HANDLE.
 657 Assume text has been decoded if DECODED is non-nil."
 658   (let ((buffer (mm-handle-buffer handle)))
 659     (cond ((stringp buffer)
 660            (dolist (elem (cdr handle))
 661              (mm-uu-dissect-text-parts elem decoded)))
 662           ((bufferp buffer)
 663            (let ((type (mm-handle-media-type handle))
 664                  (case-fold-search t) ;; string-match
 665                  children charset encoding)
 666              (when (and
 667                     (stringp type)
 668                     ;; Mutt still uses application/pgp even though
 669                     ;; it has already been withdrawn.
 670                     (string-match "\\`text/\\|\\`application/pgp\\'" type)
 671                     (setq
 672                      children
 673                      (with-current-buffer buffer
 674                        (cond
 675                         ((or decoded
 676                              (eq (setq charset (mail-content-type-get
 677                                                 (mm-handle-type handle)
 678                                                 'charset))
 679                                  'gnus-decoded))
 680                          (setq decoded t)
 681                          (mm-uu-dissect
 682                           t (cons type '((charset . gnus-decoded)))))
 683                         (charset
 684                          (setq decoded t)
 685                          (mm-with-multibyte-buffer
 686                            (insert (mm-decode-string (mm-get-part handle)
 687                                                      charset))
 688                            (mm-uu-dissect
 689                             t (cons type '((charset . gnus-decoded))))))
 690                         ((setq encoding (mm-handle-encoding handle))
 691                          (setq decoded nil)
 692                          ;; Inherit the multibyteness of the `buffer'.
 693                          (with-temp-buffer
 694                            (insert-buffer-substring buffer)
 695                            (mm-decode-content-transfer-encoding
 696                             encoding type)
 697                            (mm-uu-dissect t (list type))))
 698                         (t
 699                          (setq decoded nil)
 700                          (mm-uu-dissect t (list type)))))))
 701                ;; Ignore it if a given part is dissected into a single
 702                ;; part of which the type is the same as the given one.
 703                (if (and (<= (length children) 2)
 704                         (string-equal (mm-handle-media-type (cadr children))
 705                                       type))
 706                    (kill-buffer (mm-handle-buffer (cadr children)))
 707                  (kill-buffer buffer)
 708                  (setcdr handle (cdr children))
 709                  (setcar handle (car children)) ;; "multipart/mixed"
 710                  (dolist (elem (cdr children))
 711                    (mm-uu-dissect-text-parts elem decoded))))))
 712           (t
 713            (dolist (elem handle)
 714              (mm-uu-dissect-text-parts elem decoded))))))
 715
 716 (provide 'mm-uu)
 717
 718 ;; arch-tag: 7db076bf-53db-4320-aa19-ca76a1d2ab2c
 719 ;;; mm-uu.el ends here